Доработка ERP 2 для отражения акциза при реализации подакцизных товаров (табачной продукции)

28.11.17

Задачи пользователя - Адаптация типовых решений

При внедрении ЕРП2.4 на нашем табачном производственном предприятии встал вопрос учета в 1С ЕРП2.2 акциза с продажи табачных изделий. Компания 1С категорически игнорирует учет акцизов в 1С, а занимается только алкогольным ЕГАИС. Что ж, будем реализовывать самостоятельно.

Опираясь на опыт реализации учета акцизов в УПП, решили реализовывать как можно меньшим изменением кода конфигурации.

Задание:

При продаже подакцизных товаров рассчитывать и накапливать суммы акцизов, отражая их печатных формах СЧЕТ-ФАКТУРА и ТОРГ-12(особая форма). В дальнейшем собирать эти сведения для заполнения Налоговой декларации по акцизам на табачные изделия.

План решения:

В документе РеализацияТоваровУслуг добавить колонку «Акциз» в таблице "Товары", проработать ее заполнение. Сформировать проводку по акцизу. Изменить печатные формы.

Итак, приступим.

1. Создание и вывод столбца "Акциз" в закладке «Товары» на форме документа.

Снимаем с поддержки только корень документа «РеализацияТоваровУслуг»

Добавляем реквизит «Акциз» в табличную часть «Товары». На форму его будем выводить программным способом, благо 1С позаботилась и добавила специальный общий модуль для шаловливых ручек, вроде наших.

Снимаем с поддержки общий модуль «МодификацияКонфигурацииПереопределяемый». В нем в процедуру «ПриСозданииНаСервере» добавляем код вызова нашей процедуры для модернизации формы документа:

Процедура ПриСозданииНаСервере(Форма, Отказ, СтандартнаяОбработка) Экспорт
Если Форма.ИмяФормы = "Документ.РеализацияТоваровУслуг.Форма.ФормаДокумента" Тогда
ИТ_РаботаСДиалогами.РеализацияТоваровУслуг_ПриСозданииНаСервере_ФормаДокумента(Форма, Отказ, СтандартнаяОбработка);
КонецЕсли;
КонецПроцедуры

Создаем общий модуль «ИТ_РаботаСДиалогами» с флагами «Сервер», «ВызовСервера».
Добавляем в него процедуру:

Процедура РеализацияТоваровУслуг_ПриСозданииНаСервере_ФормаДокумента(Форма, Отказ, СтандартнаяОбработка) Экспорт
Элемент = Форма.Элементы.Добавить("ТоварАкциз", Тип("ПолеФормы"), Форма.Элементы.Товары);
Элемент.Вид = ВидПоляФормы.ПолеВвода;
Элемент.ПутьКДанным = "Объект.Товары.Акциз";
КонецПроцедуры

2. Расчет и заполнение поля «Акциз» при работе на форме документа с табличной частью «Товары».

Согласно правилам расчета акцизов на табачные изделия, сумма акциза в каждой строке зависит от вида товара и его количества. В прошлой раз, при внедрении учета акцизов в 1С УПП, мы ввели регистр сведений для сохранения суммы акциза на единицу номенклатуры. Как показал практика, это было хоть и гибкое, но ошибочное решение. В этот раз пойдем другим путем, сумма акциза будет вычисляется «с нуля» каждый раз по законодательно определенным правилам уже на общее количество товара в строке. 

Приступаем к форме документа «РеализацияТоваровУслуг».
Нужно выявить события, которые вызываются при изменении в табличной части «Товары», а вернее ее реквизитов: «Номенклатура», «Характеристика», «Количество упаковок», «Единица упаковки». Разбор полетов показал, что 1С нам приготовила всего два переопределяемых обработчика событий, это «НоменклатураПриИзмененииПереопределяемый» и  «ХарактеристикаПриИзмененииПереопределяемый». К сожалению я не нашел никаких переопределяемых процедур для перехвата события при изменений упаковки или количества упаковок (если я неправ, поправите меня в комментариях). Значит придется снимать с поддержки форму документа и вставлять вызов функции  пересчета акциза в каждое из четырех событий формы:
 

&НаКлиенте
Процедура ТоварыНоменклатураПриИзмененииВопросПользователюЗавершение(Результат, ДополнительныеПараметры) Экспорт
//…
ИТ_АкцизКлиент.ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Объект.Дата); 
КонецПроцедуры

&НаКлиенте
Процедура ТоварыХарактеристикаПриИзмененииВопросПользователюЗавершение(Результат, ДополнительныеПараметры) Экспорт
//…
ИТ_АкцизКлиент.ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Объект.Дата); 
КонецПроцедуры

&НаКлиенте
Процедура ТоварыУпаковкаПриИзменении(Элемент)
//…
ИТ_АкцизКлиент.ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Объект.Дата); 
КонецПроцедуры

&НаКлиенте
Процедура ТоварыКоличествоУпаковокПриИзменении(Элемент)
//…
ИТ_АкцизКлиент.ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Объект.Дата); 
КонецПроцедуры

Теперь пропишем функции, которую мы вызываем из формы документа, для расчета акциза. Для этого в глобальном модуле создаем «ИТ_АкцизКлиент». В свойствах модуля ставим флаг «Клиент (управляемое приложение)». Создаем процедуру:

Процедура ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Дата) Экспорт
	 Если ТекущаяСтрока = Неопределено Тогда
		 Возврат;
	 КонецЕсли;
	 ТекущаяСтрока.Акциз = 0;
	 ОНоменклатуре = ИТ_АкцизСервер.СведенияОПодакцизнойНоменклатуре(ТекущаяСтрока.Номенклатура,ТекущаяСтрока.Характеристика); 
	 Если НЕ ОНоменклатуре.ЕстьСведенияОНоменклатуре Тогда
		 Возврат;
	 ИначеЕсли НЕ ОНоменклатуре.ПодакцизныйТовар Тогда
		 Возврат;
	 ИначеЕсли ПустаяСтрока(ОНоменклатуре.КодОКП) Тогда   
		 //не определен ОКП номенклатуры, нельзя понять по какому способу расчитывать акциз.
		 Сообщить("У номенклатуры "+ТекущаяСтрока.Номенклатура+" установлен флаг ""Подакцизный товар"", но не определен код ОКП, расчет акциза невозможен.");
		 Возврат;
	 КонецЕсли;
	 
	 //Расчет акциза
	 //Определяем вид товара
	 Если ОНоменклатуре.КодОКП="919024" Тогда   //Сигареты с фильтром
		  Если НЕ ОНоменклатуре.ЕстьСведенияОХарактеристике Тогда
			Сообщить("У номенклатуры "+ТекущаяСтрока.Номенклатура+" не выбрана характеристика для выделения МРЦ.");
			Возврат;
		  Иначе
		  	РазмерМРЦ = ВытащитьМРЦИзХарактеристикиНоменклатуры(ОНоменклатуре.НаименованиеХарактеристика,Истина);
		  КонецЕсли;
		  АкцизТНС   = ПолучитьТвердуюСтавкуДляСигарет(Дата) * (ТекущаяСтрока.Количество*20/1000);
		  АкцизАНС   = РазмерМРЦ * (ПолучитьАдвалорнуюСтавкуДляСигарет(Дата)/100) * ТекущаяСтрока.Количество;
		  АкцизСумма = АкцизТНС+АкцизАНС;
		  АкцизМин   = ПолучитьМинимальнуюСтавкуДляСигарет(Дата) * (ТекущаяСтрока.Количество*20/1000);
		  
		  ТекущаяСтрока.Акциз = МАКС(АкцизСумма,АкцизМин);
	//ИначеЕсли ОНоменклатуре.КодОКП="…" для других видов подакцизных товаров
 КонецЕсли;
КонецПроцедуры

Дополнительные функции «ПолучитьТвердуюСтавкуДляСигарет», «ПолучитьАдвалорнуюСтавкуДляСигарет», «ПолучитьМинимальнуюСтавкуДляСигарет», «СведенияОПодакцизнойНоменклатуре» и «ВытащитьМРЦИзХарактеристикиНоменклатуры» описывать в этой статье не буду. По их названию и так понятно что они делают.

3. Формирование дополнительной проводки Дт 90.04 Кт 68.03 в документе РеализацияТоваровУслуг на сумму акциза.

Все проводки в ЕРП2 формируются при помощи запроса.

Любой документ в ЕРП, генерирующий проводки, в модуле менеджера содержит экспортную функцию «ТекстОтраженияВРеглУчете()» . Эта функция всегда возвращает текст запроса, который при выполнении должен вернуть таблицу проводок.

Формат запроса можно подглядеть вот здесь: РеглУчетВыборкиСерверПовтИсп .ТекстИнициализации()

Более того, формируя запрос для проводок, можно обращаться к разным данным во временных таблицах.  Они формируются в РеглУчетВыборкиСерверПовтИсп.ЗапросДанных(). Если быть честным, то именно эта процедура вызывается при проведении документа, а уже она собирает все необходимые данные для отражения проводок в виде запроса. (Советую посмотреть ее содержимое).

 Возвращаемся к нашей функции «ТекстОтраженияВРеглУчете()» в менеджере документа «РеализацияТоваровУслуг». Добавляем строку:

ТекстыОтражения.Добавить(ИТ_АкцизСервер.ТекстАкцизСРеализации());

В общий модуль «ИТ_АкцизСервер»  добавляем функцию формирования текста запроса для нашей проводки.

Функция ТекстАкцизСРеализации() Экспорт 
	
	ТекстАкцизСРеализации = "
	|ВЫБРАТЬ  //// Акциз с релизации (Дт 90.04 :: Кт 68.03)  
	|	Операция.Ссылка КАК Ссылка,
	|	Операция.Дата КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	СтрокиТовары.Акциз КАК Сумма,
	|	СтрокиТовары.Акциз / КурсВалютыУпрУчета.Курс КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ПустаяСсылка) КАК ВидСчетаДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета  КАК АналитикаУчетаДт,
	|	Аналитика.Склад КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиДт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_Акцизы) КАК СчетДт,
	|
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	0 КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	&ВалютаРеглУчета КАК ВалютаКт,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) КАК ПодразделениеКт,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Акцизы) КАК СчетКт,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог) КАК СубконтоКт1,
	|	Операция.Организация.РегистрацияВНалоговомОргане КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	СтрокиТовары.Акциз КАК ВалютнаяСуммаКт,
	|	0 КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,
	|	""Акциз с релизации"" КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		(СтрокиТовары.Ссылка = Операция.Ссылка)
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
	|	ПО
	|		СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, День)
	|
	|ГДЕ
	|	СтрокиТовары.Акциз > 0
	|	И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|	И Операция.ХозяйственнаяОперация В (
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту),
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиентуРеглУчет))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Аналитика.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстАкцизСРеализации;
	
КонецФункции

Все, проводка готова.

4. Дорабатываем печатную форму С/Ф.

Такие печатные формы как Счет-Фактура или Торг-12 вынесены в отдельную обработку «ПечатьОбщихФорм». Для ее доработки снимаем ее корень с поддержки.

Находим в модуле менеджера процедуру «ЗаполнитьТабличныйДокументСчетФактура()». Там ищем часть кода, где заполняется параметр печатной формы «акциз» примерно такой:

СтруктураПараметров.Вставить("Акциз", НСтр("ru='без акциза'"));

и меняем участок кода на:

Акциз = ИТ_АкцизСервер.ПолучитьСуммуАкцизаСтрокиДокумента(СтрокаТовары,НомерСтроки);     // Получение акциза из документа основания
Если Не НаборыСервер.ВыводитьТолькоЗаголовок(СтрокаТовары, ИспользоватьНаборы) Тогда
	Если ДействующиеПостановления.Постановление914 
		ИЛИ ОпцииПечатиСчетаФактуры.СчетФактураНаАванс
		ИЛИ ОпцииПечатиСчетаФактуры.СчетФактураНалоговыйАгент Тогда
		СтруктураПараметров.Вставить("Акциз", Формат(Акциз,"ЧЦ=15; ЧДЦ=2; ЧН='--'")); //Подстановка акциза
	Иначе
		СтруктураПараметров.Вставить("Акциз", Формат(Акциз,"ЧЦ=15; ЧДЦ=2; ЧН='без акциза'")); //Подстановка акциза 
	КонецЕсли;
КонецЕсли;

И тут есть небольшая проблема. В качестве передаваемой переменной «СтрокаТовары» передается не строка из табличной части «Товары», а строка результата запроса с выборкой из табличной части «ВидыЗапасов».

Сначала я хотел вклиниться в этот запрос, формирующий список строк, но этот запрос использовался во многих местах и количество вмешательств в конфигурацию было слишком велико.  Решил эту проблему путем преобразования строки «ВидыЗапасов» в строку «Товары» в своей процедуре. Уверен, что так делать не правильно, но нашу задачу это решило. Итак, добавляем в наш общий модуль «ИТ_АкцизСервер» функцию:

Функция ПолучитьСуммуАкцизаСтрокиДокумента(СтрокаТовары,НомерСтроки)   Экспорт
	 СсылкаНаДокументСАкцизом = СтрокаТовары.Ссылка;
	 Если СсылкаНаДокументСАкцизом.Ссылка.Метаданные().ПолноеИмя()="Документ.СчетФактураВыданный" Тогда
	 	СсылкаНаДокументСАкцизом = СтрокаТовары.Ссылка.ДокументОснование;
	 КонецЕсли;
	 Если НЕ СсылкаНаДокументСАкцизом.Ссылка.Метаданные().ПолноеИмя()="Документ.РеализацияТоваровУслуг" Тогда
		 Возврат 0;
	 КонецЕсли;
	 Если СсылкаНаДокументСАкцизом.Пустая()
		 ИЛИ СтрокаТовары.Номенклатура.Пустая()
		 ИЛИ СтрокаТовары.ЭтоКомплектующие Тогда
		 Возврат 0;
	 КонецЕсли;
	 
	 //Поскольку 1С передает в строку не таблицу товаров а таблицу видов товаров приходится находить соответствия в нужой нам табличной части.
	 Отбор = Новый Структура;
	 Отбор.Вставить("Номенклатура",СтрокаТовары.Номенклатура.Ссылка);
	 Отбор.Вставить("Характеристика",СтрокаТовары.Характеристика.Ссылка);

	 МассивСНоменклатурой = СсылкаНаДокументСАкцизом.Товары.НайтиСтроки(Отбор);
	 ИтогоАкциз = 0;
	 ИтогоКоличествоАкциз = 0;
	 Для Каждого СтрокаМассива Из МассивСНоменклатурой Цикл
		 Если СтрокаМассива.Количество = СтрокаТовары.Количество
			  И СтрокаМассива.СуммаСНДС = СтрокаТовары.СуммаСНДС Тогда
			 	Возврат СтрокаМассива.Акциз;
		 КонецЕсли;
		 ИтогоАкциз=ИтогоАкциз+СтрокаМассива.Акциз;	
		 ИтогоКоличествоАкциз=ИтогоКоличествоАкциз+СтрокаМассива.Количество;
	 КонецЦикла;
	 Если ИтогоКоличествоАкциз=СтрокаТовары.Количество Тогда
		 Возврат ИтогоАкциз;
	 ИначеЕсли ИтогоКоличествоАкциз>0 Тогда
		Возврат ИтогоАкциз/ИтогоКоличествоАкциз*СтрокаТовары.Количество; 
	 КонецЕсли;
	 Возврат 0;
 КонецФункции

Аналогичным способом меняет ТОРГ-12., правда в унифицированной форме акциза нет, пришлось дорисовывать в отдельный макет.

Задача решена.

Акциз Проводки Колонка ЕРП2

См. также

Табличная часть в доп. реквизитах и формирование таблиц в шаблоне docx для 1С:ДО 3.0

Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Россия Платные (руб)

Расширение конфигурации для «1С:Документооборот КОРП», редакция 3.0. позволяет: 1.использовать произвольные табличные части в качестве дополнительных реквизитов к документу; 2 использовать произвольные табличные части в шаблонах в формате docx для автоматического заполнения таблиц.

29400 руб.

29.06.2023    4868    10    5    

19

Расширение для 1С:УНФ. Автоматическое снятие резервов в Заказах покупателей

Логистика, склад и ТМЦ Адаптация типовых решений Пользователь Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Мы доработали УНФ, чтобы она автоматически отменяла старые резервы и не мешала эффективно продавать.

7200 руб.

02.08.2023    3241    5    0    

22

Каждому менеджеру нужен свой Excel

Адаптация типовых решений Программист Пользователь Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Абонемент ($m)

Каждый из нас сталкивается с ситуацией, когда какой-нибудь менеджер показывает свой Excel и рассказывает, как он что-то из 1С копирует в него, снабжает пояснениями, выделяет цветом и т.д. и т.п. Заканчивается все просьбой сделать вот чтобы также было в 1С. И оказывается такой человек (почти с гарантией) либо лучшим продажником, либо каким-то важным, за все отвечающим, - на ком все держится.

2 стартмани

22.04.2024    4349    dimanich70    15    

18

Создать на основании - своя кнопка (БСП). Проблема двух подменю Создать на основании

БСП (Библиотека стандартных подсистем) Адаптация типовых решений Программист Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

Понадобилось в подменю "Создать на основании" добавить свою команду, которая открывает обработку. В процессе доработок появилась проблема двух подменю "Создать на основании". В статье о том, как решились проблемы.

01.03.2024    2411    dimanich70    8    

15

Доработка отчета "Связанные документы" (структура подчиненности) для вывода объектов из любого расширения

Адаптация типовых решений Программист Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Доработка типового отчета "Связанные документы" позволяет просто и быстро расширять состав объектов для построения структуры подчиненности документов, используя объекты основной конфигурации и любых расширений.

1 стартмани

27.10.2023    2277    19    avmartynov    14    

44

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2488    34    progmaster    8    

4
Отзывы
9. dima_home 241 26.08.22 11:45 Сейчас в теме
Статья сильно устарела.
Сегодня конфигурация ЕРП сильно поменялась и мы полностью переписали учет акциза для табачной продукции.

Примерный план реализации:

Для автоматического расчета акциза введены следующие показатели:
- добавлен справочник "ИТ_ВидыАкцизнойПродукции" с реквизитом "ЕдиницаИзмерения", используемый для указания ставки акциза.
- в справочнике "Номенклатура" добавлены реквизиты "ИТ_ВидАкцизнойПродукции", "ИТ_КоэффициентПересчетаАкциза"
- в справочнике "ХарактеристикаНоменклатуры" добавлен реквизит "ИТ_МРЦ". (В отличие от компании 1С, которая решила вести МРЦ для сигарет в разрезе серий номенклатуры, мы категорически отказались от этого решения в пользу характеристик. Считаем решение 1С стратегической ошибкой).
- добавлен регистр сведений "ИТ_СтавкиАкцизаПоАкцизнымГруппамНоменклатуры" имеющий измерение "ИТ_ВидыАкцизнойПродукции", ресурсы "ТвердаяСтавка,АдвалорнаяСтавка,МинимальнаяСтавка,ЕМЦ", реквизит "КомментарийРасчета" куда делаем копию строки с описанием из налогового кодекса. (это своего рода классификатор ставок акциза)

Добавлен числовой реквизит "ИТ_Акциз" в табличные части следующих документов:
- в Документ.ВозвратТоваровОтКлиента.Товары
- в Документ.ВозвратТоваровОтКлиента.Товары и Расхождения
- в Документ.ОтчетКомиссионера.Товары
- в Документ.РеализацияТоваровУслуг.Товары
На формах вставляем событие "ИТ_ПриСозданииНаСервереПосле"
ИТ_РаботаСУправляемойФормой.ДобавитьПоле(ЭтаФорма,ВидПоляФормы.ПолеВвода,"ИТ_Акциз","ИТ_Акциз",Элементы.Товары,"Объект.Товары.ИТ_Акциз",,Новый Структура("ПутьКДаннымПодвала","Объект.Товары.ИтогИТ_Акциз"));
А также в события "ИТ_ТоварыСуммаПриИзмененииПосле","ИТ_ТоварыКоличествоУпаковокПриИзмененииПосле","ИТ_ТоварыНоменклатураПриИзмененииПосле","ИТ_ТоварыХарактеристикаПриИзмененииПосле" обработчик ИТ_АкцизыКлиент.ПересчитатьАкцизВСтрокеТЧ(Элементы.Товары.ТекущиеДанные, Объект.Дата);


Добавлен регистр оборотов "ИТ_АкцизПродажи" с измерениями "Организация,Контрагент,ДоговорКонтрагента,СчетФактура,АналитикаУчетаНоменклатуры,Экспорт,ДатаСтавкиАкциза" и ресурсами "Акциз,Количество".
Добавлен отчет для анализа регистра оборотов "ИТ_Акцизы"

Добавили общие модули:
"ИТ_АкцизыВызовСервера"
- Функция ПолучитьСтавкуАкциза(ВидАкцизнойПродукции, Период) Экспорт
- Функция РассчитатьАкциз(Номенклатура, Характеристика, Количество, Период) Экспорт
- Функция ПолучитьМРЦХарактеристики(Характеристика) Экспорт
- Функция ЭтоАкцизныйТовар(Номенклатура) Экспорт
- Функция ОтображатьМРЦ(СправочникСсылка) Экспорт

"ИТ_АкцизыСервер"
- Функция ПараметрыДляПроведенияДокумента(Документ, Свойства) Экспор
- Процедура ОтразитьДвижения(ТаблицыДляДвижений, Движения, Отказ)
- Функция ТекстыЗапросовСторнирования(МетаданныеДокумента) Экспор
- Функция ТекстыЗапросовКонтрольДатыЗапретаПоТаблицеИзменений(Запрос)

"ИТ_АкцизыКлиент"
- Процедура ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Дата) Экспорт
- Процедура УправлениеДоступностьюКолонкиАкцизВСтрокеТЧ(ТекущаяСтрока, Элементы) Экспорт

Далее на примере реализации:
"ОбщийМодуль.РеализацияТоваровУслугЛокализация"

#Область Проведение

&ИзменениеИКонтроль("ТекстОтраженияВРеглУчете")
// Функция возвращает текст запроса для отражения документа в регламентированном учете.
//
// Возвращаемое значение:
//	Строка - Текст запроса
//
Функция ИТ_ТекстОтраженияВРеглУчете() Экспорт
	
	//++ Локализация
	
	ТекстыОтражения = Новый Массив;
	ТекстыОтражения.Добавить(ТекстПередачаНаКомиссию());
	ТекстыОтражения.Добавить(ТекстПередачаНаСубкомиссию());
	ТекстыОтражения.Добавить(ТекстРеализацияБезПереходаПраваСобственности());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииКомиссионногоТовара());
	ТекстыОтражения.Добавить(ТекстПродажаКомиссионногоТовара());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииСобственногоТовара());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииРаботУслуг());
	ТекстыОтражения.Добавить(ТекстСебестоимостьОтгруженногоТовара());
	ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованногоТовара());
	ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованныхРабот());
	ТекстыОтражения.Добавить(ТекстНДССРеализации());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииРаботыУслуги());
	ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственности());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственности());
	ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственностиРаботыУслуги());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственностиРаботыУслуги­());
	ТекстыОтражения.Добавить(ТекстНулеваяСтавкаНДСОтклонена());
	ТекстыОтражения.Добавить(ТекстЗалоговаяСтоимостьПереданнойТары());
	ТекстыОтражения.Добавить(ТекстВключениеИсключениеНДСВСтоимость());
	ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиРасходы());
	ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиДоходы());
	ТекстыОтражения.Добавить(ТекстПродажаАгентскихУслуг());
	#Вставка
	//++ ИТ Начало
	ТекстыОтражения.Добавить(ТекстАкцизСРеализации());
	ТекстыОтражения.Добавить(ТекстАкцизОтложенныйСРеализации());
	//-- ИТ Конец
	#КонецВставки
	
	Возврат СтрСоединить(ТекстыОтражения, ОбщегоНазначенияУТ.РазделительЗапросовВОбъединении());
	
	//-- Локализация
	Возврат "";
	
КонецФункции

&После ("ЗарегистрироватьУчетныеМеханизмы")
// Описывает учетные механизмы используемые в документе для регистрации в механизме проведения.
//
// Параметры:
//  МеханизмыДокумента - Массив - список имен учетных механизмов, для которых будет выполнена
//              регистрация в механизме проведения.
//
Процедура ИТ_ЗарегистрироватьУчетныеМеханизмы(МеханизмыДокумента) Экспорт
	
	МеханизмыДокумента.Добавить("ИТ_Акцизы");
	МеханизмыДокумента.Добавить("ИТ_РасчетыСКлиентамиУУ");
	
КонецПроцедуры

#КонецОбласти


#Область ПроводкиРеглУчета

Функция ТекстАкцизСРеализации() Экспорт 
	
	ТекстАкцизСРеализации = "
	|ВЫБРАТЬ  
	//// Акциз с релизации (Дт 90.04 :: Кт 68.03) для реализации
	//// Акциз с релизации (Дт 76.А  :: Кт 68.03) для комиссии и отгрузки без перехода права собственности
	|	Операция.Ссылка КАК Ссылка,
	|	Операция.Дата КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	СтрокиТовары.ИТ_Акциз КАК Сумма,
	|	СтрокиТовары.ИТ_Акциз / КурсВалютыУпрУчета.Курс КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ПустаяСсылка) КАК ВидСчетаДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета  КАК АналитикаУчетаДт,
	|	Аналитика.МестоХранения КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиДт,
	|
	|	ВЫБОР
	|         КОГДА (Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|               ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)) 
	|         ТОГДА ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ИТ_АкцизНачисленныйПоОтгрузке)
	|         ИНАЧЕ ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_Акцизы)
	|   КОНЕЦ КАК СчетДт,
	|	ВЫБОР
	|         КОГДА (Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|               ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)) 
	|         ТОГДА Операция.Контрагент 
	|         ИНАЧЕ Аналитика.Номенклатура.ГруппаФинансовогоУчета 
	|   КОНЕЦ КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	0 КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	&ВалютаРеглУчета КАК ВалютаКт,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) КАК ПодразделениеКт,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Акцизы) КАК СчетКт,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог) КАК СубконтоКт1,
	|	Операция.Организация.ИТ_РегистрацияВНалоговомОрганеАкциз КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	СтрокиТовары.ИТ_Акциз КАК ВалютнаяСуммаКт,
	|	0 КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,   
	|	ВЫБОР
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|         ТОГДА ""Акциз с отгрузки без перехода права собственности"" 
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
	|         ТОГДА ""Акциз при передаче на комиссию"" 
	|         ИНАЧЕ ""Акциз с релизации""
	|   КОНЕЦ КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		(СтрокиТовары.Ссылка = Операция.Ссылка)
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
	|	ПО
	|		СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, День)
	|
	|ГДЕ
	|	СтрокиТовары.ИТ_Акциз <> 0
	|	И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|	И Операция.ХозяйственнаяОперация В (
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту),
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиентуРеглУчет),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Аналитика.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстАкцизСРеализации;
	
КонецФункции

Функция ТекстАкцизОтложенныйСРеализации() Экспорт 
	
	ТекстАкцизСРеализации = "
	|ВЫБРАТЬ  
	//// Акциз с релизации (Дт 90.04 :: Кт 76.А) для комиссии и отгрузки без перехода права собственности на дату перехода права
	//// Акциз с релизации (ничего не делаем-) для реализации
	|	Операция.Ссылка КАК Ссылка,
	|	ВЫБОР КОГДА Операция.ХозяйственнаяОперация = 
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности) ТОГДА
	|		Операция.ДатаПереходаПраваСобственности
	|	ИНАЧЕ
	|		Операция.Дата
	|	КОНЕЦ КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	СтрокиТовары.ИТ_Акциз КАК Сумма,
	|	СтрокиТовары.ИТ_Акциз / КурсВалютыУпрУчета.Курс КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ПустаяСсылка) КАК ВидСчетаДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета  КАК АналитикаУчетаДт,
	|	Аналитика.МестоХранения КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиДт,
	|
	|   ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_Акцизы)КАК СчетДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	0 КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	&ВалютаРеглУчета КАК ВалютаКт,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) КАК ПодразделениеКт,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ИТ_АкцизНачисленныйПоОтгрузке) КАК СчетКт,
	|   Операция.Контрагент КАК СубконтоКт1, 
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	СтрокиТовары.ИТ_Акциз КАК ВалютнаяСуммаКт,
	|	0 КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,   
	|	ВЫБОР
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ОтчетКомиссионера)
	|         ТОГДА ""Акциз при отчете комиссионера"" 
	|         ИНАЧЕ ""Акциз при переходе права собственности""
	|   КОНЕЦ КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		(СтрокиТовары.Ссылка = Операция.Ссылка)
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
	|	ПО
	|		СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, День)
	|
	|ГДЕ
	|	СтрокиТовары.ИТ_Акциз <> 0
	|	И Операция.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.Отгружено)
	|	И Операция.ХозяйственнаяОперация В (
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ОтчетКомиссионера))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Аналитика.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстАкцизСРеализации;
	
КонецФункции
            
&ИзменениеИКонтроль("ПоместитьВременнуюТаблицуТоваров")
Процедура ИТ_ПоместитьВременнуюТаблицуТоваров(МенеджерВременныхТаблиц, ПараметрыЗаполнения)
	
	Если ПараметрыЗаполнения = Неопределено Тогда
		ПараметрыЗаполнения = ПродажиСервер.ПараметрыЗаполненияВременнойТаблицыТоваров();
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.УстановитьПараметр("ВалютаУправленческогоУчета",     Константы.ВалютаУправленческогоУчета.Получить());
	Запрос.УстановитьПараметр("ПересчитыватьВВалютуРегл",       ПараметрыЗаполнения.ПересчитыватьВВалютуРегл);
	Запрос.УстановитьПараметр("ВключаяНомераГТД",               ПараметрыЗаполнения.ВключаяНомераГТД);
	Запрос.УстановитьПараметр("ПустаяГТД",                      Справочники.НомераГТД.ПустаяСсылка());
	Запрос.УстановитьПараметр("ВыводитьСерии",                  ПараметрыЗаполнения.ВыводитьСерииНоменклатуры);
	
	Если ПараметрыЗаполнения.ПересчитыватьВВалютуРегл И ПараметрыЗаполнения.АктуализироватьРасчеты Тогда
		Если НЕ ПолучитьФункциональнуюОпцию("НоваяАрхитектураВзаиморасчетов") Тогда
		
			Запрос.Текст = "
			|ВЫБРАТЬ РАЗЛИЧНЫЕ
			|	РасчетыСКлиентами.АналитикаУчетаПоПартнерам КАК АналитикаУчетаПоПартнерам
			|ИЗ
			|	РегистрНакопления.РасчетыСКлиентами КАК РасчетыСКлиентами
			|
			|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
			|		ТаблицаДанныхДокументов КАК ДанныеДокументов
			|	ПО
			|		РасчетыСКлиентами.Регистратор = ДанныеДокументов.Ссылка
			|
			|ГДЕ
			|	ДанныеДокументов.Валюта <> ДанныеДокументов.Ссылка.Организация.ВалютаРегламентированногоУчета
			|	И РасчетыСКлиентами.Активность
			|";
			ТаблицаАналитик = Запрос.Выполнить().Выгрузить();
			МассивАналитикУчетаПоПартнерам = ТаблицаАналитик.ВыгрузитьКолонку("АналитикаУчетаПоПартнерам");
			
			Если МассивАналитикУчетаПоПартнерам.Количество() > 0 Тогда
				ОкончаниеПериодаРасчета = КонецМесяца(ВзаиморасчетыСервер.ПолучитьМаксимальнуюДатуВКоллекцииДокументов(МенеджерВременныхТаблиц)) + 1;
				АналитикиРасчета = РаспределениеВзаиморасчетовВызовСервера.АналитикиРасчета();
				АналитикиРасчета.АналитикиУчетаПоПартнерам = МассивАналитикУчетаПоПартнерам;
				Попытка
					РаспределениеВзаиморасчетовВызовСервера.РаспределитьВсеРасчетыСКлиентами(ОкончаниеПериодаРасчета, АналитикиРасчета);
				Исключение
					ТекстСообщения = НСтр("ru = 'Печатная форма сформирована по неактуальным данным.
					|Необходимо актуализировать взаиморасчеты вручную и переформировать печатную форму.';
					|en = 'Print form is generated according to irrelevant data. 
					|Update mutual settlements manually, and then create the print form again.'");
					ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);
				КонецПопытки;
			КонецЕсли;
		Иначе
			
			Запрос.Текст = 
			"ВЫБРАТЬ
			|	ДанныеДокументов.Ссылка КАК Ссылка
			|ИЗ
			|	ТаблицаДанныхДокументов КАК ДанныеДокументов
			|ГДЕ 
			|	ДанныеДокументов.Валюта <> ДанныеДокументов.Ссылка.Организация.ВалютаРегламентированногоУчета
			|	ИЛИ ДанныеДокументов.Валюта <> &ВалютаУправленческогоУчета";
			МассивДокументов = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Ссылка");
			РегистрыСведений.СуммыДокументовВВалютахУчета.РассчитатьСуммыДокументовВВалютахУчета(МассивДокументов);
			
		КонецЕсли;
		
	КонецЕсли;
	
	Запрос.Текст = "
	|ВЫБРАТЬ
	|	ТаблицаТоваров.Ссылка КАК Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов КАК АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка КАК Упаковка,
	|	ТаблицаТоваров.Цена КАК Цена,
	|	МАКСИМУМ(ТаблицаТоваров.НомерСтроки) КАК НомерСтроки
	|
	|ПОМЕСТИТЬ СтрокиТоваров
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.Товары КАК ТаблицаТоваров
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаТоваров.Ссылка = ДанныеДокументов.Ссылка
	|
	|СГРУППИРОВАТЬ ПО
	|	ТаблицаТоваров.Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка,
	|	ТаблицаТоваров.Цена
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	ТаблицаТоваров.Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка,
	|	ТаблицаТоваров.Цена
	|;
	|////////////////////////////////////////////////////////////­/////////////////
	|ВЫБРАТЬ
	|	ТаблицаДокумента.Ссылка                                 КАК Ссылка,
	|	ДАТАВРЕМЯ(1,1,1)                                        КАК ДатаСчетаФактурыКомиссионера,
	|	НЕОПРЕДЕЛЕНО                                            КАК НомерСчетаФактурыКомиссионера,
	|	ТаблицаДокумента.Ссылка.КлиентКонтрагент                КАК Покупатель,
	
	|	ВариантыКомплектацииНоменклатуры.Ссылка КАК ВариантКомплектацииНоменклатуры,
	
	|	ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
	|	ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
	
	|	ТаблицаДокумента.НоменклатураНабора КАК НоменклатураНабора,
	|	ТаблицаДокумента.ХарактеристикаНабора КАК ХарактеристикаНабора,
	
	|	ТаблицаДокумента.НомерСтроки                            КАК НомерСтроки,
	|	ТаблицаДокумента.Номенклатура                           КАК Номенклатура,
	|	ТаблицаДокумента.Характеристика                         КАК Характеристика,
	|	ТаблицаДокумента.Серия                                  КАК Серия,
	|	&ПустаяГТД                                              КАК НомерГТД,
	|	ЗНАЧЕНИЕ(Справочник.КлассификаторТНВЭД.ПустаяСсылка)    КАК КодТНВЭД,
	|	ТаблицаДокумента.Количество                             КАК Количество,
	|	ТаблицаДокумента.Количество                             КАК КоличествоУпаковок,
	|	0                                                       КАК КоличествоПоРНПТ,
	|	
	|	ТаблицаДокумента.Цена                                   КАК Цена,
	|	ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаБезНДСРегл,
	|		ТаблицаДокумента.СуммаСНДС - ТаблицаДокумента.СуммаНДС
	|	) КАК СуммаБезНДС,
	|	
	|	ТаблицаДокумента.СтавкаНДС                              КАК СтавкаНДС,
	#Вставка
	|	0                				                        КАК Акциз,
	#КонецВставки
	|	
	|	ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаНДСРегл,
	|		ТаблицаДокумента.СуммаНДС
	|	) КАК СуммаНДС,
	|	
	|	ЛОЖЬ                                                    КАК ЭтоТовар,
	|	ЛОЖЬ                                                    КАК ЭтоНеВозвратнаяТара,
	|	ЛОЖЬ                                                    КАК ВернутьМногооборотнуюТару,
	|	ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)  КАК Упаковка
	|
	|ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.Товары КАК ТаблицаДокумента
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаДокумента.Ссылка = ДанныеДокументов.Ссылка
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК СуммыДокументовВВалютахУчета
	|	ПО
	|		ТаблицаДокумента.Ссылка = СуммыДокументовВВалютахУчета.Регистратор
	|		И ТаблицаДокумента.ИдентификаторСтроки = СуммыДокументовВВалютахУчета.ИдентификаторСтроки
	|		И СуммыДокументовВВалютахУчета.Активность
	|		И &ПересчитыватьВВалютуРегл
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВариантыКомплектацииНоменклатуры КАК ВариантыКомплектацииНоменклатуры
	|		ПО ВариантыКомплектацииНоменклатуры.Владелец = ТаблицаДокумента.НоменклатураНабора
	|		И ВариантыКомплектацииНоменклатуры.Характеристика = ТаблицаДокумента.ХарактеристикаНабора
	|		И ВариантыКомплектацииНоменклатуры.Основной
	|
	|ГДЕ
	|	ТаблицаДокумента.Номенклатура.ТипНоменклатуры В
	|		(ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Услуга),
	|		ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Работа))
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	ТаблицаДокумента.Ссылка                                        КАК Ссылка,
	|	ДАТАВРЕМЯ(1,1,1)                                               КАК ДатаСчетаФактурыКомиссионера,
	|	НЕОПРЕДЕЛЕНО                                                   КАК НомерСчетаФактурыКомиссионера,
	|	ТаблицаДокумента.Ссылка.КлиентКонтрагент                       КАК Покупатель,
	
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.Ссылка, ЗНАЧЕНИЕ(Справочник.ВариантыКомплектацииНоменклатуры.ПустаяСсылка)) КАК ВариантКомплектацииНоменклатуры,
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах, ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)) КАК ВариантПредставленияНабораВПечатныхФормах,
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора, ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)) КАК ВариантРасчетаЦеныНабора,
	
	|	ЕСТЬNULL(ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка))   КАК НоменклатураНабора,
	|	ЕСТЬNULL(ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК ХарактеристикаНабора,
	
	|	МИНИМУМ(СтрокиТоваров.НомерСтроки)                             КАК НомерСтроки,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура       КАК Номенклатура,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика     КАК Характеристика,
	|	ВЫБОР КОГДА &ВыводитьСерии ТОГДА
	|		ТаблицаДокумента.АналитикаУчетаНоменклатуры.Серия
	|	ИНАЧЕ 
	|		ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
	|	КОНЕЦ КАК Серия,
	|	
	|	ВЫБОР КОГДА &ВключаяНомераГТД ТОГДА
	|		ТаблицаДокумента.НомерГТД
	|	ИНАЧЕ
	|		&ПустаяГТД
	|	КОНЕЦ КАК НомерГТД,
	|	ТаблицаДокумента.КодТНВЭД                                      КАК КодТНВЭД,
	|
	|	СУММА(ТаблицаДокумента.Количество)                             КАК Количество,
	|	СУММА(ТаблицаДокумента.КоличествоУпаковок)                     КАК КоличествоУпаковок,
	|	СУММА(ВЫБОР
	|			КОГДА &ВключаяНомераГТД
	|				ТОГДА ТаблицаДокумента.КоличествоПоРНПТ
	|			ИНАЧЕ 0
	|	КОНЕЦ)                                                         КАК КоличествоПоРНПТ,
	|	
	|	ТаблицаДокумента.Цена                                          КАК Цена,
	|	СУММА(ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаБезНДСРегл,
	|		ТаблицаДокумента.СуммаСНДС - ТаблицаДокумента.СуммаНДС
	|	)) КАК СуммаБезНДС,
	|	
	|	ТаблицаДокумента.СтавкаНДС                                     КАК СтавкаНДС,
	#Вставка
	|	Сумма(ИТ_АкцизыТоваров.ИТ_Акциз)      						   КАК Акциз,
	#КонецВставки 
	|	
	|	СУММА(ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаНДСРегл,
	|		ТаблицаДокумента.СуммаНДС
	|	)) КАК СуммаНДС,
	|	
	|	ИСТИНА                                                         КАК ЭтоТовар,
	|	ВЫБОР
	|		КОГДА
	|			ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|			И ТаблицаДокумента.Ссылка.ВернутьМногооборотнуюТару
	|		ТОГДА
	|			ЛОЖЬ
	|		ИНАЧЕ
	|			ИСТИНА
	|	КОНЕЦ                                                          КАК ЭтоНеВозвратнаяТара,
	|	ТаблицаДокумента.Ссылка.ВернутьМногооборотнуюТару              КАК ВернутьМногооборотнуюТару,
	|	ТаблицаДокумента.Упаковка                                      КАК Упаковка
	|
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК ТаблицаДокумента
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаДокумента.Ссылка = ДанныеДокументов.Ссылка
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК СуммыДокументовВВалютахУчета
	|	ПО
	|		ТаблицаДокумента.Ссылка = СуммыДокументовВВалютахУчета.Регистратор
	|		И ТаблицаДокумента.ИдентификаторСтроки = СуммыДокументовВВалютахУчета.ИдентификаторСтроки
	|		И СуммыДокументовВВалютахУчета.Активность
	|		И &ПересчитыватьВВалютуРегл
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		СтрокиТоваров КАК СтрокиТоваров
	|	ПО
	|		ТаблицаДокумента.Ссылка = СтрокиТоваров.Ссылка
	|		И ТаблицаДокумента.АналитикаУчетаНоменклатуры = СтрокиТоваров.АналитикаУчетаНоменклатуры
	|		И ТаблицаДокумента.АналитикаУчетаНаборов = СтрокиТоваров.АналитикаУчетаНаборов
	|		И ТаблицаДокумента.Упаковка = СтрокиТоваров.Упаковка
	|		И ТаблицаДокумента.Цена = СтрокиТоваров.Цена
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВариантыКомплектацииНоменклатуры КАК ВариантыКомплектацииНоменклатуры
	|		ПО ВариантыКомплектацииНоменклатуры.Владелец = ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора
	|		И ВариантыКомплектацииНоменклатуры.Характеристика = ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора
	|		И ВариантыКомплектацииНоменклатуры.Основной
	#Вставка
	|		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	|			СУММА(РеализацияТоваровУслугТовары.ИТ_Акциз) КАК ИТ_Акциз,
	|			РеализацияТоваровУслугТовары.Ссылка КАК Ссылка,
	|			МИНИМУМ(РеализацияТоваровУслугТовары.НомерСтроки) КАК НомерСтроки,
	|			РеализацияТоваровУслугТовары.Номенклатура КАК Номенклатура,
	|			РеализацияТоваровУслугТовары.Характеристика КАК Характеристика
	|		ИЗ
	|			Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
	|				ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаДанныхДокументов КАК ТаблицаДанныхДокументов
	|				ПО РеализацияТоваровУслугТовары.Ссылка = ТаблицаДанныхДокументов.Ссылка
	|		
	|		СГРУППИРОВАТЬ ПО
	|			РеализацияТоваровУслугТовары.Ссылка,
	|			РеализацияТоваровУслугТовары.Номенклатура,
	|			РеализацияТоваровУслугТовары.Характеристика) КАК ИТ_АкцизыТоваров
	|		ПО ТаблицаДокумента.Ссылка = ИТ_АкцизыТоваров.Ссылка
	|			И ТаблицаДокумента.НомерСтроки = ИТ_АкцизыТоваров.НомерСтроки
	|			И ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура = ИТ_АкцизыТоваров.Номенклатура
	|			И ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика = ИТ_АкцизыТоваров.Характеристика
	#КонецВставки
	|
	|СГРУППИРОВАТЬ ПО
	|	ТаблицаДокумента.Ссылка,
	
	|	ВариантыКомплектацииНоменклатуры.Ссылка,
	|	ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах,
	|	ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора,
	|	ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора,
	|	ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора,
	
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика,
	|	ВЫБОР КОГДА &ВыводитьСерии ТОГДА
	|		ТаблицаДокумента.АналитикаУчетаНоменклатуры.Серия
	|	ИНАЧЕ 
	|		ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
	|	КОНЕЦ,
	|	ТаблицаДокумента.СтавкаНДС,
	|	ТаблицаДокумента.Упаковка,
	|	ТаблицаДокумента.Цена,
	|	ТаблицаДокумента.КодТНВЭД,
	|
	|	ВЫБОР КОГДА &ВключаяНомераГТД ТОГДА
	|		ТаблицаДокумента.НомерГТД
	|	ИНАЧЕ
	|		&ПустаяГТД
	|	КОНЕЦ
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	Ссылка,
	|	НомерСтроки
	|;
	|////////////////////////////////////////////////////////////­/////////////////
	|УНИЧТОЖИТЬ СтрокиТоваров
	|";
	
	Если ПараметрыЗаполнения.ОбработатьНастройкиПечатиНаборов Тогда
		
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров", "ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваровДляПреобразования");
		Запрос.Текст = Запрос.Текст + ОбщегоНазначенияУТ.РазделительЗапросовВПакете() +
		"ВЫБРАТЬ
		|	ТаблицаТоваров.Ссылка КАК Ссылка,
		|	ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	МАКСИМУМ(ТаблицаТоваров.ЭтоТовар) КАК ЭтоТовар,
		|	МИНИМУМ(ТаблицаТоваров.НомерСтроки) КАК НомерСтроки,
		|	СУММА(ВЫБОР
		|			КОГДА &ЗаполненаЕдиницаИзмеренияВеса
		|				ТОГДА ВЫБОР
		|						КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
		|							ТОГДА ТаблицаТоваров.Количество
		|						ИНАЧЕ ВЫБОР
		|								КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.Вес)
		|									ТОГДА 0
		|								ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
		|							КОНЕЦ
		|					КОНЕЦ * &ТекстЗапросаВесУпаковки
		|			ИНАЧЕ 0
		|		КОНЕЦ) КАК МассаБрутто,
		|	СУММА(ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры) КАК МассаНетто,
		|	СУММА(ТаблицаТоваров.СуммаБезНДС) КАК СуммаБезНДС,
		|	СУММА(ТаблицаТоваров.СуммаНДС) КАК СуммаНДС
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборыПодготовка
		|ИЗ
		|	РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК ТаблицаТоваров
		|ГДЕ
		|	ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|
		|СГРУППИРОВАТЬ ПО
		|	ТаблицаТоваров.Ссылка,
		|	ТаблицаТоваров.НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	Результат.Ссылка КАК Ссылка,
		|	Результат.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|	Результат.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|	Результат.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|	Результат.НоменклатураНабора КАК НоменклатураНабора,
		|	Результат.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	МАКСИМУМ(ВЫБОР
		|			КОГДА Результат.ОсновнаяКомплектующая
		|				ТОГДА Результат.СтавкаНДС
		|			ИНАЧЕ NULL
		|		КОНЕЦ) КАК СтавкаНДС,
		|	МАКСИМУМ(Результат.НомерГТД) КАК НомерГТД,
		|	МАКСИМУМ(Результат.КодТНВЭД) КАК КодТНВЭД,
		|	(ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
		|				КОГДА Результат.КоличествоПоУмолчанию <> 0
		|						И Результат.ОсновнаяКомплектующая
		|					ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|				ИНАЧЕ NULL
		|			КОНЕЦ) + 0.5 КАК ЧИСЛО(10, 0))) - 1 КАК Количество,
		|	МАКСИМУМ(Результат.КоличествоПоРНПТ) КАК КоличествоПоРНПТ,
		|	МАКСИМУМ(ВЫБОР
		|			КОГДА Результат.КоличествоПоУмолчанию <> 0
		|				ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|			ИНАЧЕ NULL
		|		КОНЕЦ) КАК КоэффициентМаксимум,
		|	(ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
		|				КОГДА Результат.КоличествоПоУмолчанию <> 0
		|					ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|				ИНАЧЕ NULL
		|			КОНЕЦ) + 0.5 КАК ЧИСЛО(10, 0))) - 1 КАК КоэффициентМинимум
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительно
		|ИЗ
		|	(ВЫБРАТЬ
		|		Таблица.Ссылка КАК Ссылка,
		|		Таблица.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|		Таблица.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|		Таблица.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|		Таблица.НоменклатураНабора КАК НоменклатураНабора,
		|		Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|		Таблица.Номенклатура КАК Номенклатура,
		|		Таблица.Характеристика КАК Характеристика,
		|		МАКСИМУМ(Таблица.СтавкаНДС) КАК СтавкаНДС,
		|		МАКСИМУМ(Таблица.НомерГТД) КАК НомерГТД,
		|		МАКСИМУМ(Таблица.КодТНВЭД) КАК КодТНВЭД,
		|		МАКСИМУМ(Таблица.ОсновнаяКомплектующая) КАК ОсновнаяКомплектующая,
		|		СУММА(Таблица.КоличествоПоУмолчанию) КАК КоличествоПоУмолчанию,
		|		СУММА(Таблица.Количество) КАК Количество,
		|		СУММА(Таблица.КоличествоПоРНПТ) КАК КоличествоПоРНПТ
		|	ИЗ
		|		(ВЫБРАТЬ
		|			Товары.Ссылка КАК Ссылка,
		|			Товары.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|			Товары.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|			Товары.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|			Товары.НоменклатураНабора КАК НоменклатураНабора,
		|			Товары.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|			Товары.Номенклатура КАК Номенклатура,
		|			Товары.Характеристика КАК Характеристика,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА ИСТИНА
		|				ИНАЧЕ ЛОЖЬ
		|			КОНЕЦ КАК ОсновнаяКомплектующая,
		|			Товары.СтавкаНДС КАК СтавкаНДС,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.НомерГТД
		|				ИНАЧЕ NULL
		|			КОНЕЦ КАК НомерГТД,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.КодТНВЭД
		|				ИНАЧЕ NULL
		|			КОНЕЦ КАК КодТНВЭД,
		|			0 КАК КоличествоПоУмолчанию,
		|			Товары.Количество КАК Количество,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.КоличествоПоРНПТ
		|				ИНАЧЕ 0
		|			КОНЕЦ КАК КоличествоПоРНПТ
		|		ИЗ
		|			РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК Товары
		|		ГДЕ
		|			Товары.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|		
		|		ОБЪЕДИНИТЬ ВСЕ
		|		
		|		ВЫБРАТЬ
		|			ТаблицаДанныхДокументов.Ссылка,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантПредставленияНабораВПечатныхФормах,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантРасчетаЦеныНабора,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика,
		|			ВариантыКомплектацииНоменклатурыТовары.Номенклатура,
		|			ВариантыКомплектацииНоменклатурыТовары.Характеристика,
		|			ЛОЖЬ,
		|			NULL,
		|			NULL,
		|			NULL,
		|			ВариантыКомплектацииНоменклатурыТовары.Количество,
		|			0,
		|			0
		|		ИЗ
		|			Справочник.ВариантыКомплектацииНоменклатуры.Товары КАК ВариантыКомплектацииНоменклатурыТовары
		|				ЛЕВОЕ СОЕДИНЕНИЕ ТаблицаДанныхДокументов КАК ТаблицаДанныхДокументов
		|				ПО (ИСТИНА)
		|		ГДЕ
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка В
		|					(ВЫБРАТЬ
		|						РеализацияТоваровУслугТаблицаТоваровДляПреобразования.ВариантКомплектацииНоменклатуры
		|					ИЗ
		|						РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК РеализацияТоваровУслугТаблицаТоваровДляПреобразования)) КАК Таблица
		|	
		|	СГРУППИРОВАТЬ ПО
		|		Таблица.Ссылка,
		|		Таблица.ВариантКомплектацииНоменклатуры,
		|		Таблица.ВариантРасчетаЦеныНабора,
		|		Таблица.ВариантПредставленияНабораВПечатныхФормах,
		|		Таблица.НоменклатураНабора,
		|		Таблица.ХарактеристикаНабора,
		|		Таблица.Номенклатура,
		|		Таблица.Характеристика) КАК Результат
		|
		|СГРУППИРОВАТЬ ПО
		|	Результат.Ссылка,
		|	Результат.ВариантКомплектацииНоменклатуры,
		|	Результат.ВариантРасчетаЦеныНабора,
		|	Результат.ВариантПредставленияНабораВПечатныхФормах,
		|	Результат.НоменклатураНабора,
		|	Результат.ХарактеристикаНабора
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	Результат.Ссылка,
		|	Результат.НоменклатураНабора,
		|	Результат.ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	ВременнаяТаблицаНаборыДополнительно.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|	ВЫБОР
		|		КОГДА ВЫРАЗИТЬ(Таблица.Ссылка КАК Документ.РеализацияТоваровУслуг).ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
		|			ТОГДА ВЫБОР
		|					КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
		|						ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|					ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|				КОНЕЦ
		|		ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|	КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
		|	ВЫБОР
		|		КОГДА ВЫРАЗИТЬ(Таблица.Ссылка КАК Документ.РеализацияТоваровУслуг).ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
		|			ТОГДА ВЫБОР
		|					КОГДА ВЫБОР
		|								КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
		|									ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|								ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|							КОНЕЦ = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|							И ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора В (ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоЦенам), ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоДолям))
		|						ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.РассчитываетсяИзЦенКомплектующих)
		|					ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
		|				КОНЕЦ
		|		ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
		|	КОНЕЦ КАК ВариантРасчетаЦеныНабора,
		|	Таблица.Ссылка КАК Ссылка,
		|	Таблица.НоменклатураНабора КАК НоменклатураНабора,
		|	Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	Таблица.НомерСтроки КАК НомерСтроки,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.НомерГТД, ЗНАЧЕНИЕ(Справочник.НомераГТД.ПустаяСсылка)) КАК НомерГТД,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.КодТНВЭД, ЗНАЧЕНИЕ(Справочник.КлассификаторТНВЭД.ПустаяСсылка)) КАК КодТНВЭД,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК КоличествоУпаковок,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК Количество,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.КоличествоПоРНПТ, 1) КАК КоличествоПоРНПТ,
		|	ВЫБОР
		|		КОГДА ВременнаяТаблицаНаборыДополнительно.КоэффициентМинимум = ВременнаяТаблицаНаборыДополнительно.КоэффициентМаксимум
		|			ТОГДА ИСТИНА
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ПолныйНабор,
		|	Таблица.МассаБрутто КАК МассаБрутто,
		|	Таблица.МассаНетто КАК МассаНетто,
		|	Таблица.СуммаБезНДС КАК СуммаБезНДС,
		|	Таблица.СуммаНДС КАК СуммаНДС,
		|	Таблица.ЭтоТовар КАК ЭтоТовар,
		|	ВременнаяТаблицаНаборыДополнительно.СтавкаНДС КАК СтавкаНДС
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборы
		|ИЗ
		|	ВременнаяТаблицаНаборыПодготовка КАК Таблица
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборыДополнительно КАК ВременнаяТаблицаНаборыДополнительно
		|		ПО Таблица.НоменклатураНабора = ВременнаяТаблицаНаборыДополнительно.НоменклатураНабора
		|			И Таблица.ХарактеристикаНабора = ВременнаяТаблицаНаборыДополнительно.ХарактеристикаНабора
		|			И Таблица.Ссылка = ВременнаяТаблицаНаборыДополнительно.Ссылка
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	Ссылка,
		|	НоменклатураНабора,
		|	ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	ТаблицаТоваров.Ссылка КАК Ссылка,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах
		|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)
		|	КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора
		|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)
		|	КОНЕЦ КАК ВариантРасчетаЦеныНабора,
		|	ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ИСТИНА
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ЭтоКомплектующие,
		|	ЛОЖЬ КАК ЭтоНабор,
		|	ТаблицаТоваров.НомерСтроки КАК НомерСтроки,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.НомерСтроки
		|		ИНАЧЕ ТаблицаТоваров.НомерСтроки
		|	КОНЕЦ КАК НомерСтрокиНаборы,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ПолныйНабор
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ПолныйНабор,
		|	ТаблицаТоваров.Номенклатура КАК Номенклатура,
		|	ТаблицаТоваров.Количество КАК Количество,
		|	ТаблицаТоваров.КоличествоУпаковок КАК КоличествоУпаковок,
		|	ТаблицаТоваров.КоличествоПоРНПТ КАК КоличествоПоРНПТ,
		|	ТаблицаТоваров.СтавкаНДС КАК СтавкаНДС,
		|	ТаблицаТоваров.НомерГТД КАК НомерГТД,
		|	ТаблицаТоваров.КодТНВЭД КАК КодТНВЭД,
		|	ТаблицаТоваров.СуммаБезНДС КАК СуммаБезНДС,
		|	ТаблицаТоваров.СуммаНДС КАК СуммаНДС,
		|	ТаблицаТоваров.Характеристика КАК Характеристика,
		|	ТаблицаТоваров.Серия КАК Серия,
		|	ТаблицаТоваров.Упаковка КАК Упаковка,
		|	ВЫБОР
		|		КОГДА &ЗаполненаЕдиницаИзмеренияВеса
		|			ТОГДА ВЫБОР
		|					КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
		|						ТОГДА ТаблицаТоваров.Количество
		|					ИНАЧЕ ВЫБОР
		|							КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.Вес)
		|								ТОГДА 0
		|							ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
		|						КОНЕЦ
		|				КОНЕЦ * &ТекстЗапросаВесУпаковки
		|		ИНАЧЕ 0
		|	КОНЕЦ КАК МассаБрутто,
		|	ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры КАК МассаНетто,
		|	ТаблицаТоваров.ЭтоТовар КАК ЭтоТовар
		|ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров
		|ИЗ
		|	РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК ТаблицаТоваров
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
		|		ПО (ВременнаяТаблицаНаборы.НоменклатураНабора = ТаблицаТоваров.НоменклатураНабора)
		|			И (ВременнаяТаблицаНаборы.ХарактеристикаНабора = ТаблицаТоваров.ХарактеристикаНабора)
		|			И (ВременнаяТаблицаНаборы.Ссылка = ТаблицаТоваров.Ссылка)
		|ГДЕ
		|	(ТаблицаТоваров.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|			ИЛИ ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|				И ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоКомплектующие), ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)))
		|
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	ВременнаяТаблицаНаборы.Ссылка,
		|	ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах,
		|	ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора,
		|	ВременнаяТаблицаНаборы.НоменклатураНабора,
		|	ВременнаяТаблицаНаборы.ХарактеристикаНабора,
		|	ЛОЖЬ,
		|	ИСТИНА,
		|	ВременнаяТаблицаНаборы.НомерСтроки,
		|	ВременнаяТаблицаНаборы.НомерСтроки,
		|	ВременнаяТаблицаНаборы.ПолныйНабор,
		|	ВременнаяТаблицаНаборы.НоменклатураНабора,
		|	ВременнаяТаблицаНаборы.Количество,
		|	ВременнаяТаблицаНаборы.КоличествоУпаковок,
		|	ВременнаяТаблицаНаборы.КоличествоПоРНПТ,
		|	ВременнаяТаблицаНаборы.СтавкаНДС,
		|	ВременнаяТаблицаНаборы.НомерГТД,
		|	ВременнаяТаблицаНаборы.КодТНВЭД,
		|	ВременнаяТаблицаНаборы.СуммаБезНДС,
		|	ВременнаяТаблицаНаборы.СуммаНДС,
		|	ВременнаяТаблицаНаборы.ХарактеристикаНабора,
		|	ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка),
		|	ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка),
		|	ВременнаяТаблицаНаборы.МассаБрутто,
		|	ВременнаяТаблицаНаборы.МассаНетто,
		|	ВременнаяТаблицаНаборы.ЭтоТовар
		|ИЗ
		|	ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
		|ГДЕ
		|	ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор), ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие))
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборыПодготовка
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборыДополнительно
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборы
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ РеализацияТоваровУслугТаблицаТоваровДляПреобразования";		
		
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ТекстЗапросаВесУпаковки",
			Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
				"ТаблицаТоваров.Упаковка",
				"ТаблицаТоваров.Номенклатура"));
			
		Запрос.Текст = СтрЗаменить(
			Запрос.Текст, 
			"&ТекстЗапросаВесНоменклатуры",
			Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
				"ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения",
				"ТаблицаТоваров.Номенклатура"));
		Запрос.УстановитьПараметр("ЗаполненаЕдиницаИзмеренияВеса",   ЗначениеЗаполнено(Константы.ЕдиницаИзмеренияВеса.Получить()));
		
	КонецЕсли;
	
	Запрос.Выполнить();
	
КонецПроцедуры

&ИзменениеИКонтроль("ТекстВыручкаОтРеализацииСобственногоТовара")
Функция ИТ_ТекстВыручкаОтРеализацииСобственногоТовара()
	
	ТекстВыручкаОтРеализацииСобственногоТовара = "
	|ВЫБРАТЬ //// Выручка от реализации собственного товара (Дт 62.01 :: Кт 90.01.1)
	|	Операция.Ссылка КАК Ссылка,
	|	ВЫБОР КОГДА Операция.ХозяйственнаяОперация В
	|				(ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|				 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|		ТОГДА Операция.ДатаПереходаПраваСобственности
	|		ИНАЧЕ Операция.Дата
	|	КОНЕЦ КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл + Суммы.СуммаНДСРегл, Строки.СуммаСНДС) КАК Сумма,
	|	ЕСТЬNULL(Суммы.СуммаБезНДСУпр + Суммы.СуммаНДСУпр, Строки.СуммаСНДС / КурсВалютыУпрУчета.Курс) КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.РасчетыСКлиентами) КАК ВидСчетаДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.ГруппаФинансовогоУчета, Расчеты.ГруппаФинансовогоУчета) КАК АналитикаУчетаДт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаДт,
	|
	|	Операция.ВалютаВзаиморасчетов КАК ВалютаДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.Подразделение, Расчеты.Подразделение) КАК ПодразделениеДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.НаправлениеДеятельности, Расчеты.НаправлениеДеятельности) КАК НаправлениеДеятельностиДт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетДт,
	|
	|	ЕСТЬNULL(РасчетыПоЗаказам.Контрагент, Расчеты.Контрагент) КАК СубконтоДт1,
	|	ЕСТЬNULL(РасчетыПоЗаказам.Договор, Расчеты.Договор) КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	Строки.СуммаВзаиморасчетов КАК ВалютнаяСуммаДт,
	|	Строки.Количество КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	ВЫБОР КОГДА Операция.НалогообложениеНДС = ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяЕНВД)
	|		ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ВыручкаОтПродажЕНВД)
	|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ВыручкаОтПродаж)
	|	КОНЕЦ КАК ВидСчетаКт,
	|	ВЫБОР КОГДА &ФормироватьВидыЗапасовПоГруппамФинансовогоУчета ТОГДА
	|		Строки.ВидЗапасов.ГруппаФинансовогоУчета
	|	ИНАЧЕ
	|		Строки.АналитикаУчетаНоменклатуры.Номенклатура.ГруппаФинансовогоУчета
	|	КОНЕЦ КАК АналитикаУчетаКт,
	|	ВЫБОР
	|		КОГДА Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионера),
	|				ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|		ТОГДА ЗНАЧЕНИЕ(Справочник.Склады.ПустаяСсылка)
	|		ИНАЧЕ Строки.АналитикаУчетаНоменклатуры.МестоХранения
	|	КОНЕЦ КАК МестоУчетаКт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаКт,
	|	Операция.Подразделение КАК ПодразделениеКт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетКт,
	|
	|	ВЫБОР КОГДА &ФормироватьВидыЗапасовПоГруппамФинансовогоУчета ТОГДА
	|		Строки.ВидЗапасов.ГруппаФинансовогоУчета
	|	ИНАЧЕ
	|		Строки.АналитикаУчетаНоменклатуры.Номенклатура.ГруппаФинансовогоУчета
	|	КОНЕЦ КАК СубконтоКт1,
	|	Строки.СтавкаНДС.ПеречислениеСтавкаНДС КАК СубконтоКт2,
	|	Строки.АналитикаУчетаНоменклатуры.Номенклатура КАК СубконтоКт3,
	|
	|	0 КАК ВалютнаяСуммаКт,
	|	Строки.Количество КАК КоличествоКт,
	#Вставка
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл, Строки.СуммаСНДС - Строки.СуммаНДС) - ЕСТЬNULL(СтрокиТовары.ИТ_Акциз, 0) КАК СуммаНУКт,
	#КонецВставки
	#Удаление
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл, Строки.СуммаСНДС - Строки.СуммаНДС) КАК СуммаНУКт,
	#КонецУдаления
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,
	|	""Выручка от реализации собственного товара"" КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК Строки
	|	ПО
	|		(Строки.Ссылка = Операция.Ссылка)
	|
	#Вставка
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		Строки.Ссылка = СтрокиТовары.Ссылка
	|		И Строки.НомерСтроки = СтрокиТовары.НомерСтроки
	|
	#КонецВставки
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК Суммы
	|	ПО
	|		Строки.Ссылка = Суммы.Регистратор
	|		И Строки.ИдентификаторСтроки = Суммы.ИдентификаторСтроки
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		ВТРасчетыСКлиентамиПоЗаказам КАК РасчетыПоЗаказам
	|	ПО 
	|		Операция.Ссылка = РасчетыПоЗаказам.Ссылка
	|		И Строки.ЗаказКлиента = РасчетыПоЗаказам.Заказ
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		ВТРасчетыСКлиентамиПоЗаказам КАК Расчеты
	|	ПО 
	|		Операция.Ссылка = Расчеты.Ссылка
	|		И Расчеты.Заказ = НЕОПРЕДЕЛЕНО
	|		И Расчеты.СуммаРегл <> 0
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = ВЫБОР КОГДА Операция.ХозяйственнаяОперация В
	|			(ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|			 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|			ТОГДА Операция.ДатаПереходаПраваСобственности ИНАЧЕ НАЧАЛОПЕРИОДА(Операция.Дата, День) КОНЕЦ
	|	
	|ГДЕ
	|	Строки.ВидЗапасов.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.Товар)
	|	И (Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту),
	|										 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионера))
	|			И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|		ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиентуРеглУчет)
	|			И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|		ИЛИ Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|											  ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|			И Операция.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.Отгружено))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Строки.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстВыручкаОтРеализацииСобственногоТовара;
	
КонецФункции

#КонецОбласти
Показать


Ну и само собой переделываем "Отчет.РегламентированныйОтчетАкцизыТабак.Форма.ФормаОтчета2020Кв1.Форма.Модуль" что бы акциз заполнялся по регистру.

Надеюсь ничего не пропустил.


Помните:
Что помимо проводк, при отражении продажи нужно убавлять налоговую прибыль "СуммаНУКт" на размер акциза.
и в регистре накопления "Выручка и себестоимость продаж" нужно акциз отразить в полях "ДопРасходы" и "Доп.раходы без НДС"
Прикрепленные файлы:
Остальные комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. teller 09.12.17 09:19 Сейчас в теме
У вас кол-во сигарет в пачке прописано явно в коде?
АкцизТНС   = ПолучитьТвердуюСтавкуДляСигарет(Дата) * (ТекущаяСтрока.Количество*20/1000);
		  АкцизАНС   = РазмерМРЦ * (ПолучитьАдвалорнуюСтавкуДляСигарет(Дата)/100) * ТекущаяСтрока.Количество;
		  АкцизСумма = АкцизТНС+АкцизАНС;
		  АкцизМин   = ПолучитьМинимальнуюСтавкуДляСигарет(Дата) * (ТекущаяСтрока.Количество*20/1000);
		  
2. dima_home 241 15.12.17 12:00 Сейчас в теме
У нас количество всегда в пачках, и только в пачках (единицы хранения товара).
Упаковки так же имеются.
Тут надо пояснить:
В ЕРП на форме нет поля "Количество" и "Единица", вернее они есть на форме, только на самом деле это "Количество упаковок" и "Единица упаковки".
Когда на форме документа вы меняете "Количество" (вы на самом деле меняете "Количество упаковок"), а уже в коде документа происходит автоматический пересчет по коэффициенту из количества упаковок в количество для хранения и запоминается в скрытом столбце данных "Количество". К нему я и обращаюсь.

Конечно, правильно было поступить так: проверить что единица - это пачка, но у нас ВСЯ номенклатура в пачках, и я это пропустил.
PS/ Акциз для сигарет рассчитывается тоже исходя из единицы "пачка", поскольку МРЦ определяется только на пачку.


Раз такая пьянка, вот вам еще несколько курьезов из табачной промышленности:
1. На конференции по ЕРП в 2017 году сотрудник компании 1С заявил что в России нет табачной промышленности, по этому они не реализуют решения по табачному акцизу. А как же мы? ))
2. Регламент производства и реализации табачных изделий четко описывает, что сигареты должны продаваться только в "ПАЧКАХ"!!!!! по 20 штук сигарет внутри. Тогда как в классификаторе единиц измерений (ОКЕИ) существуют только либо "штуки", либо "тысячи пачек". И все бы ничего, да вот некоторые покупатели обязательно требуют указание кода ОКЕИ для единиц товаров (это особенно касается крупных сетей).. все время приходится разъяснять.
3. 1С не разрешает в ГТД указывать страну происхождения "РОССИЯ" мотивируя тем, что в счетах фактурах, для Российских товарах ставится в ГТД прочерк. Хочется задать вопрос сотрудникам 1С: "А ничего, что при производстве продукции на территории Калининградской области и вывозе ее на большую землю, при перемещении (продажи) необходимо в документах указывать ГТД, где страна происхождения РОССИЯ?"
4. В расчетных документах, в том числе в реестрах чеков и реестрах на получение средств с аккредитива, первичных учетных документах и счетах-фактурах соответствующая сумма акциза выделяется отдельной строкой! Приходится самим лепить в унифицированные формы, такие как ТОРГ-12 строки (столбцы) с суммой акциза.
3. *Svetlana* 02.02.18 18:16 Сейчас в теме
Добрый вечер! Большое спасибо за статью. Не подскажете по такому вопросу: если мне нужно добавить свою проводку по забалансу к типовому документу - я добавила тоже текст запроса по шаблону (с Вашей помощью разобралась в шаблоне). Но есть сложность - мне надо получить стоимость товара на забалансе при проведении, а для этого надо как минимум дату в параметры передать как-то в запрос.... Или временную таблицу с этой забалансовой себестоимостью организовать... не понимаю, как это в данной конфигурации реализовать...
4. dima_home 241 09.02.18 23:19 Сейчас в теме
Если вы обратили внимание, в запросе уже существуют разного рода временные таблицы с данными, например "ДокументыКОтражению", они формируются в начале запроса.
Через их можно выдернуть любой реквизит документа через внутреннее соединение.
Посмотрите как в примере табличная часть присоединяется внутренним соединением. Получите табличную часть документа, а к нему левым соединением получайте остатки по забалансовым счетам (в статье есть пример как курс валюты присоединяется).
5. corbenSG 16 20.11.18 06:13 Сейчас в теме
Спасибо огромное за статью! Многое в ней мне помогло. Особенно что касается проводки.

Вставлю свои пять копеек.
в процедуру ПересчитатьАкцизВСтрокеТЧ я бы добавил еще условие
Если ТекущаяСтрока = Неопределено или не ТекущаяСтрока.Количество>0 Тогда
	 Возврат;
КонецЕсли;

Что бы при первом добавлении товара не гонять на сервер.
И еще у вас не где не написано что у общего модуля ИТ_АкцизСервер должны стоять галки "Сервер" и "Вызов сервера"

Еще хотел уточнить у вас, а как вы уменьшаете НУ Кт 90.01.1 на сумму акциза?
6. dima_home 241 29.11.18 13:17 Сейчас в теме
Для решения вопроса с доходами пришлось переделать регистр:
Регистр накопления "Выручка и себестоимость продаж".

Для решения задач по отделению НДС с акциза от обычного НДС пришлось задеть
Регистр накопления "НДС Продажи"

Хотя соблазн просто прикрутить проводку, не задевая регистры был велик, но все же склонились к добавлению ресурса "Акциз" в эти регистры. Это нужно, чтобы в управленческих отчетах мы видели нормальную прибыльность.

Извините что долго не отвечал, занят работай на маркировкой табачной продукции, передаваемые в ЦРПТ.
corbenSG; +1 Ответить
8. user1431254 08.02.21 17:52 Сейчас в теме
(6)Здравствуйте! Можете подсказать поподробнее, какие изменения в регистрах Вы сделали? Спасибо!
7. ushakovdv 18.02.20 05:48 Сейчас в теме
Дмитрий, спасибо, очень помогла Ваша статья! У нас похожая история, но только с алкоголем.
А можно немного подробнее пояснить по доработкам регистров?
9. dima_home 241 26.08.22 11:45 Сейчас в теме
Статья сильно устарела.
Сегодня конфигурация ЕРП сильно поменялась и мы полностью переписали учет акциза для табачной продукции.

Примерный план реализации:

Для автоматического расчета акциза введены следующие показатели:
- добавлен справочник "ИТ_ВидыАкцизнойПродукции" с реквизитом "ЕдиницаИзмерения", используемый для указания ставки акциза.
- в справочнике "Номенклатура" добавлены реквизиты "ИТ_ВидАкцизнойПродукции", "ИТ_КоэффициентПересчетаАкциза"
- в справочнике "ХарактеристикаНоменклатуры" добавлен реквизит "ИТ_МРЦ". (В отличие от компании 1С, которая решила вести МРЦ для сигарет в разрезе серий номенклатуры, мы категорически отказались от этого решения в пользу характеристик. Считаем решение 1С стратегической ошибкой).
- добавлен регистр сведений "ИТ_СтавкиАкцизаПоАкцизнымГруппамНоменклатуры" имеющий измерение "ИТ_ВидыАкцизнойПродукции", ресурсы "ТвердаяСтавка,АдвалорнаяСтавка,МинимальнаяСтавка,ЕМЦ", реквизит "КомментарийРасчета" куда делаем копию строки с описанием из налогового кодекса. (это своего рода классификатор ставок акциза)

Добавлен числовой реквизит "ИТ_Акциз" в табличные части следующих документов:
- в Документ.ВозвратТоваровОтКлиента.Товары
- в Документ.ВозвратТоваровОтКлиента.Товары и Расхождения
- в Документ.ОтчетКомиссионера.Товары
- в Документ.РеализацияТоваровУслуг.Товары
На формах вставляем событие "ИТ_ПриСозданииНаСервереПосле"
ИТ_РаботаСУправляемойФормой.ДобавитьПоле(ЭтаФорма,ВидПоляФормы.ПолеВвода,"ИТ_Акциз","ИТ_Акциз",Элементы.Товары,"Объект.Товары.ИТ_Акциз",,Новый Структура("ПутьКДаннымПодвала","Объект.Товары.ИтогИТ_Акциз"));
А также в события "ИТ_ТоварыСуммаПриИзмененииПосле","ИТ_ТоварыКоличествоУпаковокПриИзмененииПосле","ИТ_ТоварыНоменклатураПриИзмененииПосле","ИТ_ТоварыХарактеристикаПриИзмененииПосле" обработчик ИТ_АкцизыКлиент.ПересчитатьАкцизВСтрокеТЧ(Элементы.Товары.ТекущиеДанные, Объект.Дата);


Добавлен регистр оборотов "ИТ_АкцизПродажи" с измерениями "Организация,Контрагент,ДоговорКонтрагента,СчетФактура,АналитикаУчетаНоменклатуры,Экспорт,ДатаСтавкиАкциза" и ресурсами "Акциз,Количество".
Добавлен отчет для анализа регистра оборотов "ИТ_Акцизы"

Добавили общие модули:
"ИТ_АкцизыВызовСервера"
- Функция ПолучитьСтавкуАкциза(ВидАкцизнойПродукции, Период) Экспорт
- Функция РассчитатьАкциз(Номенклатура, Характеристика, Количество, Период) Экспорт
- Функция ПолучитьМРЦХарактеристики(Характеристика) Экспорт
- Функция ЭтоАкцизныйТовар(Номенклатура) Экспорт
- Функция ОтображатьМРЦ(СправочникСсылка) Экспорт

"ИТ_АкцизыСервер"
- Функция ПараметрыДляПроведенияДокумента(Документ, Свойства) Экспор
- Процедура ОтразитьДвижения(ТаблицыДляДвижений, Движения, Отказ)
- Функция ТекстыЗапросовСторнирования(МетаданныеДокумента) Экспор
- Функция ТекстыЗапросовКонтрольДатыЗапретаПоТаблицеИзменений(Запрос)

"ИТ_АкцизыКлиент"
- Процедура ПересчитатьАкцизВСтрокеТЧ(ТекущаяСтрока, Дата) Экспорт
- Процедура УправлениеДоступностьюКолонкиАкцизВСтрокеТЧ(ТекущаяСтрока, Элементы) Экспорт

Далее на примере реализации:
"ОбщийМодуль.РеализацияТоваровУслугЛокализация"

#Область Проведение

&ИзменениеИКонтроль("ТекстОтраженияВРеглУчете")
// Функция возвращает текст запроса для отражения документа в регламентированном учете.
//
// Возвращаемое значение:
//	Строка - Текст запроса
//
Функция ИТ_ТекстОтраженияВРеглУчете() Экспорт
	
	//++ Локализация
	
	ТекстыОтражения = Новый Массив;
	ТекстыОтражения.Добавить(ТекстПередачаНаКомиссию());
	ТекстыОтражения.Добавить(ТекстПередачаНаСубкомиссию());
	ТекстыОтражения.Добавить(ТекстРеализацияБезПереходаПраваСобственности());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииКомиссионногоТовара());
	ТекстыОтражения.Добавить(ТекстПродажаКомиссионногоТовара());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииСобственногоТовара());
	ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииРаботУслуг());
	ТекстыОтражения.Добавить(ТекстСебестоимостьОтгруженногоТовара());
	ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованногоТовара());
	ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованныхРабот());
	ТекстыОтражения.Добавить(ТекстНДССРеализации());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииРаботыУслуги());
	ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственности());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственности());
	ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственностиРаботыУслуги());
	ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственностиРаботыУслуги­());
	ТекстыОтражения.Добавить(ТекстНулеваяСтавкаНДСОтклонена());
	ТекстыОтражения.Добавить(ТекстЗалоговаяСтоимостьПереданнойТары());
	ТекстыОтражения.Добавить(ТекстВключениеИсключениеНДСВСтоимость());
	ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиРасходы());
	ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиДоходы());
	ТекстыОтражения.Добавить(ТекстПродажаАгентскихУслуг());
	#Вставка
	//++ ИТ Начало
	ТекстыОтражения.Добавить(ТекстАкцизСРеализации());
	ТекстыОтражения.Добавить(ТекстАкцизОтложенныйСРеализации());
	//-- ИТ Конец
	#КонецВставки
	
	Возврат СтрСоединить(ТекстыОтражения, ОбщегоНазначенияУТ.РазделительЗапросовВОбъединении());
	
	//-- Локализация
	Возврат "";
	
КонецФункции

&После ("ЗарегистрироватьУчетныеМеханизмы")
// Описывает учетные механизмы используемые в документе для регистрации в механизме проведения.
//
// Параметры:
//  МеханизмыДокумента - Массив - список имен учетных механизмов, для которых будет выполнена
//              регистрация в механизме проведения.
//
Процедура ИТ_ЗарегистрироватьУчетныеМеханизмы(МеханизмыДокумента) Экспорт
	
	МеханизмыДокумента.Добавить("ИТ_Акцизы");
	МеханизмыДокумента.Добавить("ИТ_РасчетыСКлиентамиУУ");
	
КонецПроцедуры

#КонецОбласти


#Область ПроводкиРеглУчета

Функция ТекстАкцизСРеализации() Экспорт 
	
	ТекстАкцизСРеализации = "
	|ВЫБРАТЬ  
	//// Акциз с релизации (Дт 90.04 :: Кт 68.03) для реализации
	//// Акциз с релизации (Дт 76.А  :: Кт 68.03) для комиссии и отгрузки без перехода права собственности
	|	Операция.Ссылка КАК Ссылка,
	|	Операция.Дата КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	СтрокиТовары.ИТ_Акциз КАК Сумма,
	|	СтрокиТовары.ИТ_Акциз / КурсВалютыУпрУчета.Курс КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ПустаяСсылка) КАК ВидСчетаДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета  КАК АналитикаУчетаДт,
	|	Аналитика.МестоХранения КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиДт,
	|
	|	ВЫБОР
	|         КОГДА (Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|               ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)) 
	|         ТОГДА ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ИТ_АкцизНачисленныйПоОтгрузке)
	|         ИНАЧЕ ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_Акцизы)
	|   КОНЕЦ КАК СчетДт,
	|	ВЫБОР
	|         КОГДА (Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|               ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)) 
	|         ТОГДА Операция.Контрагент 
	|         ИНАЧЕ Аналитика.Номенклатура.ГруппаФинансовогоУчета 
	|   КОНЕЦ КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	0 КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	&ВалютаРеглУчета КАК ВалютаКт,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) КАК ПодразделениеКт,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Акцизы) КАК СчетКт,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог) КАК СубконтоКт1,
	|	Операция.Организация.ИТ_РегистрацияВНалоговомОрганеАкциз КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	СтрокиТовары.ИТ_Акциз КАК ВалютнаяСуммаКт,
	|	0 КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,   
	|	ВЫБОР
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности)
	|         ТОГДА ""Акциз с отгрузки без перехода права собственности"" 
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
	|         ТОГДА ""Акциз при передаче на комиссию"" 
	|         ИНАЧЕ ""Акциз с релизации""
	|   КОНЕЦ КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		(СтрокиТовары.Ссылка = Операция.Ссылка)
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
	|	ПО
	|		СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, День)
	|
	|ГДЕ
	|	СтрокиТовары.ИТ_Акциз <> 0
	|	И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|	И Операция.ХозяйственнаяОперация В (
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту),
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиентуРеглУчет),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Аналитика.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстАкцизСРеализации;
	
КонецФункции

Функция ТекстАкцизОтложенныйСРеализации() Экспорт 
	
	ТекстАкцизСРеализации = "
	|ВЫБРАТЬ  
	//// Акциз с релизации (Дт 90.04 :: Кт 76.А) для комиссии и отгрузки без перехода права собственности на дату перехода права
	//// Акциз с релизации (ничего не делаем-) для реализации
	|	Операция.Ссылка КАК Ссылка,
	|	ВЫБОР КОГДА Операция.ХозяйственнаяОперация = 
	|		ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности) ТОГДА
	|		Операция.ДатаПереходаПраваСобственности
	|	ИНАЧЕ
	|		Операция.Дата
	|	КОНЕЦ КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	СтрокиТовары.ИТ_Акциз КАК Сумма,
	|	СтрокиТовары.ИТ_Акциз / КурсВалютыУпрУчета.Курс КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ПустаяСсылка) КАК ВидСчетаДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета  КАК АналитикаУчетаДт,
	|	Аналитика.МестоХранения КАК МестоУчетаДт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаДт,
	|	Операция.Подразделение КАК ПодразделениеДт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиДт,
	|
	|   ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_Акцизы)КАК СчетДт,
	|	Аналитика.Номенклатура.ГруппаФинансовогоУчета КАК СубконтоДт1,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	0 КАК ВалютнаяСуммаДт,
	|	0 КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	НЕОПРЕДЕЛЕНО КАК ВидСчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК АналитикаУчетаКт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаКт,
	|
	|	&ВалютаРеглУчета КАК ВалютаКт,
	|	ЗНАЧЕНИЕ(Справочник.СтруктураПредприятия.ПустаяСсылка) КАК ПодразделениеКт,
	|	ЗНАЧЕНИЕ(Справочник.НаправленияДеятельности.ПустаяСсылка) КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ИТ_АкцизНачисленныйПоОтгрузке) КАК СчетКт,
	|   Операция.Контрагент КАК СубконтоКт1, 
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоКт3,
	|
	|	СтрокиТовары.ИТ_Акциз КАК ВалютнаяСуммаКт,
	|	0 КАК КоличествоКт,
	|	0 КАК СуммаНУКт,
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,   
	|	ВЫБОР
	|         КОГДА Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ОтчетКомиссионера)
	|         ТОГДА ""Акциз при отчете комиссионера"" 
	|         ИНАЧЕ ""Акциз при переходе права собственности""
	|   КОНЕЦ КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		(СтрокиТовары.Ссылка = Операция.Ссылка)
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
	|	ПО
	|		СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, День)
	|
	|ГДЕ
	|	СтрокиТовары.ИТ_Акциз <> 0
	|	И Операция.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.Отгружено)
	|	И Операция.ХозяйственнаяОперация В (
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|       ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ОтчетКомиссионера))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Аналитика.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстАкцизСРеализации;
	
КонецФункции
            
&ИзменениеИКонтроль("ПоместитьВременнуюТаблицуТоваров")
Процедура ИТ_ПоместитьВременнуюТаблицуТоваров(МенеджерВременныхТаблиц, ПараметрыЗаполнения)
	
	Если ПараметрыЗаполнения = Неопределено Тогда
		ПараметрыЗаполнения = ПродажиСервер.ПараметрыЗаполненияВременнойТаблицыТоваров();
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
	Запрос.УстановитьПараметр("ВалютаУправленческогоУчета",     Константы.ВалютаУправленческогоУчета.Получить());
	Запрос.УстановитьПараметр("ПересчитыватьВВалютуРегл",       ПараметрыЗаполнения.ПересчитыватьВВалютуРегл);
	Запрос.УстановитьПараметр("ВключаяНомераГТД",               ПараметрыЗаполнения.ВключаяНомераГТД);
	Запрос.УстановитьПараметр("ПустаяГТД",                      Справочники.НомераГТД.ПустаяСсылка());
	Запрос.УстановитьПараметр("ВыводитьСерии",                  ПараметрыЗаполнения.ВыводитьСерииНоменклатуры);
	
	Если ПараметрыЗаполнения.ПересчитыватьВВалютуРегл И ПараметрыЗаполнения.АктуализироватьРасчеты Тогда
		Если НЕ ПолучитьФункциональнуюОпцию("НоваяАрхитектураВзаиморасчетов") Тогда
		
			Запрос.Текст = "
			|ВЫБРАТЬ РАЗЛИЧНЫЕ
			|	РасчетыСКлиентами.АналитикаУчетаПоПартнерам КАК АналитикаУчетаПоПартнерам
			|ИЗ
			|	РегистрНакопления.РасчетыСКлиентами КАК РасчетыСКлиентами
			|
			|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
			|		ТаблицаДанныхДокументов КАК ДанныеДокументов
			|	ПО
			|		РасчетыСКлиентами.Регистратор = ДанныеДокументов.Ссылка
			|
			|ГДЕ
			|	ДанныеДокументов.Валюта <> ДанныеДокументов.Ссылка.Организация.ВалютаРегламентированногоУчета
			|	И РасчетыСКлиентами.Активность
			|";
			ТаблицаАналитик = Запрос.Выполнить().Выгрузить();
			МассивАналитикУчетаПоПартнерам = ТаблицаАналитик.ВыгрузитьКолонку("АналитикаУчетаПоПартнерам");
			
			Если МассивАналитикУчетаПоПартнерам.Количество() > 0 Тогда
				ОкончаниеПериодаРасчета = КонецМесяца(ВзаиморасчетыСервер.ПолучитьМаксимальнуюДатуВКоллекцииДокументов(МенеджерВременныхТаблиц)) + 1;
				АналитикиРасчета = РаспределениеВзаиморасчетовВызовСервера.АналитикиРасчета();
				АналитикиРасчета.АналитикиУчетаПоПартнерам = МассивАналитикУчетаПоПартнерам;
				Попытка
					РаспределениеВзаиморасчетовВызовСервера.РаспределитьВсеРасчетыСКлиентами(ОкончаниеПериодаРасчета, АналитикиРасчета);
				Исключение
					ТекстСообщения = НСтр("ru = 'Печатная форма сформирована по неактуальным данным.
					|Необходимо актуализировать взаиморасчеты вручную и переформировать печатную форму.';
					|en = 'Print form is generated according to irrelevant data. 
					|Update mutual settlements manually, and then create the print form again.'");
					ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);
				КонецПопытки;
			КонецЕсли;
		Иначе
			
			Запрос.Текст = 
			"ВЫБРАТЬ
			|	ДанныеДокументов.Ссылка КАК Ссылка
			|ИЗ
			|	ТаблицаДанныхДокументов КАК ДанныеДокументов
			|ГДЕ 
			|	ДанныеДокументов.Валюта <> ДанныеДокументов.Ссылка.Организация.ВалютаРегламентированногоУчета
			|	ИЛИ ДанныеДокументов.Валюта <> &ВалютаУправленческогоУчета";
			МассивДокументов = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Ссылка");
			РегистрыСведений.СуммыДокументовВВалютахУчета.РассчитатьСуммыДокументовВВалютахУчета(МассивДокументов);
			
		КонецЕсли;
		
	КонецЕсли;
	
	Запрос.Текст = "
	|ВЫБРАТЬ
	|	ТаблицаТоваров.Ссылка КАК Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов КАК АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка КАК Упаковка,
	|	ТаблицаТоваров.Цена КАК Цена,
	|	МАКСИМУМ(ТаблицаТоваров.НомерСтроки) КАК НомерСтроки
	|
	|ПОМЕСТИТЬ СтрокиТоваров
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.Товары КАК ТаблицаТоваров
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаТоваров.Ссылка = ДанныеДокументов.Ссылка
	|
	|СГРУППИРОВАТЬ ПО
	|	ТаблицаТоваров.Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка,
	|	ТаблицаТоваров.Цена
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	ТаблицаТоваров.Ссылка,
	|	ТаблицаТоваров.АналитикаУчетаНоменклатуры,
	|	ТаблицаТоваров.АналитикаУчетаНаборов,
	|	ТаблицаТоваров.Упаковка,
	|	ТаблицаТоваров.Цена
	|;
	|////////////////////////////////////////////////////////////­/////////////////
	|ВЫБРАТЬ
	|	ТаблицаДокумента.Ссылка                                 КАК Ссылка,
	|	ДАТАВРЕМЯ(1,1,1)                                        КАК ДатаСчетаФактурыКомиссионера,
	|	НЕОПРЕДЕЛЕНО                                            КАК НомерСчетаФактурыКомиссионера,
	|	ТаблицаДокумента.Ссылка.КлиентКонтрагент                КАК Покупатель,
	
	|	ВариантыКомплектацииНоменклатуры.Ссылка КАК ВариантКомплектацииНоменклатуры,
	
	|	ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
	|	ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
	
	|	ТаблицаДокумента.НоменклатураНабора КАК НоменклатураНабора,
	|	ТаблицаДокумента.ХарактеристикаНабора КАК ХарактеристикаНабора,
	
	|	ТаблицаДокумента.НомерСтроки                            КАК НомерСтроки,
	|	ТаблицаДокумента.Номенклатура                           КАК Номенклатура,
	|	ТаблицаДокумента.Характеристика                         КАК Характеристика,
	|	ТаблицаДокумента.Серия                                  КАК Серия,
	|	&ПустаяГТД                                              КАК НомерГТД,
	|	ЗНАЧЕНИЕ(Справочник.КлассификаторТНВЭД.ПустаяСсылка)    КАК КодТНВЭД,
	|	ТаблицаДокумента.Количество                             КАК Количество,
	|	ТаблицаДокумента.Количество                             КАК КоличествоУпаковок,
	|	0                                                       КАК КоличествоПоРНПТ,
	|	
	|	ТаблицаДокумента.Цена                                   КАК Цена,
	|	ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаБезНДСРегл,
	|		ТаблицаДокумента.СуммаСНДС - ТаблицаДокумента.СуммаНДС
	|	) КАК СуммаБезНДС,
	|	
	|	ТаблицаДокумента.СтавкаНДС                              КАК СтавкаНДС,
	#Вставка
	|	0                				                        КАК Акциз,
	#КонецВставки
	|	
	|	ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаНДСРегл,
	|		ТаблицаДокумента.СуммаНДС
	|	) КАК СуммаНДС,
	|	
	|	ЛОЖЬ                                                    КАК ЭтоТовар,
	|	ЛОЖЬ                                                    КАК ЭтоНеВозвратнаяТара,
	|	ЛОЖЬ                                                    КАК ВернутьМногооборотнуюТару,
	|	ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)  КАК Упаковка
	|
	|ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.Товары КАК ТаблицаДокумента
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаДокумента.Ссылка = ДанныеДокументов.Ссылка
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК СуммыДокументовВВалютахУчета
	|	ПО
	|		ТаблицаДокумента.Ссылка = СуммыДокументовВВалютахУчета.Регистратор
	|		И ТаблицаДокумента.ИдентификаторСтроки = СуммыДокументовВВалютахУчета.ИдентификаторСтроки
	|		И СуммыДокументовВВалютахУчета.Активность
	|		И &ПересчитыватьВВалютуРегл
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВариантыКомплектацииНоменклатуры КАК ВариантыКомплектацииНоменклатуры
	|		ПО ВариантыКомплектацииНоменклатуры.Владелец = ТаблицаДокумента.НоменклатураНабора
	|		И ВариантыКомплектацииНоменклатуры.Характеристика = ТаблицаДокумента.ХарактеристикаНабора
	|		И ВариантыКомплектацииНоменклатуры.Основной
	|
	|ГДЕ
	|	ТаблицаДокумента.Номенклатура.ТипНоменклатуры В
	|		(ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Услуга),
	|		ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Работа))
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	ТаблицаДокумента.Ссылка                                        КАК Ссылка,
	|	ДАТАВРЕМЯ(1,1,1)                                               КАК ДатаСчетаФактурыКомиссионера,
	|	НЕОПРЕДЕЛЕНО                                                   КАК НомерСчетаФактурыКомиссионера,
	|	ТаблицаДокумента.Ссылка.КлиентКонтрагент                       КАК Покупатель,
	
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.Ссылка, ЗНАЧЕНИЕ(Справочник.ВариантыКомплектацииНоменклатуры.ПустаяСсылка)) КАК ВариантКомплектацииНоменклатуры,
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах, ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)) КАК ВариантПредставленияНабораВПечатныхФормах,
	|	ЕСТЬNULL(ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора, ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)) КАК ВариантРасчетаЦеныНабора,
	
	|	ЕСТЬNULL(ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка))   КАК НоменклатураНабора,
	|	ЕСТЬNULL(ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК ХарактеристикаНабора,
	
	|	МИНИМУМ(СтрокиТоваров.НомерСтроки)                             КАК НомерСтроки,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура       КАК Номенклатура,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика     КАК Характеристика,
	|	ВЫБОР КОГДА &ВыводитьСерии ТОГДА
	|		ТаблицаДокумента.АналитикаУчетаНоменклатуры.Серия
	|	ИНАЧЕ 
	|		ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
	|	КОНЕЦ КАК Серия,
	|	
	|	ВЫБОР КОГДА &ВключаяНомераГТД ТОГДА
	|		ТаблицаДокумента.НомерГТД
	|	ИНАЧЕ
	|		&ПустаяГТД
	|	КОНЕЦ КАК НомерГТД,
	|	ТаблицаДокумента.КодТНВЭД                                      КАК КодТНВЭД,
	|
	|	СУММА(ТаблицаДокумента.Количество)                             КАК Количество,
	|	СУММА(ТаблицаДокумента.КоличествоУпаковок)                     КАК КоличествоУпаковок,
	|	СУММА(ВЫБОР
	|			КОГДА &ВключаяНомераГТД
	|				ТОГДА ТаблицаДокумента.КоличествоПоРНПТ
	|			ИНАЧЕ 0
	|	КОНЕЦ)                                                         КАК КоличествоПоРНПТ,
	|	
	|	ТаблицаДокумента.Цена                                          КАК Цена,
	|	СУММА(ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаБезНДСРегл,
	|		ТаблицаДокумента.СуммаСНДС - ТаблицаДокумента.СуммаНДС
	|	)) КАК СуммаБезНДС,
	|	
	|	ТаблицаДокумента.СтавкаНДС                                     КАК СтавкаНДС,
	#Вставка
	|	Сумма(ИТ_АкцизыТоваров.ИТ_Акциз)      						   КАК Акциз,
	#КонецВставки 
	|	
	|	СУММА(ЕСТЬNULL(
	|		СуммыДокументовВВалютахУчета.СуммаНДСРегл,
	|		ТаблицаДокумента.СуммаНДС
	|	)) КАК СуммаНДС,
	|	
	|	ИСТИНА                                                         КАК ЭтоТовар,
	|	ВЫБОР
	|		КОГДА
	|			ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|			И ТаблицаДокумента.Ссылка.ВернутьМногооборотнуюТару
	|		ТОГДА
	|			ЛОЖЬ
	|		ИНАЧЕ
	|			ИСТИНА
	|	КОНЕЦ                                                          КАК ЭтоНеВозвратнаяТара,
	|	ТаблицаДокумента.Ссылка.ВернутьМногооборотнуюТару              КАК ВернутьМногооборотнуюТару,
	|	ТаблицаДокумента.Упаковка                                      КАК Упаковка
	|
	|ИЗ
	|	Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК ТаблицаДокумента
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		ТаблицаДанныхДокументов КАК ДанныеДокументов
	|	ПО
	|		ТаблицаДокумента.Ссылка = ДанныеДокументов.Ссылка
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК СуммыДокументовВВалютахУчета
	|	ПО
	|		ТаблицаДокумента.Ссылка = СуммыДокументовВВалютахУчета.Регистратор
	|		И ТаблицаДокумента.ИдентификаторСтроки = СуммыДокументовВВалютахУчета.ИдентификаторСтроки
	|		И СуммыДокументовВВалютахУчета.Активность
	|		И &ПересчитыватьВВалютуРегл
	|	
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		СтрокиТоваров КАК СтрокиТоваров
	|	ПО
	|		ТаблицаДокумента.Ссылка = СтрокиТоваров.Ссылка
	|		И ТаблицаДокумента.АналитикаУчетаНоменклатуры = СтрокиТоваров.АналитикаУчетаНоменклатуры
	|		И ТаблицаДокумента.АналитикаУчетаНаборов = СтрокиТоваров.АналитикаУчетаНаборов
	|		И ТаблицаДокумента.Упаковка = СтрокиТоваров.Упаковка
	|		И ТаблицаДокумента.Цена = СтрокиТоваров.Цена
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВариантыКомплектацииНоменклатуры КАК ВариантыКомплектацииНоменклатуры
	|		ПО ВариантыКомплектацииНоменклатуры.Владелец = ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора
	|		И ВариантыКомплектацииНоменклатуры.Характеристика = ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора
	|		И ВариантыКомплектацииНоменклатуры.Основной
	#Вставка
	|		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	|			СУММА(РеализацияТоваровУслугТовары.ИТ_Акциз) КАК ИТ_Акциз,
	|			РеализацияТоваровУслугТовары.Ссылка КАК Ссылка,
	|			МИНИМУМ(РеализацияТоваровУслугТовары.НомерСтроки) КАК НомерСтроки,
	|			РеализацияТоваровУслугТовары.Номенклатура КАК Номенклатура,
	|			РеализацияТоваровУслугТовары.Характеристика КАК Характеристика
	|		ИЗ
	|			Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
	|				ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаДанныхДокументов КАК ТаблицаДанныхДокументов
	|				ПО РеализацияТоваровУслугТовары.Ссылка = ТаблицаДанныхДокументов.Ссылка
	|		
	|		СГРУППИРОВАТЬ ПО
	|			РеализацияТоваровУслугТовары.Ссылка,
	|			РеализацияТоваровУслугТовары.Номенклатура,
	|			РеализацияТоваровУслугТовары.Характеристика) КАК ИТ_АкцизыТоваров
	|		ПО ТаблицаДокумента.Ссылка = ИТ_АкцизыТоваров.Ссылка
	|			И ТаблицаДокумента.НомерСтроки = ИТ_АкцизыТоваров.НомерСтроки
	|			И ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура = ИТ_АкцизыТоваров.Номенклатура
	|			И ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика = ИТ_АкцизыТоваров.Характеристика
	#КонецВставки
	|
	|СГРУППИРОВАТЬ ПО
	|	ТаблицаДокумента.Ссылка,
	
	|	ВариантыКомплектацииНоменклатуры.Ссылка,
	|	ВариантыКомплектацииНоменклатуры.ВариантПредставленияНабораВПечатныхФормах,
	|	ВариантыКомплектацииНоменклатуры.ВариантРасчетаЦеныНабора,
	|	ТаблицаДокумента.АналитикаУчетаНаборов.НоменклатураНабора,
	|	ТаблицаДокумента.АналитикаУчетаНаборов.ХарактеристикаНабора,
	
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Номенклатура,
	|	ТаблицаДокумента.АналитикаУчетаНоменклатуры.Характеристика,
	|	ВЫБОР КОГДА &ВыводитьСерии ТОГДА
	|		ТаблицаДокумента.АналитикаУчетаНоменклатуры.Серия
	|	ИНАЧЕ 
	|		ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
	|	КОНЕЦ,
	|	ТаблицаДокумента.СтавкаНДС,
	|	ТаблицаДокумента.Упаковка,
	|	ТаблицаДокумента.Цена,
	|	ТаблицаДокумента.КодТНВЭД,
	|
	|	ВЫБОР КОГДА &ВключаяНомераГТД ТОГДА
	|		ТаблицаДокумента.НомерГТД
	|	ИНАЧЕ
	|		&ПустаяГТД
	|	КОНЕЦ
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	Ссылка,
	|	НомерСтроки
	|;
	|////////////////////////////////////////////////////////////­/////////////////
	|УНИЧТОЖИТЬ СтрокиТоваров
	|";
	
	Если ПараметрыЗаполнения.ОбработатьНастройкиПечатиНаборов Тогда
		
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров", "ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваровДляПреобразования");
		Запрос.Текст = Запрос.Текст + ОбщегоНазначенияУТ.РазделительЗапросовВПакете() +
		"ВЫБРАТЬ
		|	ТаблицаТоваров.Ссылка КАК Ссылка,
		|	ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	МАКСИМУМ(ТаблицаТоваров.ЭтоТовар) КАК ЭтоТовар,
		|	МИНИМУМ(ТаблицаТоваров.НомерСтроки) КАК НомерСтроки,
		|	СУММА(ВЫБОР
		|			КОГДА &ЗаполненаЕдиницаИзмеренияВеса
		|				ТОГДА ВЫБОР
		|						КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
		|							ТОГДА ТаблицаТоваров.Количество
		|						ИНАЧЕ ВЫБОР
		|								КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.Вес)
		|									ТОГДА 0
		|								ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
		|							КОНЕЦ
		|					КОНЕЦ * &ТекстЗапросаВесУпаковки
		|			ИНАЧЕ 0
		|		КОНЕЦ) КАК МассаБрутто,
		|	СУММА(ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры) КАК МассаНетто,
		|	СУММА(ТаблицаТоваров.СуммаБезНДС) КАК СуммаБезНДС,
		|	СУММА(ТаблицаТоваров.СуммаНДС) КАК СуммаНДС
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборыПодготовка
		|ИЗ
		|	РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК ТаблицаТоваров
		|ГДЕ
		|	ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|
		|СГРУППИРОВАТЬ ПО
		|	ТаблицаТоваров.Ссылка,
		|	ТаблицаТоваров.НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	Результат.Ссылка КАК Ссылка,
		|	Результат.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|	Результат.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|	Результат.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|	Результат.НоменклатураНабора КАК НоменклатураНабора,
		|	Результат.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	МАКСИМУМ(ВЫБОР
		|			КОГДА Результат.ОсновнаяКомплектующая
		|				ТОГДА Результат.СтавкаНДС
		|			ИНАЧЕ NULL
		|		КОНЕЦ) КАК СтавкаНДС,
		|	МАКСИМУМ(Результат.НомерГТД) КАК НомерГТД,
		|	МАКСИМУМ(Результат.КодТНВЭД) КАК КодТНВЭД,
		|	(ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
		|				КОГДА Результат.КоличествоПоУмолчанию <> 0
		|						И Результат.ОсновнаяКомплектующая
		|					ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|				ИНАЧЕ NULL
		|			КОНЕЦ) + 0.5 КАК ЧИСЛО(10, 0))) - 1 КАК Количество,
		|	МАКСИМУМ(Результат.КоличествоПоРНПТ) КАК КоличествоПоРНПТ,
		|	МАКСИМУМ(ВЫБОР
		|			КОГДА Результат.КоличествоПоУмолчанию <> 0
		|				ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|			ИНАЧЕ NULL
		|		КОНЕЦ) КАК КоэффициентМаксимум,
		|	(ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
		|				КОГДА Результат.КоличествоПоУмолчанию <> 0
		|					ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
		|				ИНАЧЕ NULL
		|			КОНЕЦ) + 0.5 КАК ЧИСЛО(10, 0))) - 1 КАК КоэффициентМинимум
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительно
		|ИЗ
		|	(ВЫБРАТЬ
		|		Таблица.Ссылка КАК Ссылка,
		|		Таблица.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|		Таблица.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|		Таблица.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|		Таблица.НоменклатураНабора КАК НоменклатураНабора,
		|		Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|		Таблица.Номенклатура КАК Номенклатура,
		|		Таблица.Характеристика КАК Характеристика,
		|		МАКСИМУМ(Таблица.СтавкаНДС) КАК СтавкаНДС,
		|		МАКСИМУМ(Таблица.НомерГТД) КАК НомерГТД,
		|		МАКСИМУМ(Таблица.КодТНВЭД) КАК КодТНВЭД,
		|		МАКСИМУМ(Таблица.ОсновнаяКомплектующая) КАК ОсновнаяКомплектующая,
		|		СУММА(Таблица.КоличествоПоУмолчанию) КАК КоличествоПоУмолчанию,
		|		СУММА(Таблица.Количество) КАК Количество,
		|		СУММА(Таблица.КоличествоПоРНПТ) КАК КоличествоПоРНПТ
		|	ИЗ
		|		(ВЫБРАТЬ
		|			Товары.Ссылка КАК Ссылка,
		|			Товары.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|			Товары.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
		|			Товары.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
		|			Товары.НоменклатураНабора КАК НоменклатураНабора,
		|			Товары.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|			Товары.Номенклатура КАК Номенклатура,
		|			Товары.Характеристика КАК Характеристика,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА ИСТИНА
		|				ИНАЧЕ ЛОЖЬ
		|			КОНЕЦ КАК ОсновнаяКомплектующая,
		|			Товары.СтавкаНДС КАК СтавкаНДС,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.НомерГТД
		|				ИНАЧЕ NULL
		|			КОНЕЦ КАК НомерГТД,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.КодТНВЭД
		|				ИНАЧЕ NULL
		|			КОНЕЦ КАК КодТНВЭД,
		|			0 КАК КоличествоПоУмолчанию,
		|			Товары.Количество КАК Количество,
		|			ВЫБОР
		|				КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
		|						И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика
		|					ТОГДА Товары.КоличествоПоРНПТ
		|				ИНАЧЕ 0
		|			КОНЕЦ КАК КоличествоПоРНПТ
		|		ИЗ
		|			РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК Товары
		|		ГДЕ
		|			Товары.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|		
		|		ОБЪЕДИНИТЬ ВСЕ
		|		
		|		ВЫБРАТЬ
		|			ТаблицаДанныхДокументов.Ссылка,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантПредставленияНабораВПечатныхФормах,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантРасчетаЦеныНабора,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец,
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика,
		|			ВариантыКомплектацииНоменклатурыТовары.Номенклатура,
		|			ВариантыКомплектацииНоменклатурыТовары.Характеристика,
		|			ЛОЖЬ,
		|			NULL,
		|			NULL,
		|			NULL,
		|			ВариантыКомплектацииНоменклатурыТовары.Количество,
		|			0,
		|			0
		|		ИЗ
		|			Справочник.ВариантыКомплектацииНоменклатуры.Товары КАК ВариантыКомплектацииНоменклатурыТовары
		|				ЛЕВОЕ СОЕДИНЕНИЕ ТаблицаДанныхДокументов КАК ТаблицаДанныхДокументов
		|				ПО (ИСТИНА)
		|		ГДЕ
		|			ВариантыКомплектацииНоменклатурыТовары.Ссылка В
		|					(ВЫБРАТЬ
		|						РеализацияТоваровУслугТаблицаТоваровДляПреобразования.ВариантКомплектацииНоменклатуры
		|					ИЗ
		|						РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК РеализацияТоваровУслугТаблицаТоваровДляПреобразования)) КАК Таблица
		|	
		|	СГРУППИРОВАТЬ ПО
		|		Таблица.Ссылка,
		|		Таблица.ВариантКомплектацииНоменклатуры,
		|		Таблица.ВариантРасчетаЦеныНабора,
		|		Таблица.ВариантПредставленияНабораВПечатныхФормах,
		|		Таблица.НоменклатураНабора,
		|		Таблица.ХарактеристикаНабора,
		|		Таблица.Номенклатура,
		|		Таблица.Характеристика) КАК Результат
		|
		|СГРУППИРОВАТЬ ПО
		|	Результат.Ссылка,
		|	Результат.ВариантКомплектацииНоменклатуры,
		|	Результат.ВариантРасчетаЦеныНабора,
		|	Результат.ВариантПредставленияНабораВПечатныхФормах,
		|	Результат.НоменклатураНабора,
		|	Результат.ХарактеристикаНабора
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	Результат.Ссылка,
		|	Результат.НоменклатураНабора,
		|	Результат.ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	ВременнаяТаблицаНаборыДополнительно.ВариантКомплектацииНоменклатуры КАК ВариантКомплектацииНоменклатуры,
		|	ВЫБОР
		|		КОГДА ВЫРАЗИТЬ(Таблица.Ссылка КАК Документ.РеализацияТоваровУслуг).ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
		|			ТОГДА ВЫБОР
		|					КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
		|						ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|					ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|				КОНЕЦ
		|		ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|	КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
		|	ВЫБОР
		|		КОГДА ВЫРАЗИТЬ(Таблица.Ссылка КАК Документ.РеализацияТоваровУслуг).ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию)
		|			ТОГДА ВЫБОР
		|					КОГДА ВЫБОР
		|								КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор)
		|									ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|								ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
		|							КОНЕЦ = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
		|							И ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора В (ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоЦенам), ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоДолям))
		|						ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.РассчитываетсяИзЦенКомплектующих)
		|					ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
		|				КОНЕЦ
		|		ИНАЧЕ ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
		|	КОНЕЦ КАК ВариантРасчетаЦеныНабора,
		|	Таблица.Ссылка КАК Ссылка,
		|	Таблица.НоменклатураНабора КАК НоменклатураНабора,
		|	Таблица.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	Таблица.НомерСтроки КАК НомерСтроки,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.НомерГТД, ЗНАЧЕНИЕ(Справочник.НомераГТД.ПустаяСсылка)) КАК НомерГТД,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.КодТНВЭД, ЗНАЧЕНИЕ(Справочник.КлассификаторТНВЭД.ПустаяСсылка)) КАК КодТНВЭД,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК КоличествоУпаковок,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК Количество,
		|	ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.КоличествоПоРНПТ, 1) КАК КоличествоПоРНПТ,
		|	ВЫБОР
		|		КОГДА ВременнаяТаблицаНаборыДополнительно.КоэффициентМинимум = ВременнаяТаблицаНаборыДополнительно.КоэффициентМаксимум
		|			ТОГДА ИСТИНА
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ПолныйНабор,
		|	Таблица.МассаБрутто КАК МассаБрутто,
		|	Таблица.МассаНетто КАК МассаНетто,
		|	Таблица.СуммаБезНДС КАК СуммаБезНДС,
		|	Таблица.СуммаНДС КАК СуммаНДС,
		|	Таблица.ЭтоТовар КАК ЭтоТовар,
		|	ВременнаяТаблицаНаборыДополнительно.СтавкаНДС КАК СтавкаНДС
		|ПОМЕСТИТЬ ВременнаяТаблицаНаборы
		|ИЗ
		|	ВременнаяТаблицаНаборыПодготовка КАК Таблица
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборыДополнительно КАК ВременнаяТаблицаНаборыДополнительно
		|		ПО Таблица.НоменклатураНабора = ВременнаяТаблицаНаборыДополнительно.НоменклатураНабора
		|			И Таблица.ХарактеристикаНабора = ВременнаяТаблицаНаборыДополнительно.ХарактеристикаНабора
		|			И Таблица.Ссылка = ВременнаяТаблицаНаборыДополнительно.Ссылка
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	Ссылка,
		|	НоменклатураНабора,
		|	ХарактеристикаНабора
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|ВЫБРАТЬ
		|	ТаблицаТоваров.Ссылка КАК Ссылка,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах
		|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)
		|	КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора
		|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)
		|	КОНЕЦ КАК ВариантРасчетаЦеныНабора,
		|	ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
		|	ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ИСТИНА
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ЭтоКомплектующие,
		|	ЛОЖЬ КАК ЭтоНабор,
		|	ТаблицаТоваров.НомерСтроки КАК НомерСтроки,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.НомерСтроки
		|		ИНАЧЕ ТаблицаТоваров.НомерСтроки
		|	КОНЕЦ КАК НомерСтрокиНаборы,
		|	ВЫБОР
		|		КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0
		|			ТОГДА ВременнаяТаблицаНаборы.ПолныйНабор
		|		ИНАЧЕ ЛОЖЬ
		|	КОНЕЦ КАК ПолныйНабор,
		|	ТаблицаТоваров.Номенклатура КАК Номенклатура,
		|	ТаблицаТоваров.Количество КАК Количество,
		|	ТаблицаТоваров.КоличествоУпаковок КАК КоличествоУпаковок,
		|	ТаблицаТоваров.КоличествоПоРНПТ КАК КоличествоПоРНПТ,
		|	ТаблицаТоваров.СтавкаНДС КАК СтавкаНДС,
		|	ТаблицаТоваров.НомерГТД КАК НомерГТД,
		|	ТаблицаТоваров.КодТНВЭД КАК КодТНВЭД,
		|	ТаблицаТоваров.СуммаБезНДС КАК СуммаБезНДС,
		|	ТаблицаТоваров.СуммаНДС КАК СуммаНДС,
		|	ТаблицаТоваров.Характеристика КАК Характеристика,
		|	ТаблицаТоваров.Серия КАК Серия,
		|	ТаблицаТоваров.Упаковка КАК Упаковка,
		|	ВЫБОР
		|		КОГДА &ЗаполненаЕдиницаИзмеренияВеса
		|			ТОГДА ВЫБОР
		|					КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
		|						ТОГДА ТаблицаТоваров.Количество
		|					ИНАЧЕ ВЫБОР
		|							КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.Вес)
		|								ТОГДА 0
		|							ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
		|						КОНЕЦ
		|				КОНЕЦ * &ТекстЗапросаВесУпаковки
		|		ИНАЧЕ 0
		|	КОНЕЦ КАК МассаБрутто,
		|	ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры КАК МассаНетто,
		|	ТаблицаТоваров.ЭтоТовар КАК ЭтоТовар
		|ПОМЕСТИТЬ РеализацияТоваровУслугТаблицаТоваров
		|ИЗ
		|	РеализацияТоваровУслугТаблицаТоваровДляПреобразования КАК ТаблицаТоваров
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
		|		ПО (ВременнаяТаблицаНаборы.НоменклатураНабора = ТаблицаТоваров.НоменклатураНабора)
		|			И (ВременнаяТаблицаНаборы.ХарактеристикаНабора = ТаблицаТоваров.ХарактеристикаНабора)
		|			И (ВременнаяТаблицаНаборы.Ссылка = ТаблицаТоваров.Ссылка)
		|ГДЕ
		|	(ТаблицаТоваров.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|			ИЛИ ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
		|				И ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоКомплектующие), ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)))
		|
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	ВременнаяТаблицаНаборы.Ссылка,
		|	ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах,
		|	ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора,
		|	ВременнаяТаблицаНаборы.НоменклатураНабора,
		|	ВременнаяТаблицаНаборы.ХарактеристикаНабора,
		|	ЛОЖЬ,
		|	ИСТИНА,
		|	ВременнаяТаблицаНаборы.НомерСтроки,
		|	ВременнаяТаблицаНаборы.НомерСтроки,
		|	ВременнаяТаблицаНаборы.ПолныйНабор,
		|	ВременнаяТаблицаНаборы.НоменклатураНабора,
		|	ВременнаяТаблицаНаборы.Количество,
		|	ВременнаяТаблицаНаборы.КоличествоУпаковок,
		|	ВременнаяТаблицаНаборы.КоличествоПоРНПТ,
		|	ВременнаяТаблицаНаборы.СтавкаНДС,
		|	ВременнаяТаблицаНаборы.НомерГТД,
		|	ВременнаяТаблицаНаборы.КодТНВЭД,
		|	ВременнаяТаблицаНаборы.СуммаБезНДС,
		|	ВременнаяТаблицаНаборы.СуммаНДС,
		|	ВременнаяТаблицаНаборы.ХарактеристикаНабора,
		|	ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка),
		|	ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка),
		|	ВременнаяТаблицаНаборы.МассаБрутто,
		|	ВременнаяТаблицаНаборы.МассаНетто,
		|	ВременнаяТаблицаНаборы.ЭтоТовар
		|ИЗ
		|	ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
		|ГДЕ
		|	ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор), ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие))
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборыПодготовка
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборыДополнительно
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ ВременнаяТаблицаНаборы
		|;
		|
		|////////////////////////////////////////////////////////////­////////////////////
		|УНИЧТОЖИТЬ РеализацияТоваровУслугТаблицаТоваровДляПреобразования";		
		
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ТекстЗапросаВесУпаковки",
			Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
				"ТаблицаТоваров.Упаковка",
				"ТаблицаТоваров.Номенклатура"));
			
		Запрос.Текст = СтрЗаменить(
			Запрос.Текст, 
			"&ТекстЗапросаВесНоменклатуры",
			Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
				"ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения",
				"ТаблицаТоваров.Номенклатура"));
		Запрос.УстановитьПараметр("ЗаполненаЕдиницаИзмеренияВеса",   ЗначениеЗаполнено(Константы.ЕдиницаИзмеренияВеса.Получить()));
		
	КонецЕсли;
	
	Запрос.Выполнить();
	
КонецПроцедуры

&ИзменениеИКонтроль("ТекстВыручкаОтРеализацииСобственногоТовара")
Функция ИТ_ТекстВыручкаОтРеализацииСобственногоТовара()
	
	ТекстВыручкаОтРеализацииСобственногоТовара = "
	|ВЫБРАТЬ //// Выручка от реализации собственного товара (Дт 62.01 :: Кт 90.01.1)
	|	Операция.Ссылка КАК Ссылка,
	|	ВЫБОР КОГДА Операция.ХозяйственнаяОперация В
	|				(ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|				 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|		ТОГДА Операция.ДатаПереходаПраваСобственности
	|		ИНАЧЕ Операция.Дата
	|	КОНЕЦ КАК Период,
	|	Операция.Организация КАК Организация,
	|	НЕОПРЕДЕЛЕНО КАК ИдентификаторСтроки,
	|
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл + Суммы.СуммаНДСРегл, Строки.СуммаСНДС) КАК Сумма,
	|	ЕСТЬNULL(Суммы.СуммаБезНДСУпр + Суммы.СуммаНДСУпр, Строки.СуммаСНДС / КурсВалютыУпрУчета.Курс) КАК СуммаУУ,
	|
	|	ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.РасчетыСКлиентами) КАК ВидСчетаДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.ГруппаФинансовогоУчета, Расчеты.ГруппаФинансовогоУчета) КАК АналитикаУчетаДт,
	|	НЕОПРЕДЕЛЕНО КАК МестоУчетаДт,
	|
	|	Операция.ВалютаВзаиморасчетов КАК ВалютаДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.Подразделение, Расчеты.Подразделение) КАК ПодразделениеДт,
	|	ЕСТЬNULL(РасчетыПоЗаказам.НаправлениеДеятельности, Расчеты.НаправлениеДеятельности) КАК НаправлениеДеятельностиДт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетДт,
	|
	|	ЕСТЬNULL(РасчетыПоЗаказам.Контрагент, Расчеты.Контрагент) КАК СубконтоДт1,
	|	ЕСТЬNULL(РасчетыПоЗаказам.Договор, Расчеты.Договор) КАК СубконтоДт2,
	|	НЕОПРЕДЕЛЕНО КАК СубконтоДт3,
	|
	|	Строки.СуммаВзаиморасчетов КАК ВалютнаяСуммаДт,
	|	Строки.Количество КАК КоличествоДт,
	|	0 КАК СуммаНУДт,
	|	0 КАК СуммаПРДт,
	|	0 КАК СуммаВРДт,
	|
	|	ВЫБОР КОГДА Операция.НалогообложениеНДС = ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяЕНВД)
	|		ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ВыручкаОтПродажЕНВД)
	|		ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ВидыСчетовРеглУчета.ВыручкаОтПродаж)
	|	КОНЕЦ КАК ВидСчетаКт,
	|	ВЫБОР КОГДА &ФормироватьВидыЗапасовПоГруппамФинансовогоУчета ТОГДА
	|		Строки.ВидЗапасов.ГруппаФинансовогоУчета
	|	ИНАЧЕ
	|		Строки.АналитикаУчетаНоменклатуры.Номенклатура.ГруппаФинансовогоУчета
	|	КОНЕЦ КАК АналитикаУчетаКт,
	|	ВЫБОР
	|		КОГДА Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионера),
	|				ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|		ТОГДА ЗНАЧЕНИЕ(Справочник.Склады.ПустаяСсылка)
	|		ИНАЧЕ Строки.АналитикаУчетаНоменклатуры.МестоХранения
	|	КОНЕЦ КАК МестоУчетаКт,
	|
	|	ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК ВалютаКт,
	|	Операция.Подразделение КАК ПодразделениеКт,
	|	Операция.НаправлениеДеятельности КАК НаправлениеДеятельностиКт,
	|
	|	ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка) КАК СчетКт,
	|
	|	ВЫБОР КОГДА &ФормироватьВидыЗапасовПоГруппамФинансовогоУчета ТОГДА
	|		Строки.ВидЗапасов.ГруппаФинансовогоУчета
	|	ИНАЧЕ
	|		Строки.АналитикаУчетаНоменклатуры.Номенклатура.ГруппаФинансовогоУчета
	|	КОНЕЦ КАК СубконтоКт1,
	|	Строки.СтавкаНДС.ПеречислениеСтавкаНДС КАК СубконтоКт2,
	|	Строки.АналитикаУчетаНоменклатуры.Номенклатура КАК СубконтоКт3,
	|
	|	0 КАК ВалютнаяСуммаКт,
	|	Строки.Количество КАК КоличествоКт,
	#Вставка
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл, Строки.СуммаСНДС - Строки.СуммаНДС) - ЕСТЬNULL(СтрокиТовары.ИТ_Акциз, 0) КАК СуммаНУКт,
	#КонецВставки
	#Удаление
	|	ЕСТЬNULL(Суммы.СуммаБезНДСРегл, Строки.СуммаСНДС - Строки.СуммаНДС) КАК СуммаНУКт,
	#КонецУдаления
	|	0 КАК СуммаПРКт,
	|	0 КАК СуммаВРКт,
	|	""Выручка от реализации собственного товара"" КАК Содержание
	|
	|ИЗ
	|	ДокументыКОтражению КАК ДокументыКОтражению
	|	
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг КАК Операция
	|	ПО
	|		ДокументыКОтражению.Ссылка = Операция.Ссылка
	|
	|	ВНУТРЕННЕЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.ВидыЗапасов КАК Строки
	|	ПО
	|		(Строки.Ссылка = Операция.Ссылка)
	|
	#Вставка
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
	|	ПО
	|		Строки.Ссылка = СтрокиТовары.Ссылка
	|		И Строки.НомерСтроки = СтрокиТовары.НомерСтроки
	|
	#КонецВставки
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		РегистрСведений.СуммыДокументовВВалютахУчета КАК Суммы
	|	ПО
	|		Строки.Ссылка = Суммы.Регистратор
	|		И Строки.ИдентификаторСтроки = Суммы.ИдентификаторСтроки
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		ВТРасчетыСКлиентамиПоЗаказам КАК РасчетыПоЗаказам
	|	ПО 
	|		Операция.Ссылка = РасчетыПоЗаказам.Ссылка
	|		И Строки.ЗаказКлиента = РасчетыПоЗаказам.Заказ
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		ВТРасчетыСКлиентамиПоЗаказам КАК Расчеты
	|	ПО 
	|		Операция.Ссылка = Расчеты.Ссылка
	|		И Расчеты.Заказ = НЕОПРЕДЕЛЕНО
	|		И Расчеты.СуммаРегл <> 0
	|
	|	ЛЕВОЕ СОЕДИНЕНИЕ
	|		КурсыВалют КАК КурсВалютыУпрУчета
	|	ПО
	|		КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета
	|		И КурсВалютыУпрУчета.Дата = ВЫБОР КОГДА Операция.ХозяйственнаяОперация В
	|			(ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|			 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|			ТОГДА Операция.ДатаПереходаПраваСобственности ИНАЧЕ НАЧАЛОПЕРИОДА(Операция.Дата, День) КОНЕЦ
	|	
	|ГДЕ
	|	Строки.ВидЗапасов.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.Товар)
	|	И (Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту),
	|										 ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионера))
	|			И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|		ИЛИ Операция.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиентуРеглУчет)
	|			И Операция.Статус <> ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.КПредоплате)
	|		ИЛИ Операция.ХозяйственнаяОперация В (ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияБезПереходаПраваСобственности),
	|											  ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияЧерезКомиссионераБезПереходаПраваСобственности))
	|			И Операция.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыРеализацийТоваровУслуг.Отгружено))
	|	И (
	|		ВЫБОР КОГДА Операция.ВернутьМногооборотнуюТару ТОГДА
	|			Строки.АналитикаУчетаНоменклатуры.Номенклатура.ТипНоменклатуры <> ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
	|		ИНАЧЕ
	|			ИСТИНА
	|		КОНЕЦ)
	|";
	Возврат ТекстВыручкаОтРеализацииСобственногоТовара;
	
КонецФункции

#КонецОбласти
Показать


Ну и само собой переделываем "Отчет.РегламентированныйОтчетАкцизыТабак.Форма.ФормаОтчета2020Кв1.Форма.Модуль" что бы акциз заполнялся по регистру.

Надеюсь ничего не пропустил.


Помните:
Что помимо проводк, при отражении продажи нужно убавлять налоговую прибыль "СуммаНУКт" на размер акциза.
и в регистре накопления "Выручка и себестоимость продаж" нужно акциз отразить в полях "ДопРасходы" и "Доп.раходы без НДС"
Прикрепленные файлы:
Оставьте свое сообщение