[Примеры] Подсистема PAPI. Часть 1

Так как первоначально затевался именно универсальный http-сервис, поэтому наименование подсистемы было решено образовывать от API (application programming interface). Дальше я решил сделать, что-то шуточное. Я играл с разными наименованиями, в том числе PAPIRUS. Придумывая название, обыгрывал и логотип. В итоге я пришел к тому, что именно PAPI проще всего обыграть.

Шуточная составляющая в том, что в переводе с испанского, получается довольно-таки забавное название. Если вы смотрели испанские фильмы, то наверняка слышали, как дети называют своих отцов.

PAPI – в переводе с испанского «папочка».

Я добавил к API еще одно слово и получилось Pretty API -> PAPI.

Правда в 2021 году мне приелась эта шутка… Я работал на стартапе с программистами, которые ничего не знали про 1С, и они реально считали, что PAPI — это функционал непосредственно платформы 1С.

Первое время было забавно слушать как взрослые парни спрашивают про «папочку», но спустя какое-то время шутка надоела ;))

Подсистемы:

PAPI – Основная подсистема, содержит базовый функционал.

PAPI_Алгоритмы – Подсистема по созданию алгоритмов.

PAPI_HTTP – Подсистема для реализации http-сервисов.

PAPI_Методы – Методы http-сервисов.

PAPI_ИсторияДанных – Работа с платформенным механизмом История данных.

PAPI_ОтложенныеОперации – Подсистема с объектами отложенного выполнения.

PAPI_ПодпискиНаСобытия – Подсистема по работе с подписками на события.

PAPI_Шина – Подсистема для взаимодействия с шиной. (В процессе разработки)

PAPI_ДополнительныеИнструменты – Дополнительный функционал, не вошедший ни в одну подсистему.

PAPI_СервисыИнтеграции – Работа с сервисами интеграции.

PAPI_Каналы – Пока только для описания каналов.

PAPI_СообщенияСервисовИнтеграции – Работа с сообщениями сервисов интеграции.

Общие модули:

PAPI - Процедуры и функции для упрощения работы с алгоритмами и методами.

PAPI_АсинхронныеОперации – Модуль предыдущего PAPI, служил для выполнения запросов в фоновом задании. Нужно переработать.

PAPI_ДанныеДляЗаполненияНастроек – Содержит функционал по первоначальному заполнению шаблонов сообщений и некоторые настройки.

PAPI_ИсторияДанных – Содержит процедура и функции по работе с функционалом «История данных»

PAPI_Логирование – Служит для работы с логированием событий в регистрах и журнале регистрации.

PAPI_ОбщегоНазначенияВызовСервера – Набор вспомогательных процедур и функций.

PAPI_ОбщегоНазначенияКлиентСервер – Набор вспомогательных процедур и функций.

PAPI_ПодпискиНаСобытия – Процедуры и функции по работе с универсальными подписками на события.

PAPI_ПодпискиНаСобытияКлиентСервер – Процедуры и функции по работе с универсальными подписками на события.

PAPI_РаботаСАлгоритмами – Процедуры и функции по работе с алгоритмами.

PAPI_РаботаСВнешнимиОбработками – Модуль для подключаемых внешних обработок.

PAPI_РаботаСВходящимиЗапросами – Модуль для работы с входящими http запросами.

PAPI_РаботаСВходящимиСообщениями – Модуль для обработки входящих сообщений сервисов интеграции.

PAPI_РаботаСМетодами – Процедуры и функции по работе с методами.

PAPI_РаботаСОтветом – процедуры и функции по работе с ответами алгоритмов, http-запросов, методов, сообщений сервисов интеграций.

PAPI_СервисыИнтеграции - Содержит процедура и функции по работе с функционалом «Сервисов интеграций».

PAPI_СлужебныеДляОбмена - Набор вспомогательных процедур и функций.

Роли:

PAPI_Администратор – Дает полный функционал управления PAPI.

PAPI_БазовыеПрава – Дает минимальные права. Обычным пользователям больше и не надо.

PAPI_ПодсистемаPAPI – Дает только видимость подсистемы PAPI.

PAPI_Оператор - Предоставления доступа к объектам задействованным в интеграционных механизмах для разрешения ошибок

Подписки на события:

Регламентные задания:

Функциональные опции:

Общие команды:

PAPI_НастройкиШины – Команда открывает форму настроек.

Общие формы:

PAPI_Настройки – Форма настроек.

Общие картинки:

           PAPI, PAPI_Команды, PAPI_Метаданные, PAPI_Подписки

HTTP-сервисы:

           PAPI – универсальный http-сервис.

           Шаблон: /{MethodVersion}/{MethodName}

           Тип: ANY

           PAPI_lower – универсальный http-сервис (Нижний регистр).

           Шаблон: /{MethodVersion}/{MethodName}

Тип: ANY

Константы:

PAPI_ДатаЗапретаОбменаДокументов – Заглушка для обменов. Можно выставить дату, которую проверять, например в подписке перед записью документов и отшивать документы младше этой даты.

PAPI_Источник – Текстовое представление текущей базы, нужно для обменов через Шину, но не обязательно.

PAPI_КоличествоПопытокОчередиДокументов – Нужна для отложенных действия с документами в регистре сведений «PAPI_ОчередьДействийСДокументами».

PAPI_ЛогированиеВходящихСообщенийСервисаИнтеграции – Для функциональной опции «PAPI_ЛогированиеВходящихСообщенийСервисаИнтеграции».

PAPI_ОбменыСервисовИнтеграцииВключены – Для функциональной опции «PAPI_ОбменыСервисовИнтеграцииВключены».

Справочники:

PAPI_Алгоритмы – Служит для описания алгоритмов.

PAPI_ВнешняяОбработка – Первоначально создан для подключение внешних обработок с процедурами для подписок на события, но в будущем будут использоваться и для других вещей.

PAPI_КаналыИнтеграции – Для описания канала отправки или приемки. Используется для ответов.

PAPI_Методы – Служит для описания методов.

PAPI_ПодпискиНаСобытия – Служит для описания подписок на события.

PAPI_СозданиеСообщений – В процессе разработки.

PAPI_Участники – Отправители и получатели.

PAPI_ЧтениеСообщений – Обработка входящих сообщений сервисов интеграций. В процессе разработки.

PAPI_ШаблоныСообщений – Описание сообщений.

Документы:

           PAPI_ВходящийЗапрос – Для логирования входящих http запросов.

Перечисления:

PAPI_ДействиеСДокументом, PAPI_ТелоЗапроса, PAPI_ТелоОтвета, PAPI_ТипВыполнения, PAPI_ТипЛога, PAPI_ТипПодпискиНаСобытие

Обработки:

PAPI_НастройкаСервисовИнтеграции – Инструмент повторяет типовой функционал, но имеет несколько особенностей.

PAPI_НастройкаСоставаИсторииДанных – Обработка позволяет настраивать состав платформенной "Истории данных".

PAPI_ОтправкаСообщенияСервисовИнтеграции – Инструмент позволяет создать сообщение сервиса интеграции на выбранном канале.

PAPI_СообщенияСервисовИнтеграции – Позволяет отслеживать какие и сколько сообщений находятся в канале. Проверяет есть ли связь с шиной. Может удалять ненужные сообщения.

PAPI_ОтладкаВходящегоЗапроса - Служит для повторного выполнения запроса из Документ.PAPI_ВходящийЗапрос.

Регистры сведений:

PAPI_ВходящиеСообщенияСервисаИнтеграции – Служит для фиксации входящих сообщений сервисов интеграций.

PAPI_ЗапросНедостающихДанных – Служебный регистр. Пока под вопросом. Может быть исчезнет в будущем.

PAPI_ЛогАлгоритмов – Логи при работе алгоритмов.

PAPI_ЛогМетодов – Логи при работе методов.

PAPI_ОтборыПолучателей – Промежуточный вариант, в будущем будут нарисованы фильтры.

PAPI_ОчередьАлгоритмовДляФоновогоВыполнения – Регистр предыдущего PAPI, служил для выполнения алгоритмов в фоновом задании. Нужно переработать.

PAPI_ОчередьДействийСДокументами – Служебный регистр, хранит навигационную ссылку на документ и действие которое необходимо с ним сделать.

PAPI_ХранилищеРезультатов – Регистр предыдущего PAPI, служил для хранения данных. Нужно переработать.

Разрешен – Булево – Разрешает выполнение алгоритма. Если алгоритм запрещен значение реквизита ложь. При запрете выдаст ошибку с кодом "ALErr1", См. "Пример 3: Логирование Ошибок".

ИмяАлгоритма – Строка (200) – Ключ поиска алгоритма для программистов.

Комментарий – Строка – Информация по алгоритму.

Логировать – Булево – Указывает на необходимость записи в регистр сведений PAPI_ЛогАлгоритмов.

Привилегированный – Булево – Признак запуска алгоритма в привилегированном режиме.

Настройки – ХранилищеЗначенией – Содержит структуру алгоритма, состоящую из кода алгоритма и параметров алгоритма. Прочитать структуру можно в модуле "PAPI_РаботаСАлгоритмами", используя функцию СтруктураНастроекАлгоритма.

Создадим алгоритм "ВычислениеБезПараметров":

Обратите внимание на реквизит "Разрешен". Если его выключит, то мы получим ошибку. Проверим это позже.

Заполним закладку "Вычисления":

ПятьМинут = 60 * 5;
Результат = ТекущаяДатаСеанса() + ПятьМинут;

Выполняем следующий код:

Алгоритм = Справочники.PAPI_Алгоритмы.ПолучитьАлгоритмПоИмени("ВычислениеБезПараметров");

СтруктураВозврата = PAPI_РаботаСАлгоритмами.РешитьАлгоритм(Алгоритм);          

Если СтруктураВозврата.Отработал Тогда

	Сообщить(СтруктураВозврата.Результат);

Иначе

	Сообщить(СтруктураВозврата.ТекстОшибки);

КонецЕсли;

Снимем галочку "Разрешен" и еще раз выполним.

А теперь еще раз выполним пример 1.

Мы видим сообщение, что алгоритм запрещен.

Оставим алгоритм запрещенным и включим логирование.

Еще раз выполним и откроем "Логирование алгоритмов"

Мы видим запись в регистре с информацией об ошибке.

Если мы хотим поменять сообщение "Алгоритм запрещен" на другое сообщение, например "Запрещенный алгоритм", нам нужно поправить шаблон сообщения.

Было:

Стало:

Выполняем еще раз:

Скопируем алгоритм без параметра и немножко его поправим.

На закладке "Параметры" создадим параметр "КоличествоМинут"

Теперь поправим код на закладке "Вычисления":

ПятьМинут = 60 * ПараметрыАлгоритма.КоличествоМинут;
Результат = ТекущаяДатаСеанса() + ПятьМинут;

Выполняем следующий код:

// Ищем Алгоритм
Алгоритм = Справочники.PAPI_Алгоритмы.ПолучитьАлгоритмПоИмени("ВычислениеСПараметром");

// Выполняем Алгоритм
СтруктураВозврата = PAPI_РаботаСАлгоритмами.РешитьАлгоритм(Алгоритм);         

Если СтруктураВозврата.Отработал Тогда

	Сообщить(СтруктураВозврата.Результат);

Иначе

	Сообщить(СтруктураВозврата.ТекстОшибки);

КонецЕсли;

Теперь сделаем вычисляемый параметр

Мы установили галочку "Вычисляемый" и указали "Вычисление", теперь количество минут равняется 33.

Давайте вычислим значение в другом алгоритме.

Создадим алгоритм "60 Минут":

Добавим параметр "Час" равный 60:

На закладке "Вычисления" напишем код:

Результат = ПараметрыАлгоритма.Час;

Теперь в алгоритме с параметром в значении параметра "КоличествоМинут" выберем алгоритм "60 Минут". Незабываем снять галочку "Вычисляемый"

Проверяем:

В Алгоритмах заложен принцип, если параметр уже определен тогда он по-новому не пересчитывается. То есть если мы зададим параметр и передадим его в алгоритм, тогда алгоритм не будет его вычислять а возьмет наше значение.

Выполним следующий код:

// Ищем Алгоритм
Алгоритм = Справочники.PAPI_Алгоритмы.ПолучитьАлгоритмПоИмени("ВычислениеСПараметром");

// Переопределяем параметр Алгоритма.
ПараметрыАлгоритма = Новый Структура;
ПараметрыАлгоритма.Вставить("КоличествоМинут", 150);

// Выполняем Алгоритм
СтруктураВозврата = PAPI_РаботаСАлгоритмами.РешитьАлгоритм(Алгоритм, ПараметрыАлгоритма);      

Если СтруктураВозврата.Отработал Тогда

	Сообщить(СтруктураВозврата.Результат);

Иначе

	Сообщить(СтруктураВозврата.ТекстОшибки);

КонецЕсли;

К времени добавилось 150 минут. 

В примере, где мы выполняем два алгоритма, мы вычисляем два параметра "КоличествоМинут" и "Час", при этом результат из параметра "Час" мы закидываем в параметр "КоличествоМинут".

В параметрах алгоритма у нас будут два значения.

А в примере с переопределением, мы задаем значение параметру "КоличествоМинут" равное 150, и тот же самый алгоритм берет значение 150 и не рассчитывает его при помощи алгоритма «60 Минут»:

Это важный нюанс, он задуман так изначально.

Получение параметров код:

СтруктураВозврата = PAPI_РаботаСАлгоритмами.РешитьАлгоритм(Алгоритм,,ВернутьПараметры);

В данный момент нет удобного способа, нужно описать использование обработки кодом, но в будущих версиях данную возможность можно будет делать без кода.

Создадим еще один алгоритм:

На закладке "Вычисления" добавим код:

ОписаниеЗащиты = Новый ОписаниеЗащитыОтОпасныхДействий;
ОписаниеЗащиты.ПредупреждатьОбОпасныхДействиях = Ложь;
         
текОбработка = ВнешниеОбработки.Создать("E:\iGitYou\MyPrj\PAPI\demo\additional\ДемоПримерыАлгоритмовPAPI.epf", Ложь, ОписаниеЗащиты);
      
Результат = текОбработка.ВычислениеСПараметромВОбработке(ПараметрыАлгоритма, СтруктураВозврата);

По указанному пути: E:\iGitYou\MyPrj\PAPI\demo\additional\ДемоПримерыАлгоритмовPAPI.epf

Будет лежать обработка с одной функцией в модуле:

Функция ВычислениеСПараметромВОбработке(ПараметрыАлгоритма, СтруктураВозврата) Экспорт

	ПятьМинут = 60 * ПараметрыАлгоритма.КоличествоМинут;
	Результат = ТекущаяДатаСеанса() + ПятьМинут;

	Возврат Результат;

КонецФункции  

Проверяем:

Данный функционал удобно использовать для разработки алгоритма и его отладки.

В расширение "ЛокализацияPAPI" добавим обработку "ДемоПримерыАлгоритмовPAPI.epf"

В ней код из Примера 7: Алгоритм во внешней обработке.

Создадим копированием алгоритма из Примера 7: Алгоритм во внешней обработке новый алгоритм:

На закладке "Вычисления" добавим код:

текОбработка = Обработки.ДемоПримерыАлгоритмовPAPI.Создать();          

Результат = текОбработка.ВычислениеСПараметромВОбработке(ПараметрыАлгоритма, СтруктураВозврата);

Проверяем:

Таким образом есть возможность держать алгоритмы в обработке, что позволит использовать git.

Разрешен – Булево – Разрешает выполнение метода, в отличии от алгоритма проверяется до функции выполнения, данная особенность позволяет тестировать запрещенные методы. Если метод запрещен значение реквизита ложь. При запрете выдаст ошибку с кодом "Err4", См. Справочник.PAPI_ШаблоныСообщений.

ВерсияМетода – Строка (9) – используется в шаблоне обращения к методу, по умолчанию V1. Шаблон = /{ВерсияМетода}/{ИмяМетода}

ИмяМетода – Строка (150) – Ключ поиска метода. Используется в шаблоне. Шаблон = /{ВерсияМетода}/{ИмяМетода}

Комментарий – Строка – Информация по методу.

ЛогироватьЗапрос – Булево – Указывает на необходимость записи данных запроса в документ PAPI_ВходящийЗапрос.

ЛогироватьМетод – Булево – Указывает на необходимость записи лога в регистр сведений PAPI_ЛогМетодов.

Привилегированный – Булево – Признак запуска метода в привилегированном режиме.

Настройки – ХранилищеЗначенией – Содержит структуру метода, состоящую из кода произвольного алгоритма, кода для обработки тела запроса и параметров запроса.

ПроизвольныйАлгоритм – Булево – Указывает на то, как метод должен выполняться. Выполняется либо алгоритм, либо произвольный код.

Алгоритм – Справочник.PAPI_Алгоритмы- Если ПроизвольныйАлгоритм = Ложь, тогда метод работает по указанному алгоритму.

Стандартный – Булево - Метод создан PAPI.

ТелоЗапроса - Перечисление.PAPI_ТелоЗапроса – Тип данных в теле запроса (Строка, ДвоичныеДанные, Поток).

ТелоОтвета - Перечисление.PAPI_ТелоОтвета – Тип данных в теле ответа.

HTTPМетоды – содержит разрешенные методы (GET, POST, HEAD, PUT, DELETE, PATCH, MERGE, OPTIONS, TRACE, CONNECT).

           ЗаголовкиОтвета – содержит заголовки ответа.

 http[s]://{host}/{base}/hs/papi/{MethodVersion}/{MethodName}

Создаю метод "ping". Ставим галку "Разрешен", Версию указываем "V1", Доступные методы указываем "GET" и "POST", имя "ping".

На закладке "Вычисления" код:

Результат = "Папочка с тобой";

На закладке "Ответ" добавим заголовок "Content-Type" и значение "text/html; charset=utf-8"

Проверяем (я буду проверять в Postman):

Наш URL: http://localhost/papi_demo/hs/papi/v1/ping/

GET:

POST:

В функции выполнения метода есть параметр СтруктураВходныхПараметров – это структура, которая создается на основании запроса и имеет свойство "МетодЗапроса".

Давайте изменим код на закладке "Вычисления":

Результат = "Метод вызова: "
	+ СтруктураВходныхПараметров.МетодЗапроса
	+ ". Папочка с тобой";

Проверим:

Так же PAPI умеет вставлять заголовки ответа программно, поэтому предлагаю сделать для "GET" заголовок текст, а для "POST" будет JSON.

Для этого мы используем модуль PAPI.

Наш код на закладке "Вычисления" будет такой:

Если СтруктураВходныхПараметров.МетодЗапроса = "GET"

	Или СтруктураВходныхПараметров.МетодЗапроса = "TRACE" Тогда

	PAPI.ДобавитьЗаголовокОтвета(ПроизвольныеЗаголовки, "Content-Type", "text/html; charset=utf-8");

	Результат ="Папочка с тобой";

Иначе

	PAPI.ДобавитьЗаголовокОтвета(ПроизвольныеЗаголовки, "Content-Type", "application/json");

	СтруктураДляОтвета = Новый Структура("result", "Папочка с тобой");

	Результат = PAPI.Записать_JSON(СтруктураДляОтвета);

КонецЕсли;

Проверяем:

Давайте для начала разберемся с входящим запросом.

Установим галочку "Входящий запрос":

И еще раз выполним метод:

Теперь зайдем во входящие запросы:

Мы видим всю информацию по запросу. Тут и метод, и версия, и заголовки. Все данные, которые могут понадобиться. Даже видно есть ли тело запроса.

По большому счету можно повторить запрос к методу используя этот входящий запрос чтобы произвести отладку.

Давайте выполним входящий запрос:

Как видите мы можем логировать запросы и повторно их выполнять.

Теперь давайте включим логирование, но снимем разрешение на выполнения метода:

Повторно выполним запрос:

Текст ошибки можно так же, как и для алгоритмов поменять в справочнике PAPI_ШаблоныСообщений.

В URL можно передавать Query-параметры, они передаются после знака "?" в URL и чаще всего используются в запросах get. PAPI умеет с ними работать по разному.

Создадим новый метод:

Наш код на закладке "Вычисления" будет такой:

QueryПараметры = "";
Для Каждого Параметр Из СтруктураВходныхПараметров.ПараметрыЗапроса Цикл

	QueryПараметры = QueryПараметры + Символы.ПС
		+ "Ключ: " + СокрЛП(Параметр.Ключ)
		+", Значение: " + СокрЛП(Параметр.Значение);
      
КонецЦикла;

Результат = "Переданы параметры: " + QueryПараметры;

Проверяем:

URL: http://localhost/papi_demo/hs/papi/v1/QueryParamsGet?Dog=Барбос&Cat=Васька

У PAPI есть возможность обработать параметры до того, как начнет выполнятся код с закладки "Вычисления" и поместить параметры в специально подготовленную структуру.

Давайте создадим вторую версию метода, для этого скопируем его и укажем версию "V2"

Теперь на закладке "Запрос" заполним вычисления параметров:

Мы просто переложили имя собаки из параметра "Dog" в параметр "Собака", а имя из "Cat" в "Кот". Как к ним теперь обратится?

Для этого созданы "ПараметрыМетода".

Поменяем код на закладке "Вычисления":

QueryПараметры = "";
Для Каждого Параметр Из СтруктураВходныхПараметров.ПараметрыМетода Цикл

	QueryПараметры = QueryПараметры + Символы.ПС
		+ "Ключ: " + СокрЛП(Параметр.Ключ)
		+", Значение: " + СокрЛП(Параметр.Значение);
                 
КонецЦикла;

Результат = "Переданы параметры: " + QueryПараметры;

Пробуем:

URL: http://localhost/papi_demo/hs/papi/v2/QueryParamsGet?Dog=Барбос&Cat=Васька

В расчете параметра можно использовать алгоритм.

Давайте сделаем это для параметра "Собака".

Создаем алгоритм:

На закладке "Вычисления" вставляем код:

Результат = ?(ПараметрыАлгоритма.Свойство("Dog"),ПараметрыАлгоритма.Dog,"");

Создаем копированием третью версию метода "QueryParamsGet":

На закладке "Запрос" у параметра "Собака" выбираем созданный нами алгоритм:

Проверяем:

URL: http://localhost/papi_demo/hs/papi/v3/QueryParamsGet?Dog=Барбос&Cat=Васька

Иногда нам нужно чтобы get и post возвращали один результат, только get приходит с параметрами в URL, а пост содержит их в теле запроса.

Давайте скопируем последний запрос и немного его поменяем:

На закладке "Запрос"- "Параметры" оставляем все как было:

На закладке "Тело" пишем код:

// читаем JSON                          
ТелоЗапросаJSON = PAPI.Прочитать_JSON(СтруктураВходныхПараметров.ТелоЗапроса);
                         
Если ТипЗнч(ТелоЗапросаJSON) = Тип("Структура") Тогда

	Если ТелоЗапросаJSON.Свойство("Dog") Тогда

		ПараметрыМетода.Вставить("Собака",СокрЛП(ТелоЗапросаJSON.Dog));

	КонецЕсли;

	Если ТелоЗапросаJSON.Свойство("Cat") Тогда

		ПараметрыМетода.Вставить("Кот",СокрЛП(ТелоЗапросаJSON.Cat));

	КонецЕсли;           
                               
КонецЕсли;

Результат = ПараметрыМетода;

Проверяем Get:

Проверяем Post:

Данная возможность позволяет создавать универсальные методы с одной логикой обработки результата.

Например нам нужен метод который прекращает работу если не передан параметр, тут на помощь может прийти Goto.

Копируем предыдущий метод:

На закладке "Вычисления" пишем код:

ПрерываниеМетода = Ложь;
Если Не ПараметрыМетода.Свойство("Кот") Тогда

	PAPI.ЗаполнитьСтруктуруВозврата(СтруктураВозврата,"", "Отсутствует параметр Кот", Истина);
	Результат = СтруктураВозврата.ДанныеОтвета;

	ПрерываниеМетода = Истина;

	Перейти ~ПрерываемМетод; // выходим

КонецЕсли;

QueryПараметры = "";
Для Каждого Параметр Из ПараметрыМетода Цикл
           
	QueryПараметры = QueryПараметры + Символы.ПС
			+ "Ключ: " + СокрЛП(Параметр.Ключ)
			+", Значение: " + СокрЛП(Параметр.Значение);

 КонецЦикла;

~ПрерываемМетод:
Если Не ПрерываниеМетода Тогда     

	Результат = "Переданы параметры: " + QueryПараметры;         

КонецЕсли;

Пояснение: Мы проверяем, есть ли параметр "Кот" и если он отсутствует, заполняем структуру возврата сообщением, которое ложем в результат. После прерываем метод.

Проверяем. В запросе все хорошо:

Проверяем. В запросе нет кота:

Эта возможность может не использоваться, но она есть.

Скопируем метод "MethodWithParameters" и установим ему версию "V2"

На закладке "Вычисления" снимем галку "Произвольный алгоритм" и создадим алгоритм "MethodWithParameters"

На закладку "Вычисления" вставим код:

	QueryПараметры = "";
	Для Каждого Параметр Из ПараметрыАлгоритма Цикл

		QueryПараметры = QueryПараметры + Символы.ПС
			+ "Ключ: " + СокрЛП(Параметр.Ключ)
			+", Значение: " + СокрЛП(Параметр.Значение);             

	КонецЦикла;
	Результат = "Переданы параметры в алгоритм: " + QueryПараметры;

Проверяем:

В данный момент нет удобного способа, нужно описать использование обработки кодом, но в будущих версиях данную возможность можно будет делать без кода.

Создаем новый метод:

На закладке "Запрос" – "Тело" пишем код:

// читаем JSON                          
ТелоЗапросаJSON = PAPI.Прочитать_JSON(СтруктураВходныхПараметров.ТелоЗапроса);
Если ТипЗнч(ТелоЗапросаJSON) = Тип("Структура") Тогда

	Если ТелоЗапросаJSON.Свойство("FIO") Тогда
		ПараметрыМетода.Вставить("ФИО",СокрЛП(ТелоЗапросаJSON.FIO));
	КонецЕсли;           
                              
КонецЕсли;
Результат = ПараметрыМетода;

На закладке "Вычисления" пишем код:

ОписаниеЗащиты = Новый ОписаниеЗащитыОтОпасныхДействий;
ОписаниеЗащиты.ПредупреждатьОбОпасныхДействиях = Ложь;
текОбработка = ВнешниеОбработки.Создать("E:\iGitYou\MyPrj\PAPI\demo\additional\ДемоПримерыМетодовPAPI.epf", Ложь, ОписаниеЗащиты);

Результат = текОбработка.ПреобразоватьФИОВЛатиницу(ПараметрыМетода, СтруктураВозврата);

По указанному пути: E:\iGitYou\MyPrj\PAPI\demo\additional\ ДемоПримерыМетодовPAPI.epf

Будет лежать обработка с кодом в модуле:

Функция ПреобразоватьФИОВЛатиницу(ПараметрыМетода, СтруктураВозврата) Экспорт

ФИО = ?(ПараметрыМетода.Свойство("ФИО"), ПараметрыМетода.ФИО, "");
Результат = ПеревестиНаСервере(ФИО);                                                                                                                                                                                                               
Возврат Результат;

КонецФункции                         
                       
// Функция - Преобразует ФИО на русском в ФИО на латинском в соответствие с
//                             Приказом МИД России от 12.02.2020 N 2113
//
// Параметры:
//  ФИО        - Строка - Содержит ФИО на русском
//
// Возвращаемое значение:
//  FIO - возвращает ФИО на латинице в соответствие Приказ МИД России от 12.02.2020 N 2113
//                  "Об утверждении Административного регламента Министерства иностранных дел Российской
//                  Федерации по предоставлению государственной услуги по оформлению и выдаче паспорта,
//                  удостоверяющего личность гражданина...
//
Функция ПеревестиНаСервере(знач ФИО) 

ФИО  = СокрЛП(ФИО);
ДлинаФИО = СтрДлина(ФИО);
Если ДлинаФИО < 1 Тогда
	Возврат "";
КонецЕсли;

СоответствиеБукв = Новый Соответствие;
СоответствиеБукв.Вставить("А","A");
СоответствиеБукв.Вставить("Б","B");
СоответствиеБукв.Вставить("В","V");
СоответствиеБукв.Вставить("Г","G");
СоответствиеБукв.Вставить("Д","D");
СоответствиеБукв.Вставить("Е","E");
СоответствиеБукв.Вставить("Ё","E");
СоответствиеБукв.Вставить("Ж","ZH");
СоответствиеБукв.Вставить("З","Z");
СоответствиеБукв.Вставить("И","I");
СоответствиеБукв.Вставить("Й","I");
СоответствиеБукв.Вставить("К","K");
СоответствиеБукв.Вставить("Л","L");
СоответствиеБукв.Вставить("М","M");
СоответствиеБукв.Вставить("Н","N");
СоответствиеБукв.Вставить("О","O");
СоответствиеБукв.Вставить("П","P");
СоответствиеБукв.Вставить("Р","R");
СоответствиеБукв.Вставить("С","S");
СоответствиеБукв.Вставить("Т","T");
СоответствиеБукв.Вставить("У","U");
СоответствиеБукв.Вставить("Ф","F");
СоответствиеБукв.Вставить("Х","KH");
СоответствиеБукв.Вставить("Ц","TS");
СоответствиеБукв.Вставить("Ч","CH");
СоответствиеБукв.Вставить("Ш","SH");
СоответствиеБукв.Вставить("Щ","SHCH");
СоответствиеБукв.Вставить("Ы","Y");
СоответствиеБукв.Вставить("Ъ","IE");
СоответствиеБукв.Вставить("Ь","");
СоответствиеБукв.Вставить("Э","E");
СоответствиеБукв.Вставить("Ю","IU");
СоответствиеБукв.Вставить("Я","IA");
СоответствиеБукв.Вставить(" "," ");

ФИО = ВРег(ФИО);         
FIO = "";
Для Индекс = 1 По ДлинаФИО Цикл
	текСимвол = Сред(ФИО, Индекс, 1);
	Если СоответствиеБукв[текСимвол] <> Неопределено Тогда
		FIO = FIO + СоответствиеБукв[текСимвол];
	КонецЕсли;

КонецЦикла;

Возврат FIO;

КонецФункции

Проверяем:

В расширение "ЛокализацияPAPI" добавим обработку " ДемоПримерыМетодовPAPI.epf"                               

В ней код из Примера 8: Метод post во внешней обработке.

Создадим копированием метод из Примера 8: Метод post во внешней обработке:

На закладке "Вычисления" добавим код:

текОбработка = Обработки.ДемоПримерыМетодовPAPI.Создать();   

Результат = текОбработка.ПреобразоватьФИОВЛатиницу(ПараметрыМетода, СтруктураВозврата);

Проверяем: