Нахождение уникальных наборов строк таблицы запросом
Дано
У нас есть таблица с ключевой колонкой "ИД", значения которой определяют наборы связанных строк, и колонкой "Значение", в которой хранятся реквизиты строк набора. Дубли строк в таблице отсутствуют.
Пример таблицы входных данных:
| ИД | Значение |
| П1 | А |
| П1 | Б |
| П1 | В |
| П2 | А |
| П2 | В |
| П2 | Б |
| П3 | Б |
| П3 | В |
| П4 | А |
| П4 | В |
| П4 | Б |
| П5 | А |
| П5 | В |
| П5 | Г |
ВЫБРАТЬ
"П1" КАК ИД,
"А" КАК Значение
ПОМЕСТИТЬ ВходныеДанные
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"А" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"А" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П5" КАК ИД,
"А" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П5" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П5" КАК ИД,
"Г" КАК Значение
Найти
Нужно получить таблицу, состоящую из уникальных наборов строк, т.е. в ней должны быть удалены все дубли наборов строк.
В нашем примере наборы строк с ключами П1, П2, П4 являются дублями. Поэтому из них должен остаться лишь один набор, т.е. 3 строки с единым ключом П1 или П2 или П4.
Решение 1 (общее)
Сначала рассмотрим наиболее универсальное решение
1. Считаем количество строк в каждом наборе
2. Находим все пары наборов, являющихся дублями по составу
3. Назначаем каждому набору минимальный ключ среди всех его дублей
4. Выводим только наборы, имеющие минимальный ключ в своей группе дублей
Запишем это в виде запроса 1С, принимающего на вход созданную выше временную таблицу ВходныеДанные:
//{Запрос: 1, -4 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
КОЛИЧЕСТВО(*) КАК Число
ПОМЕСТИТЬ ЧислоЧленовВНаборе
ИЗ
ВходныеДанные КАК ВходныеДанные
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//{Запрос: 2, -3 ////////////////////////////////////////
ВЫБРАТЬ
ВходЛевое.ИД КАК ИДЛевое,
ВходПравое.ИД КАК ИДПравое
ПОМЕСТИТЬ ПарыДублейНаборов
ИЗ
ВходныеДанные КАК ВходЛевое
ЛЕВОЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходПравое
ЛЕВОЕ СОЕДИНЕНИЕ ЧислоЧленовВНаборе КАК ЧислоЧленовПравое
ПО ВходПравое.ИД = ЧислоЧленовПравое.ИД
ПО ИСТИНА
И ВходЛевое.Значение = ВходПравое.Значение
И ВходЛевое.ИД >= ВходПравое.ИД
ЛЕВОЕ СОЕДИНЕНИЕ ЧислоЧленовВНаборе КАК ЧислоЧленовЛевое
ПО ВходЛевое.ИД = ЧислоЧленовЛевое.ИД
ГДЕ ЧислоЧленовПравое.Число = ЧислоЧленовЛевое.Число
СГРУППИРОВАТЬ ПО
ВходЛевое.ИД,
ЧислоЧленовЛевое.Число,
ВходПравое.ИД
ИМЕЮЩИЕ КОЛИЧЕСТВО(ВходПравое.Значение) = ЧислоЧленовЛевое.Число
;
//{Запрос: 3, -2 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
МИНИМУМ(ПарыДублейНаборов.ИДПравое) КАК ИДГруппы
ПОМЕСТИТЬ НаборыСГруппами
ИЗ
ВходныеДанные КАК ВходныеДанные
ЛЕВОЕ СОЕДИНЕНИЕ ПарыДублейНаборов КАК ПарыДублейНаборов
ПО ВходныеДанные.ИД = ПарыДублейНаборов.ИДЛевое
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//{Запрос: 4, -1 ////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
ВходныеДанные.*
ИЗ
НаборыСГруппами КАК НаборыСГруппами
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходныеДанные
ПО ВходныеДанные.ИД = НаборыСГруппами.ИДГруппы
Решение 2 (свертка)
Теперь рассмотрим решение для частного случая, когда у нас различных значений каждого реквизита во всей таблице не более 100 (выше будет арифметическое переполнение).
1. Найдем и пронумеруем различные значения реквизита функцией АВТОНОМЕРЗАПИСИ(), добавленной в платформе 8.3.13
2. Посчитаем свертку для каждого набора формулой Сумма(2^<Номер значения реквизита>). Такая свертка имеет нулевую вероятность коллизий, поэтому решение будет строгим.
3. Найдем каждому результату свертки (группе дублей) минимальный ключ среди всех его наборов
4. Выводим только наборы, имеющие минимальный ключ в своей группе дублей
Это решение намного быстрее общего решения, если количество строк в таблице велико.
Запишем это в виде запроса 1С, принимающего на вход созданную выше временную таблицу ВходныеДанные:
//{Запрос: 1, -5 ////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
ВходныеДанные.Значение КАК Значение,
АВТОНОМЕРЗАПИСИ() КАК НомерПП
ПОМЕСТИТЬ УникальныеЗначения
ИЗ
ВходныеДанные КАК ВходныеДанные
;
//{Запрос: 2, -4 ////////////////////////////////////////
ВЫБРАТЬ
МИНИМУМ(УникальныеЗначения.НомерПП) КАК Номер
ПОМЕСТИТЬ МинимальныйНомер
ИЗ
УникальныеЗначения КАК УникальныеЗначения
;
//{Запрос: 3, -3 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
СУММА(POW(2, УникальныеЗначения.НомерПП - МинимальныйНомер.Номер)) КАК СверткаГруппы
ПОМЕСТИТЬ Свертки
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ УникальныеЗначения КАК УникальныеЗначения
ПО ВходныеДанные.Значение = УникальныеЗначения.Значение,
МинимальныйНомер КАК МинимальныйНомер
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//{Запрос: 4, -2 ////////////////////////////////////////
ВЫБРАТЬ
МИНИМУМ(Свертки.ИД) КАК ИД
ПОМЕСТИТЬ ГруппыДублейНаборов
ИЗ
Свертки КАК Свертки
СГРУППИРОВАТЬ ПО
Свертки.СверткаГруппы
;
//{Запрос: 5, -1 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ГруппыДублейНаборов КАК ИскомыеГруппы
ПО ВходныеДанные.ИД = ИскомыеГруппы.ИД
Решение 3 (хеширование)
Теперь рассмотрим очень похожее на №2 решение без ограничения на число различных значений реквизитов, но нестрогое с очень низкой вероятностью получения некорректного результата.
1. Найдем и пронумеруем различные значения реквизита функцией АВТОНОМЕРЗАПИСИ(), добавленной в платформе 8.3.13
2. Посчитаем хеш-функцию для каждого набора формулой Сумма(COS(<Номер значения реквизита>)). Такая формула имеет максимальную вероятность коллизии 10^-9, что обосновано ildarovich в комментарии. Функция COS() добавлена в платформе 8.3.20
3. Найдем каждому хешу (группе дублей) минимальный ключ среди всех его наборов
4. Выводим только наборы, имеющие минимальный ключ в своей группе дублей
Это решение намного быстрее общего решения, если количество строк в таблице велико.
Запишем это в виде запроса 1С, принимающего на вход созданную выше временную таблицу ВходныеДанные:
//{Запрос: 1, -4 ////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
ВходныеДанные.Значение КАК Значение,
АВТОНОМЕРЗАПИСИ() КАК НомерПП
ПОМЕСТИТЬ УникальныеЗначения
ИЗ
ВходныеДанные КАК ВходныеДанные
;
//{Запрос: 2, -3 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
СУММА(COS(УникальныеЗначения.НомерПП)) КАК Хеш
ПОМЕСТИТЬ Хеши
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ УникальныеЗначения КАК УникальныеЗначения
ПО ВходныеДанные.Значение = УникальныеЗначения.Значение
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//{Запрос: 3, -2 ////////////////////////////////////////
ВЫБРАТЬ
МИНИМУМ(Свертки.ИД) КАК ИД
ПОМЕСТИТЬ ГруппыДублейНаборов
ИЗ
Хеши КАК Свертки
СГРУППИРОВАТЬ ПО
Свертки.Хеш
;
//{Запрос: 4, -1 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ГруппыДублейНаборов КАК ИскомыеГруппы
ПО ВходныеДанные.ИД = ИскомыеГруппы.ИД
Результат
| ИД | Значение |
| П1 | А |
| П1 | Б |
| П1 | В |
| П3 | Б |
| П3 | В |
| П5 | А |
| П5 | В |
| П5 | Г |
Вступайте в нашу телеграмм-группу Инфостарт
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
Инструментарий разработчика Роли и права Запросы СКД Разработчик Руководитель проекта 1С:Предприятие 8 Платные (руб)
Инструменты для разработчиков 1С 8.3 и 8.5: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.
16500 руб.
02.09.2020 286674 1611 423
Кадровый учет Интеграция Запросы Журналы и реестры данных 1С:Предприятие 8 1C:Бухгалтерия 1С:Зарплата и Управление Персоналом 2.5 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 1C:ERP Россия Управленческий учет Платные (руб)
Готовое решение для автоматизации проверки сотрудников, кандидатов и контрагентов по государственным реестрам и официальным источникам прямо из интерфейса 1С. Сократите время на ручные проверки, минимизируйте риски и храните результаты в единой информационной системе.
18300 руб.
17.06.2026 952 2 0
Инструментарий разработчика Запросы Разработчик 1С 8.3 1С:Бухгалтерия 3.0 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)
Структура запроса. Обработка визуально показывает, из какого количества подзапросов состоит запрос.
2 стартмани
06.07.2026 5035 65 XSlava 20
Запросы Разработчик 1С 8.3 Россия Бесплатно (free)
Визуальный «Конструктор запроса» 1С, встроенный прямо в VS Code, — аналог конструктора из Конфигуратора и EDT, но без запуска платформы. Расширение читает конфигурацию, выгруженную в файлы, позволяет собрать запрос мышью и генерирует корректный текст на языке запросов 1С (SDBL). Открывает уже существующий текст запроса из кода для правки и — что особенно ценно — сохраняет комментарии при цикле «открыть - править - сохранить». Подходит тем, кто пишет код 1С в VS Code, держит под рукой множество проектов и не хочет ради одного запроса запускать тяжёлый Конфигуратор или EDT.
26.06.2026 10760 Alex_YAM 7
Нейросети Инструментарий разработчика Запросы Разработчик 1С:Предприятие 8 Абонемент ($m)
Консоль запросов 1.0: добавлен ИИ-помощник (запрос в DeepSeek), который помогает быстрее получать каркас Запроса 1С Сформулируйте простое описание; нажмите кнопку – получите результат прямо в консоли. Где дальше его можно дорабатывать и тестировать. 28.5.2026 Добавил "Консоль запросов 2.0" (запрос в DeepSeek + Claude) 4.10.2026 Обновил "Консоль запросов 2.0"
3 стартмани
20.05.2026 9673 46 German4739 72
WEB-интеграция Запросы Разработчик 1С 8.3 Абонемент ($m)
Post1C - это внешняя обработка, которая превращает 1С в полноценный инструмент для тестирования REST API. Всё управление сосредоточено в одном окне: настройка запроса, выполнение, просмотр ответа и генерация кода - без переключения между формами. Аналог Postman, но работающий в привычной среде 1С.
1 стартмани
02.04.2026 4828 106 priem_nv 28
Запросы Механизмы типовых конфигураций Разработчик 1С:Предприятие 8 1С:Управление торговлей 11 Россия Бесплатно (free)
Предлагается обзор работы с объектной моделью запроса по схемам запросов типовым функционалом УТ 11.5.
09.10.2025 13490 aximo 18
Инструментарий разработчика Запросы Разработчик 1С:Предприятие 8 1С:Зарплата и кадры государственного учреждения 3 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)
QueryConsole1C — расширение, включающее консоль запросов с поддержкой исполняемых представлений — аналогов виртуальных таблиц, основанных на методах программного интерфейса ЗУП. Оно позволяет выполнять запросы с учётом встроенной бизнес-логики, отлаживать алгоритмы получения данных и автоматически генерировать код на встроенном языке 1С.
1 стартмани
16.05.2025 13761 168 zup_dev 32
ИМЕЮЩИЕ СУММА(ВЫБОР
КОГДА ВходПравое.Значение ЕСТЬ NULL
ТОГДА 0
ИНАЧЕ 1
КОНЕЦ) = ЧислоЧленовЛевое.ЧислоИМЕЮЩИЕ КОЛИЧЕСТВО(ВходПравое.Значение) = ЧислоЧленовЛевое.ЧислоЧукча не читатель, но что-то Сергей тут намудрил.
1) находим уникальные значения;
2) определяем хеши для групп;
3) получаем неповторяющиеся группы;
4) получаем данные
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
ВходныеДанные.Значение КАК Значение,
АВТОНОМЕРЗАПИСИ() КАК НомерПП
ПОМЕСТИТЬ УникальныеЗначения
ИЗ
ВходныеДанные КАК ВходныеДанные
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
СУММА(SQRT(УникальныеЗначения.НомерПП)) КАК ХешГруппы
ПОМЕСТИТЬ Хеши
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ УникальныеЗначения КАК УникальныеЗначения
ПО ВходныеДанные.Значение = УникальныеЗначения.Значение
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
МИНИМУМ(Хеши.ИД) КАК ИД
ПОМЕСТИТЬ ИскомыеГруппы
ИЗ
Хеши КАК Хеши
СГРУППИРОВАТЬ ПО
Хеши.ХешГруппы
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИскомыеГруппы КАК ИскомыеГруппы
ПО ВходныеДанные.ИД = ИскомыеГруппы.ИД ПоказатьПравда, опирается на новые возможности платформы. Если их не использовать, можно посмотреть решение из статьи . Там были примеры для решения подобных задач.
Отличный метод расчета хэш. Не видел такого раньше. Интересно, какова вероятность коллизий?
А метод, приведенный в статье, будет "подвисать" на больших таблицах (больше тысячи строк).
PS: Сергей, всё ещё жду новых статей! 1с безгранична!
посмотрел снова условие Дано и Найти - выделил для себя ряд условий, затем в голове разбил на другие группы, и снова не понял, почему П4-В не подходит. Затем прочитал решение - оказывается ты ищешь минимальное Айди, хотя в Условиях этого не было.
Решил что это ваше допущение, сравнил Результат - и только потом увидел в своей голове Условие задачи.
Сразу подумал, что узкоспециализированная задача - задал вопрос про группы (множества) (А, А, А) - посмотрел запрос - увидел что запрос с подобными группами не справится.
Решил дождаться уточнений по задаче. По ходу дела - читал комменты - собирал пазл - добавил свой коммент.
Достаточно сложно передать условие задачи, когда оно абстрактно.
Без примеров.
Обычно примеры добавляют - было такое множество - стало такое в Результате. Требуется написать алгоритм (запрос).
У вас же ответ стал для меня неким маяком - о чем же просит автор задачи.
"А метод, приведенный в статье, будет "подвисать" на больших таблицах (больше тысячи строк)."
А это большого стоит)
Иначе в одну группу попадут разные наборы с номерами по порядку и это только в пределах 100: (1, 4) и (9);(1, 9) и (16); (1, 16) и (25); (1, 25) и (36); (1, 36) и (49); (1, 49) и (64); (1, 64) и (81); (1, 81) и (100); (4, 9) и (25); (4, 16) и (36); (4, 25) и (49); (4, 36) и (64); (4, 49) и (81); (4, 64) и (100); (9, 25) и (64); (9, 36) и (81); (9, 49) и (100); (16, 25) и (81); (16, 36) и (100); ... (1, 81) и (4, 64) и (9, 49) и (16, 36); (1, 64) и (4, 49) и (16, 25);...
Не знаю, что там со случаями, когда корни не целые. Но эти очевидные коллизии настораживают. Сейчас есть и другие функции в запросах.
В общем, вопрос нужно еще исследовать...
SQRT(НомерПП) + LOG10(НомерПП) - тогда результат почти всегда будет иррациональным. Тогда вряд ли будут коллизии, но моя математическая подушка, к сожалению, не позволяет мне найти доказательство для этого.
(6)
Подумал, что идеальным решением будет просто SQRT(НомерПП + SQRT(2)) - результат всегда иррациональный. В интернете при быстром поиске на нашел подтверждения, что могут существовать суммы иррациональных чисел, которые равны для разных наборов исходных слагаемых на положительной полуоси. Этот метод работает быстро и не упрется в переполнение даже для миллионов уникальных значений, в отличии от функции возведения в степень.
Для небольшого числа уникальных значений (до 100 в СУБД MSSQL) гарантирует отсутствие коллизий формула
СУММА(Pow(2, УникальныеЗначения.НомерПП))Аналогичный ответ дают и сами разработчики платформы.
Мой вариант из другого комментария справился.
ВЫБРАТЬ 1 КАК ИД, "A" КАК Значение
ПОМЕСТИТЬ ТЗ
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 5 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 6 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "D" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
Показать
ВЫБРАТЬ
"П1" КАК ИД,
"А" КАК Значение
ПОМЕСТИТЬ ВходныеДанные
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1",
"Б"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1",
"В"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2",
"А"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2",
"В"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2",
"Б"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3",
"Б"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3",
"В"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4",
"А"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4",
"В"
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4",
"Б"
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Т.ИД КАК ИД,
КОЛИЧЕСТВО(*) КАК КолВо
ПОМЕСТИТЬ ВтИтоги
ИЗ
ВходныеДанные КАК Т
СГРУППИРОВАТЬ ПО
Т.ИД
ИНДЕКСИРОВАТЬ ПО
Т.ИД
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Т.ИД КАК ИД,
Т.Значение КАК Значение,
ТИтоги.КолВо КАК КолВо
ПОМЕСТИТЬ ВтСвязь
ИЗ
ВходныеДанные КАК Т
ЛЕВОЕ СОЕДИНЕНИЕ ВтИтоги КАК ТИтоги
ПО Т.ИД = ТИтоги.ИД
ГДЕ
ТИтоги.ИД ЕСТЬ НЕ NULL
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Т1.ИД КАК ИДЛевое,
ОставляемСтроки.ИД КАК ИДПравое
ПОМЕСТИТЬ ПарыДублейНаборов
ИЗ
ВтСвязь КАК Т1
ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
МИНИМУМ(Т2.ИД) КАК ИД,
Т2.Значение КАК Значение,
Т2.КолВо КАК КолВо
ИЗ
ВтСвязь КАК Т2
СГРУППИРОВАТЬ ПО
Т2.Значение,
Т2.КолВо) КАК ОставляемСтроки
ПО Т1.Значение = ОставляемСтроки.Значение
И Т1.КолВо = ОставляемСтроки.КолВо
ГДЕ
Т1.ИД <> ОставляемСтроки.ИД
СГРУППИРОВАТЬ ПО
Т1.ИД,
Т1.КолВо,
ОставляемСтроки.ИД
ИМЕЮЩИЕ
КОЛИЧЕСТВО(Т1.Значение) = Т1.КолВо
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ГДЕ
НЕ ИСТИНА В
(ВЫБРАТЬ ПЕРВЫЕ 1
ИСТИНА
ИЗ
ПарыДублейНаборов КАК Т
ГДЕ
ВходныеДанные.ИД = Т.ИДЛевое) Показать1. Поиск и исправление некорректных движений документов
2. Распределение одинаковых наборов строк по группам. В моем случае понадобилось растащить права пользователей на группы пользователей из самописного регистра, где каждому пользователю были выделены конкретные права, которые часто пересекались с такие же правами у других пользователей.
Про исправление движений документов? Ну в ERP частенько встречается, когда из-за левых соединение с дублями ключей аналитик или реестра документов движения и проводки задваиваются/зачетверяются и т.д.
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
КОЛИЧЕСТВО(*) КАК Число
ПОМЕСТИТЬ ЧислоЧленовВНаборе
ИЗ
ВходныеДанные КАК ВходныеДанные
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
ВЫБРАТЬ
ВходныеДанные.*,
ЧислоЧленовВНаборе.Число КАК ЧислоВНаборе
ПОМЕСТИТЬ ВходныеДанныеСЧислом
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ
ЧислоЧленовВНаборе КАК ЧислоЧленовВНаборе
ПО
ВходныеДанные.ИД = ЧислоЧленовВНаборе.ИД
;
ВЫБРАТЬ
Вход1.Ид
ПОМЕСТИТЬ Дубли
ИЗ
ВходныеДанныеСЧислом КАК Вход1
ЛЕВОЕ СОЕДИНЕНИЕ
ВходныеДанныеСЧислом КАК Вход2
ПО
Вход1.ИД > Вход2.ИД
И Вход1.ЧислоВНаборе = Вход2.ЧислоВНаборе
И Вход1.Значение = Вход2.Значение
СГРУППИРОВАТЬ ПО
Вход1.Ид,
Вход2.Ид
ИМЕЮЩИЕ
КОЛИЧЕСТВО(Вход1.Значение) = КОЛИЧЕСТВО(Вход2.Значение)
;
ВЫБРАТЬ
ВходныеДанные.*
ИЗ
ВходныеДанные КАК ВходныеДанные
ГДЕ
НЕ Ид В(ВЫБРАТЬ Дубли.Ид Из Дубли)
ПоказатьВЫБРАТЬ
"П1" КАК ИД,
"А" КАК Значение
ПОМЕСТИТЬ ВходныеДанные
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П1" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"А" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П2" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3" КАК ИД,
"Б" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П3" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"А" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"В" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
"П4" КАК ИД,
"Г" КАК Значение ПоказатьРасширил пример в статье, чтобы предупредить подобные ошибки.
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
КОЛИЧЕСТВО(*) КАК Число
ПОМЕСТИТЬ ЧислоЧленовВНаборе
ИЗ
ВходныеДанные КАК ВходныеДанные
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
ВЫБРАТЬ
ВходныеДанные.*,
ЧислоЧленовВНаборе.Число КАК ЧислоВНаборе
ПОМЕСТИТЬ ВходныеДанныеСЧислом
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ
ЧислоЧленовВНаборе КАК ЧислоЧленовВНаборе
ПО
ВходныеДанные.ИД = ЧислоЧленовВНаборе.ИД
;
ВЫБРАТЬ
Вход1.Ид
ПОМЕСТИТЬ Дубли
ИЗ
ВходныеДанныеСЧислом КАК Вход1
ЛЕВОЕ СОЕДИНЕНИЕ
ВходныеДанныеСЧислом КАК Вход2
ПО
Вход1.ИД > Вход2.ИД
И Вход1.ЧислоВНаборе = Вход2.ЧислоВНаборе
И Вход1.Значение = Вход2.Значение
СГРУППИРОВАТЬ ПО
Вход1.Ид,
Вход1.ЧислоВНаборе,
Вход2.Ид
ИМЕЮЩИЕ
Вход1.ЧислоВНаборе = КОЛИЧЕСТВО(Вход2.Значение)
;
ВЫБРАТЬ
ВходныеДанные.*
ИЗ
ВходныеДанные КАК ВходныеДанные
ГДЕ
НЕ Ид В(ВЫБРАТЬ Дубли.Ид Из Дубли)
ПоказатьТогда как у запроса из (6) зависимость линейная. Все запросы (6) должны в секунду укладываться.
Есть разница? - Заставлять пользователя ждать пятьдесят минут ради задачи, которая решается за секунду?
СУММА(Pow(2, УникальныеЗначения.НомерПП) - 8)то можно вытянуть еще штук 25 значений )). Получится 125.
Но строго говоря, это не хэш. Это битовая строка - уникальный идентификатор. Хороший пример ее применения. Но не для этой задачи. Здесь, по моему мнению, нужна проверенная хэш-функция. Чуть позже постараюсь обосновать. Вопрос интересный, дискуссионный.
Пока просьба над моим вопросом подумать.
Он в следующем посте.
Начну издалека.
По моему представлению, сам собой напрашивается комбинированный способ решения обсуждаемой в статье задачи:
На первом этапе применяется запрос типа (6) с "правильной" хэш-функцией.
На втором этапе найденные совпадения перепроверяются запросом типа первого из статьи.
Теперь предположим, что правильная хэш-функция дает вероятность коллизий 10^(-38).
То есть работает как MD5.
Это значит, что если все время жизни Вселенной (4,35*10^17 сек) каждую секунду выполнять запрос к таблице из миллиона наборов строк,
то только в одной из квадриллиона (10^15) параллельных вселенных один раз может появиться коллизия.
То есть весь код запроса второго этапа всегда будет работать зря!
Так вот, вопрос: готовы ли вы выкинуть этот код за его ненадобностью или нет?
А если упростить хэш-функцию до CRC32 с вероятностью коллизий 2^(-32)?
То есть где провести границу? - Какую вероятность коллизий можно посчитать достаточной ("исчезающе малой")?
В хорошей хэш-функции требуется тщательно перемешивание битов входных аргументов. Сгодилось бы и CRC128 (если потребовать 2^(-128)).
Хорошо, берем за основу.
Итак, перепробовав разные подходы (в том числе, расчет CRC32 в запросе), я пришел к очень простому заключительному выводу: для расчета хэш-функции в запросе на основе нумерации строк лучше всего подойдет функция
СУММА(SIN(НомерПП)),либо функция
СУММА(COS(НомерПП)).Любопытно, что это преобразование, фактически, является расчетом одного из коэффициентов ДПФ. То есть у него есть логическая основа.
Чтобы убедиться, что функция подходит, нужно рассчитать вероятность коллизий и убедиться, что она меньше заданной.
Для этого используем центральную предельную теорему теории вероятностей, которая говорит, что
Это как раз наш случай.
То есть значение ХЭШ функции СУММА(SIN(НомерПП)) как случайная величина будет иметь нормальное распределение.
Математическое ожидание µ случайной величины СУММА(SIN(НомерПП)) будет равно нулю. И, исходя из формы графика плотности распределения вероятности (перевернутый колокол), ноль будет самым частым значением ХЭШ функции. Дисперсия σ^2 итогового распределения будет равна сумме дисперсий исходных распределений.
Дисперсия σ^2 случайной величины SIN(X) равна 0.5.
Потому, что рассчитывается как СРЕДНЕЕ(sin^2(x)) и известно, что СРЕДНЕЕ(sin^2(x)) = СРЕДНЕЕ(cos^2(x)) и sin^2(x) + cos^2(x) = 1.
Значит, дисперсия σ^2 случайной величины СУММА(SIN(НомерПП)) будет равна 0.5 N, а среднее квадратичное отклонение σ равно √(0.5 N), где N - число членов суммы.
Проверка показала, что значение СУММА(SIN(НомерПП)) считается в запросе с точностью девяти десятичных знаков.
Также у нас есть функция ошибок Гаусса erf(x), которая позволяет рассчитать вероятность того, что значение суммы будет отклоняться от математического ожидания (нуля) на вес младшего разряда ε = 10^(-9). А это и есть удвоенная вероятность того, что ХЭШ функция будет принимать значение ноль с точностью девяти десятичных знаков.
Таким образом, максимальная вероятность коллизий будет равна
0.5 erf (ε / (σ * √2 ) ).
Есть разложение
erf(x) = ( 2 / √π ) ( x - x^3 / 3 + x^5 / 10 - ... ).
Учитывая, что x в нашем случае x очень мало, формулу можно предельно упростить, оставив только первое слагаемое.
В итоге максимальная вероятность коллизий окажется равной
ε / ( √(0.5 N) * √(2 π)) = ε / √( π N) = 10^(-9) / √( π N),
и, значит, укладывается в заданные пределы. А в среднем будет еще меньше.
Мы не можем взаимно однозначно отобразить множество разных сочетаний значений в группе, которых 2^(max(НомерПП)) и диапазон значений агрегатной функции 10^38.
А вообще формулы
SUM(SQRT(НомерПП)) SUM(SQRT(НомерПП)) + SUM(LOG10(НомерПП))по зрелому размышлению, недостаточно эффективны (кстати, в последней формуле лучше тогда не суммировать, а отдельно считать ХЭШ1 и ХЭШ2).
Так как не используют весь диапазон возможных значений ХЭШ [0, 10^38] (упрощенно). А также не дают равную "плотность" этого отображения (которая определяет вероятность коллизии).
Так что лучше пользоваться проверенными преобразованиями типа приведенных в той , на которую я уже ссылался. Но можно изобрести что-то новое на базе появившихся функций. Минимальную вероятность коллизий (минимальную максимальную вероятность) обеспечит равномерное отображение на весь диапазон возможных значений ХЭШ.
(6)
Согласен, что вероятность коллизий <> 0
Тогда 2-ю и 3-ю ВТ можно переписать подобным образом:
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
СУММА(SIN(УникальныеЗначения.НомерПП)) КАК ХешГруппы1,
СУММА(COS(УникальныеЗначения.НомерПП)) КАК ХешГруппы2,
СУММА(LOG(УникальныеЗначения.НомерПП)) КАК ХешГруппы3,
СУММА(LOG10(УникальныеЗначения.НомерПП)) КАК ХешГруппы4,
СУММА(EXP(УникальныеЗначения.НомерПП)) КАК ХешГруппы5,
// ...
СУММА(SQRT(УникальныеЗначения.НомерПП)) КАК ХешГруппыN
ПОМЕСТИТЬ Хеши
ИЗ
ВходныеДанные КАК ВходныеДанные
ВНУТРЕННЕЕ СОЕДИНЕНИЕ УникальныеЗначения КАК УникальныеЗначения
ПО ВходныеДанные.Значение = УникальныеЗначения.Значение
СГРУППИРОВАТЬ ПО
ВходныеДанные.ИД
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
МИНИМУМ(Хеши.ИД) КАК ИД
ПОМЕСТИТЬ ИскомыеГруппы
ИЗ
Хеши КАК Хеши
СГРУППИРОВАТЬ ПО
Хеши.ХешГруппы1,
Хеши.ХешГруппы2,
Хеши.ХешГруппы3,
Хеши.ХешГруппы4,
Хеши.ХешГруппы5,
// ...
Хеши.ХешГруппыN
; Показатьгде вместо многоточий можно вставить ещё большое кол-во функций в их разном сочетании. По моему предположению, вероятность коллизий будет стремиться к 0. Это можно применять даже на боевых базах - если и случится ошибка, то, условно, раз в 100 лет. Пользователи при работе с базой чаще ошибаются, т.е. человеческий фактор создаст больше проблем, чем очень редкая коллизия.
ВЫБРАТЬ 1 КАК ИД, "A" КАК Значение
ПОМЕСТИТЬ ТЗ
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 5 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 6 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "D" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
;
ВЫБРАТЬ
Т.ИД КАК ИД,
КОЛИЧЕСТВО(*) КАК КолВо,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Т.Значение) КАК КолВоРазличных
ПОМЕСТИТЬ ВтИтоги
ИЗ
ВходныеДанные КАК Т
СГРУППИРОВАТЬ ПО
Т.ИД
ИНДЕКСИРОВАТЬ ПО
Т.ИД
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Т.ИД КАК ИД,
Т.Значение КАК Значение,
ТИтоги.КолВо КАК КолВо,
ТИтоги.КолВоРазличных КАК КолВоРазличных
ПОМЕСТИТЬ ВтСвязь
ИЗ
ВходныеДанные КАК Т
ЛЕВОЕ СОЕДИНЕНИЕ ВтИтоги КАК ТИтоги
ПО Т.ИД = ТИтоги.ИД
ГДЕ
ТИтоги.ИД ЕСТЬ НЕ NULL
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Т1.ИД КАК ИДЛевое,
ОставляемСтроки.ИД КАК ИДПравое,
ОставляемСтроки.КолВо,
ОставляемСтроки.КолВоРазличных
ПОМЕСТИТЬ ПарыДублейНаборов
ИЗ
ВтСвязь КАК Т1
ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
МИНИМУМ(Т2.ИД) КАК ИД,
Т2.Значение КАК Значение,
Т2.КолВо КАК КолВо,
Т2.КолВоРазличных КАК КолВоРазличных
ИЗ
ВтСвязь КАК Т2
СГРУППИРОВАТЬ ПО
Т2.Значение,
Т2.КолВо,
Т2.КолВоРазличных) КАК ОставляемСтроки
ПО Т1.Значение = ОставляемСтроки.Значение
И Т1.КолВо = ОставляемСтроки.КолВо
И Т1.КолВоРазличных = ОставляемСтроки.КолВоРазличных
ГДЕ
Т1.ИД <> ОставляемСтроки.ИД
СГРУППИРОВАТЬ ПО
Т1.ИД,
Т1.КолВо,
ОставляемСтроки.ИД,
ОставляемСтроки.КолВо,
ОставляемСтроки.КолВоРазличных
ИМЕЮЩИЕ
КОЛИЧЕСТВО(Т1.Значение) = ОставляемСтроки.КолВо
И КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Т1.Значение) = ОставляемСтроки.КолВоРазличных
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ГДЕ
НЕ ИСТИНА В
(ВЫБРАТЬ ПЕРВЫЕ 1
ИСТИНА
ИЗ
ПарыДублейНаборов КАК Т
ГДЕ
ВходныеДанные.ИД = Т.ИДЛевое)
ПоказатьТак в целом ага, сама сколько раз такое решала разнообразно ) кстати, про автономерзаписи надо будет не забывать, спасибо за напоминание
ВЫБРАТЬ 1 КАК ИД, "A" КАК Значение
ПОМЕСТИТЬ ВходныеДанные
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 1 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 2 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 3 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 4 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 5 КАК ИД, "C" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 6 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "B" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 7 КАК ИД, "D" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 8 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 9 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 10 КАК ИД, "A" КАК Значение
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ 10 КАК ИД, "A" КАК Значение;
//{Запрос: 1, -5 ////////////////////////////////////////
ВЫБРАТЬ
Т.ИД КАК ИД,
КОЛИЧЕСТВО(1) КАК КолВо,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Т.Значение) КАК КолВоРазличных
ПОМЕСТИТЬ ВтИтоги
ИЗ
ВходныеДанные КАК Т
СГРУППИРОВАТЬ ПО
Т.ИД
ИНДЕКСИРОВАТЬ ПО
Т.ИД
;
//{Запрос: 2, -4 ////////////////////////////////////////
ВЫБРАТЬ
Т.ИД КАК ИД,
Т.Значение КАК Значение,
ТИтоги.КолВо КАК КолВо,
ТИтоги.КолВоРазличных КАК КолВоРазличных
ПОМЕСТИТЬ ВтСвязь
ИЗ
ВходныеДанные КАК Т
ЛЕВОЕ СОЕДИНЕНИЕ ВтИтоги КАК ТИтоги
ПО Т.ИД = ТИтоги.ИД
ГДЕ ТИтоги.ИД ЕСТЬ НЕ NULL
;
//{Запрос: 3, -3 ////////////////////////////////////////
ВЫБРАТЬ
Т.ИДЛевое КАК ИДЛевое,
Т.ИДПравое КАК ИДПравое,
Т.Значение КАК Значение,
Т.КолВо КАК КолВо,
Т.КолВоРазличных КАК КолВоРазличных,
Т.Контроль КАК Контроль
ПОМЕСТИТЬ ВтДанные
ИЗ
(ВЫБРАТЬ
Т1.ИД КАК ИДЛевое,
NULL КАК ИДПравое,
Т1.Значение КАК Значение,
Т1.КолВо КАК КолВо,
Т1.КолВоРазличных КАК КолВоРазличных,
1 КАК Контроль
ИЗ
ВтСвязь КАК Т1
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
NULL КАК ИДЛевое,
МИНИМУМ(Т2.ИД) КАК ИДПравое,
Т2.Значение КАК Значение,
Т2.КолВо КАК КолВо,
Т2.КолВоРазличных КАК КолВоРазличных,
- 1 КАК Контроль
ИЗ
ВтСвязь КАК Т2
СГРУППИРОВАТЬ ПО
Т2.Значение,
Т2.КолВо,
Т2.КолВоРазличных) КАК Т
;
//{Запрос: 4, -2 ////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
МАКСИМУМ(Т.ИДЛевое) КАК ИДЛевое,
МИНИМУМ(Т.ИДПравое) КАК ИДПравое
ПОМЕСТИТЬ ПарыДублейНаборов
ИЗ
ВтДанные КАК Т
ГДЕ НЕ (ИСТИНА В (
ВЫБРАТЬ ПЕРВЫЕ 1
ИСТИНА КАК Поле1
ИЗ
ВтДанные КАК Т2
ГДЕ Т.ИДЛевое = Т2.ИДПравое))
СГРУППИРОВАТЬ ПО
Т.Значение,
Т.КолВо,
Т.КолВоРазличных
ИМЕЮЩИЕ Т.КолВо - Т.КолВоРазличных = СУММА(Т.Контроль)
;
//{Запрос: 5, -1 ////////////////////////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ВходныеДанные КАК ВходныеДанные
ГДЕ НЕ (ИСТИНА В (
ВЫБРАТЬ ПЕРВЫЕ 1
ИСТИНА КАК Поле1
ИЗ
ПарыДублейНаборов КАК Т
ГДЕ ВходныеДанные.ИД = Т.ИДЛевое))
ПоказатьИ проблема тут не только в выборе функции. Кстати, косинус (или синус) от аргумента, задаваемого в радианах, кажется, подойдет еще лучше. Так как на области значений даст более равномерное покрытие.
Проблема в агрегатной функции СУММА. Сумма большого количества аргументов дает нормальное распределение. Это означает, что срединные значения ХЭШ-функции будут более вероятны, чем крайние. То есть разряды ХЭШ будут использоваться не с максимальной эффективностью.
Вообще, когда за вами гонятся, можно закидать преследователя всем чем под руку попадется. Это я о решении из (59). Оно "на скорую руку". Но если такой спешки нет, лучше подыскать что-то из области более бережливого программирования.
ВЫБРАТЬ
ВходныеДанные1.ИД КАК ИД1,
ВходныеДанные2.ИД КАК ИД2,
ВходныеДанные1.Значение КАК Значение
ПОМЕСТИТЬ Пересечения
ИЗ
ВходныеДанные КАК ВходныеДанные1
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходныеДанные2
ПО ВходныеДанные1.ИД <= ВходныеДанные2.ИД
И ВходныеДанные1.Значение = ВходныеДанные2.Значение
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
Пересечения.ИД1 КАК ИД1,
Пересечения.ИД2 КАК ИД2
ПОМЕСТИТЬ Пары
ИЗ
Пересечения КАК Пересечения
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Пары.ИД1 КАК ИД1,
Пары.ИД2 КАК ИД2,
ВходныеДанные.Значение КАК Значение,
1 КАК Сумматор
ПОМЕСТИТЬ Объединение
ИЗ
Пары КАК Пары
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходныеДанные
ПО Пары.ИД1 = ВходныеДанные.ИД
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
Пары.ИД1,
Пары.ИД2,
ВходныеДанные.Значение,
1
ИЗ
Пары КАК Пары
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходныеДанные
ПО Пары.ИД2 = ВходныеДанные.ИД
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
Пересечения.ИД1,
Пересечения.ИД2,
Пересечения.Значение,
-2
ИЗ
Пересечения КАК Пересечения
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
Объединение.ИД1 КАК ИД1,
Объединение.ИД2 КАК ИД2
ПОМЕСТИТЬ Отношения
ИЗ
Объединение КАК Объединение
СГРУППИРОВАТЬ ПО
Объединение.ИД1,
Объединение.ИД2
ИМЕЮЩИЕ
СУММА(Объединение.Сумматор) = 0
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
МИНИМУМ(Отношения.ИД1) КАК ИД1,
Отношения.ИД2 КАК ИД2
ПОМЕСТИТЬ Классы
ИЗ
Отношения КАК Отношения
СГРУППИРОВАТЬ ПО
Отношения.ИД2
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
Классы.ИД1 КАК ИД
ПОМЕСТИТЬ ПредставителиКлассов
ИЗ
Классы КАК Классы
;
//////////////////////////////////////////////////////////// ////////////////////
ВЫБРАТЬ
ВходныеДанные.ИД КАК ИД,
ВходныеДанные.Значение КАК Значение
ИЗ
ПредставителиКлассов КАК ПредставителиКлассов
ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВходныеДанные КАК ВходныеДанные
ПО ПредставителиКлассов.ИД = ВходныеДанные.ИД
ПоказатьВы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 1903939
Создание 23.07.23 23:30
Обновление 23.07.23 23:30
Просмотры 16206
Загрузки 0
Рейтинг
41
Комментарии 81
Код открыт Да
Рубрики Запросы
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация 1C:Бухгалтерия
Операционная система Не имеет значения
Страна Не имеет значения
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)