Корректировка записей регистра и ОперацияБух в примерах

Всем привет!

В одном месте описана программная работа с документом Корректировка записей и ОперацияБух. Для программистов это похожие по смыслу документы: Корректировка используется в УТ, КА, а ОперацияБух используется в БП ПРОФ и КОРП.

- КА 2.5 -

-= Создание Корректировки =-

В рамках реализации проекта Внедрение адресного хранения на 1С:КА 2.5 понадобилось перейти от учета "складских помещений" по складу - к учету "без помещений". Изначально в здании склада были выделены помещения, созданы связанные соответствующие справочники, проведены на дату запуска документы "Ввод остатков (по помещениям)" - товары списались со Склада и были  оприходованы уже в разрезе Склад+Помещение.

Со временем решили изменить адресацию склада - убрать помещения, оставить Склад без помещений.

Для реализации подобной процедуры понадобилось списать остатки товаров в разрезе Склад+Помещение и оприходовать их на Склад (без привязки к помещениям).

Учет складских помещений в КА 2.4 ведется только по регистру накопления "Товары на складах".

Собственно, данная обработка позволяет на заданную дату списать остатки товаров по заданному разрезу (набору) Склад + Помещение и сразу же оприходовать товары на Склад. По каждому товару делается две записи с видами движений Расход и Приход. Остатки вычисляются ровно на дату обработки, документ создается и проводится на ДатуОстатков + 1 секунда. Операция проводилась ночью, когда склад не работал (не делал движений по регистру).

Здесь нет свертки остатков или проведения сторно движений, как во многих примерах, связанных с документами Корректировка регистров. Здесь через запрос собираются остатки на дату по складу+помещение, создается программно и заполняется записями документ Корректировка регистра.

Обработка была разработана на платформе 1С:Предприятие 8.3 (8.3.18.1289), использована в конфигурации 1С:Комплексная автоматизация 2 (2.4.13.282).

Разработка и принцип работы документа Корректировка регистра на управляемых формах ничем не отличается от разработки и принципа работы документа для обычных форм. Если однажды вы разберетесь с этим принципом, то сможете использовать его для любых конфигураций, в которых имеется документ Корректировка записей регистров.

- УТ 10.3 -

-= Создание Корректировки =- 

Задачи для УФ и ОФ ходят рядом - теперь это обычное дело...

После того, как база УТ 10.3 разделилась на три базы - организации "разъехались" по своим базам - стало понятно, что в каждой базе надо почистить (обнулить) остатки товаров по группе складов, связанных с "другими" подразделениями (организациями).

В УТ 10.3 за остатки товаров отвечают несколько регистров накопления - основные из них для оптовой торговли являются "ТоварыНаСкладах" и "ПартииТоваровНаСкладах". Поэтому будет создано две корректировки по каждому регистру - так нагляднее.

Обработка для УТ 10.3 была разработана на платформе 1С:Предприятие 8.3 (8.3.18.1289), использована в конфигурации 1С:Управление торговлей, редакция 10.3 (10.3.45.2).

 Алгоритм и синтаксис обработки для УТ 10.3 похож на алгоритм и синтаксис для КА 2.5.

- УТ 10.3 -

-= Удаление записей в Корректировке =- 

Пришлось однажды удалять из базы документы по одной Организации. В ходе анализа нашел документы Корректировки записей регистров по регистрам "Товары организаций" и "Взаиморасчеты с контрагентами по документам расчетов".

В записях корректировок присутствовали записи по разным организациям. Поэтому понадобилось разработать вспомогательную обработку для удаления записей по соответствующей организации.

Внешняя обработка разработана и протестирована на платформе 1С:Предприятие 8.3 (8.3.23.1865), на конфигурации Управление торговлей, редакция 10.3 (10.3.75.2).

Обработка запрограммирована на первоначальное открытие в режиме "Демо-режим".

Пробуйте сначала на Копии базы. Сначала выбираете организацию, начало и конец периода, ставите галочки для регистров, нажимаете кнопку "Очистить". При этом будут обработаны по одному документу Корректировка для каждого регистра. При этом каждый обработанный документ перед обработкой будет открыт для просмотра. После обработки записей нажмите в каждом документе кнопку "Обновить записи" - и вы увидите, что записи по вашей организации исчезнут из Корректировки.

Для групповой обработки просто снимите флажок "Демо-режим".

- БП 3.0 ПРОФ и КОРП -

Для демонстрации программной работы с документом ОперацияБух будет использоваться следующий пример. Некоторое время на счете 10.01 ведется учет без учета партий, с 2024 года подключается учет по партиям для гособоронзаказа. Для гособоронзаказа нужно материалы списывать по ФИФО, а не по средней.

Для этих целей собираются остатки по счету 10.01 на период 31.12.2023 23:59:59, используется межотчетный период. Остатки списываются по счету 10.01 на указанный период в разрезе Номенклатура и Склад, и приходуются на счет 10.01 в тех же разрезах плюс добавляем одну для всех партий - это документ Партия. 

При этом надо учесть движения по регистру Раздельный учет НДС - один раз спишем все движения по всем партиям, и оприходуем движения с количеством больше 0 на одну партию. Решение не претендует на универсальность и правильность с методической точки зрения, но для демонстрации вполне подходит.

Для данного примера не будем программно создавать документ ОперацияБух - это слишком просто. Создадим интерактивно и укажем в обработке ссылку. То же самое с документом Партия. Необходимо указать номер субконто Партия у счета 10.01 - в типовом варианте он равен 2.

&НаСервере
Процедура ЗаполнитьОстаткамиНаСервере()
	
	//1. получим список остатков по субконто 		
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	ХозрасчетныйОстатки.Счет КАК Счет,
	|	ХозрасчетныйОстатки.Субконто1 КАК Субконто1,
	|	ХозрасчетныйОстатки.Субконто2 КАК Субконто2,
	|	ХозрасчетныйОстатки.Субконто3 КАК Субконто3,
	|	ХозрасчетныйОстатки.Организация КАК Организация,
	|	ХозрасчетныйОстатки.КоличествоОстаток КАК Количество,
	|	ХозрасчетныйОстатки.СуммаОстаток КАК Сумма
	|ИЗ
	|	РегистрБухгалтерии.Хозрасчетный.Остатки(&Период, Счет = &Счет, , ) КАК ХозрасчетныйОстатки";
	
	Запрос.УстановитьПараметр("Период", Объект.Период);  
	Запрос.УстановитьПараметр("Счет", Объект.Счет); 
	
	Результат = Запрос.Выполнить();
	Выборка = Результат.Выбрать();

	Док = Объект.ОперацияБух.ПолучитьОбъект(); 
		
	НЗ = Док.Движения.Хозрасчетный;
   	
	//2. заполним операцию бух
	Пока Выборка.Следующий() Цикл 		
		
		//регистр Хозрасчетный
		Запись = НЗ.Добавить();
		Запись.Период 		= Объект.Период; 
		Запись.УточнениеПериода = Объект.Период; 
		Запись.Организация	= Выборка.Организация;
		
		Запись.СчетДт		= Объект.Счет; 
		Запись.КоличествоДт	= Выборка.Количество;
		Запись.СуммаНУДт	= Выборка.Сумма;

		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетДт, Запись.СубконтоДт, 1, Выборка.Субконто1);
		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетДт, Запись.СубконтоДт, 2, Выборка.Субконто2); 
		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетДт, Запись.СубконтоДт, 3, Выборка.Субконто3);
		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетДт, Запись.СубконтоДт, Объект.НомСубконтоПартия, Объект.ДокПартии);
		
		Запись.СчетКт    	= Объект.Счет;  
		Запись.КоличествоКт	= Выборка.Количество; 
		Запись.СуммаНУКт	= Выборка.Сумма;

		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетКт, Запись.СубконтоКт, 1, Выборка.Субконто1);
		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетКт, Запись.СубконтоКт, 2, Выборка.Субконто2); 
		БухгалтерскийУчет.УстановитьСубконто(Запись.СчетКт, Запись.СубконтоКт, 3, Выборка.Субконто3);  
		
		Запись.Сумма		= Выборка.Сумма;  		
		
	КонецЦикла;
	
	НЗ.Записывать = Истина;
	НЗ.Записать();	 

	Если Объект.ВклРаздельныйУчетНДС = Истина Тогда
		
		//3. получим список остатков по регистру НДС Раздельный учет 		
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		|	НДСРаздельныйУчетОстатки.Организация КАК Организация,
		|	НДСРаздельныйУчетОстатки.АналитикаУчетаЗатрат КАК АналитикаУчетаЗатрат,
		|	НДСРаздельныйУчетОстатки.АналитикаУчетаНДС КАК АналитикаУчетаНДС,
		|	НДСРаздельныйУчетОстатки.СпособУчетаНДС КАК СпособУчетаНДС,
		|	НДСРаздельныйУчетОстатки.Партия КАК Партия,
		|	НДСРаздельныйУчетОстатки.КоличествоОстаток КАК Количество,
		|	НДСРаздельныйУчетОстатки.СуммаБезНДСОстаток КАК СуммаБезНДС,
		|	НДСРаздельныйУчетОстатки.НДСОстаток КАК НДС
		|ИЗ
		|	РегистрНакопления.НДСРаздельныйУчет.Остатки(&Период, ) КАК НДСРаздельныйУчетОстатки";
		
		Запрос.УстановитьПараметр("Период", Объект.Период);  
		
		Результат = Запрос.Выполнить();
		Выборка = Результат.Выбрать();
		
		НайденнаяСтрока = Док.ТаблицаРегистровНакопления.Найти("НДСРаздельныйУчет", "Имя"); 
		Если НайденнаяСтрока = Неопределено Тогда
			
			СтрРегистра = Док.ТаблицаРегистровНакопления.Добавить(); 
			СтрРегистра.Имя = "НДСРаздельныйУчет"; 	
			Док.Записать(); 
			
		КонецЕсли;
		
		НЗ = Док.Движения.НДСРаздельныйУчет;
		
		//4. заполним регистр НДС Раздельный учет
		Пока Выборка.Следующий() Цикл 		
			
			//расход
			Запись = НЗ.Добавить(); 
			
			Запись.Период = Объект.Период;
			Запись.ВидДвижения = ВидДвиженияНакопления.Расход;
			ЗаполнитьЗначенияСвойств(Запись, Выборка); 
			
			//приход 
			Если Выборка.Количество > 0 Тогда
				
				Запись = НЗ.Добавить(); 
				
				Запись.Период = Объект.Период;
				Запись.ВидДвижения = ВидДвиженияНакопления.Приход;
				ЗаполнитьЗначенияСвойств(Запись, Выборка);
				Запись.Партия = Объект.ДокПартии; 
				
			КонецЕсли;
			
		КонецЦикла;
		
		НЗ.Записывать = Истина;
		НЗ.Записать();   
		
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура ЗаполнитьОстатками(Команда)
	ЗаполнитьОстаткамиНаСервере();
КонецПроцедуры

На этом все. Всем добра!

С пользой для клиентов, Рустем