Пробую делать как по инструкции, но вот проблема, у меня конфа Управление торговлей, редакция 11 (11.5.20.80). 1С:Предприятие 8.3 (8.3.26.1498). Cуть проблемы, нужно распечатать реализацию товаров. Пытаюсь это сделать как по инструкции выше, но вот такая дилемма, пишет что печатная форма недоступна.
&После ("ДобавитьКомандыПечати")
Процедура Расш1_ДобавитьКомандыПечати(КомандыПечати) Экспорт
ПараметрыОтбора = Новый Структура;
ПараметрыОтбора.Вставить("Идентификатор", "Накладная");
НайденныеСтроки = КомандыПечати.НайтиСтроки(ПараметрыОтбора);
Для каждого строкаНС из НайденныеСтроки Цикл
строкаНС.ПроверкаПроведенияПередПечатью = Ложь;
КонецЦикла;
КонецПроцедуры
&ИзменениеИКонтроль("СформироватьПечатнуюФормуНакладная")
Функция Расш1_Печать(МассивОбъектов, ОбъектыПечати,ПараметрыПечати)Экспорт
УстановитьПривилегированныйРежим(Истина);
Если ПараметрыПечати <> Неопределено
И ПараметрыПечати.Свойство("ОтображатьСкидки") Тогда
ОтображатьСкидки = ПараметрыПечати.ОтображатьСкидки;
Иначе
ОтображатьСкидки = (Константы.ОтображениеСкидокВПечатныхФормахДокументовПродажи.Получить()
<> Перечисления.ВариантыВыводаСкидокВПечатныхФормах.НеВыводитьСкидки);
КонецЕсли;
КолонкаКодов = ФормированиеПечатныхФорм.ДополнительнаяКолонкаПечатныхФормДокументов();
ИмяКолонкиКодов = КолонкаКодов.ИмяКолонки;
ПредставлениеКолонкиКодов = КолонкаКодов.ПредставлениеКолонки;
ВыводитьКоды = ЗначениеЗаполнено(ИмяКолонкиКодов);
ИспользоватьРучныеСкидки = ПолучитьФункциональнуюОпцию("ИспользоватьРучныеСкидкиВПродажах");
ИспользоватьАвтоматическиеСкидки = ПолучитьФункциональнуюОпцию("ИспользоватьАвтоматическиеСкидкиВПродажах");
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| РеализацияТоваровУслуг.Ссылка КАК Ссылка,
| РеализацияТоваровУслуг.Номер КАК Номер,
| РеализацияТоваровУслуг.Дата КАК Дата,
| РеализацияТоваровУслуг.Партнер КАК Партнер,
| РеализацияТоваровУслуг.Контрагент КАК Получатель,
| РеализацияТоваровУслуг.Организация КАК Организация,
| РеализацияТоваровУслуг.Организация.Префикс КАК Префикс,
| РеализацияТоваровУслуг.Валюта КАК Валюта,
| РеализацияТоваровУслуг.ЦенаВключаетНДС КАК ЦенаВключаетНДС,
| ВЫБОР
| КОГДА РеализацияТоваровУслуг.НалогообложениеНДС В(ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаНеОблагаетсяНДС),
| ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяЕНВД))
| ТОГДА ЛОЖЬ
| ИНАЧЕ ИСТИНА
| КОНЕЦ КАК УчитыватьНДС,
| РеализацияТоваровУслуг.Отпустил КАК ОтпускПроизвел
|ИЗ
| Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
|
|ГДЕ
| РеализацияТоваровУслуг.Ссылка В(&МассивДокументов)
|
|УПОРЯДОЧИТЬ ПО
| Ссылка
|;
|
|//////////////////////////////////////////////////////////////////////////////// 1
|ВЫБРАТЬ
| РеализацияТоваровУслуг.Ссылка КАК Ссылка,
| РеализацияТоваровУслуг.НомерСтроки КАК НомерСтроки,
| ВариантыКомплектацииНоменклатуры.Ссылка КАК ВариантКомплектацииНоменклатуры,
| ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| ЕСТЬNULL(РеализацияТоваровУслуг.АналитикаУчетаНаборов.НоменклатураНабора,
| ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК НоменклатураНабора,
| ЕСТЬNULL(РеализацияТоваровУслуг.АналитикаУчетаНаборов.ХарактеристикаНабора,
| ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК ХарактеристикаНабора,
| РеализацияТоваровУслуг.АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
| ВЫБОР
| КОГДА РеализацияТоваровУслуг.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)
| ТОГДА 1
| ИНАЧЕ &ТекстЗапросаКоэффициентУпаковки1
| КОНЕЦ КАК Коэффициент,
| ВЫБОР
| КОГДА РеализацияТоваровУслуг.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)
| ТОГДА РеализацияТоваровУслуг.АналитикаУчетаНоменклатуры.Номенклатура.ЕдиницаИзмерения
| ИНАЧЕ РеализацияТоваровУслуг.Упаковка
| КОНЕЦ КАК ЕдиницаИзмерения,
| РеализацияТоваровУслуг.АналитикаУчетаНоменклатуры.Характеристика КАК Характеристика,
| РеализацияТоваровУслуг.Упаковка КАК Упаковка,
| РеализацияТоваровУслуг.СтавкаНДС КАК СтавкаНДС,
| ВЫБОР
| КОГДА &ОтображатьСкидки
| ТОГДА РеализацияТоваровУслуг.Цена
| ИНАЧЕ РеализацияТоваровУслуг.СуммаСНДС / РеализацияТоваровУслуг.КоличествоУпаковок
| КОНЕЦ КАК Цена,
| РеализацияТоваровУслуг.Количество КАК Количество,
| РеализацияТоваровУслуг.КоличествоУпаковок КАК КоличествоУпаковок,
| ВЫБОР
| КОГДА РеализацияТоваровУслуг.Ссылка.ЦенаВключаетНДС
| ТОГДА РеализацияТоваровУслуг.СуммаСНДС
| ИНАЧЕ РеализацияТоваровУслуг.СуммаСНДС - РеализацияТоваровУслуг.СуммаНДС
| КОНЕЦ КАК Сумма,
| ВЫБОР
| КОГДА &ОтображатьСкидки ТОГДА
| РеализацияТоваровУслуг.СуммаРучнойСкидки + РеализацияТоваровУслуг.СуммаАвтоматическойСкидки
| ИНАЧЕ 0
| КОНЕЦ КАК СуммаСкидки,
| РеализацияТоваровУслуг.СуммаСНДС + РеализацияТоваровУслуг.СуммаРучнойСкидки
| + РеализацияТоваровУслуг.СуммаАвтоматическойСкидки КАК СуммаБезСкидки,
| РеализацияТоваровУслуг.СуммаНДС КАК СуммаНДС,
| ВЫБОР
| КОГДА НЕ &ИспользоватьУчетПрослеживаемыхИмпортныхТоваров
| ИЛИ НАЧАЛОПЕРИОДА(РеализацияТоваровУслуг.Ссылка.Дата, МЕСЯЦ) < &ДатаНачалаУчетаПрослеживаемыхИмпортныхТоваров
| ТОГДА 0
| ИНАЧЕ РеализацияТоваровУслуг.КоличествоПоРНПТ
| КОНЕЦ КАК КоличествоПоРНПТ,
| ВЫБОР
| КОГДА НЕ &ИспользоватьУчетПрослеживаемыхИмпортныхТоваров
| ИЛИ НАЧАЛОПЕРИОДА(РеализацияТоваровУслуг.Ссылка.Дата, МЕСЯЦ) < &ДатаНачалаУчетаПрослеживаемыхИмпортныхТоваров
| ТОГДА ЗНАЧЕНИЕ(Справочник.НомераГТД.ПустаяСсылка)
| ИНАЧЕ РеализацияТоваровУслуг.НомерГТД
| КОНЕЦ КАК НомерГТД
|ПОМЕСТИТЬ Товары
|ИЗ
| Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК РеализацияТоваровУслуг
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВариантыКомплектацииНоменклатуры КАК ВариантыКомплектацииНоменклатуры
| ПО ВариантыКомплектацииНоменклатуры.Владелец = РеализацияТоваровУслуг.АналитикаУчетаНаборов.НоменклатураНабора
| И ВариантыКомплектацииНоменклатуры.Характеристика = РеализацияТоваровУслуг.АналитикаУчетаНаборов.ХарактеристикаНабора
| И ВариантыКомплектацииНоменклатуры.Основной
|
|ГДЕ
| РеализацияТоваровУслуг.Ссылка В(&МассивДокументов)
| И &УсловиеПоТипуНоменклатуры
|;
|
|//////////////////////////////////////////////////////////////////////////////// 2
|ВЫБРАТЬ
| ТаблицаТоваров.Ссылка КАК Ссылка,
| МИНИМУМ(ТаблицаТоваров.НомерСтроки) КАК НомерСтроки,
| ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
| ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
| СУММА(ТаблицаТоваров.Сумма) КАК Сумма,
| СУММА(ТаблицаТоваров.СуммаБезСкидки) КАК СуммаБезСкидки,
| СУММА(ТаблицаТоваров.СуммаСкидки) КАК СуммаСкидки,
| СУММА(ТаблицаТоваров.СуммаНДС) КАК СуммаНДС
|ПОМЕСТИТЬ ВременнаяТаблицаНаборыПодготовка
|ИЗ
| Товары КАК ТаблицаТоваров
|
|ГДЕ
| ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
|
|СГРУППИРОВАТЬ ПО
| ТаблицаТоваров.Ссылка,
| ТаблицаТоваров.НоменклатураНабора,
| ТаблицаТоваров.ХарактеристикаНабора
|;
|
|//////////////////////////////////////////////////////////////////////////////// 3
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| ТаблицаТоваров.Ссылка КАК Ссылка
|ПОМЕСТИТЬ ТоварыРазличные
|ИЗ
| Товары КАК ТаблицаТоваров
|;
|
|//////////////////////////////////////////////////////////////////////////////// 4
|ВЫБРАТЬ
| Товары.Ссылка КАК Ссылка,
| Товары.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
| Товары.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| Товары.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| Товары.НоменклатураНабора КАК НоменклатураНабора,
| Товары.ХарактеристикаНабора КАК ХарактеристикаНабора,
| Товары.Номенклатура КАК Номенклатура,
| Товары.Характеристика КАК Характеристика,
| ВЫБОР
| КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
| И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ОсновнаяКомплектующая,
| Товары.СтавкаНДС КАК СтавкаНДС,
| 0 КАК КоличествоПоУмолчанию,
| Товары.Количество КАК Количество
|ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительноЧастьПервая
|ИЗ
| Товары КАК Товары
|
|ГДЕ
| Товары.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ТоварыРазличные.Ссылка КАК Ссылка,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка КАК ВариантКомплектацииНоменклатуры,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец КАК НоменклатураНабора,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика КАК ХарактеристикаНабора,
| ВариантыКомплектацииНоменклатурыТовары.Номенклатура КАК Номенклатура,
| ВариантыКомплектацииНоменклатурыТовары.Характеристика КАК Характеристика,
| ЛОЖЬ КАК ОсновнаяКомплектующая,
| NULL КАК СтавкаНДС,
| СУММА(ВариантыКомплектацииНоменклатурыТовары.Количество) КАК КоличествоПоУмолчанию,
| 0 КАК Количество
|ИЗ
| Справочник.ВариантыКомплектацииНоменклатуры.Товары КАК ВариантыКомплектацииНоменклатурыТовары
| ЛЕВОЕ СОЕДИНЕНИЕ ТоварыРазличные КАК ТоварыРазличные
| ПО ИСТИНА
|
|ГДЕ
| ВариантыКомплектацииНоменклатурыТовары.Ссылка В
| (ВЫБРАТЬ
| Т.ВариантКомплектацииНоменклатуры
| ИЗ
| Товары КАК Т)
|
|СГРУППИРОВАТЬ ПО
| ТоварыРазличные.Ссылка,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец,
| ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика,
| ВариантыКомплектацииНоменклатурыТовары.Номенклатура,
| ВариантыКомплектацииНоменклатурыТовары.Характеристика,
| ВариантыКомплектацииНоменклатурыТовары.Упаковка
|;
|
|//////////////////////////////////////////////////////////////////////////////// 5
|ВЫБРАТЬ
| Таблица.Ссылка КАК Ссылка,
| Таблица.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
| Таблица.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| Таблица.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| Таблица.НоменклатураНабора КАК НоменклатураНабора,
| Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
| Таблица.Номенклатура КАК Номенклатура,
| Таблица.Характеристика КАК Характеристика,
| МАКСИМУМ(Таблица.СтавкаНДС) КАК СтавкаНДС,
| МАКСИМУМ(Таблица.ОсновнаяКомплектующая) КАК ОсновнаяКомплектующая,
| СУММА(Таблица.КоличествоПоУмолчанию) КАК КоличествоПоУмолчанию,
| СУММА(Таблица.Количество) КАК Количество
|ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительноЧастьВторая
|ИЗ
| ВременнаяТаблицаНаборыДополнительноЧастьПервая КАК Таблица
|
|СГРУППИРОВАТЬ ПО
| Таблица.Ссылка,
| Таблица.ВариантКомплектацииНоменклатуры,
| Таблица.ВариантРасчетаЦеныНабора,
| Таблица.ВариантПредставленияНабораВПечатныхФормах,
| Таблица.НоменклатураНабора,
| Таблица.ХарактеристикаНабора,
| Таблица.Номенклатура,
| Таблица.Характеристика
|;
|
|//////////////////////////////////////////////////////////////////////////////// 6
|ВЫБРАТЬ
| Результат.Ссылка КАК Ссылка,
| Результат.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
| Результат.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| Результат.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| Результат.НоменклатураНабора КАК НоменклатураНабора,
| Результат.ХарактеристикаНабора КАК ХарактеристикаНабора,
| МАКСИМУМ(ВЫБОР
| КОГДА Результат.ОсновнаяКомплектующая
| ТОГДА Результат.СтавкаНДС
| ИНАЧЕ NULL
| КОНЕЦ) КАК СтавкаНДС,
| ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
| КОГДА Результат.КоличествоПоУмолчанию <> 0
| И Результат.ОсновнаяКомплектующая
| ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
| ИНАЧЕ NULL
| КОНЕЦ) + 0.5 КАК Число(10,0)) - 1 КАК Количество,
| МАКСИМУМ(ВЫБОР
| КОГДА Результат.КоличествоПоУмолчанию <> 0
| ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
| ИНАЧЕ NULL
| КОНЕЦ) КАК КоэффициентМаксимум,
| ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
| КОГДА Результат.КоличествоПоУмолчанию <> 0
| ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
| ИНАЧЕ NULL
| КОНЕЦ) + 0.5 КАК Число(10,0)) - 1 КАК КоэффициентМинимум
|ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительно
|ИЗ
| ВременнаяТаблицаНаборыДополнительноЧастьВторая КАК Результат
|
|СГРУППИРОВАТЬ ПО
| Результат.Ссылка,
| Результат.ВариантКомплектацииНоменклатуры,
| Результат.ВариантРасчетаЦеныНабора,
| Результат.ВариантПредставленияНабораВПечатныхФормах,
| Результат.НоменклатураНабора,
| Результат.ХарактеристикаНабора
|;
|
|//////////////////////////////////////////////////////////////////////////////// 7
|ВЫБРАТЬ
| Таблица.Ссылка КАК Ссылка,
| Таблица.НомерСтроки КАК НомерСтроки,
| ВременнаяТаблицаНаборыДополнительно.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
| ВЫБОР
| КОГДА Таблица.Ссылка.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
| ТОГДА ВЫБОР
| КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
| ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
| КОНЕЦ
| ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
| КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
| ВЫБОР
| КОГДА Таблица.Ссылка.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
| ТОГДА ВЫБОР
| КОГДА ВЫБОР
| КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
| ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
| КОНЕЦ = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
| И ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора В(ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоЦенам),
| ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоДолям))
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.РассчитываетсяИзЦенКомплектующих)
| ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
| КОНЕЦ
| ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
| КОНЕЦ КАК ВариантРасчетаЦеныНабора,
| Таблица.НоменклатураНабора КАК НоменклатураНабора,
| Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
| ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК КоличествоУпаковок,
| ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК Количество,
| ВЫБОР
| КОГДА ВременнаяТаблицаНаборыДополнительно.КоэффициентМинимум = ВременнаяТаблицаНаборыДополнительно.КоэффициентМаксимум
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ПолныйНабор,
| Таблица.Сумма КАК Сумма,
| Таблица.СуммаБезСкидки КАК СуммаБезСкидки,
| Таблица.СуммаСкидки КАК СуммаСкидки,
| Таблица.СуммаНДС КАК СуммаНДС,
| ВременнаяТаблицаНаборыДополнительно.СтавкаНДС КАК СтавкаНДС
|ПОМЕСТИТЬ ВременнаяТаблицаНаборы
|ИЗ
| ВременнаяТаблицаНаборыПодготовка КАК Таблица
| ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборыДополнительно КАК ВременнаяТаблицаНаборыДополнительно
| ПО Таблица.НоменклатураНабора = ВременнаяТаблицаНаборыДополнительно.НоменклатураНабора
| И Таблица.ХарактеристикаНабора = ВременнаяТаблицаНаборыДополнительно.ХарактеристикаНабора
| И Таблица.Ссылка = ВременнаяТаблицаНаборыДополнительно.Ссылка
|;
|
|//////////////////////////////////////////////////////////////////////////////// 8
|ВЫБРАТЬ
| ВложенныйЗапрос.Ссылка КАК Ссылка,
| ВложенныйЗапрос.НомерСтроки КАК НомерСтроки,
| ВложенныйЗапрос.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| ВложенныйЗапрос.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| ВложенныйЗапрос.НоменклатураНабора КАК НоменклатураНабора,
| ВложенныйЗапрос.ХарактеристикаНабора КАК ХарактеристикаНабора,
| ВложенныйЗапрос.ЭтоНабор КАК ЭтоНабор,
| ВложенныйЗапрос.ЭтоКомплектующие КАК ЭтоКомплектующие,
| ВложенныйЗапрос.ПолныйНабор КАК ПолныйНабор,
| ВложенныйЗапрос.Номенклатура КАК Номенклатура,
| ВложенныйЗапрос.Номенклатура.НаименованиеПолное КАК ТоварНаименованиеПолное,
| ВложенныйЗапрос.Номенклатура.Код КАК Код,
| ВложенныйЗапрос.Номенклатура.Артикул КАК Артикул,
| ВложенныйЗапрос.ЕдиницаИзмерения.Наименование КАК ЕдиницаЦены,
| ВложенныйЗапрос.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
| ВложенныйЗапрос.Номенклатура.ЕдиницаИзмеренияТНВЭД.Представление КАК ЕдиницаИзмеренияТНВЭД,
| ВложенныйЗапрос.Характеристика.НаименованиеПолное КАК Характеристика,
| ВЫБОР
| КОГДА ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки2, 1) = 1
| ТОГДА НЕОПРЕДЕЛЕНО
| ИНАЧЕ ВложенныйЗапрос.Упаковка.Наименование
| КОНЕЦ КАК Упаковка,
| ВложенныйЗапрос.КоличествоУпаковок КАК Количество,
| ВложенныйЗапрос.КоличествоПоРНПТ КАК КоличествоПоРНПТ,
| ВложенныйЗапрос.НомерГТД КАК НомерГТД,
| ВложенныйЗапрос.НомерГТД.ТипНомераГТД КАК ТипНомераГТД,
| ВЫБОР
| КОГДА ВложенныйЗапрос.НомерГТД.РегистрационныйНомер = """"
| ТОГДА ВложенныйЗапрос.НомерГТД.Представление
| ИНАЧЕ ВложенныйЗапрос.НомерГТД.РегистрационныйНомер
| КОНЕЦ КАК НомерРНПТ,
| ВложенныйЗапрос.Цена КАК Цена,
| ВложенныйЗапрос.Сумма КАК Сумма,
| ВложенныйЗапрос.СуммаСкидки КАК СуммаСкидки,
| ВложенныйЗапрос.СуммаБезСкидки КАК СуммаБезСкидки,
| ВложенныйЗапрос.СтавкаНДС КАК СтавкаНДС,
| ВложенныйЗапрос.СуммаНДС КАК СуммаНДС,
| ВЫБОР
| КОГДА ВложенныйЗапрос.Ссылка.ВернутьМногооборотнуюТару
| И ВложенныйЗапрос.Номенклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ЭтоВозвратнаяТара
|ИЗ
| (ВЫБРАТЬ
| Таблица.Ссылка КАК Ссылка,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
| ТОГДА ВременнаяТаблицаНаборы.НомерСтроки
| ИНАЧЕ Таблица.НомерСтроки
| КОНЕЦ КАК НомерСтроки,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
| ТОГДА ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах
| ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)
| КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
| ТОГДА ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора
| ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)
| КОНЕЦ КАК ВариантРасчетаЦеныНабора,
| Таблица.НоменклатураНабора КАК НоменклатураНабора,
| Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ЭтоКомплектующие,
| ЛОЖЬ КАК ЭтоНабор,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
| ТОГДА ВременнаяТаблицаНаборы.ПолныйНабор
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК ПолныйНабор,
| Таблица.Номенклатура КАК Номенклатура,
| Таблица.Количество КАК Количество,
| Таблица.КоличествоУпаковок КАК КоличествоУпаковок,
| Таблица.КоличествоПоРНПТ КАК КоличествоПоРНПТ,
| Таблица.НомерГТД КАК НомерГТД,
| Таблица.Цена КАК Цена,
| Таблица.Сумма КАК Сумма,
| Таблица.СтавкаНДС КАК СтавкаНДС,
| Таблица.СуммаНДС КАК СуммаНДС,
| Таблица.Характеристика КАК Характеристика,
| Таблица.Упаковка КАК Упаковка,
| Таблица.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
| Таблица.СуммаСкидки КАК СуммаСкидки,
| Таблица.СуммаБезСкидки КАК СуммаБезСкидки
| ИЗ
| Товары КАК Таблица
| ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
| ПО ВременнаяТаблицаНаборы.НоменклатураНабора = Таблица.НоменклатураНабора
| И ВременнаяТаблицаНаборы.ХарактеристикаНабора = Таблица.ХарактеристикаНабора
| И ВременнаяТаблицаНаборы.Ссылка = Таблица.Ссылка
|
| ГДЕ
| Таблица.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| ИЛИ (Таблица.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| И ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В(ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоКомплектующие),
| ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)))
|
| ОБЪЕДИНИТЬ ВСЕ
|
| ВЫБРАТЬ
| ВременнаяТаблицаНаборы.Ссылка КАК Ссылка,
| ВременнаяТаблицаНаборы.НомерСтроки КАК НомерСтроки,
| ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
| ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
| ВременнаяТаблицаНаборы.НоменклатураНабора КАК НоменклатураНабора,
| ВременнаяТаблицаНаборы.ХарактеристикаНабора КАК ХарактеристикаНабора,
| ЛОЖЬ КАК ЭтоКомплектующие,
| ИСТИНА КАК ЭтоНабор,
| ВременнаяТаблицаНаборы.ПолныйНабор КАК ПолныйНабор,
| ВременнаяТаблицаНаборы.НоменклатураНабора КАК Номенклатура,
| ВременнаяТаблицаНаборы.Количество КАК Количество,
| ВременнаяТаблицаНаборы.КоличествоУпаковок КАК КоличествоУпаковок,
| 0 КАК КоличествоПоРНПТ,
| ЗНАЧЕНИЕ(Справочник.НомераГТД.ПустаяСсылка) КАК НомерГТД,
| ВЫБОР
| КОГДА &ОтображатьСкидки
| ТОГДА ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.КоличествоУпаковок, 1) <> 0
| ТОГДА (ВременнаяТаблицаНаборы.СуммаБезСкидки) / ЕСТЬNULL(ВременнаяТаблицаНаборы.КоличествоУпаковок, 1)
| ИНАЧЕ 0
| КОНЕЦ
| ИНАЧЕ ВЫБОР
| КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.КоличествоУпаковок, 1) <> 0
| ТОГДА (ВременнаяТаблицаНаборы.Сумма) / ЕСТЬNULL(ВременнаяТаблицаНаборы.КоличествоУпаковок, 1)
| ИНАЧЕ 0
| КОНЕЦ
| КОНЕЦ КАК Цена,
| ВременнаяТаблицаНаборы.Сумма КАК Сумма,
| ВременнаяТаблицаНаборы.СтавкаНДС КАК СтавкаНДС,
| ВременнаяТаблицаНаборы.СуммаНДС КАК СуммаНДС,
| ВременнаяТаблицаНаборы.ХарактеристикаНабора КАК Характеристика,
| ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка) КАК Упаковка,
| ВременнаяТаблицаНаборы.НоменклатураНабора.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
| ВременнаяТаблицаНаборы.СуммаСкидки КАК СуммаСкидки,
| ВременнаяТаблицаНаборы.СуммаБезСкидки КАК СуммаБезСкидки
| ИЗ
| ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
|
| ГДЕ
| ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В(ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор),
| ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие))
| ) КАК ВложенныйЗапрос
|
|УПОРЯДОЧИТЬ ПО
| ВложенныйЗапрос.Ссылка,
| НомерСтроки,
| ЭтоНабор УБЫВ
|
|ИТОГИ
| СУММА(СуммаСкидки)
|ПО
| Ссылка
|;
|
|//////////////////////////////////////////////////////////////////////////////// 10
|ВЫБРАТЬ
| Товары.Ссылка КАК Ссылка,
| МАКСИМУМ(ВЫБОР
| КОГДА &ИспользоватьУчетПрослеживаемыхИмпортныхТоваров
| И НАЧАЛОПЕРИОДА(Товары.Ссылка.Дата, МЕСЯЦ) >= &ДатаНачалаУчетаПрослеживаемыхИмпортныхТоваров
| И ЕСТЬNULL(Товары.Ссылка.Соглашение.КомиссионерВедетУчетПоРНПТ, ЛОЖЬ)
| И Товары.Ссылка.ХозяйственнаяОперация В(ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию),
| ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионера))
| И ЕСТЬNULL(Товары.НомерГТД.ТипНомераГТД, НЕОПРЕДЕЛЕНО) В(ЗНАЧЕНИЕ(Перечисление.ТипыНомеровГТД.НомерРНПТ),
| ЗНАЧЕНИЕ(Перечисление.ТипыНомеровГТД.НомерРНПТКомплекта))
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ) КАК ЕстьРНПТ
|ИЗ
| Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК Товары
|
|ГДЕ
| Товары.Ссылка В(&МассивДокументов)
| И Товары.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры
| В (ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Товар),
| ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара))
|
|СГРУППИРОВАТЬ ПО
| Товары.Ссылка
|
|УПОРЯДОЧИТЬ ПО
| Товары.Ссылка
|;
|
|//////////////////////////////////////////////////////////////////////////////// 10
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| ТаблицаДокумента.НомерГТД КАК НомерГТД,
| ВЫБОР
| КОГДА Комплектующие.НомерРНПТ.РегистрационныйНомер = """"
| ТОГДА Комплектующие.НомерРНПТ
| ИНАЧЕ Комплектующие.НомерРНПТ.РегистрационныйНомер
| КОНЕЦ КАК НомерРНПТ,
| Комплектующие.КоличествоПоРНПТ КАК КоличествоПоРНПТ,
| Комплектующие.ЕдиницаИзмеренияТНВЭД.Представление КАК ЕдиницаИзмеренияТНВЭД
|ИЗ
| Товары КАК ТаблицаДокумента
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.НомераГТД.ПрослеживаемыеКомплектующие КАК Комплектующие
| ПО ТаблицаДокумента.НомерГТД = Комплектующие.Ссылка";
Запрос.Текст = СтрЗаменить(Запрос.Текст,
"&ТекстЗапросаКоэффициентУпаковки1",
Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаКоэффициентаУпаковки(
"РеализацияТоваровУслуг.Упаковка",
"РеализацияТоваровУслуг.АналитикаУчетаНоменклатуры.Номенклатура"));
Запрос.Текст = СтрЗаменить(Запрос.Текст,
"&ТекстЗапросаКоэффициентУпаковки2",
Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаКоэффициентаУпаковки(
"ВложенныйЗапрос.Упаковка",
"ВложенныйЗапрос.Номенклатура"));
Если ОбщегоНазначенияУТКлиентСервер.АвторизованВнешнийПользователь() Тогда
УсловиеПоТипуНоменклатуры = "ИСТИНА";
Иначе
УсловиеПоТипуНоменклатуры =
"РеализацияТоваровУслуг.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры В(ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Товар),
| ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара))";
КонецЕсли;
Запрос.Текст = СтрЗаменить(Запрос.Текст, "&УсловиеПоТипуНоменклатуры", УсловиеПоТипуНоменклатуры);
Запрос.УстановитьПараметр("МассивДокументов", МассивОбъектов);
Запрос.УстановитьПараметр("ОтображатьСкидки", ОтображатьСкидки);
УчетПрослеживаемыхТоваровЛокализация.УстановитьПараметрыИспользованияУчетаПрослеживаемыхТоваров(Запрос);
ТабличныйДокумент = Новый ТабличныйДокумент;
ТабличныйДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_РеализацияТоваровУслуг_Накладная";
МассивРезультатов = Запрос.ВыполнитьПакет();
РезультатДанныеПечати = МассивРезультатов[0]; // РезультатЗапроса -
РезультатВыборкаПоДокументам = МассивРезультатов[8]; // РезультатЗапроса -
ДанныеПрослеживаемостиДокументов = МассивРезультатов[9].Выгрузить(); // ТаблицаЗначений -
ПрослеживаемыеКомплектующие = МассивРезультатов[10].Выгрузить(); // ТаблицаЗначений -
ДанныеПечати = РезультатДанныеПечати.Выбрать();
ВыборкаПоДокументам = РезультатВыборкаПоДокументам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
ПоказыватьНДС = Константы.ВыводитьДопКолонкиНДС.Получить();
ПервыйДокумент = Истина;
ЕстьРНПТ = Ложь;
ДанныеПрослеживаемостиДокументов.Индексы.Добавить("Ссылка");
Пока ДанныеПечати.Следующий() Цикл
// Найдем в выборке товары по текущему документу
СтруктураПоиска = Новый Структура("Ссылка", ДанныеПечати.Ссылка);
НайденСледующий = ВыборкаПоДокументам.НайтиСледующий(СтруктураПоиска);
// Если в накладной только услуги - перейдем к следующему документу
Если НайденСледующий Тогда
ВыборкаПоТоварам = ВыборкаПоДокументам.Выбрать();
ЗаголовокСкидки = ФормированиеПечатныхФорм.НужноВыводитьСкидки(ВыборкаПоТоварам,
ИспользоватьРучныеСкидки
Или ИспользоватьАвтоматическиеСкидки);
ЕстьСкидки = ЗаголовокСкидки.ЕстьСкидки;
ЕстьНДС = ДанныеПечати.УчитыватьНДС;
ЕстьРНПТ = Ложь;
ОтборСтрокДокументов = Новый Структура("Ссылка", ДанныеПечати.Ссылка);
СтрокиДокументов = ДанныеПрослеживаемостиДокументов.НайтиСтроки(ОтборСтрокДокументов);
Если СтрокиДокументов.Количество() > 0 Тогда
ЕстьРНПТ = СтрокиДокументов[0].ЕстьРНПТ;
КонецЕсли;
ВыборкаПоТоварам.Сбросить();
Иначе
#Удаление
Текст = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'В документе %1 отсутствуют товары. Печать накладной не требуется'"),
ДанныеПечати.Ссылка);
ОбщегоНазначения.СообщитьПользователю(Текст, ДанныеПечати.Ссылка);
#КонецУдаления
Продолжить;
КонецЕсли;
// Макет необходимо получать для каждого документа, т.к. размеры колонок изменяются динамически.
Макет = УправлениеПечатью.МакетПечатнойФормы("Документ.РеализацияТоваровУслуг.ПФ_MXL_РеализацияТоваров");
Если Не ПервыйДокумент Тогда
ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
КонецЕсли;
ПервыйДокумент = Ложь;
НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;
// Выводим шапку накладной
ОбластьМакета = Макет.ПолучитьОбласть("Заголовок");
ШтрихкодированиеПечатныхФорм.ВывестиШтрихкодВТабличныйДокумент(ТабличныйДокумент,
Макет,
ОбластьМакета,
ДанныеПечати.Ссылка);
ТекстЗаголовка = ОбщегоНазначенияУТКлиентСервер.СформироватьЗаголовокДокумента(
ДанныеПечати,
НСтр("ru='Реализация товаров'", ОбщегоНазначения.КодОсновногоЯзыка()));
СтруктураДанныхШапки = Новый Структура;
СтруктураДанныхШапки.Вставить("ТекстЗаголовка", ТекстЗаголовка);
ОбластьМакета.Параметры.Заполнить(СтруктураДанныхШапки);
ТабличныйДокумент.Вывести(ОбластьМакета);
ОбластьМакета = Макет.ПолучитьОбласть("ЗаголовокПодчеркивание");
Если ЕстьРНПТ Тогда
ОбластьМакета = Макет.ПолучитьОбласть("ЗаголовокПодчеркиваниеРНПТ");
КонецЕсли;
ТабличныйДокумент.Вывести(ОбластьМакета);
ОбластьМакета = Макет.ПолучитьОбласть("Поставщик");
ПредставлениеПоставщика = ФормированиеПечатныхФорм.ОписаниеОрганизации(
ФормированиеПечатныхФорм.СведенияОЮрФизЛице(ДанныеПечати.Организация, ДанныеПечати.Дата),
"ПолноеНаименование");
СтруктураДанныхПоставщик = Новый Структура;
СтруктураДанныхПоставщик.Вставить("ПредставлениеПоставщика", ПредставлениеПоставщика);
СтруктураДанныхПоставщик.Вставить("Поставщик", ДанныеПечати.Организация);
ОбластьМакета.Параметры.Заполнить(СтруктураДанныхПоставщик);
ТабличныйДокумент.Вывести(ОбластьМакета);
ОбластьМакета = Макет.ПолучитьОбласть("Покупатель");
ПредставлениеПолучателя = ФормированиеПечатныхФорм.ОписаниеОрганизации(
ФормированиеПечатныхФорм.СведенияОЮрФизЛице(ДанныеПечати.Получатель, ДанныеПечати.Дата),
"ПолноеНаименование");
СтруктураДанныхПокупатель = Новый Структура;
СтруктураДанныхПокупатель.Вставить("ПредставлениеПолучателя", ПредставлениеПолучателя);
СтруктураДанныхПокупатель.Вставить("Получатель", ДанныеПечати.Получатель);
ОбластьМакета.Параметры.Заполнить(СтруктураДанныхПокупатель);
ТабличныйДокумент.Вывести(ОбластьМакета);
// Выводим заголовок таблицы Товары
НазванияОбластейСтрок = НазванияОбластейСтрок(ЕстьСкидки, ЕстьНДС И ПоказыватьНДС, ЕстьРНПТ);
НазванияОбластейКолонок = НазванияОбластейКолонок(ЕстьСкидки, ЕстьНДС И ПоказыватьНДС, ЕстьРНПТ);
ОбластьКолонкаТовар = Макет.Область(НазванияОбластейКолонок.ПерваяКолонкаТовара);
ОбластьКолонкаТовар.ШиринаКолонки = ОбластьКолонкаТовар.ШиринаКолонки
+ ?(ВыводитьКоды,
0,
Макет.Область(НазванияОбластейКолонок.КолонкаКодов).ШиринаКолонки);
ОбластьНомера = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодов = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТовар = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличество = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеНомерРНПТ = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеНомерРНПТ);
ОбластьДанныеСуммовые = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ШапкаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ТабличныйДокумент.Вывести(ОбластьНомера);
Если ВыводитьКоды Тогда
СтруктураДанныхКоды = Новый Структура("ИмяКолонкиКодов", ПредставлениеКолонкиКодов);
ОбластьКодов.Параметры.Заполнить(СтруктураДанныхКоды);
ТабличныйДокумент.Присоединить(ОбластьКодов);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТовар);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличество);
Если ЕстьРНПТ Тогда
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПТ);
КонецЕсли;
Если ЕстьСкидки Тогда
СтруктураЗаголовокСкидки = Новый Структура("Скидка, СуммаБезСкидки",
ЗаголовокСкидки.Скидка, ЗаголовокСкидки.СуммаСкидки);
ОбластьДанныеСуммовые.Параметры.Заполнить(СтруктураЗаголовокСкидки);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовые);
ОбластьНомераСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодовСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТоварСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличествоСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеНомерРНПТСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеНомерРНПТ);
ОбластьДанныеСуммовыеСтрокиСтандарт = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ИспользоватьНаборы = Ложь;
Если ОбщегоНазначенияУТКлиентСервер.ЕстьРеквизитОбъекта(ВыборкаПоДокументам, "ЭтоНабор") Тогда
ИспользоватьНаборы = Истина;
ОбластьНомераСтрокиНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодовСтрокиНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТоварСтрокиНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличествоСтрокиНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеНомерРНПТСтрокиНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.ДанныеНомерРНПТ);
ОбластьДанныеСуммовыеНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНабор
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ОбластьНомераСтрокиКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодовСтрокиКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТоварСтрокиКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличествоКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеНомерРНПТСтрокиКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.ДанныеНомерРНПТ);
ОбластьДанныеСуммовыеКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующие
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
КонецЕсли;
Сумма = 0;
СуммаНДС = 0;
ВсегоСкидок = 0;
НомерСтроки = 0;
ВсегоБезСкидок = 0;
ПустыеДанные = НаборыСервер.ПустыеДанные();
// Выводим строки таблицы Товары
Пока ВыборкаПоТоварам.Следующий() Цикл
Если НаборыСервер.ИспользоватьОбластьНабор(ВыборкаПоТоварам, ИспользоватьНаборы) Тогда
ОбластьКодовСтроки = ОбластьКодовСтрокиНабор;
ОбластьНомераСтроки = ОбластьНомераСтрокиНабор;
ОбластьТоварСтроки = ОбластьТоварСтрокиНабор;
ОбластьДанныеКоличествоСтроки = ОбластьДанныеКоличествоСтрокиНабор;
ОбластьДанныеНомерРНПСтроки = ОбластьДанныеНомерРНПТСтрокиНабор;
ОбластьДанныеСуммовыеСтроки = ОбластьДанныеСуммовыеНабор;
ИначеЕсли НаборыСервер.ИспользоватьОбластьКомплектующие(ВыборкаПоТоварам, ИспользоватьНаборы) Тогда
ОбластьКодовСтроки = ОбластьКодовСтрокиКомплектующие;
ОбластьНомераСтроки = ОбластьНомераСтрокиКомплектующие;
ОбластьТоварСтроки = ОбластьТоварСтрокиКомплектующие;
ОбластьДанныеКоличествоСтроки = ОбластьДанныеКоличествоКомплектующие;
ОбластьДанныеНомерРНПСтроки = ОбластьДанныеНомерРНПТСтрокиКомплектующие;
ОбластьДанныеСуммовыеСтроки = ОбластьДанныеСуммовыеКомплектующие;
Иначе
ОбластьКодовСтроки = ОбластьКодовСтрокиСтандарт;
ОбластьНомераСтроки = ОбластьНомераСтрокиСтандарт;
ОбластьТоварСтроки = ОбластьТоварСтрокиСтандарт;
ОбластьДанныеКоличествоСтроки = ОбластьДанныеКоличествоСтрокиСтандарт;
ОбластьДанныеНомерРНПСтроки = ОбластьДанныеНомерРНПТСтрокиСтандарт;
ОбластьДанныеСуммовыеСтроки = ОбластьДанныеСуммовыеСтрокиСтандарт;
КонецЕсли;
Если НаборыСервер.ВыводитьТолькоЗаголовок(ВыборкаПоТоварам, ИспользоватьНаборы) Тогда
УстановитьПараметр(ОбластьНомераСтроки, "НомерСтроки", Неопределено);
Иначе
НомерСтроки = НомерСтроки + 1;
УстановитьПараметр(ОбластьНомераСтроки, "НомерСтроки", НомерСтроки);
КонецЕсли;
Если ВыводитьКоды Тогда
СтруктураДанныхКоды = Новый Структура("Артикул", ВыборкаПоТоварам[ИмяКолонкиКодов]);
ОбластьКодовСтроки.Параметры.Заполнить(СтруктураДанныхКоды);
КонецЕсли;
ПрефиксИПостфикс = НаборыСервер.ПолучитьПрефиксИПостфикс(ВыборкаПоТоварам, ИспользоватьНаборы);
ОбластьТоварСтроки.Параметры.Заполнить(ВыборкаПоТоварам);
ДополнительныеПараметрыПолученияНаименованияДляПечати = НоменклатураКлиентСервер.ДополнительныеПараметрыПредставлениеНоменклатурыДляПечати();
ДополнительныеПараметрыПолученияНаименованияДляПечати.ВозвратнаяТара = ВыборкаПоТоварам.ЭтоВозвратнаяТара;
ДополнительныеПараметрыПолученияНаименованияДляПечати.КодОсновногоЯзыка = ОбщегоНазначения.КодОсновногоЯзыка();
ПредставлениеНоменклатуры = НоменклатураКлиентСервер.ПредставлениеНоменклатурыДляПечати(
ВыборкаПоТоварам.ТоварНаименованиеПолное,
ВыборкаПоТоварам.Характеристика,
,
,
ДополнительныеПараметрыПолученияНаименованияДляПечати);
Товар = ПрефиксИПостфикс.Префикс + ПредставлениеНоменклатуры + ПрефиксИПостфикс.Постфикс;
СтруктураДанныхТовар = Новый Структура("Товар", Товар);
ОбластьТоварСтроки.Параметры.Заполнить(СтруктураДанныхТовар);
Если ЗаголовокСкидки.ЕстьСкидки Тогда
СуммаСкидки = ?(ЗаголовокСкидки.ТолькоНаценка, - ВыборкаПоТоварам.СуммаСкидки, ВыборкаПоТоварам.СуммаСкидки);
СтруктураДанныхСуммаСкидки = Новый Структура("СуммаСкидки", СуммаСкидки);
ОбластьДанныеСуммовыеСтроки.Параметры.Заполнить(СтруктураДанныхСуммаСкидки);
КонецЕсли;
Если НаборыСервер.ВыводитьТолькоЗаголовок(ВыборкаПоТоварам, ИспользоватьНаборы) Тогда
ОбластьДанныеКоличествоСтроки.Параметры.Заполнить(ПустыеДанные);
ОбластьДанныеСуммовыеСтроки.Параметры.Заполнить(ПустыеДанные);
Иначе
ОбластьДанныеКоличествоСтроки.Параметры.Заполнить(ВыборкаПоТоварам);
ОбластьДанныеСуммовыеСтроки.Параметры.Заполнить(ВыборкаПоТоварам);
КонецЕсли;
Если ЕстьРНПТ
И ЗначениеЗаполнено(ВыборкаПоТоварам.НомерГТД)
И ВыборкаПоТоварам.НомерГТД <> Перечисления.ТипыНомеровГТД.НомерГТД Тогда
Если ВыборкаПоТоварам.ТипНомераГТД = Перечисления.ТипыНомеровГТД.НомерРНПТ Тогда
ДанныеНомераРНПТ = Новый Структура("НомерРНПТ, КоличествоПоРНПТ, ЕдиницаИзмеренияТНВЭД");
ДанныеНомераРНПТ.НомерРНПТ = СокрЛП(ВыборкаПоТоварам.НомерРНПТ);
ДанныеНомераРНПТ.КоличествоПоРНПТ = ВыборкаПоТоварам.КоличествоПоРНПТ;
ДанныеНомераРНПТ.ЕдиницаИзмеренияТНВЭД = СокрЛП(ВыборкаПоТоварам.ЕдиницаИзмеренияТНВЭД);
ОбластьДанныеНомерРНПСтроки.Параметры.Заполнить(ДанныеНомераРНПТ);
ТабличныйДокумент.Вывести(ОбластьНомераСтроки);
Если ВыводитьКоды Тогда
ТабличныйДокумент.Присоединить(ОбластьКодовСтроки);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТоварСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличествоСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовыеСтроки);
Иначе
ОбластьНомераСтрокиРНПТНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНаборРНПТ
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодовСтрокиРНПТНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНаборРНПТ
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТоварСтрокиРНПТНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНаборРНПТ
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличествоСтрокиРНПТНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНаборРНПТ
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеСуммовыеСтрокиРНПТНабор = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыНаборРНПТ
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ОбластьНомераСтрокиРНПТКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующиеРНПТ
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодовСтрокиРНПТКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующиеРНПТ
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТоварСтрокиРНПТКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующиеРНПТ
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличествоСтрокиРНПТКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующиеРНПТ
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеСуммовыеСтрокиРНПТКомплектующие = Макет.ПолучитьОбласть(НазванияОбластейСтрок.СтрокаТаблицыКомплектующиеРНПТ
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ОбластьНомераСтрокиРНПТНабор.Параметры.Заполнить(ОбластьНомераСтроки.Параметры);
ОбластьКодовСтрокиРНПТНабор.Параметры.Заполнить(ОбластьКодовСтроки.Параметры);
ОбластьТоварСтрокиРНПТНабор.Параметры.Заполнить(ОбластьТоварСтроки.Параметры);
ОбластьДанныеКоличествоСтрокиРНПТНабор.Параметры.Заполнить(ОбластьДанныеКоличествоСтроки.Параметры);
ОбластьДанныеСуммовыеСтрокиРНПТНабор.Параметры.Заполнить(ОбластьДанныеСуммовыеСтроки.Параметры);
ОтборСтрок = Новый Структура("НомерГТД", ВыборкаПоТоварам.НомерГТД);
СтрокиКомплекта = ПрослеживаемыеКомплектующие.НайтиСтроки(ОтборСтрок);
НомерСтрокиКомплекта = 1;
Для Каждого СтрокаКомплекта Из СтрокиКомплекта Цикл
ДанныеНомераРНПТ = Новый Структура("НомерРНПТ, КоличествоПоРНПТ, ЕдиницаИзмеренияТНВЭД");
ДанныеНомераРНПТ.НомерРНПТ = СокрЛП(СтрокаКомплекта.НомерРНПТ);
ДанныеНомераРНПТ.КоличествоПоРНПТ = ВыборкаПоТоварам.Количество * СтрокаКомплекта.КоличествоПоРНПТ;
ДанныеНомераРНПТ.ЕдиницаИзмеренияТНВЭД = СокрЛП(СтрокаКомплекта.ЕдиницаИзмеренияТНВЭД);
ОбластьДанныеНомерРНПСтроки.Параметры.Заполнить(ДанныеНомераРНПТ);
Если НомерСтрокиКомплекта = 1 Тогда
ТабличныйДокумент.Вывести(ОбластьНомераСтрокиРНПТНабор);
Если ВыводитьКоды Тогда
ТабличныйДокумент.Присоединить(ОбластьКодовСтрокиРНПТНабор);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТоварСтрокиРНПТНабор);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличествоСтрокиРНПТНабор);
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовыеСтрокиРНПТНабор);
Иначе
ТабличныйДокумент.Вывести(ОбластьНомераСтрокиРНПТКомплектующие);
Если ВыводитьКоды Тогда
ТабличныйДокумент.Присоединить(ОбластьКодовСтрокиРНПТКомплектующие);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТоварСтрокиРНПТКомплектующие);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличествоСтрокиРНПТКомплектующие);
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовыеСтрокиРНПТКомплектующие);
КонецЕсли;
НомерСтрокиКомплекта = НомерСтрокиКомплекта + 1;
КонецЦикла;
КонецЕсли;
Иначе
ТабличныйДокумент.Вывести(ОбластьНомераСтроки);
Если ВыводитьКоды Тогда
ТабличныйДокумент.Присоединить(ОбластьКодовСтроки);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТоварСтроки);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличествоСтроки);
Если ЕстьРНПТ Тогда
ДанныеНомераРНПТ = Новый Структура("НомерРНПТ, КоличествоПоРНПТ, ЕдиницаИзмеренияТНВЭД",
"-", 0, "-");
ОбластьДанныеНомерРНПСтроки.Параметры.Заполнить(ДанныеНомераРНПТ);
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПСтроки);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовыеСтроки);
КонецЕсли;
Если Не НаборыСервер.ИспользоватьОбластьКомплектующие(ВыборкаПоТоварам, ИспользоватьНаборы) Тогда
Сумма = Сумма + ВыборкаПоТоварам.Сумма;
СуммаНДС = СуммаНДС + ВыборкаПоТоварам.СуммаНДС;
Если ЕстьСкидки Тогда
ВсегоСкидок = ВсегоСкидок + ВыборкаПоТоварам.СуммаСкидки;
ВсегоБезСкидок = ВсегоБезСкидок + ВыборкаПоТоварам.СуммаБезСкидки;
КонецЕсли;
КонецЕсли;
КонецЦикла;
// Выводим подвал
ОбластьНомера = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.НомерСтроки);
ОбластьКодов = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.КолонкаКодов);
ОбластьТовар = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.Товар);
ОбластьДанныеКоличество = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеКоличество);
ОбластьДанныеНомерРНПТ = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеНомерРНПТ);
ОбластьДанныеСуммовые = Макет.ПолучитьОбласть(НазванияОбластейСтрок.ПодвалТаблицы
+ "|" + НазванияОбластейКолонок.ДанныеСуммовые);
ТабличныйДокумент.Вывести(ОбластьНомера);
Если ВыводитьКоды Тогда
ТабличныйДокумент.Присоединить(ОбластьКодов);
КонецЕсли;
ТабличныйДокумент.Присоединить(ОбластьТовар);
ТабличныйДокумент.Присоединить(ОбластьДанныеКоличество);
Если ЕстьРНПТ Тогда
ТабличныйДокумент.Присоединить(ОбластьДанныеНомерРНПТ);
КонецЕсли;
СтруктураДанныхВсегоСкидки = Новый Структура;
Если ЕстьСкидки Тогда
СтруктураДанныхВсегоСкидки.Вставить("ВсегоСкидок", ?(ЗаголовокСкидки.ТолькоНаценка,-ВсегоСкидок, ВсегоСкидок));
СтруктураДанныхВсегоСкидки.Вставить("ВсегоБезСкидок", ВсегоБезСкидок);
КонецЕсли;
СтруктураДанныхВсегоСкидки.Вставить("Всего", ФормированиеПечатныхФорм.ФорматСумм(Сумма));
ОбластьДанныеСуммовые.Параметры.Заполнить(СтруктураДанныхВсегоСкидки);
ТабличныйДокумент.Присоединить(ОбластьДанныеСуммовые);
// Выводим ИтогоНДС
Если ПолучитьФункциональнуюОпцию("ИспользоватьУчетНДС") Тогда
Область = Макет.ПолучитьОбласть("ПодвалНДС");
Если ЕстьРНПТ Тогда
Область = Макет.ПолучитьОбласть("ПодвалНДСРНПТ");
КонецЕсли;
Если ЕстьНДС Тогда
НадписьНДС = ?(ДанныеПечати.ЦенаВключаетНДС,
НСтр("ru='В том числе НДС:'", ОбщегоНазначения.КодОсновногоЯзыка()),
НСтр("ru='Сумма НДС:'", ОбщегоНазначения.КодОсновногоЯзыка()));
Иначе
НадписьНДС = НСтр("ru='Без налога (НДС)'", ОбщегоНазначения.КодОсновногоЯзыка());
КонецЕсли;
СтруктураДанныхПодвалНДС = Новый Структура;
СтруктураДанныхПодвалНДС.Вставить("ВсегоНДС", СуммаНДС);
СтруктураДанныхПодвалНДС.Вставить("НДС", НадписьНДС);
Область.Параметры.Заполнить(СтруктураДанныхПодвалНДС);
ТабличныйДокумент.Присоединить(Область);
КонецЕсли;
// Выводим Сумму прописью
ОбластьМакета = Макет.ПолучитьОбласть("СуммаПрописью");
СуммаКПрописи = Сумма + ?(ДанныеПечати.ЦенаВключаетНДС, 0, СуммаНДС);
ИтоговаяСтрока = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru='Всего наименований %1, на сумму %2'", ОбщегоНазначения.КодОсновногоЯзыка()),
ВыборкаПоТоварам.Количество(),
ФормированиеПечатныхФорм.ФорматСумм(СуммаКПрописи, ДанныеПечати.Валюта));
СуммаПрописью = РаботаСКурсамиВалютУТ.СформироватьСуммуПрописью(СуммаКПрописи, ДанныеПечати.Валюта);
СтруктураДанныхСуммаПрописью = Новый Структура;
СтруктураДанныхСуммаПрописью.Вставить("ИтоговаяСтрока", ИтоговаяСтрока);
СтруктураДанныхСуммаПрописью.Вставить("СуммаПрописью", СуммаПрописью);
ОбластьМакета.Параметры.Заполнить(СтруктураДанныхСуммаПрописью);
ТабличныйДокумент.Вывести(ОбластьМакета);
// Выводим подписи
ОбластьМакета = Макет.ПолучитьОбласть("Подписи");
Если ЕстьРНПТ Тогда
ОбластьМакета = Макет.ПолучитьОбласть("ПодписиРНПТ");
КонецЕсли;
Если ЗначениеЗаполнено(ДанныеПечати.ОтпускПроизвел) Тогда
СтруктураДанныхОтпускПроизвел = Новый Структура;
СтруктураДанныхОтпускПроизвел.Вставить("ОтпускПроизвел",
ФизическиеЛицаУТ.ФамилияИнициалыФизЛица(ДанныеПечати.ОтпускПроизвел, ДанныеПечати.Дата));
ОбластьМакета.Параметры.Заполнить(СтруктураДанныхОтпускПроизвел);
КонецЕсли;
ТабличныйДокумент.Вывести(ОбластьМакета);
УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент,
НомерСтрокиНачало,
ОбъектыПечати,
ДанныеПечати.Ссылка);
КонецЦикла;
ТабличныйДокумент.АвтоМасштаб = Истина;
Возврат ТабличныйДокумент;
КонецФункции Показать
