Методичка по работе с внешними обработками на УФ
(Заранее приношу свои извинения за размытые картинки, пытался побороть их, пока не получилось! на всякий случай всё продублирую текстом.)
В первую очередь ставится демо база на БСП.Открываем базу в пользовательском режиме,идем в справочник Дополнительные отчеты и обработки находим знак ? как на картинке ниже,открываем справку, в самом низу справки полностью копируем Функцию СведенияОВнешнейОбработке()
1. Создаем внешнюю обработку, добавляем в модуль объекта Функцию СведенияОВнешнейОбработке()
На всякий случай код прилагаю
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработки<...>();
ПараметрыРегистрации.Версия = "...";
///
Команда = ПараметрыРегистрации.Команды.Добавить();
Команда.Представление = НСтр("ru = '<Представление команды>'");
Команда.Идентификатор = "<Имя команды>";
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКоманды<...>();
Команда.ПоказыватьОповещение = <Истина/Ложь>;
Возврат ПараметрыРегистрации;
КонецФункции
Зде сь в функции сведения о внешней обработке уже определены ПараметрыРегистрации и Команды
И их нужно всего лишь заполнить в самой обработке
Кстати, таблица команд это по сути кнопки, которые будут располагаться на форме самой обработки
Вернемся во внешнюю обработку.
Заполним команды.
Команда.Представление = Команда представления это то, как будет видеть представление команды пользователь
Команда.Идентификатор = Это то, как будет видеть идентификатор программа.
Команда.ПоказыватьОповещение = Истина или Ложь будет показывать что команда в данный момент выполняется.
Перейдем к Команда.Использование = В общем модуле ДополнительныеОтчетыИОбработкиКлиентСервер располагаются функции с Именами типов команд,рассмотрим эти команды подробнее
Тип команды «Вызов Серверного метода», конечно же, предполагает то, что команда будет вызвана на сервере. Чаще всего такие команды нужны для выполнения регламентных обработчиков, которые будут выполниться и запускаться по расписанию.
Тип команды «Вызов клиентского метода» предполагает, что что-то должно произойти на клиенте, но не открытие формы самой обработки. Здесь на клиенте можно поработать, например с клиентскими методами Word например.
А вот тип команды «Открытие формы» позволяет открывать форму, которую мы определим в самой обработке, либо какую ни будь произвольную форму.
Тип команды «Загрузка данных из файла» доступен только в глобальных обработках (вид = «Дополнительная обработка») при наличии в конфигурации подсистемы «Загрузка данных из файла»
Теперь, когда определили ТипКоманды как на скриншоте выше, нам нужно определить обработчик этой команды
Для этого там же в модуле объекта добавляем экспортную процедуру
Процедура ВыполнитьКоманду(ИдентификаторКоманды,ПараметрыВыполненияКоманды) Экспорт
//// ИдентификаторКоманды у нас прописан в процедуре СведенияОВнешнейОбработке
Если ИдентификаторКоманды = "ФормированиеЛога" Тогда
////можно передовать разные идентификаторы команды и в соотв.с этим
///строить логику выполнения
КонецЕсли;
Если ИдентификаторКоманды = "Другой" Тогда
////можно передавать разные идентификаторы команды
КонецЕсли;
КонецПроцедуры
Кстати, если в функцию СведенияОВнешнейОбработке() добавить второй блок команд
То вторую команду мы увидим уже в пользовательском режиме в справочнике Внешние обработки и отчеты
Так как тип команды у нас серверный, в пользовательском режиме у нас появились часы, которые позволят нам настраивать в дальнейшем расписание.
Открытие формы обработки и передача данных с формы на сервер(в модуль обработки)
Иногда возникает необходимость программно открыть форму обработки, заполнить какие нибудь данные и далее передать эти данные для обработки в модуль самой обработки.
Для этого нам нужно в модуле обработки СведенияОВнешнейОбработке()
в Команда.Использование определить ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы()
Функция СведенияОВнешнейОбработке() Экспорт
////здесь определяются команды и.т.д.
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
КонецФункции
Для того, чтобы форма обработки открывалась, нужно создать форму и для примера добавить строковый реквизит, но ничего вам не мешает создать здесь таблицуЗначений или ссылку на справочник и т.д.
Продолжаем работать с возможностями обработки и сделаем 2 в 1, механизм сохранения и восстановления настроек и механизм передачи данных с формы обработки в модуль обработки.
Сперва посмотрим на справочник ДополнительныеОтчетыИОбработки, это справочник имеет реквизит Хранилище обработки, и ХранилищеНастроек.
Реквизит Хранилище обработки позволяет хранить саму внешнюю обработку, отчет, которая загружается в справочник.
Реквизит Хранилище настроек это те настройки, которые мы хотим передать при открытии этой самой обработки.
И то и другое имеет тип данных ХранилищеЗначений (не путать с временным хранилищем).
Тип ХранилищеЗначения доступен только на стороне сервера, туда можно записать всё, что сериализуется.
Вернемся в форму обработки, на закладке Параметры обработки добавим ДополнительнаяОбработкаСсылка с типом данных СправочникСсылка.ДополнительныеОтчетыИОбработки
Общая схема того, что мы собираемся реализовывать
В форме обработки реализуем механизм сохранения и восстановления настроек
&НаСервере
///---Здесь мы при открытии обработки по факту считываем данные из ХранилищеНастроек Справочника ДополнительныеОтчетыИОбработки
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
Если ЗначениеЗаполнено(Параметры.ДополнительнаяОбработкаСсылка) Тогда
ХранилищеНастроек = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Параметры.ДополнительнаяОбработкаСсылка,"ХранилищеНастроек");
НастройкиСтруктура = ХранилищеНастроек.Получить();
Если ТипЗнч(НастройкиСтруктура) = Тип("Структура") Тогда
Объект.Реквизит1 = НастройкиСтруктура.Реквизит1;
РеквизитФормы1 = НастройкиСтруктура.РеквизитФормы1;
КонецЕсли;
КонецЕсли;
КонецПроцедуры
прокоментируем процедуру ПриСозданииНаСервере()
Если мы в пользовательском режиме запустим обработку, то в модуле формы самой обработки автоматически будет заполнен Параметр Параметры.ДополнительнаяОбработкаСсылка, а заполнятся Параметры ссылкой на элемент справочника ДополнительныеОтчетыИОбработки, то есть на ссылку вашей обработки.
Ссылку мы получили, теперь нам нужно посмотреть, что хранится в реквизите ХранилищеНастроек
ХранилищеНастроек = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Параметры.ДополнительнаяОбработкаСсылка,"ХранилищеНастроек");
При первом открытии, конечно же, в Справочнике.ДополнительныеОтчетыИОбработки никаких данных не будет.
И чтобы не возникало ошибки, поставим проверку
НастройкиСтруктура = ХранилищеНастроек.Получить();
Если ТипЗнч(НастройкиСтруктура) = Тип("Структура") Тогда
Объект.Реквизит1 = НастройкиСтруктура.Реквизит1;
РеквизитФормы1 = НастройкиСтруктура.РеквизитФормы1;
КонецЕсли;
Произвольно заполним в пользовательском режиме на форме Реквизит1 и РеквизитФормы1
Теперь нам нужно где-то сохранить настройки формы, чтобы в следующий раз их открыть и заодно передать данные в модуль объекта
&НаСервере
Процедура ПриЗакрытииНаСервере()
///Получаем объект своей обработки из спр. ДополнительныеОтчетыИОбработки
ДополнительнаяОбработкаОбъект = Параметры.ДополнительнаяОбработкаСсылка.ПолучитьОбъект();
////--подготовим структуру с нашими реквизитами и данными
НастройкиСтруктура = Новый Структура;
НастройкиСтруктура.Вставить("Реквизит1",Объект.Реквизит1);
НастройкиСтруктура.Вставить("РеквизитФормы1",РеквизитФормы1);
/////И записываем в реквизит ХранилищеНастроек Объект.Реквизит1 и РеквизитФормы1
ДополнительнаяОбработкаОбъект.ХранилищеНастроек = Новый ХранилищеЗначения(НастройкиСтруктура);
ДополнительнаяОбработкаОбъект.Записать();
КонецПроцедуры
Данные переданные с формы обработки теперь хранятся в справочнике ДополнительныеОтчетыИОбработки в реквизите ХранилищеНастроек, принадлежащем нашей обработке.
После того как форма была закрыта, в модуле обработки автоматически запускается Процедура ВыполнитьКоманду()
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыВыполненияКоманды) Экспорт
ССылкаНаОбработку = ПараметрыВыполненияКоманды.ДополнительнаяОбработкаСсылка;
Если ЗначениеЗаполнено(ССылкаНаОбработку) Тогда
ХранилищеНастроек = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ССылкаНаОбработку,"ХранилищеНастроек");
НастройкиСтруктура = ХранилищеНастроек.Получить();
Если ТипЗнч(НастройкиСтруктура) = Тип("Структура") Тогда
Реквизит1 = НастройкиСтруктура.Реквизит1;
РеквизитФормы1 = НастройкиСтруктура.РеквизитФормы1;
Если ИдентификаторКоманды = "ФормированиеЛога" Тогда
ЗаписьЖурналаРегистрации(Реквизит1);
ИначеЕсли ИдентификаторКоманды = "ФормированиеЛога2" Тогда
ЗаписьЖурналаРегистрации(РеквизитФормы1);
КонецЕсли;
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Прокомментируем процедуру ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыВыполненияКоманды)
Здесь мы уже через ПараметрыВыполненияКоманды обращаемся к ДополнительнаяОбработкаСсылка, что прилетела к нам с формы обработки, проверяем, что она заполнена и с помощью метода БСП получаем ХранилищеНастроек
ХранилищеНастроек = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ССылкаНаОбработку,"ХранилищеНастроек");
НастройкиСтруктура = ХранилищеНастроек.Получить();
Получив структуру НастройкиСтруктура = ХранилищеНастроек.Получить(); обрабатываем её так как нужно.
Реквизит1 = НастройкиСтруктура.Реквизит1;
РеквизитФормы1 = НастройкиСтруктура.РеквизитФормы1;
Кстати, параметр процедуры Идентификатор Команды передается из Функции СведенияОВнешнейОбработке()
Далее при выполнении команды делаем с данными, что нам заблагорассудится.
Файл обработки прилагаю. Тестировал на конфигурации "Библиотека стандартных подсистем", редакция 3.1 (3.1.9.179).
