Взаимозачёт (зачёт аванса) в документах - "Корректировка поступления" и "Корректировка реализации". БП 3.0

23.10.24

Задачи пользователя - Корректировка данных

В БП 3.0 документы - "Корректировка поступления" и "Корректировка реализации" создают проводки аванса - 60.02 или 62.02 соответственно, даже если есть задолженности по этому договору, но по другим документам. Расширение позволяет автоматически зачесть эту сумму "аванса" на задолженность других документов. Т.е. при проведении "Корректировка поступления" и "Корректировка реализации" будет проводка взаимозачёта по другим документам этого договора.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование	Скачано	Купить файл (только для физ. лиц)	По подписке PRO
Бух 3.0, Расширение для взаимозачёта (зачёт аванса), документы - "Корректировка поступления" и "Корректировка реализации": .cfe 11,92Kb ver:v2 5	5	2 150 руб. Купить	2 SM Скачать

В 1С:Бухгалтерия 3.0 документы - "Корректировка поступления" и "Корректировка реализации" создают проводки аванса - 60.02 или 62.02 соответственно.

Это происходит в ситуации, когда корректируемый документ оплачен, но есть задолженности по этому договору, но по другим документам.

Расширение позволяет автоматически зачесть эту сумму "аванса" на задолженность других документов.
Т.е. при проведении "Корректировка поступления" и "Корректировка реализации" будет проводка взаимозачёта долга по другим документам этого договора, а не проводка аванса.

Работает в случае учёта на счетах 60/62 по субконто:
Контрагент / Договор / Документы расчетов

На данный момент отключить субконто "Документы расчетов с контрагентом" нельзя, это связано с учётом налогов. Из-за этого и возникают такие "авансы" !

Ниже решение, код которого можно использовать в Расширении.

Либо можно скачать готовое расширение во вложенном файле и установить в вашей базе Бухгалтерия 3.0.

Разрабатывалось и тестировалось на последней версии 1С:Бухгалтерия 3.0.161.хх

КорректировкаПоступления - модуль менеджера

// Корректировка поступления
// перехватываем таблицу с данными, делаем зачёт денег по другим документам
&Перед("СформироватьДвиженияВыделениеАванса")
Процедура Корр_СформироватьДвиженияВыделениеАванса(ТаблицаВзаиморасчеты, ТаблицаРеквизиты, Движения, Отказ, ЭтоОтложенноеПроведение) Экспорт

	Если Не ЗначениеЗаполнено(ТаблицаВзаиморасчеты)
	 Или Не ЗначениеЗаполнено(ТаблицаРеквизиты) Тогда
	    Возврат;
	КонецЕсли;
	
	Реквизиты = ТаблицаРеквизиты[0];
	Если Реквизиты.СпособЗачетаАвансов = Перечисления.СпособыЗачетаАвансов.НеЗачитывать Тогда
		Возврат;
	КонецЕсли;
	
	Если Не ЭтоОтложенноеПроведение
	   И ПроведениеСервер.ИспользуетсяОтложенноеПроведение(Реквизиты.Организация, Реквизиты.Период)
	   И Реквизиты.ВалютаВзаиморасчетов = ОбщегоНазначенияБПВызовСервераПовтИсп.ПолучитьВалютуРегламентированногоУчета()
	   И Не УчетВзаиморасчетов.ЭтоВидДоговораРасчетыПоКомиссии(Реквизиты.ВидДоговора) Тогда
		// При включенном отложенном проведении в момент оперативного проведения остатки по рублевым взаиморасчетам не получаем,
		// они будут актуализированы при выполнении отложенных расчетов.
		Возврат;
	КонецЕсли;
	
	//Параметры = ПодготовитьПараметрыДвиженияВыделениеАванса(ТаблицаВзаиморасчеты, ТаблицаРеквизиты);
	//Реквизиты = Параметры.Реквизиты[0];
	
	Реквизиты = ТаблицаРеквизиты[0];
	тзнОстаткиПоДоговору_6001 = ПолучитьОстатокЗадолженности_ПоДоговору(Реквизиты);
	
// по аналогии с типовым кодом - создаём Проводки зачёта суммы по задолженностям Договора	
	
	ОтражатьВНалоговомУчете = УчетнаяПолитика.ПлательщикНалогаНаПрибыль(Реквизиты.Организация, Реквизиты.Период);
    ПрименениеПБУ18 		= УчетнаяПолитика.ПоддержкаПБУ18(Реквизиты.Организация, Реквизиты.Период);
	
	Проводки = Движения.Хозрасчетный;

//	Для каждого СтрокаВзаиморасчетов Из Параметры.Взаиморасчеты Цикл
	Для каждого СтрокаВзаиморасчетов Из ТаблицаВзаиморасчеты Цикл

		Если СтрокаВзаиморасчетов.ДокументРасчетов = Реквизиты.Регистратор Тогда


////////////////////////////////////////////////////////////
			СуммаДока_Осталось = СтрокаВзаиморасчетов.СуммаРуб;
			СуммаВал_Осталось = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
			Если СуммаДока_Осталось <= 0 Тогда 
				Продолжить;
			КонецЕсли;

			
////////////////////////////////////////////////////////////
// наш цикл внутри, пока хватит сумм
// при этом мы уменьшим сумму цикла выше - СтрокаВзаиморасчетов
		Для каждого СтрокаОстатки Из тзнОстаткиПоДоговору_6001 Цикл

			Если СуммаДока_Осталось<=0 Тогда
				Прервать;
			КонецЕсли;
			Если СтрокаОстатки.СуммаРуб<=0 Тогда
				Продолжить;
			КонецЕсли;
			
			СписатьСумму 	= Мин(СуммаДока_Осталось, СтрокаОстатки.СуммаРуб);
			СписатьСумму_Вал = Мин(СуммаВал_Осталось, СтрокаОстатки.СуммаВзаиморасчетов);
			
			// корректируем остатки, если циклов будет несколько
			СтрокаОстатки.СуммаРуб	= СтрокаОстатки.СуммаРуб - СписатьСумму;
			СуммаДока_Осталось		= СуммаДока_Осталось - СписатьСумму;
			СтрокаОстатки.СуммаВзаиморасчетов	= СтрокаОстатки.СуммаВзаиморасчетов - СписатьСумму_Вал;
			СуммаВал_Осталось					= СуммаВал_Осталось - СписатьСумму_Вал;

////////////////////////////////////////////////////////////
			Проводка = Проводки.Добавить();

			Проводка.Период      = Реквизиты.период;
			Проводка.Организация = Реквизиты.Организация;
			Проводка.Содержание  = "Взаимозачет";   //Зачет аванса
			Проводка.Сумма       = СписатьСумму;

			//СчетАванса = ?(ЗначениеЗаполнено(Реквизиты.СчетУчетаРасчетовПоАвансам),
			//	Реквизиты.СчетУчетаРасчетовПоАвансам,
			//	Реквизиты.СчетУчетаРасчетовСКонтрагентом);

			//Проводка.СчетДт = СчетАванса;
			Проводка.СчетДт = СтрокаОстатки.Счет;
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "Контрагенты", Реквизиты.Контрагент);
			//БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "Договоры", Реквизиты.ДоговорКонтрагента);
			//БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "ДокументыРасчетовСКонтрагентами", Реквизиты.Регистратор);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "Договоры", 							СтрокаОстатки.ДоговорКонтрагента);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "ДокументыРасчетовСКонтрагентами", 	СтрокаОстатки.ДокументРасчетов);

			Проводка.СчетКт = Реквизиты.СчетУчетаРасчетовСКонтрагентом;
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Контрагенты", Реквизиты.Контрагент);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Договоры", Реквизиты.ДоговорКонтрагента);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "ДокументыРасчетовСКонтрагентами", Реквизиты.ДокументПоступленияСсылка);
			
			СвойстваСчетаДт = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Проводка.СчетДт);
			СвойстваСчетаКт = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Проводка.СчетКт);
			Если СвойстваСчетаДт.Валютный Тогда
				Проводка.ВалютаДт        = Реквизиты.ВалютаВзаиморасчетов;
				//Проводка.ВалютнаяСуммаДт = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
				Проводка.ВалютнаяСуммаДт = СписатьСумму_Вал;
			КонецЕсли;
			Если СвойстваСчетаКт.Валютный Тогда
				Проводка.ВалютаКт        = Реквизиты.ВалютаВзаиморасчетов;
				//Проводка.ВалютнаяСуммаКт = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
				Проводка.ВалютнаяСуммаКт = СписатьСумму_Вал;
			КонецЕсли;

			Если СвойстваСчетаДт.УчетПоПодразделениям Тогда
				Проводка.ПодразделениеДт = Реквизиты.Подразделение;
			КонецЕсли;
			Если СвойстваСчетаКт.УчетПоПодразделениям Тогда
				Проводка.ПодразделениеКт = Реквизиты.Подразделение;
			КонецЕсли;
				
			Если ОтражатьВНалоговомУчете Тогда
				//НалоговыйУчет.ЗаполнитьНалоговыеСуммыПроводки(СтрокаВзаиморасчетов.СуммаРуб, СтрокаВзаиморасчетов.СуммаРуб,,,,,
				//	Проводка, ПрименениеПБУ18);
 				НалоговыйУчет.ЗаполнитьНалоговыеСуммыПроводки(Проводка.Сумма, Проводка.Сумма,,,,,
					Проводка, ПрименениеПБУ18);
			КонецЕсли;
			
		КонецЦикла; //остатки
		
		// корректируем основоную таблицу, для будущих процедур
  		СтрокаВзаиморасчетов.СуммаРуб = СуммаДока_Осталось;
		СтрокаВзаиморасчетов.СуммаВзаиморасчетов = СуммаВал_Осталось;


		КонецЕсли;

	КонецЦикла;
	
//удаляем нулевые
	МассивСтрокУдалить = ТаблицаВзаиморасчеты.НайтиСтроки( Новый Структура("СуммаРуб", 0));
	Для Каждого СтрокаУдалить Из МассивСтрокУдалить Цикл
       ТаблицаВзаиморасчеты.Удалить(СтрокаУдалить);
   КонецЦикла
   
КонецПроцедуры


Функция ПолучитьОстатокЗадолженности_ПоДоговору( Реквизиты )
	
	Текст = "
		|ВЫБРАТЬ
		|	Счет,
		|	Субконто1 КАК Контрагент,
		|	Субконто2 КАК ДоговорКонтрагента,
		|	Субконто3 КАК ДокументРасчетов,
		|	-СуммаОстаток КАК СуммаРуб,
		|	-ВалютнаяСуммаОстаток КАК СуммаВзаиморасчетов
		//|	,ДоговорыКонтрагентов.ВалютаВзаиморасчетов КАК ВалютаВзаиморасчетов,
		//|	ДоговорыКонтрагентов.РасчетыВУсловныхЕдиницах КАК РасчетыВУсловныхЕдиницах
		|ИЗ
		|	РегистрБухгалтерии.Хозрасчетный.Остатки(
		|			&Момент,
		|			Счет = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.РасчетыСПоставщиками), //60.01
		|			&ВидыСубконтоСДокументами,
		|			Организация = &Организация  И Субконто1 = &Контрагент И Субконто2 = &Договор И Субконто3 <> &ДокПоступления) // кроме дока в Корректировке 
		|	КАК ХозрасчетныйОстатки
		//|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
		//|			ПО Субконто2 = ДоговорыКонтрагентов.Ссылка
		|ГДЕ
		|	СуммаОстаток < 0
		|";

	Запрос = Новый Запрос(Текст);

    ВидыСубконтоСДокументами = Новый Массив();
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты);
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры);
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами);

	// Установка параметров.
	Запрос.УстановитьПараметр("ВидыСубконтоСДокументами", ВидыСубконтоСДокументами);
	Запрос.УстановитьПараметр("Организация",	Реквизиты.Организация);
	Запрос.УстановитьПараметр("Контрагент",		Реквизиты.Контрагент);
	Запрос.УстановитьПараметр("Договор",		Реквизиты.ДоговорКонтрагента);
	Запрос.УстановитьПараметр("ДокПоступления",	Реквизиты.ДокументПоступленияСсылка);
	Запрос.УстановитьПараметр("Момент", 		Реквизиты.Регистратор.МоментВремени() );

	Возврат  Запрос.Выполнить().Выгрузить();

КонецФункции

КорректировкаРеализации - модуль менеджера

// КорректировкаРеализации
// перехватываем таблицу с данными, делаем зачёт денег по другим документам
&Перед("СформироватьДвиженияВыделениеАванса")
Процедура КоррПост_СформироватьДвиженияВыделениеАванса(ТаблицаВзаиморасчеты, ТаблицаРеквизиты, Движения, Отказ, ЭтоОтложенноеПроведение)

#Область ТиповойКусок
	Если Не ЗначениеЗаполнено(ТаблицаВзаиморасчеты)
		Или Не ЗначениеЗаполнено(ТаблицаРеквизиты) Тогда
		Возврат;
	КонецЕсли;

	Реквизиты = ТаблицаРеквизиты[0];
	Если Реквизиты.СпособЗачетаАвансов = Перечисления.СпособыЗачетаАвансов.НеЗачитывать Тогда
		Возврат;
	КонецЕсли;

	Если ПроведениеСервер.ИспользуетсяОтложенноеПроведение(Реквизиты.Организация, Реквизиты.Период)
		И НЕ ЭтоОтложенноеПроведение
		И Реквизиты.ВалютаВзаиморасчетов = ОбщегоНазначенияБПВызовСервераПовтИсп.ПолучитьВалютуРегламентированногоУчета()
		И НЕ УчетВзаиморасчетов.ЭтоВидДоговораРасчетыПоКомиссии(Реквизиты.ВидДоговора) Тогда
		// При включенном отложенном проведении в момент оперативного проведения остатки по рублевым взаиморасчетам не получаем,
		// они будут актуализированы при выполнении отложенных расчетов.
		Возврат;
	КонецЕсли;

	//Параметры = ПодготовитьПараметрыДвиженияВыделениеАванса(ТаблицаВзаиморасчеты, ТаблицаРеквизиты);
	//Реквизиты = Параметры.Реквизиты[0];
#КонецОбласти

	Реквизиты = ТаблицаРеквизиты[0];
	тзнОстаткиПоДоговору_6201 = ПолучитьОстатокЗадолженности_ПоДоговору(Реквизиты);
	
	ОтражатьВНалоговомУчете = УчетнаяПолитика.ПлательщикНалогаНаПрибыль(Реквизиты.Организация, Реквизиты.Период);
	ПрименениеПБУ18 		= УчетнаяПолитика.ПоддержкаПБУ18(Реквизиты.Организация, Реквизиты.Период);

	Проводки = Движения.Хозрасчетный;

//	Для каждого СтрокаВзаиморасчетов Из Параметры.Взаиморасчеты Цикл
	Для каждого СтрокаВзаиморасчетов Из ТаблицаВзаиморасчеты Цикл

		Если СтрокаВзаиморасчетов.ДокументРасчетов = Реквизиты.Регистратор Тогда

////////////////////////////////////////////////////////////
			СуммаДока_Осталось = СтрокаВзаиморасчетов.СуммаРуб;
			СуммаВал_Осталось = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
			Если СуммаДока_Осталось <= 0 Тогда 
				Продолжить;
			КонецЕсли;

			
////////////////////////////////////////////////////////////
// наш цикл внутри, пока хватит сумм
// при этом мы уменьшим сумму цикла выше - СтрокаВзаиморасчетов
		Для каждого СтрокаОстатки Из тзнОстаткиПоДоговору_6201 Цикл

			Если СуммаДока_Осталось<=0 Тогда
				Прервать;
			КонецЕсли;
			Если СтрокаОстатки.СуммаРуб<=0 Тогда
				Продолжить;
			КонецЕсли;
			
			СписатьСумму 	= Мин(СуммаДока_Осталось, СтрокаОстатки.СуммаРуб);
			СписатьСумму_Вал = Мин(СуммаВал_Осталось, СтрокаОстатки.СуммаВзаиморасчетов);
			
			// корректируем остатки, если циклов будет несколько
			СтрокаОстатки.СуммаРуб	= СтрокаОстатки.СуммаРуб - СписатьСумму;
			СуммаДока_Осталось		= СуммаДока_Осталось - СписатьСумму;
			СтрокаОстатки.СуммаВзаиморасчетов	= СтрокаОстатки.СуммаВзаиморасчетов - СписатьСумму_Вал;
			СуммаВал_Осталось					= СуммаВал_Осталось - СписатьСумму_Вал;

////////////////////////////////////////////////////////////
// типовой код
			Проводка = Проводки.Добавить();

			Проводка.Период      = Реквизиты.период;
			Проводка.Организация = Реквизиты.Организация;
//			Проводка.Содержание  = "Выделение аванса покупателя";
//			Проводка.Сумма       = СтрокаВзаиморасчетов.СуммаРуб;
// Доработка
			Проводка.Содержание  = "Взаимозачет";
			Проводка.Сумма       = СписатьСумму;

			//СчетАванса = ?(ЗначениеЗаполнено(Реквизиты.СчетУчетаРасчетовПоАвансам),
			//Реквизиты.СчетУчетаРасчетовПоАвансам,
			//Реквизиты.СчетУчетаРасчетовСКонтрагентом);

			Проводка.СчетДт = Реквизиты.СчетУчетаРасчетовСКонтрагентом;
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "Контрагенты", Реквизиты.Контрагент);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "Договоры", Реквизиты.ДоговорКонтрагента);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "ДокументыРасчетовСКонтрагентами", Реквизиты.ДокументРеализацииСсылка);

			//Проводка.СчетКт = СчетАванса;
			//БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Контрагенты", Реквизиты.Контрагент);
			//БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Договоры", Реквизиты.ДоговорКонтрагента);
			//БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "ДокументыРасчетовСКонтрагентами", Реквизиты.Регистратор);
// Доработка
			Проводка.СчетКт = СтрокаОстатки.Счет;
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Контрагенты", Реквизиты.Контрагент);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "Договоры", 							СтрокаОстатки.ДоговорКонтрагента);
			БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетКт, Проводка.СубконтоКт, "ДокументыРасчетовСКонтрагентами", 	СтрокаОстатки.ДокументРасчетов);

			СвойстваСчетаДт = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Проводка.СчетДт);
			СвойстваСчетаКт = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Проводка.СчетКт);
			Если СвойстваСчетаДт.Валютный Тогда
				Проводка.ВалютаДт        = Реквизиты.ВалютаВзаиморасчетов;
//				Проводка.ВалютнаяСуммаДт = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
// Доработка
				Проводка.ВалютнаяСуммаДт = СписатьСумму_Вал;
			КонецЕсли;
			Если СвойстваСчетаКт.Валютный Тогда
				Проводка.ВалютаКт        = Реквизиты.ВалютаВзаиморасчетов;
//				Проводка.ВалютнаяСуммаКт = СтрокаВзаиморасчетов.СуммаВзаиморасчетов;
// Доработка
				Проводка.ВалютнаяСуммаКт = СписатьСумму_Вал;
			КонецЕсли;

			Если СвойстваСчетаДт.УчетПоПодразделениям Тогда
				Проводка.ПодразделениеДт = Реквизиты.Подразделение;
			КонецЕсли;
			Если СвойстваСчетаКт.УчетПоПодразделениям Тогда
				Проводка.ПодразделениеКт = Реквизиты.Подразделение;
			КонецЕсли;

			Если ОтражатьВНалоговомУчете Тогда
 //   			НалоговыйУчет.ЗаполнитьНалоговыеСуммыПроводки(СтрокаВзаиморасчетов.СуммаРуб, СтрокаВзаиморасчетов.СуммаРуб,,,,,
 //   			Проводка, ПрименениеПБУ18);
 // Доработка
				НалоговыйУчет.ЗаполнитьНалоговыеСуммыПроводки(Проводка.Сумма, Проводка.Сумма,,,,,
					Проводка, ПрименениеПБУ18);
			КонецЕсли;

 // Доработка
		КонецЦикла; //остатки
		
 // Доработка
		// корректируем основоную таблицу, для будущих процедур
  		СтрокаВзаиморасчетов.СуммаРуб = СуммаДока_Осталось;
		СтрокаВзаиморасчетов.СуммаВзаиморасчетов = СуммаВал_Осталось;

		КонецЕсли;

	КонецЦикла;

// Доработка
	// удаляем нулевые строки, по сути зачтённые авансы
	МассивСтрокУдалить = ТаблицаВзаиморасчеты.НайтиСтроки( Новый Структура("СуммаРуб", 0));
	Для Каждого СтрокаУдалить Из МассивСтрокУдалить Цикл
       ТаблицаВзаиморасчеты.Удалить(СтрокаУдалить);
   КонецЦикла
   
КонецПроцедуры


Функция ПолучитьОстатокЗадолженности_ПоДоговору( Реквизиты )
	
	Текст = "
		|ВЫБРАТЬ
		|	Счет,
		|	Субконто1 КАК Контрагент,
		|	Субконто2 КАК ДоговорКонтрагента,
		|	Субконто3 КАК ДокументРасчетов,
		|	СуммаОстаток КАК СуммаРуб,
		|	ВалютнаяСуммаОстаток КАК СуммаВзаиморасчетов
		//|	,ДоговорыКонтрагентов.ВалютаВзаиморасчетов КАК ВалютаВзаиморасчетов,
		//|	ДоговорыКонтрагентов.РасчетыВУсловныхЕдиницах КАК РасчетыВУсловныхЕдиницах
		|ИЗ
		|	РегистрБухгалтерии.Хозрасчетный.Остатки(
		|			&Момент,
		|			Счет = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.РасчетыСПокупателями), //62.01
		|			&ВидыСубконтоСДокументами,
		|			Организация = &Организация  И Субконто1 = &Контрагент И Субконто2 = &Договор И Субконто3 <> &ДокСсылка) // кроме дока в Корректировке 
		|	КАК ХозрасчетныйОстатки
		|ГДЕ
		|	СуммаОстаток > 0
		|УПОРЯДОЧИТЬ ПО Субконто3 АВТОУПОРЯДОЧИВАНИЕ
		|";

	Запрос = Новый Запрос(Текст);

    ВидыСубконтоСДокументами = Новый Массив();
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты);
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры);
	ВидыСубконтоСДокументами.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами);

	// Установка параметров.
	Запрос.УстановитьПараметр("ВидыСубконтоСДокументами", ВидыСубконтоСДокументами);
	Запрос.УстановитьПараметр("Организация",	Реквизиты.Организация);
	Запрос.УстановитьПараметр("Контрагент",		Реквизиты.Контрагент);
	Запрос.УстановитьПараметр("Договор",		Реквизиты.ДоговорКонтрагента);
	Запрос.УстановитьПараметр("ДокСсылка",		Реквизиты.ДокументРеализацииСсылка);
	Запрос.УстановитьПараметр("Момент", 		Реквизиты.Регистратор.МоментВремени() );

	Возврат  Запрос.Выполнить().Выгрузить();

КонецФункции

Проверено на следующих конфигурациях и релизах:

Бухгалтерия предприятия, редакция 3.0, релизы 3.0.161.22

Вступайте в нашу телеграмм-группу Инфостарт

аванс взаимозачет по договору задолженность Корректировка поступления Корректировка реализации 1С:Бухгалтерия 3.0

+3 –

См. также

Перенос данных и обмен из УТ 10.3 в УТ 11 / КА 2 / ERP 2. Переносятся документы, справочники и остатки

Перенос данных 1C Взаиморасчеты Оптовая торговля Логистика, склад и ТМЦ Файловый обмен (TXT, XML, DBF), FTP Системный администратор Программист 1С v8.3 1С:Управление торговлей 10 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Управленческий учет Платные (руб)

Можно проверить до покупки, оставьте заявку! Воспользовались более 268 компаний! Перенос данных из УТ 10.3 в УТ 11 | из УТ 10.3 в КА 2 | из УТ 10.3 в ERP. Решение для перехода с УТ 10.3. Можно перенести начальные остатки, нормативно-справочную информацию и все возможные документы. При выгрузке можно установить отбор по периоду, организациям и складам.

55778 руб.

24.04.2015 201198 166 247

291

Акты сверки + Групповая подготовка и рассылка актов сверки для Бухгалтерии 3.0

Взаиморасчеты Email рассылки Акт сверки Бухгалтер Пользователь 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Бухгалтерский учет Платные (руб)

Внешняя обработка для Бухгалтерии 3.0 - позволяет автоматически формировать документы «Акт сверки расчетов» с контрагентами за выбранный период с последующей фоновой отправкой на почту контрагента.

4800 руб.

25.11.2020 27016 293 9

251

Рассылка по электронной почте и автоматическое формирование актов сверки взаиморасчетов для 1С:КА 2.5, УТ 11, ERP 2.5

Email рассылки Взаиморасчеты Мастера заполнения Акт сверки Бухгалтер Пользователь 1С v8.3 Бухгалтерский учет 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Бухгалтерский учет Управленческий учет Платные (руб)

Расширение для автоматического формирования актов сверки по контрагентам/партнерам, а также для массовой рассылки печатных форм акта взаиморасчетов пользователям на их электронный адрес.

9600 руб.

01.06.2020 35260 94 53

УТ 11, КА 2, ERP 2: Настраиваемые под каждую организацию печать и подпись ответственных лиц в печатных формах (ТОРГ-12, Счёт-фактура, УПД, УКД, Заказ клиента, Акт сверки, М-15 и др.)

Печатные формы Взаиморасчеты Оптовая торговля Производство готовой продукции (работ, услуг) Акт сверки Бухгалтер Пользователь Оперативный учет Управляемые формы 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Бухгалтерский учет Управленческий учет Платные (руб)

Задайте для каждой организации свою печать и для каждого физического лица свою подпись. Выберите в документе печатную форму "... с печатью и подписью" - и автоматически сформируется табличный документ с печатью и подписями той организации и ответственных лиц, которые указаны в документе.

14400 руб.

13.03.2018 64698 231 79

121

Автоматический зачет авансов в 1С:УНФ 3.0 по ФИФО

Взаиморасчеты Бухгалтер Пользователь 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Знаем о взаиморасчетах в Управлении нашей фирмой все, что только можно знать. Самая большая проблема взаиморасчетов в УНФ в том, что зависают непонятные долги и предоплаты, в Пульсе бизнеса показываются неадекватные цифры, отчеты по долгам показывают не пойми что. Автоматический зачет авансов в 1С:УНФ 3.0 поможет решить эту проблему.

18000 руб.

22.07.2021 28385 44 34

Дебиторская задолженность по срокам долга в 1С

Взаиморасчеты Бухгалтер Пользователь 1С v8.3 1С:Комплексная автоматизация 1.х 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Бухгалтерский учет Управленческий учет Платные (руб)

Один из лучших вариантов отчета по дебиторской задолженности в 1С. Отображает сроки возникновения задолженности, просроченной задолженности с точностью до регистратора, а также многое другое, вне зависимости от объекта расчетов (УТ 11.3, 11.4, 11.5, КА 2.4, 2.5, ERP 2.4, 2.5), состояния флажка По документам расчета ( УТ 10, КА 1.1, УПП 1.3) в договоре. Группирует задолженность по интервалам. Имеет большое количество настроек. Доступен API для использования рассчитанной задолженности в других отчетах, обработках, рабочих местах и т.п. Не требует доработок конфигурации. Не требует перепроведения документов.

16680 руб.

28.09.2012 101293 593 297

150

"Расчет и начисление пени" для 1С:БП 3.0 (8.3 Бухгалтерия)

Взаиморасчеты Бухгалтер Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Расширение позволяет гибко настроить расчет и начисление пени в 1С в организации. Представлена в двух вариантах исполнения: как расширение и как обработка.

9600 руб.

18.10.2017 41030 86 47

Тестирование и исправление ключей аналитики в 1С ERP, УТ11, КА

Корректировка данных Системный администратор Программист 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Незаменимая обработка для сопровождения конфигураций: ERP, УТ, КА. Позволяет вычистить многие ошибки в ключах аналитики, в ключевых справочниках конфигурации.

3600 руб.

10.02.2017 115072 690 176

731