Ошибки регламентированного отчета статистики «Форма №11 (краткая)» за 2017 год для БГУ 1.0 и их исправление

16.02.18

Задачи пользователя - Адаптация типовых решений

В статье описываются ошибки регламентированного отчета статистики «Форма №11 (краткая)» для конфигурации "Бухгалтерия государственного учреждения 8, редакция 1.0" за 2017 год и даются рекомендации по их исправлению.

В первом квартале 2018 года государственные органы, органы местного самоуправления, государственные (муниципальные) учреждения и ряд других некоммерческих организаций,  должны подготовить и сдать в территориальные органы статистики годовую форму федерального статистического наблюдения №11 (краткая) за 2017 год. Срок представления формы – 1 апреля 2018г.

Для облегчения процесса подготовки этого отчета в состав регламентированной отчетности типовой конфигурации  БГУ 1.0 в раздел «Статистика» включен отчет «Форма №11 (краткая)», который для релизов  1.0.50.3  и  выше может быть заполнен автоматически по данным информационной базы. Однако тестирование этого отчета показало, что он содержит ряд ошибок, не дающих возможности успешно подготовить отчет. Перечислим эти ошибки и рассмотрим, как их можно устранить.

1.  Неверно заполняется строка 03 табличной части отчета – «Жилые здания». Вместо жилых зданий с кодом ОКОФ 100 в строку 03 попадают нежилые здания с кодом 210.

2.  Не заполняется строка 13 табличной части отчета – «Объекты, относящиеся к интеллектуальной собственности и продуктам интеллектуальной деятельности».

3.  Данные строки 13  отсутствуют в итоговой строке 01 –  «Всего основных фондов, без незавершенных активов».

4.  Неверно заполняются графы 5, 6, 7 и 11, отражающие показатели выбытия основных фондов за отчетный год.

Как показал анализ, причинами первых двух ошибок является некорректность программного кода функции  ПолучитьДанныеЗаполненияТаблицыФормы11К(ПараметрыОтчета), находящейся в общем модуле ЗаполнениеРегламентированнойОтчетностиСервер конфигурации БГУ 1.0. На рис.1 показан фрагмент этого программного кода.

ТекстУсловияСтроки(УсловияЯчеек, "002", "Показатели.ОКОФ3 В (""100"",""210"")");
ТекстУсловияСтроки(УсловияЯчеек, "003", "Показатели.ОКОФ3 = ""210""");
ТекстУсловияСтроки(УсловияЯчеек, "004", "Показатели.ОКОФ3 = ""220""");
ТекстУсловияСтроки(УсловияЯчеек, "006", "Показатели.ОКОФ3 В (""320"",""330"")
					|И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Оборудование)");
ТекстУсловияСтроки(УсловияЯчеек, "007", "Показатели.ОКОФ3 = ""320""");	
ТекстУсловияСтроки(УсловияЯчеек, "008", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(8)) = ""320.26.2""");                                                 
ТекстУсловияСтроки(УсловияЯчеек, "108", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(9)) = ""320.26.30""");	
ТекстУсловияСтроки(УсловияЯчеек, "009", "Показатели.ОКОФ3 = ""310""");
ТекстУсловияСтроки(УсловияЯчеек, "010", "Показатели.ОКОФ3 = ""510""");
ТекстУсловияСтроки(УсловияЯчеек, "011", "Показатели.ОКОФ3 = ""520""");		
ТекстУсловияСтроки(УсловияЯчеек, "012", "Показатели.ОКОФ3 = ""330""
					|И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Инвентарь)");
ТекстУсловияСтроки(УсловияЯчеек, "013", "Показатели.ОКОФ3 = ""700""");
ТекстУсловияСтроки(УсловияЯчеек, "113", "Показатели.ОКОФ3 = ""710""");	
ТекстУсловияСтроки(УсловияЯчеек, "213", "Показатели.ОКОФ3 = ""720""");
ТекстУсловияСтроки(УсловияЯчеек, "313", "Показатели.ОКОФ3 = ""731""");
ТекстУсловияСтроки(УсловияЯчеек, "413", "Показатели.ОКОФ3 = ""732""");

Рис.1. Фрагмент программного кода заполнения табличной части отчета

Как показывает рис.1, в строке «003»  для группы ОКОФ «Жилые здания и помещения» вместо кода 100 стоит код 210 для группы «Здания (кроме жилых)». Для того, чтобы исправить эту ошибку необходимо код 210 заменить на код 100.

Что касается второй ошибки, то она кроется в строке «013» для группы ОКОФ «Объекты интеллектуальной собственности» с кодом 700, а причина ее в том, что код ОКОФ конкретных объектов интеллектуальной собственности всегда начинается с кода подгруппы – 710 «Научные исследования и разработки», 720 – «Расходы на разведку недр и оценку запасов полезных ископаемых», 730 – «Программное обеспечение и базы данных» и т.д. А поскольку условием отбора является код 700, то эти объекты с кодами подгрупп в строку «013» не попадают. Для того, чтобы исправить эту ошибку необходимо в строке «013» равенство трехзначного кода ОКОФ объекта  коду группы 700 заменить на принадлежность множеству кодов подгрупп 710 – 790. На рис. 2 показан исправленный программный код  рис.1, который обеспечивает правильные результаты расчета показателей отчета.

ТекстУсловияСтроки(УсловияЯчеек, "002", "Показатели.ОКОФ3 В (""100"",""210"")");
ТекстУсловияСтроки(УсловияЯчеек, "003", "Показатели.ОКОФ3 = ""100""");
ТекстУсловияСтроки(УсловияЯчеек, "004", "Показатели.ОКОФ3 = ""220""");
ТекстУсловияСтроки(УсловияЯчеек, "006", "Показатели.ОКОФ3 В (""320"",""330"")
					|И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Оборудование)");
ТекстУсловияСтроки(УсловияЯчеек, "007", "Показатели.ОКОФ3 = ""320""");	
ТекстУсловияСтроки(УсловияЯчеек, "008", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(8)) = ""320.26.2""");                                                 
ТекстУсловияСтроки(УсловияЯчеек, "108", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(9)) = ""320.26.30""");	
ТекстУсловияСтроки(УсловияЯчеек, "009", "Показатели.ОКОФ3 = ""310""");
ТекстУсловияСтроки(УсловияЯчеек, "010", "Показатели.ОКОФ3 = ""510""");
ТекстУсловияСтроки(УсловияЯчеек, "011", "Показатели.ОКОФ3 = ""520""");		
ТекстУсловияСтроки(УсловияЯчеек, "012", "Показатели.ОКОФ3 = ""330""
					|И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Инвентарь)");
ТекстУсловияСтроки(УсловияЯчеек, "013", "Показатели.ОКОФ3 В
                                        |(""710"",""720"",""730"",""731"",""732"",""740"",""790"")
                                        |И Показатели.ВидНФА = ЗНАЧЕНИЕ(Перечисление.ВидыНФА.НМА)");
ТекстУсловияСтроки(УсловияЯчеек, "113", "Показатели.ОКОФ3 = ""710""");	
ТекстУсловияСтроки(УсловияЯчеек, "213", "Показатели.ОКОФ3 = ""720""");
ТекстУсловияСтроки(УсловияЯчеек, "313", "Показатели.ОКОФ3 = ""731""");
ТекстУсловияСтроки(УсловияЯчеек, "413", "Показатели.ОКОФ3 = ""732""");

 Рис.2. Исправленный программный код заполнения табличной части отчета

Третья ошибка полностью определяется второй, поскольку при не заполнении строки 13 данные этой строки отсутствуют в итоговой строке 01.

Четвертая ошибка, которая, как уже отмечалось, заключается  в неверном заполнении граф 5, 6, 7 и 11 отчета, так же как и первые две определяется некорректностью программного кода. Фрагмент этого кода в виде части запроса приведен на рис.3 и находится в той же функции ПолучитьДанныеЗаполненияТаблицыФормы11К(ПараметрыОтчета), фрагмент которой приведен на рис.1.

 |ВЫБРАТЬ
 |	Стоимость_Расход.ОС,
 |	0,
 |	0,
 //         Заполнение графы 5
 |	ВЫБОР
 |		КОГДА Стоимость_Расход.Сумма = ЕСТЬNULL(Амортизация_Приход.Сумма, 0)
 |			ТОГДА Стоимость_Расход.Сумма
 |		ИНАЧЕ 0
 |	КОНЕЦ,
 //         Заполнение графы 6
 |	ВЫБОР
 |		КОГДА Стоимость_Расход.Сумма = ЕСТЬNULL(Амортизация_Приход.Сумма, 0)
 |				И Стоимость_Расход.КЭК = &КЭККатастрофа
 |			ТОГДА Стоимость_Расход.Сумма
 |		ИНАЧЕ 0
 |	КОНЕЦ,
 //         Заполнение графы 7 
 |	ВЫБОР
 |		КОГДА Стоимость_Расход.Сумма > ЕСТЬNULL(Амортизация_Приход.Сумма, 0)
 |			ТОГДА Стоимость_Расход.Сумма
 |		ИНАЧЕ 0
 |	КОНЕЦ,
 |	0,
 |	0,
 |	0,
 //         Заполнение графы 11
 |	ВЫБОР
 |		КОГДА Стоимость_Расход.Сумма = ЕСТЬNULL(Амортизация_Приход.Сумма, 0)
 |			ТОГДА Амортизация_Приход.Сумма
 |		ИНАЧЕ 0
 |	КОНЕЦ
 |ИЗ
 |	Стоимость_Расход КАК Стоимость_Расход
 |		ЛЕВОЕ СОЕДИНЕНИЕ Амортизация_Приход КАК Амортизация_Приход
 |		ПО Стоимость_Расход.ОС = Амортизация_Приход.ОС

Рис.3. Фрагмент программного кода  заполнения граф 5,6,7,11 табличной части отчета

Этот фрагмент программного кода содержит два условия распределения рассчитанных показателей табличной части отчета по графам 5, 6, 7 и 11:

                  Стоимость_Расход.Сумма = ЕСТЬNULL(Амортизация_Приход.Сумма, 0)   ( условие для граф 5, 6, 7, 11)

                  Стоимость_Расход.КЭК = &КЭККатастрофа                                             ( условие для графы 6)

Эти условия основаны на двух типовых бухгалтерских проводках по списанию объектов ОС (НМА):

                  Дебет 010400410 (010439420)   Кредит 10100410 (010230420)   Сумма накопленной амортизации объекта

                  Дебет 040120273                      Кредит 10100410 (010230420)   Сумма остаточной стоимости объекта

Первое из этих условий говорит о том, что часть стоимости объекта ОС (НМА), равная сумме накопленной амортизации, которая списывается  первой проводкой, может попасть как в графу 5, так и в графу 7, так как никаких других условий распределения показателей по графам 5 и 7 в программном коде нет.

Второе условие эквивалентно равенству:

                   КЭК расхода = 273 (чрезвычайные расходы по операциям с активами),

и говорит о том, что остаточная стоимость списываемого объекта попадает в графу 6, когда код экономической классификации расхода (КЭК) объекта равен коду 273 (стихийные бедствия, катастрофы и т.д.). Однако для объектов с погашенной стоимостью, но еще находящихся в эксплуатации, это условие вообще не имеет смысла, так как для них остаточная стоимость равна нулю, и вторая проводка отсутствует, а для объектов с непогашенной стоимостью КЭК оборотов по кредиту всегда равен коду 410, поэтому это условие и в этом случае не работает.

Реально описанные некорректности программного кода проявляются в том, что при автоматическом заполнении типового регламентированного отчета по кнопке «Заполнить» все рассчитанные показатели выбытия объектов ОС (НМА) отражаются только в графе 7, а в графы 5 и 6, а следовательно и в графу 11, не попадают, что противоречит требованиям пунктов 12, 13, 14, 19 Указаний Росстата № 799 от 30.11.2017 г. о порядке заполнения граф 5, 6, 7, 11.

Как же исправить ошибку №4, чтобы графы 5, 6, 7 и 11 заполнялись правильно?

К сожалению простого способа исправления этой ошибки путем внесения незначительных изменений в исходный программный код, как в первых двух случаях, не существует, и прежде всего потому, что правильное распределение показателей по графам 5, 6, 7, 11 можно обеспечить только путем использования более информативного реквизита, чем имеющиеся. И таким рекизитом, на наш взгляд, является вид движения основных фондов, который в конфигурации БГУ 1.0 представлен перечислением ВидыДвиженийНФА и имеется в каждой проводке по списанию объектов основных фондов в виде характеристики движения по кредиту. В таблице 1 показан принцип распределения объектов основных фондов по графам 5, 6, 7 на основе этого реквизита.

Таблица 1. Распределение видов движения (выбытия) основных фондов по графам 5, 6, 7

Номера граф

Наименование показателей

Характеристика объектов учета Виды движения основных фондов
5
  Уменьшение полной
  учетной стоимости
  основных фондов
  за отчетный год
  (выбытие)
  Физически ликвидированные объекты основных фондов
   (путем  разборки, утилизации и т.д.)
  Списано на нужды учреждения
  Выбыло по причине порчи
  Выбыло вследствие чрезвычайных ситуаций
6
   Объекты основных фондов, учтенные в графе 5 и
   ликвидированные вследствие потерь от стихийных бедствий,
   техногенных  катастроф, автокатастроф, пожаров, военных
   действий и т.д.
  Выбыло вследствие чрезвычайных ситуаций
7
  Объекты основных фондов, выбывшие по прочим причинам
  (продажа, передача, кража, пропажа и т.д.)

Передано безвозмездно в порядке расчетов между учреждениями одного уровня бюджета РФ

Передано безвозмездно в порядке межбюджетных отношений

Выбыло (иные безвозмездные передачи)

Передано в порядке внутриведомственных расчетов

Выбыло в порядке централизованного снабжения

Выбыло вследствие недостач и хищений

Реализовано

Прочее уменьшение

 

 

 

 

 

 

 

 

 

 

 

 

 

Приведем программный код процедуры, содержащей текст запроса, который построен на описанном принципе и позволяет правильно распределить списанные объекты основных фондов по графам 5, 6, 7, 11.

Процедура ЗаполнитьПоказателиКолонок56711_Форма11К_2018Кв1(ПараметрыОтчета) Экспорт
  ТекстЗапроса = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
  |  ДвиженияОС.СубконтоКт2, 
  |  ДвиженияОС.ХарактеристикаДвиженияКт,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеБезвозмездноеИное
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеБезвозмездноеИное,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеВнутриведомственное
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеВнутриведомственное,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеМежбюджетное
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеМежбюджетное,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеНаНуждыУчреждения
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеНаНуждыУчреждения,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеНедостачИХищений
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеНедостачИХищений,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеОдногоУровняБюджета
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеОдногоУровняБюджета,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеПорчи
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеПорчи,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеЦС
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеЦС,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &СписаниеЧС
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаСписаниеЧС,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &Реализация
  |              ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |       КОНЕЦ) КАК СуммаРеализация,
  |  СУММА(ВЫБОР
  |          КОГДА ДвиженияОС.ХарактеристикаДвиженияКт = &УменьшениеПрочее
  |             ТОГДА ДвиженияОС.Сумма
  |          ИНАЧЕ 0
  |        КОНЕЦ) КАК СуммаУменьшениеПрочее
  |ПОМЕСТИТЬ ВТ_ДвижениеОС
  |ИЗ
  |  РегистрБухгалтерии.ЕПСБУ.ДвиженияССубконто(
  |       &НачалоПериода,
  |       &КонецПериода,
  |       СчетДт <> СчетКт
  |             И СчетКт В ИЕРАРХИИ (&СчетаОФ),
  |       ,
  |       ) КАК ДвиженияОС
  |ГДЕ
  |  ДвиженияОС.Учреждение = &Организация
  |  И ВЫРАЗИТЬ(ДвиженияОС.СубконтоКт2 КАК Справочник.ОсновныеСредства).ИмуществоКазны = &ИмуществоКазны
  |  И ВЫРАЗИТЬ(ДвиженияОС.СубконтоКт2 КАК Справочник.ОсновныеСредства).ПорядокПогашенияСтоимости = &НачислениеАмортизации
  |  И ВЫРАЗИТЬ(ДвиженияОС.СубконтоКт2 КАК Справочник.ОсновныеСредства).СпособНачисленияАмортизации = &Линейный
  |
  |СГРУППИРОВАТЬ ПО
  |  ДвиженияОС.СубконтоКт2,
  |  ДвиженияОС.ХарактеристикаДвиженияКт
  |;
  |
  |////////////////////////////////////////////////////////////////////////////////
  |
  |ВЫБРАТЬ РАЗРЕШЕННЫЕ
  |  ВТ_ДвижениеОС.СубконтоКт2 КАК ОсновноеСредство,
  |  ВТ_ДвижениеОС.СубконтоКт2.КодПоОКОФ КАК ОКОФ,
  |  ВТ_ДвижениеОС.СубконтоКт2.ВидНФА КАК ВидНФА,
  |  ВТ_ДвижениеОС.СубконтоКт2.ТипНФА КАК ТипНФА,
  |  (СУММА(ВТ_ДвижениеОС.СуммаСписаниеНаНуждыУчреждения)+ СУММА(ВТ_ДвижениеОС.СуммаСписаниеПорчи)+
  |  СУММА(ВТ_ДвижениеОС.СуммаСписаниеЧС)) КАК Колонка5,
  |  СУММА(ВТ_ДвижениеОС.СуммаСписаниеЧС) КАК Колонка6,
  |  (СУММА(ВТ_ДвижениеОС.СуммаСписаниеБезвозмездноеИное)+ СУММА(ВТ_ДвижениеОС.СуммаСписаниеВнутриведомственное)+
  |  СУММА(ВТ_ДвижениеОС.СуммаСписаниеМежбюджетное)+ СУММА(ВТ_ДвижениеОС.СуммаСписаниеОдногоУровняБюджета)+
  |  СУММА(ВТ_ДвижениеОС.СуммаСписаниеЦС)+ СУММА(ВТ_ДвижениеОС.СуммаУменьшениеПрочее)+
  |  СУММА(ВТ_ДвижениеОС.СуммаСписаниеНедостачИХищений)+ СУММА(ВТ_ДвижениеОС.СуммаРеализация)) КАК Колонка7,
  |  (СУММА(ВЫБОР
  |         КОГДА ВТ_ДвижениеОС.ХарактеристикаДвиженияКт = &СписаниеНаНуждыУчреждения
  |             ТОГДА Амортизация.СуммаОборотДт
  |         ИНАЧЕ 0
  |       КОНЕЦ) +
  |  СУММА(ВЫБОР
  |         КОГДА ВТ_ДвижениеОС.ХарактеристикаДвиженияКт = &СписаниеПорчи
  |             ТОГДА Амортизация.СуммаОборотДт
  |         ИНАЧЕ 0
  |       КОНЕЦ) +
  |  СУММА(ВЫБОР
  |          КОГДА ВТ_ДвижениеОС.ХарактеристикаДвиженияКт = &СписаниеЧС
  |               ТОГДА Амортизация.СуммаОборотДт
  |          ИНАЧЕ 0
  |        КОНЕЦ)) КАК Колонка11
  |ПОМЕСТИТЬ Показатели       
  |ИЗ 
  |  РегистрБухгалтерии.ЕПСБУ.ОстаткиИОбороты(
  |        &НачалоПериода,
  |        &КонецПериода,
  |        Период,
  |        ДвиженияИГраницыПериода,
  |        Счет В ИЕРАРХИИ (&СчетаОФ),
  |        &СубконтоОС,
  |        ) КАК ОС
  |  ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.ЕПСБУ.Обороты(
  |        &НачалоПериода,
  |        &КонецПериода,
  |        Период,
  |        Счет В ИЕРАРХИИ (&СчетаОФ),
  |        &СубконтоОС,
  |        ,
  |        (НЕ КорСчет В ИЕРАРХИИ (&СчетаОФ)),
  |        ) КАК ОборотыОС
  |  ПО ОС.Субконто1 = ОборотыОС.Субконто1
  |  ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.ЕПСБУ.ОстаткиИОбороты(
  |         &НачалоПериода,
  |         &КонецПериода,
  |         Период,
  |         ,
  |         Счет В ИЕРАРХИИ (&СчетАмортизацииОС),
  |         &СубконтоОС,
  |         ) КАК Амортизация
  |  ПО ОС.Субконто1 = Амортизация.Субконто1
  |  ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ДвижениеОС КАК ВТ_ДвижениеОС
  |  ПО ОС.Субконто1 = ВТ_ДвижениеОС.СубконтоКт2
  |ГДЕ
  |  ОС.Учреждение = &Организация
  |
  |СГРУППИРОВАТЬ ПО
  |  ВТ_ДвижениеОС.СубконтоКт2,
  |  ВТ_ДвижениеОС.СубконтоКт2.КодПоОКОФ,
  |  ВТ_ДвижениеОС.СубконтоКт2.ВидНФА,
  |  ВТ_ДвижениеОС.СубконтоКт2.ТипНФА";

  УсловияЯчеек = "ОсновноеСредство";

  ТекстУсловияСтроки(УсловияЯчеек, "002", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) В (""100"",""210"")");
  ТекстУсловияСтроки(УсловияЯчеек, "003", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) = ""100""");
  ТекстУсловияСтроки(УсловияЯчеек, "004", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) = ""220""");
  ТекстУсловияСтроки(УсловияЯчеек, "006", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) В (""320"",""330"")
                                   | И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Оборудование)");
  ТекстУсловияСтроки(УсловияЯчеек, "007", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) = ""320""");
  ТекстУсловияСтроки(УсловияЯчеек, "008", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(8)) = ""320.26.2""");
  ТекстУсловияСтроки(УсловияЯчеек, "108", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(9)) = ""320.26.30""");
  ТекстУсловияСтроки(УсловияЯчеек, "009", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""310""");
  ТекстУсловияСтроки(УсловияЯчеек, "010", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""510""");
  ТекстУсловияСтроки(УсловияЯчеек, "011", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""520""");
  ТекстУсловияСтроки(УсловияЯчеек, "012", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""330""
                                   | И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Инвентарь)");
  ТекстУсловияСтроки(УсловияЯчеек, "013", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) В (&Коды013)
                                   | И Показатели.ВидНФА = ЗНАЧЕНИЕ(Перечисление.ВидыНФА.НМА)");
  ТекстУсловияСтроки(УсловияЯчеек, "113", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""710""");
  ТекстУсловияСтроки(УсловияЯчеек, "213", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""720""");
  ТекстУсловияСтроки(УсловияЯчеек, "313", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""731""");
  ТекстУсловияСтроки(УсловияЯчеек, "413", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""732""");
  ТекстУсловияСтроки(УсловияЯчеек, "513", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3))= ""740""");
  ТекстУсловияСтроки(УсловияЯчеек, "014", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) В (&Коды014)
                                   | И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.Прочие)
                                   | ИЛИ Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.БиблиотечныйФонд)");
  ТекстУсловияСтроки(УсловияЯчеек, "114", "ВЫРАЗИТЬ(Показатели.ОКОФ КАК СТРОКА(3)) В (""740"",""790"")
                                   | И Показатели.ТипНФА = ЗНАЧЕНИЕ(Перечисление.ТипыНФА.БиблиотечныйФонд)");

  МассивКодовСтроки013 = Новый Массив;
  МассивКодовСтроки013.Добавить("710");
  МассивКодовСтроки013.Добавить("720");
  МассивКодовСтроки013.Добавить("730");
  МассивКодовСтроки013.Добавить("731");
  МассивКодовСтроки013.Добавить("732");
  МассивКодовСтроки013.Добавить("740");
  МассивКодовСтроки013.Добавить("790");

  МассивКодовСтроки014 = Новый Массив;
  МассивКодовСтроки014.Добавить("230");
  МассивКодовСтроки014.Добавить("400");
  МассивКодовСтроки014.Добавить("510");
  МассивКодовСтроки014.Добавить("600");
  МассивКодовСтроки014.Добавить("790");

  Запрос = Новый Запрос;

  Запрос.УстановитьПараметр("Коды013", МассивКодовСтроки013);
  Запрос.УстановитьПараметр("Коды014", МассивКодовСтроки014);

  Запрос.Текст = ТекстЗапроса + "; ВЫБРАТЬ " + УсловияЯчеек + " ИЗ Показатели КАК Показатели
                |СГРУППИРОВАТЬ ПО
                |    Показатели.ОсновноеСредство
                |УПОРЯДОЧИТЬ ПО
                |    ОсновноеСредство
                |ИТОГИ ПО
                |    ОБЩИЕ";
  
ИмуществоКазны = ПараметрыОтчета.Свойство("ИмуществоКазны") И ПараметрыОтчета["ИмуществоКазны"] = Истина;

  Если ИмуществоКазны Тогда
      КодыСчетаУчета = "108.00";
      КодыСчетаАм    = "104.50";
  Иначе
      КодыСчетаУчета = "101.00,102.00";
      КодыСчетаАм    = "104.10,104.20,104.30,104.40";
  КонецЕсли;

  Запрос.УстановитьПараметр("Организация"  , ПараметрыОтчета.Организация);
  Запрос.УстановитьПараметр("НачалоПериода", ПараметрыОтчета.ПериодНачало);
  Запрос.УстановитьПараметр("КонецПериода" , ПараметрыОтчета.ПериодКонец);
  Запрос.УстановитьПараметр("СчетаОФ",    ПлановыеПоказателиОтчетыПовтИсп.ПолучитьМассивСчетов(КодыСчетаУчета));
  Запрос.УстановитьПараметр("СубконтоОС", ПланыВидовХарактеристик.ВидыСубконтоБюджет.ОсновныеСредства);
  Запрос.УстановитьПараметр("СчетАмортизацииОС",ПлановыеПоказателиОтчетыПовтИсп.ПолучитьМассивСчетов(КодыСчетаАм));
  Запрос.УстановитьПараметр("ИмуществоКазны",   ИмуществоКазны);
  Запрос.УстановитьПараметр("НачислениеАмортизации", Перечисления.ПорядокПогашенияСтоимостиОС.НачислениеАмортизации);
  Запрос.УстановитьПараметр("Линейный",                    Перечисления.СпособНачисленияАмортизации.Линейный);
  Запрос.УстановитьПараметр("СписаниеБезвозмездноеИное",   Перечисления.ВидыДвиженийНФА.СписаниеБезвозмездноеИное);
  Запрос.УстановитьПараметр("СписаниеВнутриведомственное", Перечисления.ВидыДвиженийНФА.СписаниеВнутриведомственное);
  Запрос.УстановитьПараметр("СписаниеМежбюджетное",        Перечисления.ВидыДвиженийНФА.СписаниеМежбюджетное);
  Запрос.УстановитьПараметр("СписаниеНаНуждыУчреждения",   Перечисления.ВидыДвиженийНФА.СписаниеНаНуждыУчреждения);
  Запрос.УстановитьПараметр("СписаниеНедостачИХищений",    Перечисления.ВидыДвиженийНФА.СписаниеНедостачИХищений);
  Запрос.УстановитьПараметр("СписаниеОдногоУровняБюджета", Перечисления.ВидыДвиженийНФА.СписаниеОдногоУровняБюджета);
  Запрос.УстановитьПараметр("СписаниеПорчи",               Перечисления.ВидыДвиженийНФА.СписаниеПорчи);
  Запрос.УстановитьПараметр("СписаниеЦС",                  Перечисления.ВидыДвиженийНФА.СписаниеЦС);
  Запрос.УстановитьПараметр("СписаниеЧС",                  Перечисления.ВидыДвиженийНФА.СписаниеЧС);
  Запрос.УстановитьПараметр("Реализация",                  Перечисления.ВидыДвиженийНФА.Реализация);
  Запрос.УстановитьПараметр("УменьшениеПрочее",            Перечисления.ВидыДвиженийНФА.УменьшениеПрочее);

  Результат = Запрос.Выполнить().Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкамСИерархией);

КонецПроцедуры

Предложенные рекомендации апробированы и могут быть использованы для исправления ошибок типового регламентированного отчета статистики «Форма 11 (краткая)» за 2017 год, а описанная процедура ЗаполнитьПоказателиКолонок56711_Форма11К_2018Кв1(ПараметрыОтчета) – при создании внешних обработок для автоматического заполнения этого отчета. Пример такой обработки с открытым кодом опубликован  //infostart.ru/public/753866.

Ошибки регламентированный отчет форма 11 (краткая) исправление ошибок

См. также

Табличная часть в доп. реквизитах и формирование таблиц в шаблоне docx для 1С:ДО 3.0

Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Платные (руб)

Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.

29400 руб.

29.06.2023    4976    11    5    

20

Расширение для 1С:УНФ. Автоматическое снятие резервов в Заказах покупателей

Логистика, склад и ТМЦ Адаптация типовых решений Пользователь Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Мы доработали УНФ, чтобы она автоматически отменяла старые резервы и не мешала эффективно продавать.

7200 руб.

02.08.2023    3349    6    0    

24

Каждому менеджеру нужен свой Excel

Адаптация типовых решений Программист Пользователь Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Абонемент ($m)

Каждый из нас сталкивается с ситуацией, когда какой-нибудь менеджер показывает свой Excel и рассказывает, как он что-то из 1С копирует в него, снабжает пояснениями, выделяет цветом и т.д. и т.п. Заканчивается все просьбой сделать вот чтобы также было в 1С. И оказывается такой человек (почти с гарантией) либо лучшим продажником, либо каким-то важным, за все отвечающим, - на ком все держится.

2 стартмани

22.04.2024    4538    dimanich70    15    

20

Создать на основании - своя кнопка (БСП). Проблема двух подменю Создать на основании

БСП (Библиотека стандартных подсистем) Адаптация типовых решений Программист Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

Понадобилось в подменю "Создать на основании" добавить свою команду, которая открывает обработку. В процессе доработок появилась проблема двух подменю "Создать на основании". В статье о том, как решились проблемы.

01.03.2024    2845    dimanich70    8    

15

Доработка отчета "Связанные документы" (структура подчиненности) для вывода объектов из любого расширения

Адаптация типовых решений Программист Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Доработка типового отчета "Связанные документы" позволяет просто и быстро расширять состав объектов для построения структуры подчиненности документов, используя объекты основной конфигурации и любых расширений.

1 стартмани

27.10.2023    2389    20    avmartynov    14    

44

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2630    40    progmaster    8    

4
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. ЕВА/ГРИНИНА 13.03.18 15:28 Сейчас в теме
Добрый день. Скажите, а почему не заполняется в этом году в 1 с 8.3 БГУ 1.0 (1.0.50.7) Форма №11-краткая??? в прошлом году заполнялась нажатием кнопки заполнить.
2. ЕВА/ГРИНИНА 13.03.18 15:43 Сейчас в теме
Необходимо скорее всего перейти на новый ОКОФ, но как это сделать? Неужели перечикивать несколько тысяч наименований?
3. ЕВА/ГРИНИНА 13.03.18 16:41 Сейчас в теме
4. infotec 43 13.03.18 16:44 Сейчас в теме
Здравствуйте, Женя! На Ваши два вопроса у меня несколько ответов.
1) Если в вашей организации основные фонды в 2017 году не были переведены со старого классификатора ОКОФ ОК 013-94 на новый ОК 013-2014, то несмотря на наличие на типовом отчете "Форма №11-краткая" кнопки "Заполнить" этот отчет заполняться не будет, так как он настроен на новые коды ОКОФ и объекты основных фондов со старыми кодами просто "не увидит".
2) Вы скачали мой отчет (публикация № 753866), однако хочу предупредить, что он прекрасно заполняет форму 11-краткая за 2017 год, но тоже при условии, что основные фонды переведены на новый классификатор ОКОФ.
3) Поскольку вопрос перевода основных фондов на новый ОКОФ не простой, я своевременно подготовил и опубликовал статью "Особенности подготовки отчетной формы статистики №11 (краткая) за 2017 год для государственных и муниципальных учреждений" (публикация № 702352 от 19 ноября 2017 г.)
Оставьте свое сообщение