Методика переопределения и вызова обработчиков событий обычной формы

11.05.18

Разработка - Механизмы платформы 1С

Каждый из нас хотя бы раз задумывался над тем, как было бы удобно, если бы мы могли переопределять обработчики событий формы, сохраняя возможность вызова старого обработчика независимо от его имени. В этой статье изложен метод, который позволяет реализовать эту возможность.

 

Например, есть конфигурация, которая является доработанной типовой. Вы ее постоянно обновляете и добавляете все больше своих изменений. Обновлять в общем случае с каждым разом становится все труднее и дольше. Заметную часть ваший доработок составляют вставки в начало и конец обработчиков событий формы. А также новые обработчики, которые некоторые еще и назначают в режиме редактирования конфигурации (статически), что дополнительно затрудняет процесс обновления.

Предлагаемый метод состоит в том, чтобы объявить в модуле формы свои обработчики событий, которые будут вызывать старые обработчики и выполнять нужный код до и после этого вызова. Установка новых обработчиков будет производиться в разделе основной программы модуля формы путем вызова общей процедуры, скажем "УстановитьДействиеФормы". Эта процедура в динамически добавленном невидимом элементе формы будет сохранять все старые обработчики для каждого переопределенного события, что позволит довольно просто вызывать их через общую функцию, скажем "ПолучитьСтароеДействиеФормы". Следуя рекомендациям 1С, а также для удобства возьмем за правило: имена новых обработчиков следует формировать как <Префикс>[<ИмяЭлементаФормы>][<ИмяСубэлемента1>...<ИмяСубэлементаN>][<ИмяСобытия>] и параметры их называть стандартно. Субэлементы - элементы внутри элементов формы. Индексы субэлементов означают уровень вложенности.

Случай 1. Добавляем вставку в начало и конец имеющихся в типовой обработчиков событий формы.
Обычно делают примерно так.
// Процедура - обработчик события "ПередОткрытием" формы.
//
Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в начало обработчика>
	// }}Добавил TormozIT 23.03.2006

	<Текст тела типового обработчика>

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в конец  обработчика>
	// }}Добавил TormozIT 23.03.2006
 
КонецПроцедуры // ПередОткрытием()

// Процедура - обработчик события "ПриИзменении" поля ввода "Склад".
//
Процедура СкладПриИзмененииВыбора(Элемент)

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в начало обработчика>
	// }}Добавил TormozIT 23.03.2006
	
	<Текст тела типового обработчика>

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в конец  обработчика>
	// }}Добавил TormozIT 23.03.2006

КонецПроцедуры // СкладПриИзменении()

// Процедура - обработчик события "НачалоВыбора" элемента "Товары.ЗаказПокупателя".
// (Событие "НачалоВыбора" поля ввода "ЗаказПокупателя"
// в строке табличной части "Товары")
//
Процедура ТоварыЗаказПокупателяНачалоВыбора(Элемент, СтандартнаяОбработка)
	
	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в начало обработчика>
	// }}Добавил TormozIT 23.03.2006
	
	<Текст тела типового обработчика>

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в конец  обработчика>
	// }}Добавил TormozIT 23.03.2006
	
КонецПроцедуры // ТоварыЗаказПокупателяНачалоВыбора()


// Процедура - обработчик события кнопки "КнопкаВыбратьВвестиХарактеристику" командной панели "ОсновныеДействияФормы".
//
Процедура ОсновныеДействияФормыКнопкаВыбратьВвестиХарактеристику(Кнопка)
	
	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в начало обработчика>
	// }}Добавил TormozIT 23.03.2006
	
	<Текст тела типового обработчика>

	// {{Добавил TormozIT 23.03.2006
	<Текст вставки в конец  обработчика>
	// }}Добавил TormozIT 23.03.2006

КонецПроцедуры // ОсновныеДействияФормыКнопкаВыбратьВвестиХарактеристику()

Все работает и выглядит неплохо. Однако после обновления нам приходится вручную вносить это в новую версию обработчика, если в нем произошли изменения по отношению к старому релизу.

Теперь следует делать так.
// {{Добавил TormozIT 23.03.2006

// Процедура - обработчик события "ПередОткрытием" элемента формы "". 
// 
Процедура ЛксПередОткрытием(Отказ, СтандартнаяОбработка)
	
	<Текст вставки в начало обработчика>
	[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "ПередОткрытием"));]
	<Текст вставки в конец  обработчика>
	
КонецПроцедуры // ЛксПередОткрытием() 

// Процедура - обработчик события "ПриИзменении" элемента формы "Склад".
//
Процедура ЛксСкладПриИзменении(Элемент)
	
	<Текст вставки в начало обработчика>
	[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "ПриИзменении", "Склад"));]
	<Текст вставки в конец  обработчика>
	
КонецПроцедуры // ЛксСкладПриИзменении()

// Процедура - обработчик события "НачалоВыбора" элемента "Товары.ЗаказПокупателя".
// (Событие "НачалоВыбора" поля ввода "ЗаказПокупателя"
// в строке табличной части "Товары")
//
Процедура ЛксТоварыЗаказПокупателяНачалоВыбора(Элемент, СтандартнаяОбработка)
	
	<Текст вставки в начало обработчика>
	[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "НачалоВыбора", "Товары.ЗаказПокупателя"));]
	<Текст вставки в конец  обработчика>
	
КонецПроцедуры // ЛксТоварыЗаказПокупателяНачалоВыбора()

// Процедура - обработчик события кнопки "КнопкаВыбратьВвестиХарактеристику" командной панели "ОсновныеДействияФормы".
//
Процедура ЛксОсновныеДействияФормыКнопкаВыбратьВвестиХарактеристику(Кнопка)

	<Текст вставки в начало обработчика>
	[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, , "ОсновныеДействияФормы.КнопкаВыбратьВвестиХарактеристику"));]
	<Текст вставки в конец  обработчика>

КонецПроцедуры // ЛксОсновныеДействияФормыКнопкаВыбратьВвестиХарактеристику()

ЛксУстановитьДействиеФормы(ЭтаФорма, "ПередОткрытием");
ЛксУстановитьДействиеФормы(ЭтаФорма, "ПриИзменении"  , "Склад");
ЛксУстановитьДействиеФормы(ЭтаФорма, "НачалоВыбора"  , "Товары.ЗаказПокупателя");
ЛксУстановитьДействиеФормы(ЭтаФорма,				 , "ОсновныеДействияФормы.КнопкаВыбратьВвестиХарактеристику");

// }}Добавил TormozIT 23.03.2006 

//////////////////////////////////////////////////////////////////////////////// 
// ОПЕРАТОРЫ ОСНОВНОЙ ПРОГРАММЫ


Таким образом, при обновлении в общем случае нам нужно будет всего лишь добавить один блок в раздел операторов основной программы. Строго говоря, этот блок нужно поместить в самый конец этого раздела, т.к. в нем могут присутствовать конкурентные назначения обработчиков. Однако в типовых конфигурациях это встречается крайне редко. Альтернативным вариантом является вынесение установки всех обработчиков, кроме ПередОткрытием, в новый обработчик ПередОткрытием.
Так как раздел основной программы модуля формы почти никогда не меняется, то для него в настройке объединения просто уберем галочку, чем полностью исключим ручную правку модуля формы после обновления.

Случай 2. Добавляем новый обработчик события элемента формы.
Обычно делают примерно так.
// {{Добавил TormozIT 23.03.2006

// Процедура - обработчик события "ПриИзменении" элемента формы "Склад".
//
Процедура СкладПриИзменении(Элемент)
	
	<Текст начала своего обработчика>
	<Текст конца  своего обработчика>
	
КонецПроцедуры // СкладПриИзменении()

// }}Добавил TormozIT 23.03.2006

Все работает и выглядит хорошо.
Но подумайте, что будет, если в новом релизе будет добавлен в режиме редактирования конфигурации (статически) связанный обработчик для того же события и, возможно, что еще хуже, с таким же именем!

Как следует поступать в этом случае?
Опять по той же схеме.
// {{Добавил TormozIT 23.03.2006

// Процедура - обработчик события "ПриИзменении" элемента формы "Склад".
//
Процедура ЛксСкладПриИзменении(Элемент)
	
	<Текст начала обработчика>
	[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "ПриИзменении", "Склад"));]
	<Текст конца  обработчика>
	
КонецПроцедуры // ЛксСкладПриИзменении()

ЛксУстановитьДействиеФормы(ЭтаФорма, "ПриИзменении"  , "Склад");
// }}Добавил TormozIT 23.03.2006

//////////////////////////////////////////////////////////////////////////////// 
// ОПЕРАТОРЫ ОСНОВНОЙ ПРОГРАММЫ

Теперь уже нам не страшен добавленный в одном из будущих релизов обработчик этого события и его имя! Как только он появится, наш обработчик будет его вызывать там, где мы прописали.

Отдельно хочется упомянуть о новых элементах формы. Если вы добавили в форму свой элемент и хотите сделать для него обработчик какого-нибудь события, то имеет смысл и в этом случае поступать так же. Ведь в новом релизе могут добавить элемент формы того же функционального назначения. Если он будет с тем же именем, что и ваш, то вам после обновления даже ничего менять не придется. А если имя будет другое, то просто нужно будет исправить название вашего обработчика и параметр в вызове его установки.

Необходимые процедуры и функции общего модуля
Сначала процедура переопределения события.
Для хранения старых обработчиков событий мы используем хитрость, предложенную Гением 1С http://kb.mista.ru/article.php?id=101.
Суть ее состоит в динамическом добавлении нулевых размеров служебного элемента формы для хранения в нем списка значений в свойстве СписокВыбора. Т.е. сначала проверяем есть ли элемент формы с заданным именем (в примере "рСтарыеОбработчики"). Если его нет, то создаем. Затем получаем обработчик нужного действия формы или элемента формы. Сохраняем его в свойстве СписокВыбора служебного элемента формы. Устанавливаем новый обработчик, имя которого формируем по нашему правилу <Префикс> [ + <ИмяЭлементаФормы>] [ + <ИмяСубэлемента1> ... + <ИмяСубэлементаN>] [ + <ИмяСобытия>]. Параметр "пЛиИсключительное" отвечает за проверку наличия старого обработчика. Такая проверка может понадобится для назначения обработчиков, которые не вызывают старый обработчик (например, НачалоВыбора). Параметр "пПсевдонимЭлементаФормы" позволяет нам назначить нескольким однотипным событиям один обработчик через указание одинакового псевдонима при установке обработчика.
// Переопределяет обработчик события формы.
// Сохраняет штатный обработчик события внутри формы и устанавливает новый.
//
// Параметры:
//  пФорма	   – Форма – форма;
//  *пИмяСобытия – Строка – имя события;
//  *пИмяЭлементаФормы – Строка – полное имя элемента формы.
//  *пЛиИсключительное – Булево – сообщать о наличии старого обработчика;
//  *пПсевдонимЭлементаФормы – Строка – псевдоним элемента формы, используется для назначения одного обработчика
//			   для нескольких однотипных событий формы.
//
Процедура ЛксУстановитьДействиеФормы(пФорма, пИмяСобытия = "", пИмяЭлементаФормы = "",
									 пЛиИсключительное = Ложь, пПсевдонимЭлементаФормы = "") Экспорт
	
	Если пИмяЭлементаФормы <> "" Тогда
		МассивФрагментов = ЛксПолучитьМассивИзСтрокиСРазделителем(пИмяЭлементаФормы);
		ИмяЭлементаФормы = МассивФрагментов[0];
		Объект = пФорма.ЭлементыФормы[ИмяЭлементаФормы];
		Если МассивФрагментов.Количество() > 1 Тогда 
			ИмяЭлементаФормы = ИмяЭлементаФормы + МассивФрагментов[1];
			Если ТипЗнч(Объект) = Тип("ТабличноеПоле") Тогда 
				Объект = Объект.Колонки[МассивФрагментов[1]].ЭлементУправления;
			ИначеЕсли ТипЗнч(Объект) = Тип("КоманднаяПанель") Тогда 
				Объект = Объект.Кнопки[МассивФрагментов[1]];				
			КонецЕсли;
		КонецЕсли;
	Иначе
		Объект = пФорма;
		ИмяЭлементаФормы = "";
	КонецЕсли;
	
	ТекстМаркера = "рСтарыеОбработчики";
	Если пФорма.ЭлементыФормы.Найти(ТекстМаркера) = Неопределено Тогда
		пФорма.ЭлементыФормы.Добавить(Тип("ПолеВвода"), ТекстМаркера, Ложь);
	КонецЕсли;
	
	Если пПсевдонимЭлементаФормы <> "" Тогда 
		ПолноеИмяСобытия = пПсевдонимЭлементаФормы + пИмяСобытия;
	Иначе
		ПолноеИмяСобытия = ИмяЭлементаФормы		+ пИмяСобытия;
	КонецЕсли;
	
	Если ТипЗнч(Объект) = Тип("КнопкаКоманднойПанели") Тогда
		СтароеДействие = Объект.Действие;
	Иначе
		СтароеДействие = Объект.ПолучитьДействие(пИмяСобытия);
	КонецЕсли;
	
	Если пЛиИсключительное и СтароеДействие <> Неопределено Тогда 
		Сообщить("Конфликт обработчиков события """ + пИмяСобытия + """ объекта """ + Строка(Объект) + """",
				 СтатусСообщения.Важное);
	КонецЕсли;
	НовоеДействие = Новый Действие("Лкс" + ПолноеИмяСобытия);
	
	// Для отладки здесь следует отключать попытку. Она используется для назначения унифицированных обработчиков,
	// наличие которых не является обязательным.
	Попытка
		Если ТипЗнч(Объект) = Тип("КнопкаКоманднойПанели") Тогда
			Объект.Действие = НовоеДействие;
		Иначе
			Объект.УстановитьДействие(пИмяСобытия, НовоеДействие);
		КонецЕсли;
	Исключение
		Возврат;
	КонецПопытки;
	
	СписокСоответствияОбработчиков = пФорма.ЭлементыФормы.рСтарыеОбработчики.СписокВыбора;
	СписокСоответствияОбработчиков.Добавить(ИмяЭлементаФормы + "." + пИмяСобытия, СтароеДействие);

КонецПроцедуры // ЛксУстановитьДействиеФормы()

Теперь функция для получения выражения на языке 1С, которое можно выполнить в модуле формы с целью запуска старого обработчика и передачи ему нужных параметров. В случае, если старого обработчика не было назначено для события, функция вернет пустую строку. Сначала приведена вспомогательная функция получения строки аргументов.
// Получаем стандартную строку аргументов для выполнения вызова обработчика события формы.
//
// Параметры:
//  пОбъект	  – Форма, ЭлементФормы – объект события;
//  *пИмяСобытия – Строка – имя события.
//
// Возвращаемое значение:
//			   – Строка – строка аргументов вида "([Аргумент1][, Аргумент2, ... , АргументN]);",
//			   где аргументы имеют свои стандартные названия для каждого события.
//
Функция ЛксПолучитьАргументыДействияФормы(пОбъект, пИмяСобытия = "")

	Аргументы = "";
	Если ТипЗнч(пОбъект) = Тип("КнопкаКоманднойПанели") Тогда
		// Это действие кнопки командной панели формы
		Аргументы = "(Кнопка)";		
	ИначеЕсли ТипЗнч(пОбъект) = Тип("Форма") Тогда
		// Это событие формы
		Попытка
			ОбъектОсновнойРеквизитФормы = пОбъект.ЭтотОбъект;
		Исключение
			ОбъектОсновнойРеквизитФормы = Неопределено;
		КонецПопытки;
		Если Аргументы = "" Тогда 
			Если	  пИмяСобытия = "ВнешнееСобытие" Тогда 
				Аргументы = "(Источник, Событие, Данные)";
			ИначеЕсли пИмяСобытия = "ОбработкаАктивизацииОбъекта" Тогда 
				Аргументы = "(АктивныйОбъект, Источник)";
			ИначеЕсли пИмяСобытия = "ОбработкаВыбора" Тогда 
				Аргументы = "(ЗначениеВыбора, Источник)";
			ИначеЕсли пИмяСобытия = "ОбработкаЗаписиНовогоОбъекта" Тогда 
				Аргументы = "(Объект, Источник)";
			ИначеЕсли пИмяСобытия = "ОбработкаОповещения" Тогда 
				Аргументы = "(ИмяСобытия, Параметр, Источник)";
			ИначеЕсли пИмяСобытия = "ПередЗакрытием" Тогда 
				Аргументы = "(Отказ, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ПередЗаписью" Тогда 
				Если ЛксПолучитьКорневойТипКонфигурации(ОбъектОсновнойРеквизитФормы) = "Документ" Тогда
					Аргументы = "(Отказ, РежимЗаписи, РежимПроведения)";
				Иначе
					Аргументы = "(Отказ)";
				КонецЕсли;
			ИначеЕсли пИмяСобытия = "ПередОткрытием" Тогда 
				Аргументы = "(Отказ, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ПриЗаписи" Тогда 
				Аргументы = "(Отказ)";
			ИначеЕсли пИмяСобытия = "ПриПовторномОткрытии" Тогда 
				Аргументы = "(СтандартнаяОбработка)";
			Иначе
				Аргументы = "()";
			КонецЕсли;
		КонецЕсли;		
	Иначе
		// Это событие элемента формы
		Если ТипЗнч(пОбъект) = Тип("ТабличноеПоле") Тогда
			Если	  пИмяСобытия = "Выбор" Тогда 
				Аргументы = "(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "Перетаскивание" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка, Строка, Колонка)";
			ИначеЕсли пИмяСобытия = "ПроверкаПеретаскивания" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка, Строка, Колонка)";
			КонецЕсли;
		ИначеЕсли ТипЗнч(пОбъект) = Тип("ТабличныйДокумент") Тогда
			Если	  пИмяСобытия = "Выбор" Тогда 
				Аргументы = "(Элемент, Область, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "Перетаскивание" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка, Область)";
			ИначеЕсли пИмяСобытия = "ПроверкаПеретаскивания" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка, Область)";
			КонецЕсли;
		КонецЕсли;
		Если Аргументы = "" Тогда 
			Если	  пИмяСобытия = "АвтоПодборТекста" Тогда 
				Аргументы = "(Элемент, Текст, ТекстАвтоПодбора, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "НачалоВыбора" Тогда 
				Аргументы = "(Элемент, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "НачалоПеретаскивания" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ОбработкаВыбора" Тогда 
				Аргументы = "(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ОбработкаЗаписиНовогоОбъекта" Тогда 
				Аргументы = "(Элемент, Объект, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ОбработкаРасшифровки" Тогда 
				Аргументы = "(Элемент, Расшифровка, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ОкончаниеВводаТекста" Тогда 
				Аргументы = "(Элемент, Текст, Значение, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ОкончаниеПеретаскивания" Тогда 
				Аргументы = "(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "Открытие" Тогда 
				Аргументы = "(Элемент, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "Очистка" Тогда 
				Аргументы = "(Элемент, СтандартнаяОбработка)";
			ИначеЕсли пИмяСобытия = "ПередНачаломДобавления" Тогда 
				Аргументы = "(Элемент, Отказ, Копирование)";
			ИначеЕсли пИмяСобытия = "ПередНачаломИзменения" Тогда 
				Аргументы = "(Элемент, Отказ)";
			ИначеЕсли пИмяСобытия = "ПередОкончаниемРедактирования" Тогда 
				Аргументы = "(Элемент, НоваяСтрока, ОтменаРедактирования, Отказ)";
			ИначеЕсли пИмяСобытия = "ПередУдалением" Тогда 
				Аргументы = "(Элемент, Отказ)";
			ИначеЕсли пИмяСобытия = "ПриВыводеСтроки" Тогда 
				Аргументы = "(Элемент, ОформлениеСтроки, ДанныеСтроки)";
			ИначеЕсли пИмяСобытия = "ПриИзмененииСодержимогоОбласти" Тогда 
				Аргументы = "(Элемент, Область)";
			ИначеЕсли пИмяСобытия = "ПриНачалеРедактирования" Тогда 
				Аргументы = "(Элемент, НоваяСтрока, Копирование)";
			ИначеЕсли пИмяСобытия = "ПриОкончанииРедактирования" Тогда 
				Аргументы = "(Элемент, НоваяСтрока, ОтменаРедактирования)";
			ИначеЕсли пИмяСобытия = "ПриОкончанииРедактированияИнтервала" Тогда 
				Аргументы = "(Элемент, Интервал, Отмена)";
			ИначеЕсли пИмяСобытия = "ПриПолученииДанных" Тогда 
				Аргументы = "(Элемент, ОформленияСтрок)";
			ИначеЕсли пИмяСобытия = "ПриСменеСтраницы" Тогда 
				Аргументы = "(Элемент, ТекущаяСтраница)";
			ИначеЕсли пИмяСобытия = "Регулирование" Тогда 
				Аргументы = "(Элемент, Направление, СтандартнаяОбработка)";
			Иначе
				Аргументы = "(Элемент)";
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	Возврат Аргументы + ";";

КонецФункции // ЛксПолучитьАргументыДействияФормы()

// Получаем текст для выполнения вызова старого обработчика события формы или элемента формы.
//
// Параметры:
//  пФорма	   – Форма – форма;
//  *пИмяСобытия – Строка – имя события;
//  *пИмяЭлементаФормы – Строка – полное имя элемента формы.
//
// Возвращаемое значение:
//			   – Строка – текст для выполнения.
//
Функция ЛксПолучитьСтароеДействиеФормы(пФорма, пИмяСобытия = "", пИмяЭлементаФормы = "") Экспорт
	
	Если пИмяЭлементаФормы <> "" Тогда 
		МассивФрагментов = ЛксПолучитьМассивИзСтрокиСРазделителем(пИмяЭлементаФормы);
		ИмяЭлементаФормы = МассивФрагментов[0];
		Объект = пФорма.ЭлементыФормы[ИмяЭлементаФормы];
		Если МассивФрагментов.Количество() > 1 Тогда 
			ИмяЭлементаФормы = ИмяЭлементаФормы + МассивФрагментов[1];
			Если ТипЗнч(Объект) = Тип("ТабличноеПоле") Тогда 
				Объект = Объект.Колонки[МассивФрагментов[1]].ЭлементУправления;
			ИначеЕсли ТипЗнч(Объект) = Тип("КоманднаяПанель") Тогда 
				Объект = Объект.Кнопки[МассивФрагментов[1]];				
			КонецЕсли;
		КонецЕсли;
	Иначе
		ИмяЭлементаФормы = "";
		Объект = пФорма;
	КонецЕсли;
	
	СтарыйОбработчик = "";
	СписокСоответствияОбработчиков = пФорма.ЭлементыФормы.рСтарыеОбработчики.СписокВыбора;
	ЭлементСписка = СписокСоответствияОбработчиков.НайтиПоЗначению(ИмяЭлементаФормы + "." + пИмяСобытия);
	Если ЭлементСписка <> Неопределено Тогда 
		СтарыйОбработчик = ЭлементСписка.Представление;
	КонецЕсли;
	Если СтарыйОбработчик <> "" Тогда 
		СтарыйОбработчик = СтарыйОбработчик + ЛксПолучитьАргументыДействияФормы(Объект, пИмяСобытия);
	КонецЕсли;
	Возврат СтарыйОбработчик;

КонецФункции // ЛксПолучитьСтароеДействиеФормы()

Теперь функция для получения выражения на языке 1С, которое можно выполнить в модуле формы с целью запуска актуального обработчика и передачи ему нужных параметров. В случае, если актуального обработчика не было назначено для события, функция вернет пустую строку.
// Получаем текст для выполнения вызова обработчика события формы.
// Текст включает инициализацию параметра Элемент для событий элементов формы.
//
// Параметры:
//  пФорма	   – Форма – форма;
//  *пИмяСобытия – Строка – имя события;
//  *пИмяЭлементаФормы – Строка – полное имя элемента формы.
//
// Возвращаемое значение:
//			   – Строка – текст для выполнения.
//
Функция ЛксПолучитьДействиеФормы(пФорма, пИмяСобытия = "", пИмяЭлементаФормы = "") Экспорт

	// Явное "определение" типа переменных.
	Если Ложь Тогда
		пФорма = ПолучитьОбщуюФорму(0);
	КонецЕсли;
	
	Если пИмяЭлементаФормы <> "" Тогда 
		МассивФрагментов = ЛксПолучитьМассивИзСтрокиСРазделителем(пИмяЭлементаФормы);
		Объект = пФорма.ЭлементыФормы[МассивФрагментов[0]];
		Если МассивФрагментов.Количество() > 1 Тогда
			ИмяСубэлемента = МассивФрагментов[1];
			ИмяЭлементаФормы = ИмяЭлементаФормы + ИмяСубэлемента;
			Если ТипЗнч(Объект) = Тип("ТабличноеПоле") Тогда 
				Объект = Объект.Колонки[ИмяСубэлемента].ЭлементУправления;
				УстановкаПараметров = "Элемент = ЭлементыФормы." + ИмяЭлементаФормы + "Колонки[" 
						   + ИмяСубэлемента + "].ЭлементУправления;" + Символы.ПС;
			ИначеЕсли ТипЗнч(Объект) = Тип("КоманднаяПанель") Тогда 
				Объект = Объект.Кнопки[ИмяСубэлемента];				
				УстановкаПараметров = "Кнопка = ЭлементыФормы." + ИмяЭлементаФормы + "Кнопки[" 
						   + ИмяСубэлемента + "];" + Символы.ПС;
			Иначе
				Сообщить("Неизвестный тип элемента """ + ТипЗнч(Объект) + """ с  субэлементом """ 
					   + ИмяСубэлемента + """ при получении действия формы");
			КонецЕсли;
		Иначе
			УстановкаПараметров = "Элемент = ЭлементыФормы." + пИмяЭлементаФормы + ";" + Символы.ПС;
		КонецЕсли;
	Иначе
		Объект = пФорма;
	КонецЕсли;
	
	Обработчик = Строка(Объект.ПолучитьДействие(пИмяСобытия));
	Если Обработчик <> "" Тогда 
		Обработчик = УстановкаПараметров + Обработчик + ЛксПолучитьАргументыДействияФормы(Объект, пИмяСобытия)
				   + Символы.ПС;
	КонецЕсли;
	Возврат Обработчик;

КонецФункции // ЛксПолучитьДействиеФормы()

Ну и вспомогательные функции парсинга (разбора) строки и получения типа ссылки.
// Функция разбивает строку разделителем.
// 
// Параметры:
//  пСтрока	  - Строка - которую разбиваем;
//  *пРазделитель - Строка - символ-разделитель.
//
// Возвращаемое значение:
//			   - Массив - содержащий фрагменты, на которые разбивает строку разделитель.
//
Функция ЛксПолучитьМассивИзСтрокиСРазделителем(пСтрока, пРазделитель = ".") Экспорт
	
	Массив = Новый Массив;
	лСтрока = СтрЗаменить(пСтрока, пРазделитель, Символы.ПС);
	Для Счетчик = 1 По СтрЧислоСтрок(лСтрока) Цикл 
		Массив.Добавить(СтрПолучитьСтроку(лСтрока, Счетчик));
	КонецЦикла;
	Возврат Массив;
	
КонецФункции // ЛксПолучитьМассивИзСтрокиСРазделителем()

// Определяет корневой тип конфигурации.
//
// Параметры:
//  пЗначение	– Произвольный – проверяемое значение.
//
// Возвращаемое значение:
//  Строка	   – имя корневого типа конфигурации метаданных;
//  Неопределено – значение не является объектом коневого типа конфигурации.
//
Функция ЛксПолучитьКорневойТипКонфигурации(пЗначение) Экспорт

	ОбъектМетаданных = Метаданные.НайтиПоТипу(ТипЗнч(пЗначение));
	Если ОбъектМетаданных <> Неопределено Тогда 
		МассивФрагментов = ЛксПолучитьМассивИзСтрокиСРазделителем(ОбъектМетаданных.ПолноеИмя());
		Если МассивФрагментов.Количество() = 2 Тогда 
			Возврат МассивФрагментов[0];
		Иначе
			// Ссылка на субобъект
		КонецЕсли;
	КонецЕсли;
	Возврат Неопределено;
	
КонецФункции // ЛксПолучитьКорневойТипКонфигурации()


Как программно вызвать обработчик события формы из ее модуля, не привязываясь к имени обработчика?
В этом случае нам поможет функция ЛксПолучитьДействиеФормы(), которая возвращает текст для вызова обработчика события. Перед выполнением самого вызова необходимо инициализировать параметры обработчика.

Общий случай:
<Инициализация параметров вызова обработчика события>
Выполнить(ЛксПолучитьДействиеФормы(Форма, ИмяСобытия, ИмяЭлементаФормы));

Пример вызова события НачалоВыбора для элемента формы с именем "Склад":
СтандартнаяОбработка = Ложь;
Выполнить(ЛксПолучитьДействиеФормы(Форма, "НачалоВыбора", "Склад"));


Как программно вызвать обработчик события формы из любого модуля, не привязываясь к имени обработчика?
Для этого трюка в модуле формы конечно придется разместить метод, выполняющих произвольный код через метод Выполнить:
// Выполняет выражение. Используется извне для программного вызова событий и выполнения
// приватных методов. В параметр необходимо помещать не только вызов метода, но и инициализацию
// его параметров.
// 
// Параметры:
//  пВыражение - Строка - которую нужно выполнить.
//
Процедура ЛксВыполнить(пВыражение) Экспорт
	Выполнить(пВыражение);
КонецПроцедуры // ЛксВыполнить()

Инициализацию парамертов обработчика события естественно необходимо размещать в параметре "Выражение".

Пример вызова обработчика события НачалоВыбора для элемента формы с именем "Склад":
Выражение = "СтандартнаяОбработка = Ложь;" + Символы.ПС;
Выражение = Выражение + ЛксПолучитьДействиеФормы(Форма, "НачалоВыбора", "Склад");
Форма.ЛксВыполнить(Выражение);


Шаблоны
Для облегчения создания новых обработчиков разумно написать общий шаблон. Вот мой:
// Процедура - обработчик события "" элемента формы "".
//
<?>Процедура Лкс<?"Объект"><?><?"Событие">()

	<?>
	Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "Событие">", "Объект">"));	

КонецПроцедуры // Лкс()

ЛксУстановитьДействиеФормы(ЭтаФорма, "Событие">", "Объект">");

Также можно написать и частные шаблоны для еще большего ускорения разработки. Тогда вам даже не придется искать/вспоминать стандартную строку параметров обработчика события.

Например шаблон для обработчика события ПриИзменении:

// Процедура - обработчик события "ПриИзменении" элемента формы "".
//
Процедура Лкс<?"Объект">ПриИзменении(Элемент)

	Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "ПриИзменении", "Объект">"));	
	<?>

КонецПроцедуры // ЛксПриИзменении()

ЛксУстановитьДействиеФормы(ЭтаФорма, "ПриИзменении", "Объект">");


А вот шаблон для обработчика события кнопки:

// Процедура - обработчик события кнопки "" командной панели "".
//
Процедура Лкс<?"Командная панель"><?><?"Кнопка">(Кнопка)

	Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "", "Командная панель">.Кнопка">"));	
	<?>

КонецПроцедуры // Лкс()

ЛксУстановитьДействиеФормы(ЭтаФорма, "", "Командная панель">.Кнопка">");


Итоги
Я успешно применяю данную методику на практике. Реализованы унифицированные обработчики однотипных событий формы, что позволяет не привязываться к имени элемента формы. Многие типы событий обрабатываются почти глобально при сохранении вызова типовых и наличии новых обрабочтиков.

Думаю, что описанная методика заслуживает платформенной реализации.

 

http://kb.mista.ru/article.php?id=268

См. также

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Обмен между базами 1C Администрирование СУБД Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024    4614    dsdred    53    

73

Как готовить и есть массивы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    5307    YA_418728146    25    

64

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6436    dsdred    36    

112

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18502    SeiOkami    46    

118

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023    12111    human_new    27    

74

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8847    YA_418728146    6    

141

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023    6288    sebekerga    54    

94

Все скопируем и вставим! (Буфер обмена в 1С 8.3.24)

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим новую возможность 8.3.24 и как её можно эффективно использовать

27.06.2023    16016    SeiOkami    31    

103
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. цыпа 02.06.09 15:14 Сейчас в теме
подскажите,как найти центр в геометрической схеме ограничивающего прямоугольника?
2. tormozit 7138 02.06.09 15:25 Сейчас в теме
8. Поручик 4670 16.09.10 22:28 Сейчас в теме
(2) Для управляемых форм 8.2. не пробовал портировать?
12. HIgor 21 24.10.12 10:01 Сейчас в теме
(8) Поручик, присоединяюсь. Кто знает подобное решение для управляемых форм?
13. stalker18 09.11.12 17:37 Сейчас в теме
(12) HIgor, поддерживаю, очень интересует подобная схема для управляемых форм
16. pbazeliuk 1955 10.02.13 11:50 Сейчас в теме
(8) Поручик, (12) HIgor, (13) stalker18, (15) alekseies, вот для УФ http://infostart.ru/public/169131/. Метод похож на та этот. Спасибо автору за идею и малость кода.
27. dima_home 238 11.05.18 13:56 Сейчас в теме
(1)
центр в геометрической схеме ограничивающего прямоугольника

Центр = Половина длины сторон ограничивающего прямоугольника. ;)
3. vheart 25.07.09 10:12 Сейчас в теме
А в чем преимущество данного функционала перед возможностью платформы переопределять обработчики событий (only v8.1). Ведь можно назначать обработчики для событий прикладных объектов, прикладных объектов, наборов записей и СОМ - объектов.
4. KapasMordorov 428 25.07.09 10:18 Сейчас в теме
(3)
Вообще-то статья о формах. Форма - прикладной объект?
5. inse0f 25.07.09 12:22 Сейчас в теме
юзаю уже давно респект, но вчера наткнулся на баг небольшой, в событии ПриИзмененииФлажка
6. Поручик 4670 10.01.10 21:16 Сейчас в теме
Лучше поздно, чем никогда.
Сам применил эту методику в рабочей конфе. Спасибо автору.
7. bashhhh 25 12.01.10 07:39 Сейчас в теме
Внедряю УПП. Попоробую эту методику, т.к. события форм максимально автоматизируются. Только вот вопрос вида форм для разных ролей этой методикой не решить, скорее всего будет несколько форм документов для различных должностей. :?:

+1 Шпасиба!
9. amiralnar 9 03.12.10 12:14 Сейчас в теме
Не работает на подменю:
ЛксУстановитьДействиеФормы(ЭтаФорма, , "ДействияФормы.Подменю2.ЭлектронныеПисьмаПлюсКонтактныеЛица");
10. HIgor 21 19.01.12 09:17 Сейчас в теме
Классное решение. Правда не сразу разобрался, но сейчас доволен как удав :-) (УПП 8.2 работает)
11. script 128 13.09.12 16:12 Сейчас в теме
Пожалуйста продемонтрируйте данную технологию на практическом примере.
Описание методики до меня начало доходить только после 2 прочтения. И все равно я не понял
как будут переопределяться динамичиские обработчики событий, назначенные программно (напр. меню кнопки "Печать","Заполнить" или "Вид операции" в документах типовых конфигураций).
Очень прошу описать выполнение действий для простой задачи, например:
1) Ручное добавление реквизита "НаименованиеДляНалоговойНакладной" в справочник "Контрагенты"
и заполнение данного реквизита при изменении заначения в реквизите "Наименование".
По аналогии с реквизитом "Полное наименование".
2) В документе "Реализация товаров и услуг" в процедуре ПриОткрытии() вызывается процедура
РаботаСДиалогами.УстановитьПодменюВыбораВидаОперации(,......,Новый Действие("ДействияФормыДействиеУстановитьОперацию"));
Цель задачи: необходимо переопределить обработчик "ДействияФормыДействиеУстановитьОперацию".
В новом обработчике необходимо реализовать вывод некоторой картинки-пиктограммы, которая отображалась бы перед наименованием вида опреации.
14. script 128 29.01.13 02:38 Сейчас в теме
БРАВО!!! Это просто круть.
15. alekseies 30.01.13 12:47 Сейчас в теме
хорошо бы реализовать подобное для управляемых форм 8.2................
17. LexSeIch 210 11.02.13 07:13 Сейчас в теме
Мир этому дому. Спасибо за статью. Чужой опыт, всегда полезен - указывает возможный путь и решение.
18. mikhailovaew 127 13.02.13 14:09 Сейчас в теме
Можно попросить Вас отформатировать программный текст? Сейчас он растянут, читается тяжело
(
особенно
перенос
скобок
на новую
строчку
)
19. tormozit 7138 13.02.13 14:21 Сейчас в теме
(18) К сожалению вручную это большие трудозатраты. Как это сделать автоматизировано, у меня пока нет идей. Сломалось по вине движка сайта. Я лишь добавил ссылку на версию методики для управляемых форм. После сохранения все форматирование сломалось. Я обращался к модератору с просьбой помочь, но он пока не отреагировал на нее =(
20. tormozit 7138 25.02.13 10:22 Сейчас в теме
Тех. поддержка восстановила форматирование содержимого публикации.
21. alekseies 27.02.13 13:46 Сейчас в теме
для УФ http://infostart.ru/public/169131/. Метод похож , но более трудоемк для обновления на новые конфигурации .............
22. tormozit 7138 27.02.13 14:51 Сейчас в теме
(21) Я все надеялся в самой публикации указать эту ссылку, но к сожалению при попытке отредактировать публикацию в ней ломается все оформление программного кода. Видимо теперь она навсегда останется в текущем виде.
23. mikhailv 19 02.04.15 16:01 Сейчас в теме
Шаблоны в конце статьи не читабельны. Здесь зеркало статьи с нормальными шаблонами: http://kb.mista.ru/article.php?id=268
И еще: долго с коллегами думали, что же делает, например, код:
[Выполнить(ЛксПолучитьСтароеДействиеФормы(ЭтаФорма, "ПередОткрытием"));]

Оказалось, что квадратные здесь - просто для красоты ^.^ Может быть, хотя бы в статье-зеркале уберёте, раз эта не недактируется?
24. tormozit 7138 03.04.15 09:14 Сейчас в теме
Квадратные скобки обозначают необязательный фрагмент.
25. Патриот 450 20.02.18 19:55 Сейчас в теме
(0), спасибо.
Потребовалось добавить во все формы конфы немного программного кода. В платформе есть возможность выгружать загружать файлы конфы. Чтоб велосипеды не городить да время сэкономить, не подскажите, нет ли обработки, позволяющей во все формы конфы добавить некий код? Может даже с указанием, в какую процедуру надо код вопхнуть...
26. script 128 11.05.18 00:04 Сейчас в теме
Сколько лет прошло, а методика жива и работает
28. UNIT68RUS 08.05.19 09:35 Сейчас в теме
По обработке можно выложить скрин экрана обработки?
29. Cерый 25 16.07.19 18:55 Сейчас в теме
По образцу Вашей статьи мной решалась задача вызова обработчика "ПриИзменении" реквизита формы документа в процедуре общего модуля;
оказалось, что для обработчиков, не объявленных как экспортные, возвращается ПолучитьДействие (отличное от Неопределено),
но попытка выполнения их вне формы выдает ошибку: Метод объекта не обнаружен, объявление их экспортными ошибку устраняло
(8.3.9, режим совместимости Версия 8.2.16, обычные формы).

Благодарю за статью.
30. tormozit 7138 08.08.19 07:17 Сейчас в теме
Обработчик ПриИзменении для поля формы часто удобнее вызывать через https://infostart.ru/public/16985/
triviumfan; +1 Ответить
32. Andrew_Foedorov 11.04.23 14:50 Сейчас в теме
Для управляемых форм всё это выглядит странно (впрочем, и для обычных форм, хотя там делается несколько иначе, но по схожему алгоритму).
В управляемой форме достаточно в процедуру OnCreateAtServer добавить все обработчики, который Вы собираетесь изменять (а лучше это сделать в специальной процедуре, вызываемой из OnCreateAtServer).

Добавляете, допустим, такие строки (добавляем в процедуру myНастроитьОбработкуСобытий):

&AtServer
Procedure myНастроитьОбработкуСобытий()
Items.ТоварыТовар.SetAction("OnChange", "myТоварыТовар_OnChange");
Items.ТоварыТовар.SetAction("ChoiceProcessing", "myТоварыТовар_ChoiceProcessing");
EndProcedure

А текст модуля дополняете процедурам:

&AtClient
Procedure myТоварыТовар_OnChange(Элемент)
<Собственный обработчик до стандартной процедуры>;
ТоварыТоварПриИзменении(Элемент);
<Собственный обработчик после стандартной процедуры>;
EndProcedure

&AtClient
Procedure myТоварыТовар_ChoiceProcessing(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
<Собственный обработчик до стандартной процедуры>;
ТоварыТоварОбработкаВыбора(Элемент);
<Собственный обработчик после стандартной процедуры>;
EndProcedure

Если в модуле ещё нет процедур ТоварыТоварПриИзменении и ТоварыТоварОбработкаВыбора, создаёте пустые. Если при обновлении они появятся, упадут как раз в Ваши пустые процедуры.

И, заметьте, при обновлении будет достаточно вставить в процедуру OnCreateAtServer вызов myНастроитьОбработкуСобытий.

Как я уже говорил, для обычных форм достаточно примерно того же, но установка обработчиков и вызов myНастроитьОбработкуСобытий происходит чуточку иначе.
Оставьте свое сообщение