Пример создания кадрового отчета для ЗУП 3.1

22.12.20

Задачи пользователя - Адаптация типовых решений

+32 –
> >
  • Структура запроса.jpg
  • Регистраторы.jpg
Пример создания отчёта "Изменение графиков работы" для ЗУП 3.1 с использованием механизма представлений и объекта СхемаЗапроса.

Скачать файлы

Наименование Файл Версия Размер
Пример создания кадрового отчёта для ЗУП 3.1:
.erf 12,52Kb
196
.erf 12,52Kb 196 Скачать бесплатно

Заказчику на производственном предприятии понадобился отчет, содержащий информацию об истории изменения графиков работы сотрудников. Штатного отчёта в конфигурации ЗУП 3.1 (3.1.14.334) не оказалось. Потребовалось написать новый внешний отчет. За основу был взят отчет Кадровая история сотрудников. На практике именно этот отчет дорабатывался. Для статьи же я написал отдельный отчет, чтобы можно было использовать его как шаблон создания своих отчетов.

Введение

Типовые отчеты в ЗУП построены так, что текст запроса для отчета формируется программно в процедуре ПриКомпоновкеРезультата(). В ней необходимо вызвать следующую процедуру: ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбщиеИсточникиДанныхОтчета(ЭтотОбъект), которая подготовит реальный запрос для нашего отчета. Используется так называемый механизм представлений. В Схеме компоновки же составляется обычно запрос-пустышка. В запросе по определенным правилам составляются имена виртуальных таблиц. Далее процедуры общих модулей ЗУП заменяют такие виртуальные таблицы на реально исполняемые. Механизм замены представлений в совокупности с программным интерфейсом позволяет безболезненно получать данные из базы.

  Ранее коллеги  уже описывали функции для получения данных. Например, вот здесь: //infostart.ru/1c/articles/841337/ и здесь: //infostart.ru/1c/articles/942569/

Если игнорировать использование программного интерфейса при получении данных в Зарплате, можно испытать много боли и разочарования. Даже если вы опытный сеньор и знаете особенности проектирования Зарплаты, никто не гарантирует, что в следующем релизе разработчики, как минимум, не переименуют реквизиты.  Поэтому, самостоятельно запрашивать у ЗУП данные, если для из получения имеется программный интерфейс, это не наш метод. Наша задача сделать так, чтобы отчет пережил как можно больше релизов.

На мой взгляд, серьезный недостаток программного интерфейса, это отсутствие описания процедур и функций, и взаимосвязи между ними. Плюс не описано, какие именно выходные поля можно запросить. Мечта, если бы все функции были описаны так же как КадровыйУчет.КадровыеДанныеСотрудников(...). И несмотря на это описание, какие имена полей допустимы в параметре КадровыеДанные, не так просто найти. Также нет информации о том, из какиз таблиц и какие данные можно получать с помощью виртуальных таблиц Представлений.

Для понимания, как же устроен этот механизм пришлось изучать типовые отчеты и пользоваться глобальным поиском. Также очень выручает вот эта обработка с ИТС https://its.1c.ru/db/metod81/content/7329/hdoc

Процедура ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбщиеИсточникиДанныхОтчета(ЭтотОбъект) Содержит еще процедуру, которая заменяет тексты запросов. Эта большая процедура, в свою очередь, ищет, в каком из общих модулей содержится код по замене данного конкретного представления. То есть во многих общих модулях содержатся целые области по формированию запросов к базе данных. Эти области кода также используются в документах и справочниках соответствующих подсистем. Как правило, помимо сбора запроса представления, эти области содержат процедуры по получению данных в менеджер временных таблиц. Очень жаль, что они не описаны разработчиками и приходится самостоятельно их исследовать и подсматривать использование в типовых документах. Чтобы иметь представление, какие данные мы можем получать через представления, я составил вот такую табличку названий, которые встречаются в конфигурации.

 

"СотрудникиПодлежащиеАттестации"
"РезультатыАттестацииСотрудников"
"Периоды"
"ТаблицаРегистра"
"СрезПоследних"
"СрезПервых"
"ТаблицаРегистра"
"ТаблицаРегистра"а
"СрезПоследних"а
"КадровыеДанныеФизическихЛиц"
"КадровыеДанныеСотрудников"
"РабочиеМестаСотрудников"
"СотрудникиОрганизации"
"ОтработанноеВремя"
"КадровыеДанныеСотрудниковАнализНачисленийИУдержаний"
"ПодразделенияСортировкиСотрудников"
"НачисленныеДоходыНДФЛ"
"ШтатноеРасписание"
"ТекущаяКадроваяРасстановка"
"ФункциональныеОпцииОрганизаций"
"ФактическиеОтпускаСотрудников"
"ПлановыеНачисленияСотрудников"
"ПлановыеУдержанияСотрудников"
"СтажиСотрудников"
"СвойстваСтатейФинансирования"
"ПлановоеВремя"

 

Например, представление ШтатноеРасписание используется в отчетах по штатному расписанию. В недрах функций по замене представлений есть функция, получающая набор источников данных для заменяемой таблицы. И конкретно по штатному расписанию источник построения запроса далеко не один

"ВТОТБОРПОЗИЦИЙШТАТНОГОРАСПИСАНИЯ" Структура
"СПРАВОЧНИКШТАТНОЕРАСПИСАНИЕ" Структура
"РЕГИСТРСВЕДЕНИЙИСТОРИЯИСПОЛЬЗОВАНИЯШТАТНОГОРАСПИСАНИЯ" Структура
"РЕГИСТРСВЕДЕНИЙТЕРРИТОРИАЛЬНЫЕУСЛОВИЯПФР" Структура
"РЕГИСТРСВЕДЕНИЙКЛАССЫУСЛОВИЙТРУДАПОДОЛЖНОСТЯМ" Структура
"РЕГИСТРСВЕДЕНИЙЗАНЯТОСТЬПОЗИЦИЙШТАТНОГОРАСПИСАНИЯ" Структура
"РЕГИСТРСВЕДЕНИЙСТРОКИОТЧЕТНОСТИМОНИТОРИНГАРАБОТНИКОВСОЦИАЛЬНОЙСФЕРЫ" Структура
"РЕГИСТРСВЕДЕНИЙМЕСТОПОЗИЦИИШТАТНОГОРАСПИСАНИЯВСТРУКТУРЕПРЕДПРИЯТИЯ" Структура

 

Ну и финальный запрос выглядит устрашающе:

 
 Финальный запрос по штатному расписанию

Запрос-пустышка выглядел так:

 

 

В финальном запросе можно посмотреть. какие поля доступны для получения.

При компоновке макета СКД, естественно, запрос сильно похудеет...

 

Часть 1 

От разработчика отчета требуется правильно подготовить запрос-пустышку.

Итак приступим.

Откуда брать информацию по графикам работы? Так как у нас по сути всего получение одной сущности, это график работы, вряд-ли нам нужен большой контейнер-представление, вроде ШтатноеРасисание. Можно посмотреть, какой запрос строит функция КадровыйУчет.КадровыеДанныеСотрудников(..), например. Я посмотрел, куда делает движения документ Изменение графиков работы. Всего 4 регистра. Очевидно, что наш регистр ГрафикРаботыСотрудников. Допустим, мы бы захотели сами построить запрос. Но в базе 3 регистра!!! Один основной и 2 вспомогательных (ГрафикРаботыСотрудниковИспр и ГрафикРаботыСотрудниковИнтервальный).   Лучше построим запрос к этому регистру правильно. Готовим так называемую таблицу отбора, таблицу-фильтр. 

ВЫБРАТЬ
	&НачалоПериода КАК ДатаНачала,
	&ОкончаниеПериода КАК ДатаОкончания,
	Сотрудники.Ссылка КАК Сотрудник
ПОМЕСТИТЬ ВТОтборДляТаблицыРегистра
ИЗ
	Справочник.Сотрудники КАК Сотрудники

Далее основная пустышка:

ВЫБРАТЬ
	ДАТАВРЕМЯ(1, 1, 1) КАК Период,
	ДАТАВРЕМЯ(1, 1, 1) КАК ПериодЗаписи,
	ДАТАВРЕМЯ(1, 1, 1) КАК ПериодВозвратногоСобытия,
	ЗНАЧЕНИЕ(Документ.ИзменениеГрафикаРаботыСписком.ПустаяСсылка) КАК Регистратор,
	ЛОЖЬ КАК ЭтоВозвратноеСобытие,
	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК Сотрудник,
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК ГоловнаяОрганизация,
	ЗНАЧЕНИЕ(Справочник.ГрафикиРаботыСотрудников.ПустаяСсылка) КАК ГрафикРаботы
ПОМЕСТИТЬ Представления_ТаблицаРегистра_ГрафикРаботыСотрудников
ИЗ
	ВТОтборДляТаблицыРегистра КАК ОтборДляТаблицыРегистра
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
	И "ПараметрыПостроения_ФормироватьСПериодичностьДень" = ЛОЖЬ
	И "ПараметрыПостроения_ВключатьЗаписиНаНачалоПериода" = ИСТИНА

 

Выборка данных в пустышке идет из Таблицы для отбора. Однако никаких полей мы не выбрали. Переживать не стоит, это необходимо для получения реального запроса. Очень важно правильно назвать эту таблицу, обработка подскажет нам как..

Еще нам потребуется некоторая кадровая информация по сотрудникам, ее также получаем похожим образом. Только кадровые данные могут быть очень различны и содержатся в разных регистрах (как и штатное расписание), поэтому строим пустышку не по _ТаблицаРегистра_

Таблица для отбора кадровых данных:

ВЫБРАТЬ
	Представления_ТаблицаРегистра_ГрафикРаботыСотрудников.Период КАК Период,
	Представления_ТаблицаРегистра_ГрафикРаботыСотрудников.Сотрудник КАК Сотрудник
ПОМЕСТИТЬ ВТСотрудникиПериоды
ИЗ
	Представления_ТаблицаРегистра_ГрафикРаботыСотрудников КАК Представления_ТаблицаРегистра_ГрафикРаботыСотрудников

Поскольку в ЗУП период получения данных ахриважен, для получения кадровых данных нам нужен сам сотрудник и дата получения кадрвоых данных. Поэтому таблица содержит 2 "параметра": Сотрудник, Период. Брать эти данные мы будем из таблицы выше. Ведь для предыдущей таблицы нам как раз не хватает колонок с кадровыми данными. Для каждой строки (которая как раз содержит Сотрудника и дату изменения его графика) мы ниже и получим недостающие колонки.

Теперь. когда готова таблица для отбора, основная пустышка для получения кадровых данных:

ВЫБРАТЬ
	ДАТАВРЕМЯ(1, 1, 1) КАК Период,
	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК Сотрудник,
	ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка) КАК Подразделение,
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК Организация,
	ЗНАЧЕНИЕ(Справочник.ШтатноеРасписание.ПустаяСсылка) КАК ДолжностьПоШтатномуРасписанию,
	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность
ПОМЕСТИТЬ Представления_КадровыеДанныеСотрудников
ИЗ
	ВТСотрудникиПериоды КАК СотрудникиПериоды

И в этой таблице в наименовании видим Представление_...., необходимое для работы программного интерфейса.

Итак, осталось только сделать выборку данных (см. приложенном к статье отчёте).

Часть 2

При анализе похожих отчетов ( КадроваяИсторияСотрудников, ФактическиеОтпускаСотрудников) обратил внимание на то, что что виртуальную таблицу Представления_ТаблицаРегистра_ИмяРегистраизКоторогоПолучаютсяДанные разработчики ЗУП собирают объединением. Конкретно, собираются пустые ссылки в поле Регистратор. Сначала было предположение, что механизм представлений сделает ограничение по типам регистратора, но отладчик не подтвердил гипотезу. При этом, если не собирать данную виртуальную таблицу объединением а поставить наобум любой тип из перечня регистраторов, отчет также успешно отработает, и покажет все типы регистраторов. Для чего так сделали разработчики, пока непонятно, если кто знает, прошу разъяснить в комментариях. Предполагаю, что разработчики будут развивать механизм представлений и такое построение типовых отчетов - задел на будущее. Поэтому решено было в своем отчете сделать также.

В отчёте КадроваяИсторияСотрудников объединение собрано из 12 запросов (соответственно, 12 типов регистраторов). У регистра ГрафикРаботыСотрудников (основа нашего отчета) в данный момент 9 регистраторов. На данный момент непонятно:

1. Будут ли разработчики развивать механизм представлений и какое влияние это окажет на разрабатываемый отчет, если не собрать объединение пустых ссылок регистраторов; 

2. Изменится ли состав регистраторов. 

Поэтому виртуальную таблицу Предстваления_ТаблицаРегистра_ГрафикРаботыСотрудников решено было доработать программно. Для этого в схеме компоновки отчета конструктором создана таблица Представлений с одной пустой ссылкой регистратора, и уже эта таблица дорабатывается в процедуре ДополнитьЗапросПредставленияТаблицыРегистра(). 

Ранее при вклинивании в монстры-запросы ЗУП была идея попробовать для этих целей такой объект как СхемаЗапроса. Слышал много нелестных отзывов об этом объекте, что он очень медленный и применять его надо с осторожностью. В конфигурации ЗУП, однако, данный объект используется. разработчики даже написали несколько функций в общем модуле ЗарплатаКадрыОбщиеНаборыДанных для работы со схемой запроса. Специально замеров производительности не проводил, но в рамках доработанного отчета схема запроса прекрасно прижилась, проблем с работой не было. Также она оказалась очень удобной в разработке. Как инструкция по работе со схемой была использована вот эта статья : Объектная модель запроса "Схема запроса" - теория и примеры использования (infostart.ru).

Итак, сама процедура ДополнитьЗапросПредставленияТаблицыРегистра()

     

		ТекстДляДополнения = ЭтотОбъект.СхемаКомпоновкиДанных.НаборыДанных.НаборДанныхГрафик.Запрос;
		
		Схема = Новый Схемазапроса;
		
		Схема.УстановитьТекстЗапроса(ТекстДляДополнения);
		
		ЗапросПакета = ЗарплатаКадрыОбщиеНаборыДанных.ЗапросСхемыФормирующийВТ(Схема, "Представления_ТаблицаРегистра_ГрафикРаботыСотрудников");
		
		Если ЗапросПакета = Неопределено Тогда
			
			Возврат;
			
		КонецЕсли;
		
		НаборЗаписей = РегистрыСведений.ГрафикРаботыСотрудников.СоздатьНаборЗаписей();
		
		Для к = 0 по НаборЗаписей.Отбор.Регистратор.ТипЗначения.Типы().Количество() - 1 цикл
			
			ПромТип = НаборЗаписей.Отбор.Регистратор.ТипЗначения.Типы()[к];
			
			Если ПромТип = Тип("ДокументСсылка.ИзменениеГрафикаРаботыСписком") Тогда
				
				Продолжить;
				
			КонецЕсли;
			
			МДОбъект = Метаданные.НайтиПоТипу(ПромТип);
			
			Если МДОбъект <> Неопределено тогда
				
				ОператорВыбораРегистратора = ЗапросПакета.Операторы.Добавить();
				
				Для каждого ПолеОператора Из ЗапросПакета.Операторы[0].ВыбираемыеПоля Цикл
					
					Если ПолеОператора = Новый	ВыражениеСхемыЗапроса("ЗНАЧЕНИЕ(Документ.ИзменениеГрафикаРаботыСписком.ПустаяСсылка)") Тогда
						
						Регистратор = ОператорВыбораРегистратора.ВыбираемыеПоля.Добавить("Значение(Документ."+МДОбъект.Имя+".ПустаяСсылка)");
						
					Иначе
						
						Регистратор = ОператорВыбораРегистратора.ВыбираемыеПоля.Добавить("NULL");
						
					КонецЕсли;					
					
				КонецЦикла; 
				
			КонецЕсли;
			
		КонецЦикла;
		
		ЭтотОбъект.СхемаКомпоновкиДанных.НаборыДанных.НаборДанныхГрафик.Запрос = Схема.ПолучитьТекстЗапроса();

   Как можно заметить, виртуальная таблица Представления... была получена функцией из общего модуля.  Далее Происходит получение массива регистраторов для регистра ГрафикРаботыСотрудников и работа с коллекцией Операторы конкретного пакета запроса Схемы запроса. Первый элемент этой коллекции это и есть наш запрос, созданный в конструкторе. Для сопоставления полей получившегося объединения было как минимум три варианта действий.   Сначала сделал вариант, где в виртуальной таблице Представлений выбрал регистратор первым в списке, а во вновь создаваемых операторах просто добавлял выбираемое поле с пустой ссылкой следующего регистратора. Но в случае, если другой разработчик изменит порядок полей в схеме компоновки, отчет перестанет работать. Можно было попробовать сопоставить поля как описано в статье выше. Но решил остановиться на варианте с обходом коллекции выбираемых полей первого оператора. 

Весь код модуля объекта получившегося отчета ниже:

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда
	
	#Область ОбработчикиСобытий
	
	Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
		
		УстановитьПривилегированныйРежим(Истина);
		
		ИнициализироватьОтчет();
		
		УстановитьПривилегированныйРежим(Ложь);
		
	КонецПроцедуры
	
	#КонецОбласти
	
	#Область СлужебныеПроцедурыИФункции
	
	Функция СведенияОВнешнейОбработке() Экспорт
		
		ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();
		ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет();
		ПараметрыРегистрации.Версия = "1.0";
		ПараметрыРегистрации.Наименование = НСтр("ru = 'Изменения графиков работы'");
		ПараметрыРегистрации.Информация = НСтр("ru = 'Изменения графиков работы'");
		
		ПараметрыРегистрации.БезопасныйРежим = Ложь;
		
		Команда = ПараметрыРегистрации.Команды.Добавить();
		Команда.Представление = НСтр("ru = 'Изменения графиков работы'");
		Команда.Идентификатор = "КадровыеИзмененияИГрафикиРаботыСотрудниковВнешний";
		Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
		Команда.ПоказыватьОповещение = ИСТИНА;
		Команда.Модификатор="ПечатьMXL";
		
		
		Возврат ПараметрыРегистрации;
		
	КонецФункции
	
	Процедура ИнициализироватьОтчет() Экспорт
		
		ДополнитьЗапросПредставленияТаблицыРегистра();
		
		ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбщиеИсточникиДанныхОтчета(ЭтотОбъект);
		
	КонецПроцедуры
	
	Процедура ДополнитьЗапросПредставленияТаблицыРегистра()
		//
		ТекстДляДополнения = ЭтотОбъект.СхемаКомпоновкиДанных.НаборыДанных.НаборДанныхГрафик.Запрос;
		
		Схема = Новый Схемазапроса;
		
		Схема.УстановитьТекстЗапроса(ТекстДляДополнения);
		
		ЗапросПакета = ЗарплатаКадрыОбщиеНаборыДанных.ЗапросСхемыФормирующийВТ(Схема, "Представления_ТаблицаРегистра_ГрафикРаботыСотрудников");
		
		Если ЗапросПакета = Неопределено Тогда
			
			Возврат;
			
		КонецЕсли;
		
		НаборЗаписей = РегистрыСведений.ГрафикРаботыСотрудников.СоздатьНаборЗаписей();
		
		Для к = 0 по НаборЗаписей.Отбор.Регистратор.ТипЗначения.Типы().Количество() - 1 цикл
			
			ПромТип = НаборЗаписей.Отбор.Регистратор.ТипЗначения.Типы()[к];
			
			Если ПромТип = Тип("ДокументСсылка.ИзменениеГрафикаРаботыСписком") Тогда
				
				Продолжить;
				
			КонецЕсли;
			
			МДОбъект = Метаданные.НайтиПоТипу(ПромТип);
			
			Если МДОбъект <> Неопределено тогда
				
				ОператорВыбораРегистратора = ЗапросПакета.Операторы.Добавить();
				
				Для каждого ПолеОператора Из ЗапросПакета.Операторы[0].ВыбираемыеПоля Цикл
					
					Если ПолеОператора = Новый	ВыражениеСхемыЗапроса("ЗНАЧЕНИЕ(Документ.ИзменениеГрафикаРаботыСписком.ПустаяСсылка)") Тогда
						
						Регистратор = ОператорВыбораРегистратора.ВыбираемыеПоля.Добавить("Значение(Документ."+МДОбъект.Имя+".ПустаяСсылка)");
						
					Иначе
						
						Регистратор = ОператорВыбораРегистратора.ВыбираемыеПоля.Добавить("NULL");
						
					КонецЕсли;					
					
				КонецЦикла; 
				
			КонецЕсли;
			
		КонецЦикла;
		
		ЭтотОбъект.СхемаКомпоновкиДанных.НаборыДанных.НаборДанныхГрафик.Запрос = Схема.ПолучитьТекстЗапроса();
		
	КонецПроцедуры
	
	#КонецОбласти
	
	
#Иначе
	ВызватьИсключение НСтр("ru = 'Недопустимый вызов объекта на клиенте.'");
#КонецЕсли

В целях развития данного подхода к созданию отчетов для ЗУП 3.1 можно вынести процедуру ДополнитьЗапросПредставленияТаблицыРегистра() в общий модуль( планирую  с повторным использованием) , немного доработать чтобы можно было использовать в других отчетах. В функции есть что улучшить, но сейчас цель не в оптимизации кода, а в том, чтобы попробовать отвязаться от метаданных (в данном случае от регистраторов) с помощью СхемыЗапроса.

Надеюсь, данный шаблон поможет начинающим свой путь в дебрях ЗУП избежать ошибок и боли, и полюбить эту прекрасную конфигурацию так, как люблю её я.

Отчет ЗУП 3.1 СхемаЗапроса Представления программный интерфейс

+32 –

См. также

Табличная часть в доп. реквизитах и формирование таблиц в шаблоне docx для 1С:ДО 3.0

Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Платные (руб)

Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.

9000 руб.

29.06.2023    2566    3    0    

5

Расширение для 1С:УНФ. Автоматическое снятие резервов в Заказах покупателей

Логистика, склад и ТМЦ Адаптация типовых решений Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Мы доработали УНФ, чтобы она автоматически отменяла старые резервы и не мешала эффективно продавать.

7200 руб.

02.08.2023    1897    1    0    

15

Печать любых непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать любые печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

3480 руб.

22.08.2023    806    1    0    

1

Вес и объем в документах «Заказ поставщику» и «Заказ покупателя»

Адаптация типовых решений Логистика, склад и ТМЦ Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Управленческий учет Платные (руб)

Теперь вывод весо-объемных характеристик в документы «Заказ поставщику» и «Заказ покупателя» возможен – наше расширение поможет в этом Вам!

2400 руб.

03.08.2023    1077    1    0    

2

Даты запрета изменения

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Понадобилось добавить свои разделы и документы в типовой механизм контроля дат запрета изменения данных. Внятного описания, как это сделать, сходу обнаружить не удалось: статьи в интернете или неполные, или устаревшие. Пришлось читать документацию к БСП. Но и там ждала засада. В итоге разобрался и решил сохранить на будущее, может, кому время сэкономит.

26.06.2023    2614    gamletspb    4    

45

Программное получение стека вызовов для поиска точек входа

Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Получение информации о точке входа в процедуру записи справочника.

13.06.2023    4299    cheiser1982    36    

92

Работа с документами PDF

Файловый обмен (TXT, XML, DBF), FTP Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Абонемент ($m)

Начиная с версии 8.3.21, в платформе 1С:Предприятие появились новые объекты для работы с популярным форматом PDF. Примеров использования в типовых конфигурациях пока найти не удалось, но задачи, где это было бы полезно, встречаются. В результате решения некоторых из них и родилось представляемое вашему вниманию расширение.

1 стартмани

12.04.2023    5955    13    VladimirElohov    10    

17

Корректный вывод суммы и сроков в печатной форме

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Простой лайфхак для вывода суммы или числа дней В скобках и склоняемых единиц измерения или валюты ЗА скобками.

16.11.2022    1248    vladimir-89    0    

13
Оставьте свое сообщение