gifts2017

Запрос по остаткам регистра накопления на каждый день

Опубликовал Богдан Буляков (Laertid) в раздел Программирование - Практика программирования

Неоднократно сталкивался с необходимостью написания запроса для получения остатков по периоду накопления на каждый день. Поскольку рабочий инструмент - консоль запросов, то хотелось получить результат без использования СКД (да и разбираться с ней начал существенно позже). Идея, вероятно, слегка извращенная, но работающая. Альтернативные более быстрые варианты принимаются)
ВЫБРАТЬ  

ТоварыНаСкладах2Обороты.Период,

ТоварыНаСкладах2Обороты.ХарактеристикаНоменклатуры,   

ТоварыНаСкладах2Обороты.КоличествоОборот,  

ТоварыНаСкладах2Обороты.СуммаОборот

ПОМЕСТИТЬ Движения

ИЗ  РегистрНакопления.ТоварыНаСкладах2.Обороты(&НачалоПериода, &КонецПериода, День,) КАК ТоварыНаСкладах2Обороты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ  

ДОБАВИТЬКДАТЕ(НАЧАЛОПЕРИОДА(&НачалоПериода, ДЕНЬ), ДЕНЬ, -1),  

ТоварыНаСкладах2Остатки.ХарактеристикаНоменклатуры,

ТоварыНаСкладах2Остатки.КоличествоОстаток,  

ТоварыНаСкладах2Остатки.СуммаОстаток

ИЗ  РегистрНакопления.ТоварыНаСкладах2.Остатки(&НачалоПериода,) КАК ТоварыНаСкладах2Остатки ;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ РАЗЛИЧНЫЕ  

ДвиженияДенежныхСредствОбороты.Период КАК Период

ПОМЕСТИТЬ Дни

// Тут не важно, откуда брать дни, но это необходимо, поскольку в регистре накопления есть только те дни, в которые были движения. А нам хочется знать остатки, даже если в течении дня они не менялись. Выбирайте способ построения этой таблицы, наиболее быстрый для вашей конфигурации.

ИЗ  РегистрНакопления.ДвиженияДенежныхСредств.Обороты(&НачалоПериода, &КонецПериода, День, ) КАК ДвиженияДенежныхСредствОбороты ;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ  

Дни.Период КАК Период,  

Движения.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,  

СУММА(Движения.КоличествоОборот) КАК КоличествоОборот,  

Движения.СуммаОборот ПОМЕСТИТЬ ОстаткинаНачалоДня

ИЗ  Дни КАК Дни   

ЛЕВОЕ СОЕДИНЕНИЕ Движения КАК Движения   

ПО (Движения.Период < Дни.Период)

СГРУППИРОВАТЬ ПО  

Дни.Период,  

Движения.ХарактеристикаНоменклатуры,  

Движения.СуммаОборот

 

 

 

P.S. Замечу. что у этого метода есть недостаток, полноценно проявляющийся в СКД - в нем не предусмотрен расчет итогов по остаткам по измерению Дата. Суммирование или усреднение, понятно, не подходят, поскольку Начальныйостаток нам нужен на начало периода, Конечный,  соответственно, на конец периода.

На счастье *или нет:)* в СКД то же самое можно получить легче, через виртуальный регистр ОстаткиИОбороты. Нужно только для полей с начальным и конечным остатками прописать в описании поля значение Остаток (что СКД делает Автоматически, если стоит галочка Автозаполнение), в Настройках СКД для группировки Дата во вкладке Группировка в Дополнение прописать День. СКД добавит дни без оборотов и адекватно оформит итоги по дате. Ура :)

Решение для Построителя отчета в интернете ищется легко.

См. также

Подписаться Добавить вознаграждение

Комментарии

1. zling zling (zling) 19.01.12 12:41
сам делал давеча нечто подобное. Только мне нужны были остатки на начало и конец каждого дня, а период - год :) Добавил промежуточные таблицы - одна на начало каждого месяца. Но запрос работает оч. долго. Чую надо оптимизировать :(
2. Богдан Буляков (Laertid) 19.01.12 12:45
Проблема такая есть. Если запрос простой (не навороченно-извращенный в кучей объединенных и соединенных таблиц), то рекомендую использовать СКД и ОстаткиИОбороты по регистру.
3. zling zling (zling) 19.01.12 12:58
к (1). + у меня еще остатки на начало и конец дня не обязательно одно и тоже (задумано так).
4. Богдан Буляков (Laertid) 19.01.12 12:59
Тогда да, приходится извращаться подобным образом... >_<
5. Валерий Дубовой (Valerich) 27.01.12 13:16
Отсюда можно взять очень полезный запрос с календариком "Работаем с датами в запросе".

Закидываем календарик во временную таблицу.
Далее берем 1 таблицу движений по дням (с существующими оборотами) и кидаем в другую временную таблицу.
Далее объединяем календарик с таблицей остатков и для каждой даты календарика получаем дату остатков, актуальных для этой даты. Для этого используем группировку с максимумом даты остатков, условия соединения дата остатков <= даты календарика.

А уже потом получаем таблицу остатков используя все три полученные таблицы (условия соединения надеюсь уже понятны - известна дата календарика, дата остатков для этой даты).

И никаких условностей с какой-то вспомогательной таблицей движений, в которой может и не оказаться нужной даты (т.е. отсутствие пропусков не гарантировано). и быстродействие достаточно высокое.

Особенно если прочитать про оптимизацию работы с временными таблицами в заметочках про....
6. Богдан Буляков (Laertid) 27.01.12 13:36
Не, это лишнее.
Список дней можно получать любым удобным способом, я об этом написал в комментарии при создании таблицы Дни. можно и формировать календарик, просто он занимает больше строк, и его код и так легко найти.
А дата остатков, актуальных для данной даты (где движений нет) не нужна - раз движений нет, то остаток, который посчитается на рассматриваемую дату, никак не будет отличаться от остатка, который получился после последнего движения.
Ваш метод необходим при работе с регистрами сведений, но в данном случае он ни к чему. *хотя, было время, я пользовался подобным алгоритмом. Он медленнее и чересчур усложнен.
7. Сергей (ildarovich) 22.04.12 15:44
Идея правильная. Именно по этому принципу платформа считает остатки внутри периода итогов. То же самое можно записать гораздо короче:
ВЫБРАТЬ РАЗЛИЧНЫЕ
	КурсыВалют.Период
ПОМЕСТИТЬ Дни
ИЗ
	РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
	КурсыВалют.Период МЕЖДУ &НачалоПериода И &КонецПериода
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Движения.Номенклатура,
	ДНИ.Период,
	СУММА(ВЫБОР
			КОГДА Движения.Период = &НачалоПериода
				ТОГДА Движения.КоличествоНачальныйОстаток
		КОНЕЦ + Движения.КоличествоОборот) КАК КоличествоКонечныйОстаток
ИЗ
	Дни КАК ДНИ
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , ) КАК Движения
		ПО (Движения.Период <= ДНИ.Период)

СГРУППИРОВАТЬ ПО
	Движения.Номенклатура,
	ДНИ.Период
...Показать Скрыть

Правда, здесь рассчитываются остатки на конец каждого дня (это легко поправить, сдвинув даты на -1). Регистр "КурсыВалют" взят для краткости и для разнообразия. Для скорости лучше использовать "календарик" на основе [Порождающий запрос]. Классический вариант (5) проигрывает по быстродействию предложенному примерно в 1.5 раза (проверялось на файловой базе УПП). Похожая математика используется в [Расчет средних по периодам в запросе].
NazarovV; maljaev; Lapitskiy; igormiro; Lemkus; RockClimber; vit_evv; lrs; perpleks; truba; vst; +11 Ответить 3
8. Руслан (lrs) 06.09.13 14:35
(7) ildarovich,
...
Сумма(ВЫБОР
КОГДА Движения.Период = &НачалоПериода
ТОГДА Движения.КоличествоНачальныйОстаток
//{LRS: Если не начальный остаток, то NULL. Необходимо заменить его на 0, иначе мы получим Начальный остаток на каждую дату
ИНАЧЕ 0
//}
КОНЕЦ + Движения.КоличествоОборот) КАК КоличествоКонечныйОстаток
...
9. Николай ~ ~ (kuzyara) 17.06.14 11:24
(7) ildarovich, Вы поторопились группировать по номенклатуре, ведь движение на дату может быть null, запрос топикастера более верный. Но он не учитывает варианта, когда товар вообще появился на складе после начала периода, во-вторых, остатки обачно нужны на конец дня, а не начало, в этом случае поможет отнимание оборотов от конечного остатка(&КонецПериода оканчивается на 23:59:59):

ВЫБРАТЬ
ТоварыНаСкладах2Обороты.Период,
-ТоварыНаСкладах2Обороты.КоличествоОборот КАК КоличествоОборот,
ТоварыНаСкладах2Обороты.Номенклатура
ПОМЕСТИТЬ Движения
ИЗ
РегистрНакопления.ПартииНоменклатуры.Обороты(
&НачалоПериода,
&КонецПериода,
День,
Номенклатура = &ном
И склад = &склад) КАК ТоварыНаСкладах2Обороты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
ДОБАВИТЬКДАТЕ(&КонецПериода, СЕКУНДА, 1),
ТоварыНаСкладах2Остатки.КоличествоОстаток,
ТоварыНаСкладах2Остатки.Номенклатура
ИЗ
РегистрНакопления.ПартииНоменклатуры.Остатки(
&КонецПериода,
Номенклатура = &ном
И склад = &склад) КАК ТоварыНаСкладах2Остатки
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
Дни.Период КАК Период,
Движения.Номенклатура КАК Номенклатура,
СУММА(Движения.КоличествоОборот) КАК КоличествоОстаток
ИЗ
тДаты КАК Дни
ЛЕВОЕ СОЕДИНЕНИЕ Движения КАК Движения
ПО (Движения.Период > Дни.Период)

СГРУППИРОВАТЬ ПО
Дни.Период,
Движения.Номенклатура
ildarovich; +1 Ответить
10. Николай ~ ~ (kuzyara) 17.06.14 11:27
Ещё добавлю, что только таким способом можно средствами скд брать остатки в нужном нам разрезе, а не использовать запрос по ВСЕЙ номенклатуре при левом соединении.
11. Сергей (ildarovich) 17.06.14 21:43
(7)(10) kuzyara, Вы совершенно правы, я допустил неточности в этом запросе. Но их можно исправить в рамках того же подхода, когда используется только один виртуальный регистр, не увеличивая число строк в запросе. Нужно было предусмотреть ситуацию отсутствия товаров на складе в начальный момент. Вот исправленный запрос
ВЫБРАТЬ РАЗЛИЧНЫЕ
	КурсыВалют.Период
ПОМЕСТИТЬ Дни
ИЗ
	РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
	КурсыВалют.Период МЕЖДУ &НачалоПериода И &КонецПериода
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Движения.Номенклатура,
	ДНИ.Период,
	ЕСТЬNULL(СУММА(ВЫБОР
			КОГДА Движения.Период = &НачалоПериода
				ТОГДА Движения.КоличествоНачальныйОстаток
		КОНЕЦ), 0) + ЕСТЬNULL(СУММА(Движения.КоличествоОборот), 0) КАК КоличествоКонечныйОстаток
ИЗ
	Дни КАК ДНИ
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , Номенклатура = &Номенклатура) КАК Движения
		ПО (Движения.Период <= ДНИ.Период)

СГРУППИРОВАТЬ ПО
	Движения.Номенклатура,
	ДНИ.Период
...Показать Скрыть


... здесь также есть недостатки. Окончательный вариант приведен в комментарии (14)
12. Николай ~ ~ (kuzyara) 18.06.14 04:23
(11) ildarovich, почему вы упорно не замечаете ЕстьNull(Движения.Номенклатура, ?)
ildarovich; +1 Ответить 2
13. Сергей (ildarovich) 18.06.14 11:15
(12) kuzyara, упс - сообразил, наконец: если входящего остатка нет, то номенклатуру до первого прихода при таком подходе не показать - возьму, пожалуй, пока паузу на обдумывание...
14. Сергей (ildarovich) 19.06.14 13:15
(12) kuzyara, переписал запрос еще раз. Получилось так
ВЫБРАТЬ РАЗЛИЧНЫЕ
	КурсыВалют.Период
ПОМЕСТИТЬ Дни
ИЗ
	РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
	КурсыВалют.Период МЕЖДУ &НачалоПериода И &КонецПериода
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Движения.Номенклатура,
	ДНИ.Период,
	СУММА(ВЫБОР
			КОГДА Движения.Период = &НачалоПериода
				ТОГДА Движения.КоличествоКонечныйОстаток
			ИНАЧЕ ВЫБОР
					КОГДА Движения.Период <= ДНИ.Период
						ТОГДА Движения.КоличествоОборот
					ИНАЧЕ 0
				КОНЕЦ
		КОНЕЦ) КАК КоличествоКонечныйОстаток
ИЗ
	Дни КАК ДНИ,
	РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , Номенклатура = &Номенклатура) КАК Движения

СГРУППИРОВАТЬ ПО
	Движения.Номенклатура,
	ДНИ.Период
...Показать Скрыть
Обнаружил, что если мой старый вариант не отображал номенклатуру до ее первого появления на складе, то ваш не отображает после последнего. То есть, если в течение периода товар ушел со склада, то в таблице остатков его не будет и возникает та же проблема, что и в моем старом запросе. Ну и исходный вариант в статье тоже этим страдает.
Так что, когда у вас появится таблица движущейся номенклатуры, то ваш запрос станет еще сложнее и дольше.
Недостатком моего последнего варианта является "двойной" обход оборотов, но, скорее всего, при группировке при нахождении движущейся номенклатуры будут примерно те же затраты, да еще и затраты на запись и соединение. Так что предполагаю победу своего варианта и в соревновании по быстродействию.
Ну а вообще спасибо за критическое отношение и внимательность - впредь буду тщательнее тестировать предлагаемые запросы.
victorkim64; ph33l; james404; arakelyan; s_tagil@mail.ru; ololoanonim; Ingeneer; dj_serega; ignorant; FilatovRA; zqzq; olbu; venger; kuzyara; +14 Ответить 6
15. Николай ~ ~ (kuzyara) 23.06.14 10:08
16. Павел (Yimaida) 02.09.14 19:43
Вот пример на виртуальной таблице остатков и оборотов, а также таблице дат ("Календарик"). Добавил отбор по номенклатуре, для тестирования. Можно смело копипастить и тестить в УТ 10.3. При добавлении характеристик и прочих измерений, надо добавить их в виртуальные таблицы (с этим проблем быть не должно)
ВЫБРАТЬ
	0 КАК Р
ПОМЕСТИТЬ Разряды

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	1

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	2

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	3

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	4

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	5

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	6

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	7

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	8

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	9
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ДОБАВИТЬКДАТЕ(НАЧАЛОПЕРИОДА(&ДатаНачала, ДЕНЬ), ДЕНЬ, Единицы.Р + Десятки.Р * 10 + Сотни.Р * 100 + Тысячи.Р * 1000) КАК Период
ПОМЕСТИТЬ ТаблицаДат
ИЗ
	Разряды КАК Единицы,
	Разряды КАК Сотни,
	Разряды КАК Десятки,
	Разряды КАК Тысячи
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ТоварыВРезервеНаСкладахОстаткиИОбороты.Период,
	ТоварыВРезервеНаСкладахОстаткиИОбороты.Номенклатура КАК Номенклатура,
	ТоварыВРезервеНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток
ПОМЕСТИТЬ ВТ_Остатки
ИЗ
	РегистрНакопления.ТоварыВРезервеНаСкладах.ОстаткиИОбороты(, , День, Движения, Номенклатура = &Номенклатура) КАК ТоварыВРезервеНаСкладахОстаткиИОбороты
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ТаблицаДат.Период КАК ТДПериод,
	МАКСИМУМ(ВТ_Остатки.Период) КАК ПериодРО,
	ВТ_Остатки.Номенклатура
ПОМЕСТИТЬ ВТ_БлижайшиеДатыОстатков
ИЗ
	ТаблицаДат КАК ТаблицаДат
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
		ПО ТаблицаДат.Период >= ВТ_Остатки.Период

СГРУППИРОВАТЬ ПО
	ТаблицаДат.Период,
	ВТ_Остатки.Номенклатура
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВТ_БлижайшиеДатыОстатков.ТДПериод КАК ТДПериод,
	ВТ_Остатки.Номенклатура,
	ВТ_Остатки.КоличествоКонечныйОстаток
ИЗ
	ВТ_БлижайшиеДатыОстатков КАК ВТ_БлижайшиеДатыОстатков
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
		ПО ВТ_БлижайшиеДатыОстатков.ПериодРО = ВТ_Остатки.Период
			И ВТ_БлижайшиеДатыОстатков.Номенклатура = ВТ_Остатки.Номенклатура

УПОРЯДОЧИТЬ ПО
	ТДПериод
...Показать Скрыть
s_tagil@mail.ru; martemp; bss; +3 Ответить
17. Денис Распопов (draspopov) 18.09.14 19:37
(14) ildarovich, Работает, но не пойму как. Нет правила по которому соединяются таблицы. Как тогда они правильно соединяются?
18. Денис Распопов (draspopov) 18.09.14 19:42
19. Александр Венгер (venger) 02.10.14 15:34
(14) Да, классно, конечно!

Но мне понадобилось выбрать и начальный, и обороты (и приход, и расход) и конечный. Выкрутился так, в подчиненном запросе все кроме начальных остатков, по приниципу как в 14-м комменте у ildarovich, а уже из подчиненного по конечному и обороту вычисляю начальный в "верхнем" запросе, т.е. так:

ВЫБРАТЬ РАЗЛИЧНЫЕ
    КурсыВалют.Период
ПОМЕСТИТЬ Дни
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &НачалоПериода И &КонецПериода;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ 
	ВложенныйЗапрос.Период,
	ВложенныйЗапрос.Номенклатура,
	ВложенныйЗапрос.КолВоКонОст-ВложенныйЗапрос.КолВоОборот КАК КолВоНачОст,
	ВложенныйЗапрос.КолВоПриход,
	ВложенныйЗапрос.КолВоРасход,
	ВложенныйЗапрос.КолВоОборот,
	ВложенныйЗапрос.КолВоКонОст
ИЗ
	(ВЫБРАТЬ
		ДНИ.Период,
	    Движения.Номенклатура,
	    
		СУММА(ВЫБОР КОГДА Движения.Период = ДНИ.Период
			ТОГДА Движения.КоличествоПриход
			ИНАЧЕ 0 
			КОНЕЦ) КАК КолВоПриход,	        
			
		СУММА(ВЫБОР КОГДА Движения.Период = ДНИ.Период
			ТОГДА Движения.КоличествоРасход
			ИНАЧЕ 0
			КОНЕЦ) КАК КолВоРасход,	        
			
		СУММА(ВЫБОР КОГДА Движения.Период = ДНИ.Период
			ТОГДА Движения.КоличествоОборот
			ИНАЧЕ 0
			КОНЕЦ) КАК КолВоОборот,
	    
	    СУММА(ВЫБОР
	            КОГДА Движения.Период = &НачалоПериода
	                ТОГДА Движения.КоличествоКонечныйОстаток
	            ИНАЧЕ ВЫБОР
	                    КОГДА Движения.Период <= ДНИ.Период
	                        ТОГДА Движения.КоличествоОборот
	                    ИНАЧЕ 0
	                КОНЕЦ
	        КОНЕЦ) КАК КолВоКонОст
	ИЗ
	    Дни КАК ДНИ,
	    РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(НАЧАЛОПЕРИОДА(&НачалоПериода,ДЕНЬ), КОНЕЦПЕРИОДА(&КонецПериода,ДЕНЬ), День, , Номенклатура = &Номенклатура) КАК Движения

	СГРУППИРОВАТЬ ПО
	    Движения.Номенклатура,
	    ДНИ.Период) КАК ВложенныйЗапрос
УПОРЯДОЧИТЬ ПО
	ВложенныйЗапрос.Номенклатура,
	ВложенныйЗапрос.Период
...Показать Скрыть


Но может можно красивее или еще какую критику кто-то выскажет?
Flyerink; Deoman; romku; Dregnar; +4 Ответить 1
20. Николай ~ ~ (kuzyara) 16.01.15 04:20
(19), я не стал городить подзапрос для начальный остатков, а обошелся разностью сумм КолВоКонОст и КолВоОборот
21. Олег (olbu) 10.02.15 08:45
(14) ildarovich, А кто ни будь смог получить остатки на начало и на конец дня одним запросом? Я так и не смог этого добиться... Если кто это получил, не подскажите как?
22. Сергей (ildarovich) 10.02.15 11:39
(21) olbu, попробуйте добавить в запрос приведенный в (14) для вычисления начального остатка следующую конструкцию
СУММА(ВЫБОР
            КОГДА Движения.Период = &НачалоПериода
                ТОГДА Движения.КоличествоНачальныйОстаток
            ИНАЧЕ ВЫБОР
                    КОГДА Движения.Период < ДНИ.Период
                        ТОГДА Движения.КоличествоОборот
                    ИНАЧЕ 0
                КОНЕЦ
        КОНЕЦ) КАК КоличествоНачальныйОстаток
...Показать Скрыть
Хотя могу и ошибаться - желательно еще протестировать.
23. Сергей Галюк (dj_serega) 09.06.15 16:11
(22) ildarovich, Не работает на начало. Сейчас ковыряюсь.А может и работает. Непонятно :)
24. q_i 16.02.16 18:36
(22) ildarovich, насколько я понял, это не работает, т.к. не учитывает Движения.КоличествоОборот за &НачалоПериода. Например, нач.остаток на второй день будет рассчитан как Движения.КоличествоНачальныйОстаток, а должен быть рассчитан как "Движения.КоличествоНачальныйОстаток + Движения.КоличествоОборот" (т.е. остаток на &НачалоПериода + оборот за &НачалоПериода).
Видимо должно быть что-то вроде этого:
СУММА(ВЫБОР
            КОГДА Движения.Период = &НачалоПериода
				ТОГДА ВЫБОР 
					КОГДА ДНИ.Период = &НачалоПериода
						ТОГДА Движения.КоличествоНачальныйОстаток
					ИНАЧЕ Движения.КоличествоКонечныйОстаток
				КОНЕЦ
			ИНАЧЕ ВЫБОР
                    КОГДА Движения.Период < ДНИ.Период
                        ТОГДА Движения.КоличествоОборот
                    ИНАЧЕ 0
                КОНЕЦ
        КОНЕЦ) КАК КоличествоНачальныйОстаток
...Показать Скрыть
25. Сан Саныч (herfis) 19.02.16 15:46
(24) q_i, Мой вариант:

	СУММА(ВЫБОР
			КОГДА Движения.Период = &НачалоПериода И Дни.Период = &НачалоПериода
				ТОГДА Движения.КоличествоНачальныйОстаток
			КОГДА Движения.Период = &НачалоПериода
				ТОГДА Движения.КоличествоНачальныйОстаток + Движения.КоличествоОборот
			ИНАЧЕ ВЫБОР
					КОГДА Движения.Период < Дни.Период
						ТОГДА Движения.КоличествоОборот
					ИНАЧЕ 0
				КОНЕЦ
		КОНЕЦ) КАК КоличествоНачальныйОстаток,
...Показать Скрыть
26. Виктор Ким (victorkim64) 22.11.16 10:11
(14) ildarovich, Спасибо! Работает, только остатки по записи сделал.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа