Новые сообщения для расшифровки в ЗУП и как отключить окно при запуске программы

1. Если вы из тех, кому «нужно, чтобы работало», то можете, не читая остальные пункты, загрузить расширение (создано на версии ЗУП 3.1.29.21), после чего у вас в настройках пользователя в раздел «Запуск и завершение работы» добавится флаг «Отключить сообщения для пользователя ЭДО», который, как следует из его наименования, отключает/включает показ этого окна при запуске системы.

Доработки в следующих местах типового ЗУП: общая форма «ПерсональныеНастройки», где запоминается настройка, и общий модуль «ДокументооборотСКОКлиент», где происходит отложенный запуск получения входящих сообщений ЭДО.

ОбщийМодуль.ДокументооборотСКОГлобальный

&Вместо("ПолучитьИнформациюОВходящихСообщенияхДляПользователяЭДО")
Процедура DEV_ПолучитьИнформациюОВходящихСообщенияхДляПользователяЭДО()
	
	DEV_ОтключитьСообщенияДляПользователяЭДО = ОбщегоНазначенияВызовСервера.ХранилищеОбщихНастроекЗагрузить(
		"ОбщиеНастройкиПользователя", 
		"DEV_ОтключитьСообщенияДляПользователяЭДО",
		Ложь);
	Если DEV_ОтключитьСообщенияДляПользователяЭДО Тогда
		Возврат;
	КонецЕсли;	
		
	ПродолжитьВызов();
	
КонецПроцедуры

ОбщаяФорма. ПерсональныеНастройки

&НаСервере
&После("ПриСозданииНаСервере")
Процедура DEV_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	ДобавляемыеРеквизиты = Новый Массив; 
	НовыйРеквизит = Новый РеквизитФормы("DEV_ОтключитьСообщенияДляПользователяЭДО",Новый ОписаниеТипов("Булево")); 
	ДобавляемыеРеквизиты.Добавить(НовыйРеквизит);	
	ЭтаФорма.ИзменитьРеквизиты(ДобавляемыеРеквизиты);
	
	ЭтаФорма.DEV_ОтключитьСообщенияДляПользователяЭДО = ОбщегоНазначения.ХранилищеОбщихНастроекЗагрузить(
		"ОбщиеНастройкиПользователя", 
		"DEV_ОтключитьСообщенияДляПользователяЭДО",
		Ложь);
	
	НовыйЭлемент = ЭтаФорма.Элементы.Добавить("DEV_ОтключитьСообщенияДляПользователяЭДО", Тип("ПолеФормы"),Элементы.ГруппаЗапускИЗавершениеРаботы);
	НовыйЭлемент.Вид = ВидПоляФормы.ПолеФлажка;
	НовыйЭлемент.ПутьКДанным = "DEV_ОтключитьСообщенияДляПользователяЭДО";
	НовыйЭлемент.Заголовок = "Отключить сообщения для пользователя ЭДО"; 
	НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Право;
	
КонецПроцедуры

&НаСервере
&После("ЗаписатьНастройкиНаСервере")
Процедура DEV_ЗаписатьНастройкиНаСервере(ПараметрыКлиента)
	СохранитьСвойстваКоллекции("ОбщиеНастройкиПользователя", ЭтотОбъект,
		"DEV_ОтключитьСообщенияДляПользователяЭДО");
КонецПроцедуры

2. Для тех, кто любит понимать, что происходит в программе, краткая справка: все эти сообщения относятся к подсистеме «Регламентированная отчетность» и ее подчиненной подсистеме «Электронный Документооборот с Контролирующими Органами» и далее подчиненной подсистеме «Электронный документооборот с ФНС, ПФР и Росстатом». Даже если у вас в ЗУП не подключен сервис 1С-Отчетность, у вас все равно будет присутствовать СЭДО (Социальный электронный документооборот) с СФР по выплате пособий  – это входит в базовую функциональность ЗУП. 

И если вы отключите это окно при входе, вы, конечно, всегда сможете загрузить эти сообщения в удобный для вас момент либо из раздела 1С-Отчетность, либо, если у вас только базовый СЭДО, из специального рабочего места «Сообщения ФСС об изменении электронных листков нетрудоспособности», там это можно сделать с отбором по выбранным организациям за указанный период, выбрав в подменю «Еще» команду «Получить сообщения за период».

3. И наконец для пытливых умов, ещё немного подробностей: каким пользователям показывается это окно?

Если, у вас подключен сервис 1С-Отчетность, то программа будет проверять, как настроены учетные записи по пользователям в регистре сведений «Пользователи учетных записей документооборота».

Если же у вас не подключен сервис 1С-Отчетность, то это окно показывается всем пользователям, у которых есть права на чтение на регистр сведений «Настройки обмена с СФР (бывш. ФСС)», а такие права есть, например, у роли «Чтение данных регламентированной отчетности», которая входит в состав многих базовых профилей доступа в ЗУП, например, такие как «Аудитор», «Кадровик», «Кадровик (без доступа к зарплате),  и конечно «Старший Кадровик» и все профиля «Расчетчиков».

И в последнем случае пользователям с полными правами это окно показывается априори, т.е. если вы что-то разрабатываете и делаете отладку, регулярно запуская программу, вы будете видеть это сообщение очень часто, прямо скажем, не соскучитесь по нему.

upd.: Добавлено аналогичное расширение для конфигурации "1С:Бухгалтерия 3.0", в ней немного  отличается форма персональных настроек.