Сверка данных между базами УТ и БП по складам

На форме нужно заполнить отборы и параметры соединения с бухгалтерской базой.

Галка "Только различия" убирает из отчета строки с одинаковым количеством.

Если у вас используется интеркампани, тогда корректными будут только данные после оформления всех передач товаров между организациями.

Выбор счета добавлен для варианта, когда различные виды номенклатуры находятся на разных складах (склад готовой продукции, склад материалов и т.п.)

Запрос к базе БП:

    Запрос = База.NewObject("Запрос");
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ХозрасчетныйОстатки.Счет.Представление КАК СчетПредставление,
    |    ХозрасчетныйОстатки.Счет.Код КАК СчетКод,
    |    ХозрасчетныйОстатки.Организация.Наименование КАК ОрганизацияНаименование,
    |    ХозрасчетныйОстатки.Организация.ИНН КАК ОрганизацияИНН,
    |    ХозрасчетныйОстатки.Организация.КПП КАК ОрганизацияКПП,
    |    ХозрасчетныйОстатки.Субконто1.Наименование КАК Субконто1Наименование,
    |    ХозрасчетныйОстатки.Субконто3.Наименование КАК Субконто3Наименование,
    |    СУММА(ХозрасчетныйОстатки.СуммаОстаток) КАК СуммаОстаток,
    |    СУММА(ХозрасчетныйОстатки.СуммаОстатокДт) КАК СуммаОстатокДт,
    |    СУММА(ХозрасчетныйОстатки.СуммаОстатокКт) КАК СуммаОстатокКт,
    |    СУММА(ХозрасчетныйОстатки.КоличествоОстаток) КАК КоличествоОстаток,
    |    СУММА(ХозрасчетныйОстатки.КоличествоОстатокДт) КАК КоличествоОстатокДт,
    |    СУММА(ХозрасчетныйОстатки.КоличествоОстатокКт) КАК КоличествоОстатокКт
    |ИЗ
    |    РегистрБухгалтерии.Хозрасчетный.Остатки(
    |            &Дата,
    |            Счет В ИЕРАРХИИ (&Счет),
    |            ,
    |            Организация = &Организация
    |                "+?(ЗначениеЗаполнено(Склад),"и Субконто3 = &Субконто3","")+") КАК ХозрасчетныйОстатки
    |
    |СГРУППИРОВАТЬ ПО
    |    ХозрасчетныйОстатки.Организация.Наименование,
    |    ХозрасчетныйОстатки.Организация.ИНН,
    |    ХозрасчетныйОстатки.Организация.КПП,
    |    ХозрасчетныйОстатки.Субконто1.Наименование,
    |    ХозрасчетныйОстатки.Субконто3.Наименование,
    |    ХозрасчетныйОстатки.Счет.Представление,
    |    ХозрасчетныйОстатки.Счет.Код";

Сумма в отчете по умолчанию не выводится, можно добавить, если у вас в БП есть суммовой учет по субконто склад.

Запрос в УТ:

    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ТадБП30.СчетПредставление КАК СчетПредставление,
    |    ТадБП30.СчетКод КАК СчетКод,
    |    ТадБП30.ОрганизацияНаименование КАК ОрганизацияНаименование,
    |    ТадБП30.ОрганизацияИНН КАК ОрганизацияИНН,
    |    ТадБП30.ОрганизацияКПП КАК ОрганизацияКПП,
    |    ТадБП30.Субконто1Наименование КАК НоменклатураНаименование,
    |    ТадБП30.Субконто3Наименование КАК СкладНаименование,
    |    ТадБП30.СуммаОстаток КАК СуммаОстаток,
    |    ТадБП30.СуммаОстатокДт КАК СуммаОстатокДт,
    |    ТадБП30.СуммаОстатокКт КАК СуммаОстатокКт,
    |    ТадБП30.КоличествоОстаток КАК КоличествоОстаток,
    |    ТадБП30.КоличествоОстатокДт КАК КоличествоОстатокДт,
    |    ТадБП30.КоличествоОстатокКт КАК КоличествоОстатокКт
    |ПОМЕСТИТЬ ТадБП
    |ИЗ
    |    &ТадБП30 КАК ТадБП30
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.Организация.Наименование, ТадБП.ОрганизацияНаименование) КАК Организация,
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.МестоХранения.Наименование, ТадБП.СкладНаименование) КАК АналитикаУчетаНоменклатурыМестоХранения,
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.Номенклатура.Наименование, ТадБП.НоменклатураНаименование) КАК АналитикаУчетаНоменклатурыНоменклатура,
    |    СУММА(ЕСТЬNULL(ТоварыОрганизацийОстатки.КоличествоОстаток, 0)) КАК ОстатокУТ,
    |    ЕСТЬNULL(ТадБП.СчетКод, ""-"") КАК СчетКод,
    |    СУММА(ТадБП.СуммаОстаток) КАК СуммаОстаток,
    |    СУММА(ТадБП.СуммаОстатокДт) КАК СуммаОстатокДт,
    |    СУММА(ТадБП.СуммаОстатокКт) КАК СуммаОстатокКт,
    |    СУММА(ЕСТЬNULL(ТадБП.КоличествоОстаток, 0)) КАК КоличествоОстаток,
    |    СУММА(ТадБП.КоличествоОстатокДт) КАК КоличествоОстатокДт,
    |    СУММА(ТадБП.КоличествоОстатокКт) КАК КоличествоОстатокКт
    |ИЗ
    |    РегистрНакопления.ТоварыОрганизаций.Остатки(
    |            &Дата,
    |            АналитикаУчетаНоменклатуры.МестоХранения = &Склад
    |                И Организация = &Организация) КАК ТоварыОрганизацийОстатки
    |        ПОЛНОЕ СОЕДИНЕНИЕ ТадБП КАК ТадБП
    |        ПО ТоварыОрганизацийОстатки.Организация.ИНН = ТадБП.ОрганизацияИНН
    |            И ТоварыОрганизацийОстатки.Организация.КПП = ТадБП.ОрганизацияКПП
    |            И ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.МестоХранения.Наименование = ТадБП.СкладНаименование
    |            И ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.Номенклатура.Наименование = ТадБП.НоменклатураНаименование
    |
    |СГРУППИРОВАТЬ ПО
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.Организация.Наименование, ТадБП.ОрганизацияНаименование),
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.МестоХранения.Наименование, ТадБП.СкладНаименование),
    |    ЕСТЬNULL(ТоварыОрганизацийОстатки.АналитикаУчетаНоменклатуры.Номенклатура.Наименование, ТадБП.НоменклатураНаименование),
    |    ЕСТЬNULL(ТадБП.СчетКод, ""-"")";
    
    Если ТолькоРазличия Тогда
        Запрос.Текст = Запрос.Текст +
        "
        |
        |ИМЕЮЩИЕ
        |    СУММА(ЕСТЬNULL(ТадБП.КоличествоОстаток,0)) <> СУММА(ЕСТЬNULL(ТоварыОрганизацийОстатки.КоличествоОстаток,0))";
        
    КонецЕсли;

Тестировалась на платформе 1С:Предприятие 8.3 (8.3.20.1789).

Конфигурации баз: Управление торговлей, редакция 11 (11.4.13.227) и Бухгалтерия предприятия КОРП, редакция 3.0 (3.0.110.24).