Принцип работы: При проведении документа Поступление товаров по заказу поставщику, который создан на основании заказа клиента - делается запись в регистр. Записывается сообщение о поступлении товара для пользователя, который ответственный за заказ клиента. Каждые 10 минут срабатывает обработчик ожидания, проверяет, есть ли неотправленные сообщения, и отправляет их пользователю. Весь механизм можно отключить, это делается перед групповым перепроведением или при закрытии месяца, чтобы на пользователя не сыпались сообщения. Время проверки сообщений можно уменьшить (например, каждую минуту) или увеличить (например, один раз в день).
Описание:
1. Создан справочник: ОП_ДублированиеОповещенийПользователям
Пользователь = Спр Пользователи
ДублироватьОповещения = Булево
2. Создан Регистр Сведений :
Документ Событие - Любой документ , при проведении которого делается запись в регистр (У меня поступление товаров)
Дополнительный Документ - Любой документ, при необходимости (У меня Заказ клиента)
Справочник Событие - Любой справочник (на всякий случай, можно этот механизм реализовать например при записи элемента справочника, только код доработать)
Пользователь - Тут все понятно
Оповещение выполнено - булево
Дата Доставки Оповещения - ДатаиВремя
Текст - то что будете выводить пользователю
3. Создана константа, которая включает механизм оповещения. Если константа - ложь, запись в регистр не делается.
4. Созданы две подписки на событие: При проведении документа поступление делается запись в регистр, а при удалении проведения - запись удаляется
5. Созданы 3 общих модуля. См скрины и код
5.1
Процедура ОП_ОповещениеПользователей() Экспорт
ОП_ОповещениеПользователейКлиент.ОП_ОповещениеПользователейКлиент()
КонецПроцедуры
5.2
Процедура ОП_ОповещениеПользователейКлиент() Экспорт
Пользователь = "";
ТекстСообщения = ""; //Если документов будет несколько текст будет общий для всех документов
ДокументСобытие = Новый Массив; //Если документов будет несколько создадим массив, для корректоного формирования записи в регистр
ОП_ОповещениеПользователейСервер.СформироватьСообщение(ТекстСообщения,ДокументСобытие,Пользователь);
Параметры = Новый Структура;
Параметры.Вставить("Пользователь",Пользователь);
Параметры.Вставить("ДокументСобытие",ДокументСобытие);
Если ТекстСообщения<>"" Тогда
Оповещение = Новый ОписаниеОповещения("СделатьЗаписьВРегистр",ОП_ОповещениеПользователейКлиент,Параметры);
ПоказатьВопрос(Оповещение,ТекстСообщения,РежимДиалогаВопрос.ОК);
КонецЕсли;
КонецПроцедуры
Процедура СделатьЗаписьВРегистр(Результат, ДополнительныеПараметры) Экспорт
ОП_ОповещениеПользователейСервер.СделатьЗаписьВРегистрОТомЧтоОповещениеПолучено(ДополнительныеПараметры);
КонецПроцедуры
5.3
Процедура ОП_ОповещениеПользователейОбработкаПроведения(Источник, Отказ, РежимПроведения) Экспорт
ИспользоватьОповещение = Константы.ОП_ОповещениеПользователей.Получить();
Если ИспользоватьОповещение Тогда
ЗаказКлиента = Источник.Ссылка.ЗаказПоставщику.ДокументОснование;
//сообщения в регистр должны записываться только если поступление формируется на основании заказа поставщику,
//а заказ поставщику формируется по заказу клиента.
Если ЗначениеЗаполнено(ЗаказКлиента) Тогда
Пользователь = Источник.Ссылка.ЗаказПоставщику.ДокументОснование.Менеджер;
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Пользователь",Пользователь);
Запрос.Текст = "ВЫБРАТЬ
| ОП_ДублированиеОповещенийПользователям.Ссылка КАК Ссылка
|ИЗ
| Справочник.ОП_ДублированиеОповещенийПользователям КАК ОП_ДублированиеОповещенийПользователям
|ГДЕ
| ОП_ДублированиеОповещенийПользователям.Пользователь = &Пользователь
| И ОП_ДублированиеОповещенийПользователям.Ссылка.ПометкаУдаления = ЛОЖЬ";
Результат = Запрос.Выполнить().Выбрать();
Пока Результат.Следующий() Цикл
//Если записи есть в регистре тогда их нужно удалить и записать новые, т.к. документ мог быть изменен
//и пользователь должен снова получить сообщение для перепроверки документа (своего рода подстраховка от изменений документа)
НаборЗаписей = РегистрыСведений.ОП_ОповещениеПользователей.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.ДокументСобытие.Установить(Источник.Ссылка);
НаборЗаписей.Прочитать();
НаборЗаписей.Очистить();
Если Результат.Ссылка.ДублироватьОповещения = Ложь Тогда //Сделаем только одну запись для данного пользователя
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись. ДокументСобытие = Источник.Ссылка;
НоваяЗапись.ДополнительныйДокумент = ЗаказКлиента;
НоваяЗапись.Период = Источник.Ссылка.Дата;
НоваяЗапись.Пользователь = Пользователь;
НоваяЗапись.ТекстСообщения = "Поступил товар по заказу клиента № " + ЗаказКлиента.Номер + " , от "+ ЗаказКлиента.Дата + " . "+ Источник.Ссылка;
НаборЗаписей.Записать();
Иначе //Если нужно дублировать записи, тогда делаем записи только для тех пользователей, которым нужно дублировать
//Здесь записи для дублирования
Для Каждого Строка Из Результат.Ссылка.ТабличнаяЧасть Цикл
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись. ДокументСобытие = Источник.Ссылка;
НоваяЗапись.ДополнительныйДокумент = ЗаказКлиента;
НоваяЗапись.Период = Источник.Ссылка.Дата;
НоваяЗапись.Пользователь = Строка.ПользовательДляДублирования;
НоваяЗапись.ТекстСообщения = "Поступил товар по заказу клиента № " + ЗаказКлиента.Номер + " , от "+ ЗаказКлиента.Дата + " . "+ Источник.Ссылка;
НаборЗаписей.Записать();
КонецЦикла;
КонецЕсли;
КонецЦикла;
КонецЕсли; //Если ЗначениеЗаполнено(ЗаказКлиента)
КонецЕсли; //Константа "Включить оповещение пользователей" = истина
КонецПроцедуры
Процедура ОП_ОповещениеПользователейОбработкаУдаленияПроведения(Источник, Отказ) Экспорт
ИспользоватьОповещение = Константы.ОП_ОповещениеПользователей.Получить();
Если ИспользоватьОповещение Тогда
ЗаказКлиента = Источник.Ссылка.ЗаказПоставщику.ДокументОснование;
Если ЗначениеЗаполнено(ЗаказКлиента) Тогда
//При отменен проведения документа удаляем записи из регистра
НаборЗаписей = РегистрыСведений.ОП_ОповещениеПользователей.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.ДокументСобытие.Установить(Источник.Ссылка);
НаборЗаписей.Прочитать();
НаборЗаписей.Очистить();
НаборЗаписей.Записать();
КонецЕсли;
КонецЕсли; //Константа "Включить оповещение пользователей" = истина
КонецПроцедуры
Процедура СформироватьСообщение(ТекстСообщения,ДокументСобытие,Пользователь) Экспорт
ТекстСообщения = "";
Пользователь = Пользователи.ТекущийПользователь();
//Период берем за 3 месяца, при желании можно увеличить
НачалоПериода = ДобавитьМесяц(ТекущаяДата(),-3);
КонецПериода = ТекущаяДата();
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("НачалоПериода",НачалоПериода);
Запрос.УстановитьПараметр("КонецПериода",КонецПериода);
Запрос.УстановитьПараметр("Пользователь",Пользователь);
Запрос.Текст = "ВЫБРАТЬ
| ОП_ОповещениеПользователей.ДокументСобытие КАК ДокументСобытие,
| ОП_ОповещениеПользователей.ДополнительныйДокумент КАК ДополнительныйДокумент,
| ОП_ОповещениеПользователей.Пользователь КАК Пользователь,
| ОП_ОповещениеПользователей.ТекстСообщения КАК ТекстСообщения
|ИЗ
| РегистрСведений.ОП_ОповещениеПользователей КАК ОП_ОповещениеПользователей
|ГДЕ
| ОП_ОповещениеПользователей.Период МЕЖДУ &НачалоПериода И &КонецПериода
| И ОП_ОповещениеПользователей.ОповещениеВыполнено = ЛОЖЬ
| И ОП_ОповещениеПользователей.Пользователь = &Пользователь" ;
Результат = Запрос.Выполнить().Выбрать();
Пока Результат.Следующий() Цикл
Попытка
ТекстСообщения = Результат.ТекстСообщения + Символы.ПС+ ТекстСообщения;
ДокументСобытие.Добавить(Результат.ДокументСобытие);
Исключение
КонецПопытки;
КонецЦикла;
КонецПроцедуры
Процедура СделатьЗаписьВРегистрОТомЧтоОповещениеПолучено(ДополнительныеПараметры) Экспорт
Для Каждого Документ Из ДополнительныеПараметры.ДокументСобытие Цикл
НаборЗаписей = РегистрыСведений.ОП_ОповещениеПользователей.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.ДокументСобытие.Установить(Документ);
НаборЗаписей.Отбор.Пользователь.Установить(ДополнительныеПараметры.Пользователь);
НаборЗаписей.Прочитать();
СтрокаЗаписи = НаборЗаписей[0];
СтрокаЗаписи.ОповещениеВыполнено = Истина;
СтрокаЗаписи.ДатаДоставкиОповещения = ТекущаяДата();
НаборЗаписей.Записать();
КонецЦикла;
КонецПроцедуры
6. В модуле управляемого приложения Процедура ПриНачалеРаботыСистемы() нужно добавить обработчик ожидания
//\\ Рассылка оповещения менеджерам о поступлении по заказу клиента
ПодключитьОбработчикОжидания("ОП_ОповещениеПользователей",600,Ложь);
//\\
7. Создана подсистема, которая соединила все новые объекты конфигурации
Ну вот и всё!!!! Может, кому пригодится. Сильно за код не ругаться )))) . Не спорю, что можно и улучшить, можно доработать систему, чтобы оповещала пользователей при нескольких событиях. Всё в ваших руках.
Разрабатывалась для Управление торговлей, редакция 11 (11.4.2.123). На других конфигурациях не тестировалась, но думаю, что при небольших доработках будет работать везде. Кому неохота возиться - есть cf-ник, только при объединении не нужно объединять справочник пользователи и документ Приобретение товаров. Они созданы фиктивно для целостности ссылок.
