Всем привет. Хочу поделиться тем, как начать использовать новый объект WebSocketКлиентСоединения, описать некоторые тонкости, которые успел заметить.
Пробовать буду на внешней обработке. Она будет очень простая: три кнопки "Открыть соединение", "Отправить сообщение", "Закрыть соединение".
Также понадобится реквизит формы "КлючСоединения" с типом строка, который я заполняю при создании формы:
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
КлючСоединения = "f5d8323e-482a-4c42-9109-96875f0599d0";
КонецПроцедуры
Ключ соединения может быть любой строкой, "Соединение1", "WSconnect" и т.д. Я сгенерировал GUID, мне показалось так удобнее. Ключ используется для последующей работы с WebSocket соединениями.
Все процедуры можно писать даже на клиенте.
Кнопка "Открыть соединение"
&НаКлиенте
Процедура ОткрытьCоединение(Команда)
Попытка
URL = "ws://192.168.0.19:8765";
WebSocketКлиентСоединения.ОткрытьСоединение(КлючСоединения, URL);
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
В справке не указано, каким образом должен выглядеть URL. Методом проб и ошибок выяснил, что он состоит из имени протокола "ws://" и адреса хоста. У меня в качестве сервера выступает питоновский скрипт, который открывает порт 8765 на удалённой машине с адресом 192.168.0.19
Кнопка "Отправить сообщение"
&НаКлиенте
Процедура ОтправитьCообщение(Команда)
Попытка
Соединение = WebSocketКлиентСоединения.ПолучитьСоединение(КлючСоединения);
Соединение.ОтправитьСообщение("Hello websocket!");
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
Первое, что тут происходит, это поиск соединения в менеджере вебсокет соединений как раз по ключу, который добавлен в переменную КлючСоединения. Потом отправка сообщения в него.
Объект WebSocketКлиентСоединение не сериализуется, поэтому его нельзя передавать с клиента на сервер. Но 1С поступили разумно, создав менеджер вебсокет соединений, который самостоятельно управляет ими. То есть, нам не нужно заботиться о сохранении своего соединения в переменной. Более того, если закрыть обработку, из которой создавали соединение, и открыть заново, то можно сразу отправлять сообщения, потому что своё соединение всегда можно получить по ключу! Соединения не сбрасываются, пока не завершена сессия текущего пользователя. Из другой сессии того же пользователя, к сожалению, получить соединение по тому же ключу нельзя.
Кнопка "Закрыть соединение"
&НаКлиенте
Процедура ЗакрытьСоединение(Команда)
Попытка
Соединение = WebSocketКлиентСоединения.ПолучитьСоединение(КлючСоединения);
Соединение.Закрыть();
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
Тут снова находим наше соединение по ключу и завершаем его.
Заключение
Всё оказалось довольно просто и удобно. Надеюсь, для кого-то статья станет отправной точкой для создания своих обработок для Websocket соединений.
Для интересующихся домашнее задание: изучить обработчики объекта и создать код для "ОбработчикПолученияСообщения" для обработки входящих запросов :)
[Upd]
Я выполнил своё же домашнее задание. Вот как это было.
В моём проекте требуется организовать связь между базой 1С и web-приложением через посредника - Websocket сервер, который бы работал своего рода MQ broker-ом (обработчиком очереди сообщений).
Убедившись в первой части статьи, что со стороны 1С подключение и отправка довольно просты, я провёл несколько последующих дней на разработку серверной части. Когда пришло время возвратиться к 1С и обработать входящее сообщение, понадобилось внести минимальные правки в прошлый код.
Изменение процедуры кнопки "Открыть соединение"
&НаКлиенте
Процедура Соединить(Команда)
Попытка
Обработчики = Новый ОбработчикиWebSocketКлиентСоединения(, "ВходящееСообщение", , , ЭтаФорма);
URL = "ws://192.168.0.19:8765";
WebSocketКлиентСоединения.ОткрытьСоединение(КлючСоединения, URL, Обработчики);
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
Добавляю создание описания обработчиков событий "ОбработчикиWebSocketКлиентСоединения". "ВходящееСообщение" - это имя экспортной процедуры, которая будет выполняться, она указана второй, потому что отвечает за событие приём сообщения. "ЭтаФорма" - модуль, где находятся указанные процедуры. В создание соединения нужно добавить обработчики третьим аргументом.
Добавление процедуры "ВходящееСообщение"
&НаКлиенте
Процедура ВходящееСообщение(Соединение, Сообщение) Экспорт
Попытка
СообщениеОбъект = ПрочитатьЗначениеJSON(Сообщение);
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
У процедуры обработки входящего веб сокет сообщения два параметра "Соединение" и "Сообщение". Если на отправляющей стороне позаботиться об отправке json-строки, то здесь всего лишь нужно применить "ПрочитатьЗначениеJSON", после которой в структуре будут все поля с данными! Очень просто, даже с кириллицей.
Содержание сообщения:
{
"type": "text",
"content": "\u041f\u0440\u0438\u0432\u0435\u0442 1\u0421!",
"from": "web",
"message_id": "bb7eac3c-265d-4bfe-9758-3e1cc7681084"
}
Содержание структуры после обработки:
Ещё один важный момент. Я пробовал имитировать длительную операцию на стороне 1С после приёма входящего сообщения, и в этот момент отправлял ещё одно. Похоже, что сообщения кэшируются в соединении и событие получения срабатывает на очередное сообщение сразу после выполнения предыдущего. Я останавливал код на 5 минут, после чего успешно получал отправленные в этот момент сообщения. Здорово!
В очередной раз всё обошлось несколькими строчками кода. Понятно, что логику обработки сообщений всё равно придётся писать, но вопрос по поводу Websocket-а для меня теперь снят.
Всем удачи, пока.
