Оперативная доработка отчетов без обновления конфигурации или расширения

Публикация № 1058689

Программирование - Практика программирования

7
В статье рассматривается вариант оперативной доработки отчетов при помощи механизма дополнительных отчетов и обработок и небольшой модификации конфигурации.

Многие сталкиваются с проблемой, что тот или иной разрабатываемый отчет нужно срочно переделать под новые требования или исправить ошибки при формировании. Для этого нужно внести правки в конфигурацию (расширение) и обновить ее, а это не всегда возможно, когда с базой работает большое число пользователей. Вдохновившись статьями: //infostart.ru/public/169131/ и //infostart.ru/public/16980/ решил сделать следующий механизм.

Данный механизм применим ко всем типовым конфигурациям на осонове БСП.

Без правки конфигурации здесь дело не обошлось, но 

  • 1. Правки минимальны: в конфигурацию добавляются 3 элемента: общая форма, подписка на событие, общий модуль.
  • 2. Функционал можно переложить в расширение ( в случае, если конфигурация на поддержке)

Создаем подписку на событие "ОбработкаПолученияФормы" для источника "ОтчетМенеджер".

Создаем обработчик в общем модуле:


Процедура ОперативнаяДоработкаОтчетовОбработкаПолученияФормы(Источник, ВидФормы, Параметры, ВыбраннаяФорма, ДополнительнаяИнформация, СтандартнаяОбработка) Экспорт
	
	ИмяОтчета = СтрЗаменить(Строка(Источник),"ОтчетМенеджер.","");
	
	ДопОтчет = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию("ДопОтчет_" + ИмяОтчета, Истина);
	Если ЗначениеЗаполнено(ДопОтчет) Тогда
		
		Попытка
			ВерсияОтчета = Отчеты[ИмяОтчета].СоздатьОбъект().ПолучитьВерсиюОтчета();
		Исключение
			ВерсияОтчета = "0.0";
		КонецПопытки;
		
		Если ДопОтчет.Версия <> ВерсияОтчета Тогда
			СтандартнаяОбработка = Ложь;
			ИмяВнешнегоОтчета = ДополнительныеОтчетыИОбработки.ПодключитьВнешнююОбработку(ДопОтчет);
			ВыбраннаяФорма = "ОбщаяФорма.ФормаОткрытияДополнительныхОтчетов";
			Параметры.Вставить("ИмяВнешнегоОтчета", ИмяВнешнегоОтчета);
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

В обработчике события ищем дополнительный отчет в справочнике "ДополнительныеОтчетыИОбработки"по имени отчета с префиксом "ДопОтчет_". В экспортной процедуре "ПолучитьВерсиюОтчета", если она существует, получаем последнюю версию отчета и сравниваем ее с версией дополнительного отчета. Если они различны, подключаем его и открываем общую форму, с ключевым параметром "ИмяВнешнегоОтчета".

В которую передаем имя подключенного отчета, открываем его и закрываем общую форму.

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	Закрыть();
	Если Параметры.ИмяВнешнегоОтчета = "" Тогда
		Предупреждение("Отчет не найден, обратитесь к администратору");
	Иначе
		ОткрытьФорму("ВнешнийОтчет." + Параметры.ИмяВнешнегоОтчета + ".Форма");
	КонецЕсли;
	
КонецПроцедуры

В дополнительном отчете необходимо создать процедуру получения версии отчета. Это необходимо для простой и удобной замены отчета в конфигурации. Ниже листинг дополнительного отчета.

Функция СведенияОВнешнейОбработке() Экспорт

    РегистрационныеДанные = Новый Структура;
    РегистрационныеДанные.Вставить("Наименование",		"ДопОтчет_" + ПолучитьИмяВнешнейОбработки());
    РегистрационныеДанные.Вставить("БезопасныйРежим",		Ложь);
    РегистрационныеДанные.Вставить("Вид",			"ДополнительныйОтчет");
    РегистрационныеДанные.Вставить("Версия",			ПолучитьВерсиюОбъекта());
    РегистрационныеДанные.Вставить("Информация",		ПолучитьИмяВнешнейОбработки());
    
    ///////////// Команды /////////////////////////
    тзКоманд = Новый ТаблицаЗначений;
    тзКоманд.Колонки.Добавить("Идентификатор",			Новый ОписаниеТипов("Строка"));
    тзКоманд.Колонки.Добавить("Представление",			Новый ОписаниеТипов("Строка"));
    тзКоманд.Колонки.Добавить("Модификатор",			Новый ОписаниеТипов("Строка"));
    тзКоманд.Колонки.Добавить("ПоказыватьОповещение",		Новый ОписаниеТипов("Булево"));
    тзКоманд.Колонки.Добавить("Использование",			Новый ОписаниеТипов("Строка"));
    
    РегистрационныеДанные.Вставить("Команды", тзКоманд);
    
    Возврат РегистрационныеДанные;

КонецФункции

Функция ПолучитьВерсиюОбъекта() Экспорт
	Возврат "1.1";
КонецФункции

Функция ПолучитьИмяВнешнейОбработки()
	Возврат "ИмяВнешнейОбработки";	
КонецФункции

Важно! Данный метод работает при условии открытия стандартных форм объекта. Например, "ОткрытьФорму("Отчет.ИмяОтчета.ФормаОбъекта", ""ОткрытьФорму("Отчет.ИмяОтчета.ФормаВарианта", ""ОткрытьФорму("Отчет.ИмяОтчета.ФормаНастроек". Если открывать конкретную форму "ОткрытьФорму("Отчет.ИмяОтчета.Форма.ФормаНеосновная")", тогда обработчик срабатывать не будет.

Так же, в виду отсутствия в дополнительной обработке модуля менеджера заменить или дополнить процедуры менеджера оперативно не получится.

Спасибо за внимание!

P. S.: Отдельное спасибо за помощь "SlavaKron" в решении проблемы открытия формы дополнительного отчета в теме на форуме https://forum.infostart.ru/forum9/topic217101/

Жду конструктивной критики.

7

См. также

Специальные предложения

Избранное Подписка Сортировка: Древо
В этой теме еще нет сообщений.
Оставьте свое сообщение