Графическая схема. Управление при помощи XDTO.

Публикация № 576498 16.01.17

Разработка - Практика программирования

Графическая схема XDTO бизнес процессы

В статье описывается методика программного управления элементами графической схемы при помощи механизма XDTO. Приложена готовая к использованию библиотека функций для создания и удаления графических объектов, а также для связи элементов схемы соединительными линиями.

Невозможность программного управления графической схемой периодически вызывает появление публикаций, которые тем или иным способом устраняют этот недостаток платформы. В качестве примера можно привести

//infostart.ru/public/537353/

//infostart.ru/public/551576/

//infostart.ru/public/336564/

//infostart.ru/public/320691/

Как правило, в этих публикациях графическая схема  либо сохраняется в файл GRS, который может быть программно изменен, либо используется  XML-, JSON- сериализация, конвертация в платформенные структуры и массивы. К сожалению, ни в одной публикации не был упомянут самый простой и логичный (на мой взгляд) способ - использование механизма XDTO. Этот способ имеет много общего с использованием XML-сериализации, но гораздо удобнее  в изучении и реализации, а также позволяет получить более понятный код.

Описание механизма

Несколько слов о механизме XDTO. Я не буду останавливаться на теории, желающие без труда найдут соответствующие статьи (например цикл статей //infostart.ru/public/167459/), ограничусь лишь рассмотрением практических вопросов, необходимых в рамках нашей задачи. Заранее прошу прощения у гуру за некий повтор информации из документации,  цель моей публикации - изложить информацию в максимально доступной для новичков форме.

Итак, для работы нам потребуется 2 вида сущностей: ОбъектXDTO - объекты, которые будут для нас элементами графической схемы, и СписокXDTO - список объектов ОбъектXDTO. Многие объекты 1С, в том числе графическая схема, могут быть преобразованы в объекты XDTO:

ГрафСхемаXDTO=СериализаторXDTO.ЗаписатьXDTO(ГрафСхема);

Каждый объект характеризуется типом. Программист может создавать объекты XDTO произвольных типов. Тип определяется совокупностью двух строк: URIПространстваИмен и Имя типа. Например создание объекта - элемента графической схемы выглядит так:

НовОбъект=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.2/data/graphscheme","GraphSchemeItem"));

Возникает вопрос: как перед созданием узнать тип нужного программисту объекта, т.е. Имя и URIПространстваИмен? Существует 2 способа: первый - создать объект вручную и посмотреть в отладчике свойства его типа:

Вариант второй - обратиться к в желтым книжкам, или синтаксис-помощнику. Так, для графической схемы:

... Данный объект может быть сериализован в/из XDTO. Тип XDTO, соответствующий данному объекту, определяется в пространстве имен {http://v8.1c.ru/8.1/data/graphscheme}. Имя типа XDTO: FlowchartContextType. 

У объекта XDTO есть свойства, значениями которых могут выступать как простые типы, так и сложные: другие объекты или их списки.

Как видим, у объекта графической схемы есть собственные свойства, кроме того есть реквизит item - Список XDTO.  Забегая вперед, отметим, что это - список графических элементов, т.е. именно то, что нам нужно.

Большинство свойств объектов доступны для изменения.

После модификации Объект XDTO можно преобразовать обратно в объект платформы 1С:

ГрафСхема=СериализаторXDTO.ПрочитатьXDTO(ГрафСхемаXDTO);

Таким образом методика программного изменения графической схемы выглядит так: 

  • Сериализуем (т.е. преобразовываем в объект XDTO) графическую схему
  • Меняем свойства объекта XDTO, список графических элементов,
  • Десериализуем объект XDTO обратно в графическую схему.

Неоспоримым плюсом и отличием от способов, предлагаемых в других публикациях, является тот факт, что на этапе изменения схемы мы работаем с понятной объектной моделью - объектами (с доступными свойствами-реквизитами) и списками объектов.

Примеры создания элементов

Для примера попробуем добавить в графическую схему элемент "Действие":

Сериализуем графическую схему и создадим новый элемент схемы:

	ГрафСхемаXDTO=СериализаторXDTO.ЗаписатьXDTO(ГрафСхема);
	НовОбъект=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.2/data/graphscheme","GraphSchemeItem"));
	НовОбъект.itemType=5;

Реквизит itemType - один из самых важных. Он задает тип графического элемента и его внешний вид.

Список типов:

  • 0 - Декорация
  • 1 - Линия
  • 2 - Старт
  • 3 - Завершение
  • 4 - Условие
  • 5 - Действие
  • 6 - Выбор варианта
  • 7 - Разделение
  • 8 - Слияние
  • 9 - Обработка
  • 10 - Вложенный процесс 

Далее зададим имя создаваемого объекта, его идентификатор (должен быть уникальным среди элементов схемы) и номер порядка обхода.

	НовОбъект.itemCode="Действие1";
	НовОбъект.itemId=1;
	НовОбъект.itemTabOrder=1;

Следующий шаг - мы должны задать координаты прямоугольника, внутри которого будет расположен наш объект. Именно к серединам его сторон будут потом "привязываться" соединительные линии. Координаты отсчитываются от левого верхнего угла схемы.

	НовОбъект.rectLeft=100;
	НовОбъект.rectRight=200;
	НовОбъект.rectTop=100;
	НовОбъект.rectBottom=200;

Заголовок элемента - это несколько вариантов строк, для разных языков. Нам хватит одного.

	Заголовки=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.1/data/core","LocalStringType"));
	ЗаголовокЭлемента=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.1/data/core","LocalStringItemType"));
	ЗаголовокЭлемента.lang="#";
	ЗаголовокЭлемента.content="Действие №1";
	Заголовки.Item.Добавить(ЗаголовокЭлемента);
	НовОбъект.itemTitle=Заголовки;
	НовОбъект.currentLanguage="#";

Определим цвет элемента. В нашем случае - цвет по умолчанию, определяется типом элемента.

	НовОбъект.backColor=новый Цвет;

Следующий момент - задание типа линии границы элемента - значение реквизита border. На этом шаге спотыкается большинство разработчиков, так как в документации этот вопрос не рассмотрен, а реверс-инжиниринг дает непонятный результат. Правильно делать так:

	НовОбъект.Border=СериализаторXDTO.ЗаписатьXDTO(новый линия(ТипСоединительнойЛинии.Сплошная,1));

У нашего объекта есть свойство point - список объектов XDTO - точек вершин элемента. Для корректного отображения элемента их надо задать. Правые и нижние координаты на единицу меньше чем координаты ограничивающего прямоугольника. (Почему так? Кто знает...)

	НовОбъект.Point.Добавить(НоваяТочкаXDTO(100,100));
	НовОбъект.Point.Добавить(НоваяТочкаXDTO(200-1,100));
	НовОбъект.Point.Добавить(НоваяТочкаXDTO(200-1,200-1));
	НовОбъект.Point.Добавить(НоваяТочкаXDTO(100,200-1));
////////////////////////////////////////////////////////////


Функция НоваяТочкаXDTO(x,y)
	Точка=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.2/data/graphscheme","Point"));
	Точка.x=x;
	Точка.y=y;	
	Возврат Точка;
КонецФункции

Что будет если мы зададим свой набор точек? Можно будет нарисовать многоугольник произвольной формы? Да можно, но... до первого "шевеления" элемента мышкой. При первом же удобном случае элемент примет форму, определяемую его типом, в пределах ограничивающего прямоугольника.

И, наконец, добавим наш созданный элемент в список элементов графической схемы и десериализуем ее.

	ГрафСхемаXDTO.item.Добавить(НовОбъект);
	ГрафСхема=СериализаторXDTO.ПрочитатьXDTO(ГрафСхемаXDTO);

Приведенного выше кода достаточно для отображения элемента "Действие". Но можно настроить и другие свойства: alignHor, alignVer, hyperlink, picturePlacement, pictureStyle, transparent, lineColor, textColor и др. Их назначение понятно из названий. 

Аналогичным образом создаются и другие объекты. При этом необходимо учесть несколько особенностей:

  • По умолчанию у объектов "Старт" и "Завершение" угол при вершине равен 120º
  • По умолчанию у объекта "Условие" углы правой и левой стороны равны 120º
  • Объект "Декорация" имеет реквизит shape, который отвечает за форму объекта: Блок, Документ, Эллипс и т.д.
  • У объекта "ВыборВарианта" есть реквизит transition, содержащий список вариантов.
  • Высота заголовка объекта "Действие" и высота вариантов объекта "ВыборВарианта" - величина постоянная

Создание соединительной линии несколько отличается  от создания прочих объектов:

	НовОбъект=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.2/data/graphscheme","GraphSchemeItem"));
	НовОбъект.itemType=1;
	НовОбъект.itemId=2;
	НовОбъект.itemTabOrder=2;
	НовОбъект.itemCode="Линия1";
	
	Заголовки=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.1/data/core","LocalStringType"));
	ЗаголовокЭлемента=СериализаторXDTO.Фабрика.Создать(СериализаторXDTO.Фабрика.Тип("http://v8.1c.ru/8.1/data/core","LocalStringItemType"));
	ЗаголовокЭлемента.lang="#";
	ЗаголовокЭлемента.content="Линия №1";
	Заголовки.Item.Добавить(ЗаголовокЭлемента);
	НовОбъект.itemTitle=Заголовки;
	НовОбъект.currentLanguage="#";
	
	НовОбъект.beginArrowStyle=СтильСтрелки.Нет;
	НовОбъект.endArrowStyle=СтильСтрелки.Заполненная;

	НовОбъект.connectFromItemId=-1;
	НовОбъект.connectToItemId=1;
	НовОбъект.portIndexFrom=0;
	НовОбъект.portIndexTo=3;
	НовОбъект.connectFromPortIndex=0;
	
	НовОбъект.backColor=новый Цвет;
	НовОбъект.decorativeLine=Ложь;
	НовОбъект.Border=СериализаторXDTO.ЗаписатьXDTO(новый линия(ТипСоединительнойЛинии.Сплошная,1));
	
	НовОбъект.Point.Добавить(НоваяТочкаXDTO(300,150));
	НовОбъект.Point.Добавить(НоваяТочкаXDTO(200,150));
	
	ГрафСхемаXDTO.item.Добавить(НовОбъект);

Здесь надо обратить внимание на следующие реквизиты: connectFromItemId, connectToItemId - идентификаторы объектов, к которым "привязаны" начало и конец линии.  portIndexFrom, portIndexTo - номера сторон, к которым присоединены линии.

Список номеров сторон:

  • 1 - середина левой стороны ограничивающего объект прямоугольника
  • 2 - середина верхней стороны 
  • 3 - середина правой стороны 
  • 4 - середина нижней стороны 
  • 6, 8, 10, ... - середина левой стороны варианта 1, 2, 3, ... для объекта ВыборВарианта
  • 7, 9, 11, ... - середина правой стороны варианта 1, 2, 3, ... для объекта ВыборВарианта

Особенности работы с линиями:

  • Если линия начинается из варианта объекта ВыборВарианта, то реквизит connectFromPortIndex равен номеру варианта.
  • Реквизит decorativeLine - флаг декоративной линии.
  • Соединительная линия, в отличие от декоративной, перестраивается при перемещении объекта, к которому присоединена. Присоединенная декоративная линия также перемещается вслед за перемещаемым объектом, но, как правило, ее форма не так сильно меняется.
  • Декоративная линия может иметь наконечники разных типов, а соединительная - только в виде заполненной стрелки.
  • Нельзя допускать наличия соседних сегментов линии, лежащих на одной прямой, иначе перемещение линии вызывает странные визуальные эффекты.

Библиотека для работы с графической схемой

Для упрощения работы с графической схемой была разработана библиотека функций, приложенная к статье.

Функции создания и удаления объектов:

// Создает XDTO объект - Действие
Функция НовыйОбъектДействие(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - ВыборВарианта
Функция НовыйОбъектВыборВарианта(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Старт
Функция НовыйОбъектСтарт(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Завершение
Функция НовыйОбъектЗавершение(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Условие
Функция НовыйОбъектУсловие(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Разделение
Функция НовыйОбъектРазделение(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Слияние
Функция НовыйОбъектСлияние(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Обработка
Функция НовыйОбъектОбработка(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - ВложенныйПроцесс
Функция НовыйОбъектВложенныйПроцесс(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Декорация
Функция НовыйОбъектДекорация(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Фигура,Лево,Верх,Ширина,Высота,Цвет=Неопределено,Линия=Неопределено)Экспорт
// Создает XDTO объект - Декоративную линию
Функция новаяДекоративнаяЛинияСхемы(ГрафСхемаXDTO,Имя,Заголовок=Неопределено,Знач Координаты,Линия=Неопределено,СтрелкаНачала=Неопределено,СтрелкаКонца=Неопределено)Экспорт
// Удаляет объект из схемы
Процедура УдалитьОбъектСхемы(ГрафСхемаXDTO,Объект)Экспорт

Функции работы с вариантами:

// Добавляет новый вариант в объект ВыборВарианта
Процедура ДобавитьВариант(ОбъектВыборВарианта,Имя,Заголовок=Неопределено,Цвет=Неопределено)Экспорт
// Вставляет (со сдвигом) новый вариант в объект ВыборВарианта
Процедура ВставитьВариант(ГрафСхемаXDTO,ОбъектВыборВарианта,Позиция,Имя,Заголовок=Неопределено,Цвет=Неопределено)Экспорт
// Удаляет (со сдвигом) вариант из объекта ВыборВарианта
Процедура УдалитьВариант(ГрафСхемаXDTO,ОбъектВыборВарианта,Позиция)Экспорт

Функции поиска:

// Возвращает объект схемы по его имени или идентификатору
Функция НайтиОбъектСхемы(ГрафСхемаXDTO,ЗначениеПоиска)Экспорт
// Возвращает индекс объекта схемы по его имени или идентификатору
Функция НайтиИндексОбъектаСхемы(ГрафСхемаXDTO,ЗначениеПоиска)Экспорт

Функция соединения объектов:

// Соединяет два объекта соединительной линией
Функция СоединитьОбъектыЛинией(ГрафСхемаXDTO,Знач Объект1,Знач Объект2,Направление1,Направление2,НомерВарианта1=0,НомерВарианта2=0,ТипЛинии=Неопределено,СтрелкаНачала=Неопределено,СтрелкаКонца=Неопределено)Экспорт

Задача соединения объектов линией оказалась неожиданно непростой. Количество вариантов взаимного расположения объектов с учетом комбинаций соединяемых сторон довольно велико. Для сокращения количества вариантов пришлось использовать поворот объектов вокруг оси координат так, чтобы линия в первый объект входила всегда с левой стороны. Интересной выглядит следующая задача: написать алгоритм построения соединительной линии так, чтобы а) линия по возможности огибала бы другие элементы схемы и б) количество пересечений с другими линиями было бы минимально. Задача а) уже решена в платформе. Желающие могут из решения этой задачи сделать очень хорошую публикацию.

Пример использования библиотеки:

	ГрафСхемаXDTO=СериализаторXDTO.ЗаписатьXDTO(ГрафСхема);	
	
	НовОбъект=РаботаСГС.НовыйОбъектДействие(ГрафСхемаXDTO,"Действие1",,240,40,80,60,WebЦвета.БледноБирюзовый);
	ГрафСхемаXDTO.item.Добавить(НовОбъект);
	
	НовОбъект=РаботаСГС.НовыйОбъектОбработка(ГрафСхемаXDTO,"Обработка1",,140,180,80,60);
	ГрафСхемаXDTO.item.Добавить(НовОбъект);
	РаботаСГС.СоединитьОбъектыЛинией(ГрафСхемаXDTO,"Действие1","Обработка1",4,1);	
	
	НовОбъект=РаботаСГС.НовыйОбъектВыборВарианта(ГрафСхемаXDTO,"Выбор",,260,200,100,60,WebЦвета.СветлоСерый);
	РаботаСГС.ДобавитьВариант(НовОбъект,"Вариант 1","",WebЦвета.Красный);
	РаботаСГС.ДобавитьВариант(НовОбъект,"Вариант 2","",WebЦвета.Желтый);
	РаботаСГС.ДобавитьВариант(НовОбъект,"Вариант 3","",WebЦвета.Зеленый);
	ГрафСхемаXDTO.item.Добавить(НовОбъект);	
	
	РаботаСГС.СоединитьОбъектыЛинией(ГрафСхемаXDTO,"Выбор","Действие1",3,3,2,0);	
	
	ГрафСхема=СериализаторXDTO.ПрочитатьXDTO(ГрафСхемаXDTO);

Предлагаемая библиотека позволит разработчику упростить построение схем произвольных бизнес-процессов, организационных диаграмм, структур подчиненности и т.п.

В заключение хотелось бы отметить, что использование XDTO позволяет программисту получить дополнительные возможности по работе с самыми разными объектами (Дерево значений, табличный документ, и т.д.), тем самым несколько скомпенсировать отсутствие таких возможностей в объектной модели, предоставляемой платформой.

Скачать файлы

Наименование Файл Версия Размер
Библиотека функций работы с графической схемой

.cf 20,87Kb
122
.cf 20,87Kb 122 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. boln 1032 18.01.17 11:00 Сейчас в теме
Интересуюсь возможностями программного управления ГС. "Плюс".
2. RainyAugust22 254 20.01.17 06:25 Сейчас в теме
Не хватает стартмоней чтобы скачать и попробовать, сделайте скидку в 1 старт плз :-D
4. Alxby 585 23.01.17 21:51 Сейчас в теме
3. Evil Beaver 7075 23.01.17 10:17 Сейчас в теме
Заплюсовал! Логичное решение, а сразу в голову не придет, что есть из коробки XDTO-сериализация. Спасибо.
5. Alxby 585 23.01.17 22:05 Сейчас в теме
(3) Да, чаще XDTO рассматривается с точки зрения обмена данными, Web-сервисов и т.п. Я сам несколько лет назад порядочно времени потратил на редактирование графической схемы через преобразование ее в строку: ЗначениеВСтрокуВнутр(ГрафСхема), пока не открыл для себя XDTO. Так что повторюсь: "...использование XDTO позволяет программисту получить дополнительные возможности по работе с самыми разными объектами ... , тем самым несколько скомпенсировать отсутствие таких возможностей в объектной модели, предоставляемой платформой". И это здОрово.
boln; dj_serega; +2 Ответить
6. dj_serega 379 21.03.17 16:46 Сейчас в теме
Очень крутая публикация.
Как-то не получилось с прозрачным фоном декорации... А так все что хотел сделал.

Спасибо.
7. RainyAugust22 254 30.06.17 12:53 Сейчас в теме
Возможно ли доработать библиотеку чтобы стрелки выходили/входили из/в фигуры не с центра стороны, а с разных позиций стороны фигуры? (рис.) т.к стрелок много, сливаются в одну становиться нечитабельно. Возможно фигуру "выбор варианта" еще попробовать.
Прикрепленные файлы:
8. Alxby 585 04.07.17 19:37 Сейчас в теме
К сожалению, механизм работы с графической схемой подразумевает наличие соединительных линий только между серединами сторон ограничивающего фигуру прямоугольника (не серединами сторон фигуры!). Единственный выход - самостоятельно построить декоративную, а не соединительную линию, рассчитав координаты конца линии, но в этом случае: а) в схеме не будет информации о связи линии с фигурой, б) линия не будет "тянуться" за фигурой при перемещении. В этом случае придется самостоятельно обеспечивать учет связей графических примитивов и механизм изменений. Я думаю, это выходит за рамки предлагаемой библиотеки, но буду рад, если кто-нибудь возьмется за реализацию данного функционала, мне кажется он будет востребован.
9. Kamikadze 46 24.07.17 10:07 Сейчас в теме
Крутая публикация. Попробую использовать для своих потребностей, отпишусь по результатах.
10. Абигоп-НахУрт 23.10.17 21:40 Сейчас в теме
Решение у меня есть, уже года 4-5 как тому назад, но совершенно не правильное, тогда распарсили текстовый файл в структуру. Хочу перейти на Вашу, что для этого надо?
Прикрепленные файлы:
Проблема.txt
11. Alxby 585 24.10.17 19:49 Сейчас в теме
(10) Распарсить текстовый файл в структуру - не обязательно неправильное решение. Может быть неэффективное, это верно. Я тоже через это проходил, еще в предыдущей версии платформы. По вопросу перехода написал по почте.
12. AlexKo84 07.10.18 13:44 Сейчас в теме
Добрый день. Интересно посмотреть, но маников осталось только на совсем непредвиденные нужды. Можете поделиться?
13. Kr666 30.11.18 13:07 Сейчас в теме
14. TEST654321 10.10.19 08:19 Сейчас в теме
Великолепная статья!
Скачать пример пока нет возможности, но в тексте разжевано абсолютно все!
Реализовать получилось сразу. Жаль тут таких статей не так много ( с фрагментами кода скользких мест)
15. Alxby 585 10.10.19 19:15 Сейчас в теме
16. KirillM1987 1 05.05.20 17:56 Сейчас в теме
Шикарная обработка!

С её помощью быстро своял схему маршрута согласования платежей)). Код понятный, можно объекты подкрутить под себя. Спасибо!
17. Alxby 585 16.05.20 11:42 Сейчас в теме
18. poar 17.06.20 15:13 Сейчас в теме
Статья отличная, спасибо автору.
Повторил, все получилось.

Когда стал подходить к своей задаче столкнулся с одним моментом, который пока не смог решить.

Сделал 3 блока действия.
Два блока один под вторым, третий правее.
От первых двух линии идут к третьему.

При программной расстановке блоков линии заходят на блоки. После того как любой из блоков двину мышкой линии выстраиваются красиво. Картинки приложены.

Есть мысли как поправить?
Прикрепленные файлы:
19. Alxby 585 19.06.20 18:22 Сейчас в теме
(18)
Пришлите пожалуйста код, который дает такой эффект, посмотрим что можно сделать
21. poar 14.07.20 16:06 Сейчас в теме
(19)
Добрый день. Решил проблему тем, что сам рассчитал промежуточные точки, а линии отвязал от конечных точек.
20. poar 14.07.20 16:04 Сейчас в теме
Добрый день. Решил проблему тем, что сам рассчитал промежуточные точки, а линии отвязал от конечных точек.
22. Nicholas 773 15.09.20 07:15 Сейчас в теме
Скажите, а цвета элементов, картинки и прочее оформление можно менять?
23. Alxby 585 15.09.20 12:28 Сейчас в теме
(22)Да, конечно. Посмотрите, в статье упомянут этот момент.
24. Valeric650 22.07.21 15:05 Сейчас в теме
При использовании решений с других статей (тут и тут) столкнулся с проблемой, что соединительные линии не обходят элементы схемы и рисуются напрямую через другие блоки (пример см. в приложенном файле, в примере связующая линия блок 1 -> блок 3 пересекает блок 2).
А это решение способно решить данную проблему?
Прикрепленные файлы:
25. Alxby 585 22.07.21 20:46 Сейчас в теме
(24)Вы можете создать линию, указав все точки ее узлов, обходя тем самым блоки. К сожалению, автоматическое соединение с помощью СоединитьОбъектыЛинией построит линию по кратчайшему пути. Эту проблему решить в большинстве случаев (но не всегда!) в принципе возможно, но значительно усложнится алгоритм.
Оставьте свое сообщение

См. также

FormCodeGenerator Программная доработка форм. Часть 2 (Режим работы "Режим сравнения форм") на примере ERP 2.5 Промо

Практика программирования Адаптация типовых решений Прочие инструменты разработчика v8 1cv8.cf Абонемент ($m)

Данная публикация является продолжением описания функционирования обработки "FormCodeGenerator " в режиме сравнения форм и генерирования кода на основании сравнения. Подходит для перевода уже доработанных форм с интерактивной доработки на программную. Данный режим работы обработки снизит издержки при дальнейших обновлениях конфигураций.

5 стартмани

21.12.2020    6938    21    huxuxuya    11    

Интерактивная справка по объектам 1С (подключаемое расширение)

Практика программирования Работа с интерфейсом v8 ERP2 Абонемент ($m)

База знаний, подключаемая к объектам основной базы. Пополняется интерактивно, формируется в виде статей прямо в 1С (текст, картинки, таблицы, ссылки). Есть возможность прикрепления файлов, привязки к объектам 1С, возможности рейтинга и комментирования пользователями.

3 стартмани

29.09.2020    13094    73    sapervodichka    43    

Конвейер проверки качества кода

Инструментарий разработчика Практика программирования Математика и алгоритмы Jenkins SonarQube v8 1cv8.cf Абонемент ($m)

Jenkinsfile для выполнения проверки качества кода. Собирает информацию с АПК, EDT и BSL-LS. Сопоставляет ошибки с гит-репозиторием, выгруженным ГитКонвертором. Отправляет в Сонар.

3 стартмани

04.09.2019    33766    27    Stepa86    46    

Алгоритмы поиска пути в графе

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

Реализуем алгоритмы поиска пути в графе на платформе 1С 8.3, такие как алгоритм А*, поиск в ширину, жадный поиск, алгоритм Дейкстры и вконце волновой.

1 стартмани

09.07.2019    21663    12    RonX01    10    

Вам нравятся запросы в 1С? Промо

Практика программирования Разработка v8 v8::Запросы 1cv8.cf Абонемент ($m)

Речь не только о том, что простейший запрос с "легальным" оформлением растянется на пол-экрана, речь еще обо всем, что нужно написать "в нагрузку" к тексту запроса. Все эти "Новый Запрос", "УстановитьПараметр" и последующие пляски с обработкой результата... Пора с этим заканчивать!

1 стартмани

03.07.2019    26053    7    m-rv    91    

Диаграмма Ганта и графическая схема сторонними средствами

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Примеры формирования диаграммы Ганта и графической схемы в 1С сторонними средствами.

1 стартмани

01.11.2018    9176    7    no_betrayal    6    

Работа с публикациями "Инфостарт"

Практика программирования О сообществе WEB v8 УУ Абонемент ($m)

Работа с рублевыми публикациями на сайте "Инфостарт": ведение клиентов, заказов, обновление файлов публикации, рассылка обновлений.

1 стартмани

13.09.2018    26343    14    RocKeR_13    16    

HTTP Сервисы: Путь к своему сервису. Часть 3

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Продолжение статьи «HTTP Сервисы: Путь к своему сервису. Часть 2». В предыдущих частях мы использовали только Get, в этой части поговорим о других методах и длительных операциях.

1 стартмани

27.08.2018    50381    66    dsdred    17    

ВСТАВИТЬ В Справочник.Номенклатура (Код, Наименование) ЗНАЧЕНИЯ ("001", "Новый товар") Промо

Практика программирования v8 v8::Запросы 1cv8.cf Абонемент ($m)

Вас не обманывают ваши глаза, это запрос на изменение данных! И это работает без прямого доступа к БД, регистрации и смс.

1 стартмани

01.06.2018    35032    93    m-rv    58    

Позиционирование в помещении с помощью нейросети по сигналу Wi-Fi. Интерактивная карта склада в 1С с показом позиции

Инструментарий разработчика Практика программирования v8 Абонемент ($m)

Данная публикация содержит в себе редактор и интерактивную карту склада или иного помещения, на которой в реальном времени отображается позиция устройства, координаты которого вычисляются по уровням сигнала нескольких роутеров Wi-Fi. В статье и приложенным к ней разработкам предлагаются инструменты и методика для реализации вычисления точной геопозиции внутри помещений с помощью нейронной сети. Конфигурация написана на релизе 1С:Предприятие 8.3.12.1412, клиентское приложение имеет минимальный уровень совместимости SDK -16.

5 стартмани

09.08.2018    34157    31    informa1555    30    

Работа с данными выбора

Практика программирования Работа с интерфейсом v8 Россия Абонемент ($m)

В управляемом интерфейсе заложена мощная возможность описывать связи реквизитов формы через параметры. Установка параметров связей позволяет ограничить выбор данных так, чтобы целостность данных была обеспечена на этапе ввода. Однако без дополнительного программирования задать можно только самые простые связи. Такие условия связи, как зависимость от реквизита через точку или зависимость через дополнительное отношение, заданное в регистре сведений - уже задать без программирования не получится.

1 стартмани

17.07.2018    62241    24    kalyaka    17    

Полезные примеры составления схемы компоновки данных #2

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Еще один набор примеров как решить частные задачи в СКД

1 стартмани

22.05.2018    38099    11    SITR-utyos    13    

Заполняем по шаблону (по умолчанию) Промо

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Простой в подключении, универсальный и достаточно удобный механизм заполнения реквизитов произвольных документов/справочников значениями по умолчанию. Реализован в расширении, но может быть и непосредственно включен практически в любую конфигурацию на управляемых формах простым копированием одной формы и двух команд. Весь код в статье.

1 стартмани

08.02.2018    32967    20    mvxyz    17    

Печатная форма, сделанная как расширение конфигурации для БП 3.0. Новые возможности БСП

Практика программирования Универсальные печатные формы v8 БП3.0 Абонемент ($m)

Печатные формы на внешних обработках скоро канут в лету. На смену им приходят ПФ, реализованные в виде расширений конфигурации. Не нашел на сайте примеров таких расширений. Привожу пример подобного расширения для БП 3.0.

1 стартмани

06.12.2017    31394    56    kwazi    6    

Паузы при исполнении кода (Sleep для 1С)

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Решил проверить все найденные варианты паузы для 1С. В результате получилась обработка для тестирования и небольшая статья с итогом.

1 стартмани

28.11.2017    62888    17    swimdog    49    

Макет в СКД - пример всех возможных типовых вариантов

Практика программирования Инструментарий разработчика v8 v8::СКД 1cv8.cf Абонемент ($m)

Макет СКД: наглядное представление того, что, как и куда выводится при типовых настройках.

1 стартмани

09.11.2017    25962    80    freelancer    4    

Нечеткий поиск одним запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Использование механизма полнотекстового поиска в 1С не всегда оправдано, т.к. построение индекса и поддержание его в актуальном состоянии может значительно нагружать систему. Предлагаемая реализация нечеткого поиска методом N-грамм выполняется одним запросом, что позволяет производить поиск в любой таблице и не требует предварительного построения индекса.

1 стартмани

28.12.2015    32707    73    vasvl123    9    

Telegram-боты

Практика программирования v8 Абонемент ($m)

Описание теории, разбор архитектуры и пример реализации telegram-ботов. Сразу скажу, со структурированием изложения мало что могу поделать. :) редакция от 18.07.2018 Правки последней редакции выделены жирным.

1 стартмани

01.09.2017    40016    146    PLAstic    68    

Умный дом на 1С + ардуино

Практика программирования v8 Абонемент ($m)

Конфигурация для автоматизации быта программиста 1C и не только. В данной статье будет рассказано, как можно использовать 1С для задач, не входящих в стандартные рамки этой платформы. Например, управление домом. В качестве периферии для подключения будет использован микроконтроллер (МК) Ардуино, но на нём не будет никакой логической нагрузки, весь процесс будет проходить на сервере 1С. Работа с пинами ввода/вывода происходит напрямую из 1С.

1 стартмани

07.08.2017    26668    21    sasha777666    64    

Расширения конфигураций 1С: учимся перехватывать методы

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

В этой статье я на примерах разберу некоторые механизмы расширений конфигураций 1С. А именно «перехваты» методов модуля объекта и «перехваты» событий формы и элементов формы. Данная статья написана с учебными целями, чтобы показать, как при помощи расширений конфигурации можно делать такие доработки, ради которых раньше приходилось снимать конфигурацию с поддержки.

1 стартмани

30.05.2017    158771    13    signum2009    48    

1С: Предприятие + корпоративный чат, как наладить оперативные уведомления за 10 минут Промо

Практика программирования v8 Абонемент ($m)

Как сделать автоматические уведомления о разных событиях из 1С в корпоративный чат MyChat для сотрудников компании

1 стартмани

14.08.2016    53084    36    Demanoidos    60    

Регулярные выражения – это просто. Построитель и отладчик регулярных выражений

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Предлагается к использованию построитель регулярных выражений. Выполненный в виде внешней обработки, он позволит строить сложно-структурированные выражения на основе параметрического описания, тестировать их, и в результате получить программный код 1С.

1 стартмани

13.03.2017    37016    122    romasna    52    

Распознавание текста с помощью нейросетей Google Cloud Vision и 1С

Практика программирования v8 1cv8.cf Абонемент ($m)

Возможности Google Cloud Vision в распознавании текста.

1 стартмани

08.02.2017    36215    143    kiv1c    18    

Простой редактор плана помещения JavaScript

Практика программирования Работа с интерфейсом v8 1cv8.cf Абонемент ($m)

На ресурсе сейчас очень много решений, которые позволяют редактировать карты, используя географические схемы. Так же много решений, которые позволяют редактировать объекты онлайн веб-карт. Мне же нужно было простое решение, для того чтобы расставить квадратные объекты на плане, показать их пользователю. Ну и распечатать, опять же. Я решил написать простенький редактор на JavaScript с использованием библиотеки Raphael.

1 стартмани

23.11.2016    25448    103    igel9780    22    

Быстрое определение интервалов в запросе Промо

Практика программирования v8 Абонемент ($m)

В статье описывается новый метод определения интервалов между данными различных записей в запросе. В отличие от общеизвестного метода, время работы предлагаемого метода зависит от объема данных ЛИНЕЙНО. Это обеспечивает ему значительный выигрыш по быстродействию на больших объемах данных. В качестве иллюстрации возможностей метода приведен отчет, показывающий гистограмму распределения времени между продажами.

1 стартмани

01.10.2015    58554    35    ildarovich    41    

Работа с двоичными данными на примере чтения файлов изображений. Новые возможности 8.3.9

Практика программирования WEB v8 1cv8.cf Россия Абонемент ($m)

В статье приводятся новые функции по работе с двоичными данными, появившимися в версии платформы 8.3.9 , на примере анализа формата и размера изображений. А также пример отправки изображения через API ВКонтакте с помощью новых объектов (без использования ОбъединитьФайлы())

1 стартмани

14.11.2016    32862    17    Anton64    23    

Загрузка файлов на сервер с прогрессом и докачкой

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Пример использования новых возможностей платформы 8.3.9 по низкоуровневой работе с двоичными данными для инкрементальной передачи файлов на сервер.

1 стартмани

04.10.2016    16208    57    mrstomak    21    

Несколько шаблонов для доработки типовых конфигураций

Практика программирования Инструментарий разработчика v8 v8::УФ Абонемент ($m)

Предлагаю несколько каркасов для создания новых объектов в типовых конфигурациях. Это выжимка из кода нескольких конфигураций, которая позволит быстро и красиво создавать и дорабатывать объекты метаданных с соблюдением идеологии исходной системы

1 стартмани

03.10.2016    40687    98    json    25    

HTTP-сервис: отчеты [Расширение]

Практика программирования Работа с интерфейсом v8 1cv8.cf Абонемент ($m)

Это HTTP-сервис, который возвращает почти любой отчет в HTML, XLSX или в JSON. Сохраните вариант отчета, получите на него ссылку и можно получить данные без захода в 1С. Работает в конфигурациях на основе БСП 2.3.3+, для отчетов на СКД и в 1С 8.3.8+

2 стартмани

30.08.2016    31984    147    Stepa86    16    

Недокументированное использование стандартных форм Upd.

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Вам не хватает возможностей в платформе 1С или у Вас нет времени на углубленное изучение платформы 1С? Рассмотрены возможности использования стандартных форм, вызываемых из платформы.

1 стартмани

26.07.2016    32441    96    ZhokhovM    65    

Хранение файлов в томах на диске (для УПП 1.3)

Практика программирования v8 УПП1 Абонемент ($m)

Доработка типовой УПП 1.3 в плане хранения присоединенных файлов вне базы данных

2 стартмани

05.06.2016    65174    11    wowik    32    

БСП 2.3 и БСП 3.0: Просто про выполнение внешней обработки в фоне (c индикацией прогресса выполнения)

Инструментарий разработчика Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

Простое пояснение о том, как сделать внешнюю обработку с фоновым выполнением и индикацией процесса для любой конфигурации на основе БСП 2.3.2. UPDATE 20/09/19: добавлен вариант обработки с индикацией процента выполнения и статусом выполнения для БСП 3.0.

1 стартмани

18.05.2016    71553    211    rozer    67    

Остатки на каждый день в запросе

Практика программирования Учет ТМЦ Учет ТМЦ v8 1cv8.cf УУ Абонемент ($m)

Запрос формирует остатки товаров на каждый день в пределах выбранного периода.

1 стартмани

26.04.2016    72816    20    arakelyan    25    

Еще один способ расчета остатков на каждый день в запросе

Математика и алгоритмы Практика программирования v8 Абонемент ($m)

Предлагается новый способ расчета остатков на каждый день (час, минуту, секунду) в запросе. Способ не требует предварительного формирования таблицы дат и также подходит для расчета курсов валют, цен номенклатуры и других периодических сведений на каждую дату периода. На больших объемах данных предлагаемый способ может превосходить по быстродействию ранее известные методы из-за линейной (в лучшем случае) зависимости трудоемкости от длины периода.

1 стартмани

24.04.2016    39252    54    ildarovich    23    

Вывод печатных форм с запросом данных в форму "Печать документов" из подсистемы БСП "Печать".

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

Все не раз видели, как в типовых конфигурациях, построенных на основе БСП (Библиотека стандартных подсистем), печатные формы, построенные на основе Табличного документа, выводятся в специальную форму "ПечатьДокументов". Эта форма входит в состав подсистемы "Печать" из БСП. При разработке своих печатных форм, иногда необходимо запросить у пользователя дополнительные данные необходимые для печати. Тут встает вопрос, как в этом случае вывести печатную форму в форму "Печать документа". В этой статье я рассмотрю, как реализовать вывод печатной формы в упомянутую форму из подсистемы "Печать", в случае если мы хотим перед выводом печатной формы запросить у пользователя дополнительные данные. Здесь будут рассмотрены два случая: когда реализуется печатная форма с использованием подсистемы "Дополнительные отчеты и обработки" и когда печатная форма добавляется в конфигурацию в режиме конфигуратора, т.е. вносятся изменения в типовую конфигурацию.

1 стартмани

29.03.2016    107941    204    lopatin    15    

Выполнение JavaScript кода из 1С в объекте Поле HTML Документа (HTML 5) и вызов события в 1С ПриНажатии

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Пример выполнения JS кода из 1С в Поле HTML Документа под управляемыми формами, с удобным получением результата в 1С(С помощью вызова привязанного события ПриНажатии к элементу ПолеHTMLДокумента)

1 стартмани

22.03.2016    92246    172    igo1    58    

Количество дней недели (понедельников/вторников/...) в заданном диапазоне одним запросом

Практика программирования v8 Абонемент ($m)

При реализации периодического авто-заполнения маршрутных листов по графику (недельному) необходимо было просчитать стоимость всего периода, с условием выездов только по определенным дням. Заморачиваться с обходом результата не хотелось. Пришлось написать "Небольшой" запрос.

1 стартмани

03.03.2016    21653    1    Alexander.Shvets    5    

Простые радости жизни программиста 1С: выбор типа значения

Работа с интерфейсом Практика программирования v8 1cv8.cf Абонемент ($m)

Предлагаемая в работе обработка включает обычную и управляемую формы, которые максимально точно реализуют функциональность системного диалога выбора типа в толстом клиенте обычное приложение (включая оформление диалога). Эти формы имеют дополнительные интерфейсные удобства и могут быть использованы в качестве альтернативных диалогов выбора типа.

1 стартмани

17.02.2016    56958    56    yuraos    18    

Отображение прогресса выполнения длительных операций в БСП и их отладка в текущем сеансе.

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

В статье описан способ исполнения длительных операций в конфигурациях, в которых используется библиотека стандартных подсистем, с визуализацией прогресса исполнения и отображения хода обработки данных. Также дается краткое описание процесса отладки длительных операций в текущем сеансе.

1 стартмани

17.02.2016    65946    211    balanton    23    

Яндекс.Деньги "Благотворительность"

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Яндекс.Деньги теперь в 1С. Форма для приема благотворительных взносов. Форму легко сделать и вставить на любую страницу сайта или блога. Платежи будут приходить на ваш кошелек. На форме есть три способа платежа: из кошелька, с банковской карты, с баланса мобильного.

1 стартмани

16.02.2016    26860    8    Tatitutu    5    

Мастер рассылки e-mail 2.2 для управляемых форм

Практика программирования Email v8 v8::УФ ERP2 БП3.0 УТ11 Абонемент ($m)

Для пользователей: переделанный из старый разработки под 8.2 с использованием библиотеки Мастер рассылки e-mail 2.2 (ERP, УТ, БП) (Только управляемые формы), который теперь может запускаться под любой версией платформы с разрешенными или запрещенными модальными/синхронными вызовами в конфигурации. Также удобный выбор e-mail и их владельцев с помощью отбора динамического списка по любым критериям и галочки исключения.

1 стартмани

29.12.2015    44814    21    milkers    4