HTTP Сервисы: Путь к своему сервису. Часть 2

Публикация № 885287

Разработка - Инструментарий разработчика

HTTP-сервис API JSON IIS http web apache сервис Публикатор Линк PAPI Pretty API atom-xml XML oData Код состояния Get Post Patch

Продолжение статьи «HTTP Сервисы: Путь к своему сервису. Часть 1». В этой части будет "Микс" из OData+HTTP-Сервис(Get)+СКД. Наш пример будет работать как в браузере, так и в написанной нами обработке. Работать будем с разными версиями платформ.

В первой части мы создали каркас для Get метода в расширении конфигурации. Как Вы помните, мы получали через один метод список или конкретный документ, давайте рассмотрим еще один инструмент, позволяющий без особого труда и без доработок конфигурации получать те же данные. Как Вы догадались, начнем разговор с OData, далее смиксуем OData с нашим сервисом который будет возвращать данные на основе СКД. 

Как и в предыдущей статье http-сервис будет в расширении конфигурации ERP 2.4.3.145 на платформе 8.3.10.2650, а вот посылать запросы и получать ответы будем в Демо конфигурации БСП 3.0.1.231 на платформе 8.3.12.1567. Специально чтобы версии платформы отличались.

Начнем.

Немножко про OData.

Для начала дам ссылки, где можно почитать про использование OData в 1с:

  1. Глава 17.2.1. Cтандартный интерфейс OData
  2. Приложение 12. Описание сущностей, предоставляемых через стандартный интерфейс OData
  3. Способы интеграции с 1С

Давайте кратенько пройдем по основным пунктам.

 
1 Как опубликовать OData? 

 В конфигураторе Администрирование/Публикация на веб-сервере...

 
2 Из чего складывается URL OData? 

http://host/base/odata/standard.odata/ПрефиксИмени_ИмяОбъектаКонфигурации_СуффиксИмени/Параметры?Параметры&УсловияОтбора

host – IP адрес или доменное имя веб сервера.

base – Имя базы. Указывается при публикации.

odata/standard.odata - Признак обращения к стандартному интерфейсу OData.

ПрефиксИмени - Представление объекта конфигурации для указания в URL (Объекты доступные в OData и их префиксы описаны в главе 17.2.1.4. Правила формирования имени ресурса, а так же можно посмотреть с помощью обработки Доступный состав стандартного интерфейса OData).

ИмяОбъектаКонфигурации - свойство Имя объекта конфигурации, как оно задано при разработке прикладного решения в конфигураторе.

СуффиксИмени - предназначено для уточнения имени ресурса и является необязательной частью имени. В качестве суффикса имени могут выступать следующие выражения:

  • Имя табличной части объекта;
  • Имя реквизита табличной части или набора записей;
  • Имя виртуальной таблицы регистра;
  • RowType;
  • RecordType.

Праметры и УсловияОтбора – В качестве параметров обращения выступают параметры в виде, принятом для HTTP-запросов: ?ключ=значение&ключ2=значение2.
При обращении к ресурсу могут использоваться специальные ключевые слова, имеющие специальное назначение:

  • $format - указывает, в каком формате необходимо получить данные. Если ключевое слово не указано, данные получаются в формате atom-xml.
  • $format=atom - возвращает данные в формате atom-xml.
  • $format=json - возвращает данные в формате json. Для указания того, что данные должны возвращаться в формате json, можно указать MIME-тип application/json в заголовке Accept HTTP-запроса на получение данных.
  • $metadata - указывает, что требуется получить описание стандартного интерфейса OData.
  • $filter - описывает отбор, применяемый при получении данных.
  • $select - описывает перечень свойств сущности, которые получаются при обращении к стандартному интерфейсу OData. 
 
 3 Какие HTTP-методы используется в OData?
  • GET - Получение данных;
  • POST - Создание объекта;

Обновление данных:

  • PATCH - в этом случае можно указывать только те свойств, которые необходимо обновить;
  • PUT - в этом случае необходимо указывать все свойства сущности;
  • DELETE - Удаление данных.

Лично я использую только GET, так как изменение, добавление и тем более удаление данных через OData считаю неправильным (потенциально опасным) для Учетных систем. Данные методы могут быть хороши для конфигурации разработанной например под мобильный клиент, ну или под сайт.

Давайте узнаем, сколько элементов в справочнике Склады в Демо конфигурации ERP 2.4.3.145.

Для этого мы будем использовать параметр $count. Наш запрос: 

http://127.0.0.1/DemoEnterprise2_4_3_145/odata/standard.odata/Catalog_Склады/$count

Как мы видим, получить данные не удалось. В чем же дело?

Дело в том, что начиная с версии платформы 8.3.5.1068 необходимо использовать метод УстановитьСоставСтандартногоИнтерфейсаOData для того чтобы объекты конфигурации были доступны для использования в OData. Давайте воспользуемся обработкой Доступный состав стандартного интерфейса OData и дадим доступ к нужному нам справочнику.

Проверяем наш запрос еще раз.

Как мы видим в конфигурации 49 элементов справочника Склады.

 

Давайте нарисуем сервис по получению остатков на складе, при этом в ЕРП мы будем брать за основу отчет «ОстаткиИДоступностьТоваров» и на основании СКД макета будем получать данные и возвращать их в формате JSON (Реализовано в версии 8.3.6.1977). Обращаться к сервису будем с помощью обработки из конфигурации на платформе 8.3.12.

Хочу сразу сказать json выбран из-за своей компактности, удобочитаемости и легкости работы с данным форматом.

 
Для примера сравните atom-xml и json, я вывел один и тот же элемент в этих форматах. 

Для начала нам нужно получить в обработку перечень складов (наименование и идентификатор), при этом склады должны быть элементами, не помеченными на удаление.

Проверим сколько таких элементов: http://127.0.0.1/DemoEnterprise2_4_3_145/odata/standard.odata/Catalog_Склады/$count?$select=Ref_Key,Description&$filter=DeletionMark eq false and IsFolder eq false&$format=json;odata=nometadata

38 это немного, нас это вполне устраивает, будем создавать на форме реквизит cклад, и заполнять список данными полученными по OData.

Создаем обработку «ПолучитьОстаткиИДоступностьТоваров.epf», добавляем форму и добавляем на нее реквизит «Склад» с типом строка и команду ЗагрузитьСклады

 
 Текст команды ЗагрузитьСклады
&НаКлиенте
Процедура ЗагрузитьСклады(Команда)
	ПолучитьСписокСкладовНаСервере();	
КонецПроцедуры
&НаСервере
Процедура ПолучитьСписокСкладовНаСервере()
	//Чистим список
	Элементы.Склад.СписокВыбора.Очистить();
	
	//В тестовых обработках так делать можно, но когда делаете в рабочей такие вещи НЕДОПУСТИМЫ!
	//Храните логины и пароли в недоступных для глаз местах! (https://its.1c.ru/db/v8std#content:2149184389:hdoc) 
	перПорт = 0;
	перСервер = "127.0.0.1";
	перПользователь = "Администратор (ОрловАВ)";
	перПароль = "";

	//Формируем запрос для OData
	перРесурсНаСервере = "/DemoEnterprise2_4_3_145/odata/standard.odata/";	
	перРесурсНаСервереФин = перРесурсНаСервере + 
	"Catalog_Склады?$select=Ref_Key,Description&$filter=DeletionMark eq false and IsFolder eq false&$format=json;odata=nometadata";
	
	Попытка
		Если перПорт <= 0 Тогда 
			HTTPСоединение = Новый HTTPСоединение(перСервер,,перПользователь,перПароль);
		Иначе 
			HTTPСоединение = Новый HTTPСоединение(перСервер,перПорт,перПользователь,перПароль);
		КонецЕсли;
		
		HTTPЗапрос= Новый HTTPЗапрос(перРесурсНаСервереФин);
		HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
		
		РезультатМассив = Новый СписокЗначений;	
		Если HTTPОтвет.КодСостояния = 200 Тогда 
			Ответочка = HTTPОтвет.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);	
					
			ЧтениеJSON = Новый ЧтениеJSON;
			ЧтениеJSON.УстановитьСтроку(Ответочка);
			Попытка
				ДопДанные = ПрочитатьJSON(ЧтениеJSON);
			Исключение
				ДопДанные = "";
			КонецПопытки;
				
			Если ТипЗнч(ДопДанные) = Тип("Структура") Тогда
				//Заполняем список Складов
				Если ДопДанные.Свойство("Ref_Key") и ДопДанные.Свойство("Description") Тогда 
					Элементы.Склад.СписокВыбора.Добавить(ДопДанные.Ref_Key,ДопДанные.Description);
				ИначеЕсли ДопДанные.Свойство("value") Тогда
					ДопДанные = ДопДанные.value;
					
					Если ТипЗнч(ДопДанные) = Тип("Массив") Тогда	
						Для Каждого элМассива из ДопДанные Цикл 
							Если ТипЗнч(элМассива) = Тип("Структура") Тогда
								Если элМассива.Свойство("Ref_Key") и элМассива.Свойство("Description") Тогда 
									Элементы.Склад.СписокВыбора.Добавить(элМассива.Ref_Key,элМассива.Description);	
								Иначе
									//Нет Ref_Key
								КонецЕсли;
							КонецЕсли
						КонецЦикла;
					КонецЕсли;
				Иначе
					//Нет Ref_Key
				КонецЕсли;	
			Иначе 
				//не смогли прочитать
			КонецЕсли;	

		КонецЕсли;
	Исключение
		Сообщить("Подключится к ERP не получилось: "+ОписаниеОшибки());	
	КонецПопытки;
	
	HTTPСоединение = Неопределено;

КонецПроцедуры

 

У реквизита Склад делаем РежимВыбораИзСписка

Первая часть сделана, давайте перейдем к нашему отчету в ЕРП.

Мы видим следующую картину:

Это значит, что при попытке программно получить данные из СКД в ДеревоЗначений мы получим ошибку.

 
 Ошибка при вызове метода контекста (Выполнить)

        МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновки, НастройкиКомпоновки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

по причине:

Ошибка компоновки макета

по причине:

Ошибка генерации макета

по причине:

Не поддерживается вывод таблиц и диаграмм в универсальную коллекцию значений

Есть несколько путей решения данной проблемы, я пойду самым простым. В расширение добавлю отчет и создам в нем нужный мне макет.

Теперь можно создать новый метод «ОстаткиИДоступностьТоваровПоСкладу». Подготовлю почву под следующую часть данного цикла статей и создам модуль «PAPI_ОбработкаУниверсальныхМетодов»

 
 Код модуля PAPI_ОбработкаУниверсальныхМетодов
#Область Методы
Процедура ПолучитьОстаткиИДоступностьТоваровПоСкладу(СтруктураОтвет,СтруктураВхПараметров) Экспорт 
	//ПраметрыЗапроса - number
	Склад_Key = СтруктураВхПараметров.ПараметрыЗапроса.Получить("Ref_Key");

	Если не Склад_Key = Неопределено Тогда
		//Получаем Склад
		Попытка
			Склад = XMLЗначение(Тип("СправочникСсылка.Склады"), Склад_Key); 
		Исключение
			Склад = Неопределено;
		КонецПопытки;
		
		Если ЗначениеЗаполнено(Склад) Тогда 
			//Получаем схему компоновки и вариант отчета
			//СхемаКомпоновки = Отчеты.ОстаткиИДоступностьТоваров.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
			//ВариантНастроеки = СхемаКомпоновки.ВариантыНастроек.Найти("ОстаткиИДоступностьТоваров");	
			СхемаКомпоновки = Отчеты.PAPI_ХранилищеМакетов.ПолучитьМакет("СКД_ОстаткиИДоступностьТоваров_HTTP");
			ВариантНастроеки = СхемаКомпоновки.ВариантыНастроек.Найти("ОстаткиИДоступностьТоваровНеТаблица");
			НастройкиКомпоновки = ВариантНастроеки.Настройки;	
				
			//Взято из модуля отчета.ОстаткиИДоступностьТоваров "ПриКомпоновкеРезультата"++	
			ТекстЗапроса = СхемаКомпоновки.НаборыДанных.Основной.Запрос;

			ТекстЗапроса = СтрЗаменить(
				ТекстЗапроса, 
				"&ТекстЗапросаВесНоменклатуры", 
				Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки("Набор.Номенклатура.ЕдиницаИзмерения", "Набор.Номенклатура"));
					
			ТекстЗапроса = СтрЗаменить(
				ТекстЗапроса, 
				"&ТекстЗапросаОбъемНоменклатуры", 
				Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаОбъемУпаковки("Набор.Номенклатура.ЕдиницаИзмерения", "Набор.Номенклатура"));

			СхемаКомпоновки.НаборыДанных.Основной.Запрос = ТекстЗапроса;
			//Взято из модуля отчета.ОстаткиИДоступностьТоваров "ПриКомпоновкеРезультата"--                           	
					
			ПрараметрОтбора = НастройкиКомпоновки.Отбор.Элементы;
			СкладПолеКомпоновки = Новый ПолеКомпоновкиДанных("Склад");
			Для Каждого СтрокаОтбора из ПрараметрОтбора Цикл 
				Если СтрокаОтбора.ЛевоеЗначение = СкладПолеКомпоновки  Тогда
					СтрокаОтбора.Использование 	= Истина;
					СтрокаОтбора.ВидСравнения 	= ВидСравненияКомпоновкиДанных.Равно;
					СтрокаОтбора.ПравоеЗначение = Склад; 	
				КонецЕсли;
			КонецЦикла;	
						
			КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
			
			МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновки, НастройкиКомпоновки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
				
			ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;     
			ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,,Истина);
			
			ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;     
			ДеревоЗначений = Новый ДеревоЗначений;     
			ПроцессорВывода.УстановитьОбъект(ДеревоЗначений);         	
			ПроцессорВывода.Вывести(ПроцессорКомпоновки);
				
			//Обходим дерево и формируем РезультатОтвет
			РезультатОтвет = Новый Массив;
			Для Каждого ВерхнийУровеньДерева Из ДеревоЗначений.Строки Цикл	
				Для Каждого ПодчиненныйУровеньДерева Из ВерхнийУровеньДерева.Строки Цикл	
					Если ЗначениеЗаполнено(ПодчиненныйУровеньДерева.Номенклатура) 
						И ТипЗнч(ПодчиненныйУровеньДерева.Номенклатура) = Тип("СправочникСсылка.Номенклатура") 
					Тогда 
						РезультатОтвет.Добавить(Новый Структура("ИмяЗначение,Артикул,Guid,ДоступноСейчас,Остаток",
						ПодчиненныйУровеньДерева.Номенклатура.Наименование +
							?(ЗначениеЗаполнено(ПодчиненныйУровеньДерева.Характеристика),
								","+Строка(ПодчиненныйУровеньДерева.Характеристика),""),
						ПодчиненныйУровеньДерева.НоменклатураАртикул,
						XMLСтрока(ПодчиненныйУровеньДерева.Номенклатура),
						ПодчиненныйУровеньДерева.ДоступноСейчас,
						ПодчиненныйУровеньДерева.ВНаличии));
					КонецЕсли;	
				КонецЦикла;
			КонецЦикла;
				
			//РезультатОтвет в JSON
			ПараметрыJSON	= Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет, " " , Истина, ЭкранированиеСимволовJSON.Нет, Ложь, Ложь, Ложь, Ложь);
			ЗаписьJSON		= Новый ЗаписьJSON;
			ЗаписьJSON.ПроверятьСтруктуру = Истина;
			ЗаписьJSON.УстановитьСтроку(ПараметрыJSON);

			ЗаписатьJSON(ЗаписьJSON, РезультатОтвет);
			Результат = ЗаписьJSON.Закрыть();
				
			СтруктураОтвет.ДанныеОтвета = Результат;
			
			СтруктураОтвет.Вставить("ФорматОтвета",PAPI_ОбщиеПроцедурыИФункции.ФорматОтветаJSON());
		Иначе
			PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Не заполнен или неверно заполнен параметр ""Ref_Key""",ложь,"");	
		КонецЕсли;	
	Иначе
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Отсутствует параметр ""Ref_Key""",ложь,"");	
	КонецЕсли;	
КонецПроцедуры	
#КонецОбласти

 

Так же добавим модуль PAPI_ОбщиеПроцедурыИФункции

 
 Код модуля PAPI_ОбщиеПроцедурыИФункции
//Заполняем структуру ответа
Процедура ЗаполнитьСтруктуруОтвета(СтруктураОтвет,КодОтвета,ТекстОшибки,Отработало,ДанныеОтвета) Экспорт
	СтруктураОтвет.КодОтвета 	= КодОтвета;
	СтруктураОтвет.ТекстОшибки	= ТекстОшибки;
	СтруктураОтвет.Отработало	= Отработало;
	СтруктураОтвет.ДанныеОтвета = ДанныеОтвета;	
КонецПроцедуры


#Область ФорматыОтвета
Процедура ВозвращаемНужныйФорматОтвета(Ответ,СтруктураОтвет) Экспорт
	
	Если СтруктураОтвет.Свойство("ФорматОтвета") Тогда 
		ФорматОтвета = СтруктураОтвет.ФорматОтвета;
	Иначе
		ФорматОтвета = "";
	КонецЕсли;	

	Если ВРег(ФорматОтвета) = Врег(ФорматОтветаJSON()) Тогда 
		Ответ.Заголовки.Вставить("Content-Type","application/json; charset=utf-8");
	Иначе 	
		Ответ.Заголовки.Вставить("Content-Type","text/html; charset=utf-8");
	КонецЕсли;
КонецПроцедуры

Функция ФорматОтветаJSON() Экспорт 
	Возврат "JSON";	
КонецФункции
#КонецОбласти

 

Подредактируем модуль PAPI_ОбработкаМетодовGET, добавим в него новый метод "ОстаткиИДоступностьТоваровПоСкладу" и уберем процедуру "ЗаполнитьСтруктуруОтвета"

 
 Код модуля PAPI_ОбработкаМетодовGET
//Функция экспортная, специально чтобы можно было отлаживать как по HTTP(https://its.1c.ru/db/metod8dev#content:5756:hdoc)
//Так и через внешнюю обработку
Функция PAPI_ОбработкаМетодовGET(СтруктураВхПараметров) Экспорт
	//структура ответа. Собственна нужна для формирования ответа
	СтруктураОтвет = Новый Структура("ДанныеОтвета,Отработало,ТекстОшибки,КодОтвета","",Истина,"",200);
	
	//Переправляем на нужный метод
	Если ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("Список") Тогда
		
		ПолучитьСписок(СтруктураОтвет,СтруктураВхПараметров);	
		
	ИначеЕсли ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("Документ") Тогда

		ПолучитьДокумент(СтруктураОтвет,СтруктураВхПараметров);
		
//Получаем доступные остатки по складу в формате JSON	
	ИначеЕсли ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("ОстаткиИДоступностьТоваровПоСкладу") Тогда
		
		PAPI_ОбработкаУниверсальныхМетодов.ПолучитьОстаткиИДоступностьТоваровПоСкладу(СтруктураОтвет,СтруктураВхПараметров);	
		
	Иначе
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,501,"Отсутствует Метод " + ?(СтруктураВхПараметров.ИмяМетода=Неопределено,"",СтруктураВхПараметров.ИмяМетода),ложь,"");
	КонецЕсли;
	Возврат СтруктураОтвет;	
КонецФункции

#Область Методы
Процедура ПолучитьСписок(СтруктураОтвет,СтруктураВхПараметров)
	Результат = "Расходная накладная, 1, 01.01.2014
	|Расходная накладная, 2, 01.01.2014";
	СтруктураОтвет.ДанныеОтвета = Результат;
КонецПроцедуры	

Процедура ПолучитьДокумент(СтруктураОтвет,СтруктураВхПараметров)
	//ПраметрыЗапроса - number
	ПарНомер = СтруктураВхПараметров.ПараметрыЗапроса.Получить("number");

	Номер = Число(?(ПарНомер=Неопределено,0,ПарНомер));
	Если Номер > 2 Тогда
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Отсутствует документ с номером: " + Номер,ложь,"");
	Иначе	
		Если Номер = 1 Тогда
			Результат = "Расходная накладная, 1, 01.01.2014";
		Иначе
			Результат = "Расходная накладная, 2, 01.01.2014";
		КонецЕсли;
		СтруктураОтвет.ДанныеОтвета = Результат;	
	КонецЕсли;
КонецПроцедуры	

#КонецОбласти

 

Добавим одну строчку в обработчик метода Get.

 
 Код PrettyAPIGET
Функция PrettyAPIGET(Запрос)
	СтруктураВхПараметров = Новый Структура;
	//Получаем имя метода
	перИмяМетода  = Запрос.ПараметрыURL["ИмяМетода"];    
	//Помещаем имя метода в структуру
	СтруктураВхПараметров.Вставить("ИмяМетода",перИмяМетода);  
	
	//Забираем параметры из запроса
	ВхПараметрыЗапроса = Новый Соответствие;
	Для каждого Параметр Из Запрос.ПараметрыЗапроса Цикл
        ВхПараметрыЗапроса.Вставить(Параметр.Ключ,Параметр.Значение);
    КонецЦикла;
	СтруктураВхПараметров.Вставить("ПараметрыЗапроса",ВхПараметрыЗапроса);
	
	//Передаем входящие параметры (Модуль для метода GET)
	СтруктураОтвет = PAPI_ОбработкаМетодовGET.PAPI_ОбработкаМетодовGET(СтруктураВхПараметров);
	
	//Создаем ответ с кодом состояния
	Ответ = Новый HTTPСервисОтвет(СтруктураОтвет.КодОтвета);
	Если СтруктураОтвет.Отработало Тогда 
	    Ответ.УстановитьТелоИзСтроки(СтруктураОтвет.ДанныеОтвета,КодировкаТекста.UTF8);
	Иначе
		Ответ.УстановитьТелоИзСтроки(СтруктураОтвет.ТекстОшибки,КодировкаТекста.UTF8);
	КонецЕсли;	
	
	//В зависимости от формата меняем "Content-Type"
	PAPI_ОбщиеПроцедурыИФункции.ВозвращаемНужныйФорматОтвета(Ответ,СтруктураОтвет);
	
	Возврат Ответ;
КонецФункции

 

На этом подготовка ЕРП окончена. Проверим через браузер результат, выполним следующий запрос:

http://127.0.0.1/DemoEnterprise2_4_3_145/hs/PrettyAPI/V1/ОстаткиИДоступностьТоваровПоСкладу?Ref_Key=3ae74af9-e911-11e6-b7b5-bcaec56cc144

Наш сервис готов! Давайте теперь дорисуем обработку и будем подводить итоги.

Добавим в обработку реквизит "Результат" с типом строка. В него мы просто будем выводить текст ответа.

Добавим ТаблицуЗначений "ОстаткиИДоступность":

  • Наименование (Строка)
  • Артикул (Строка)
  • Доступно (Число(15,3))
  • Остаток (Число(15,3))
  • Идентификатор (Строка)

Добавим команду "ПолучитьРезультат"

 
 Код команды ПолучитьРезультат
&НаКлиенте
Процедура ПолучитьРезультат(Команда)
	ОчиститьСообщения();
	Если Не ЗначениеЗаполнено(Склад) Тогда 
		Сообщить("Склад не заполнен!");
		Возврат;
	КонецЕсли;	
	
	ОстаткиИДоступность.Очистить();
	ПолучитьРезультатНаСервере();
КонецПроцедуры
&НаСервере
Процедура ПолучитьРезультатНаСервере()
	перПорт = 0;
	перСервер = "127.0.0.1";
	перПользователь = "Администратор (ОрловАВ)";
	перПароль = "";

	//Формируем запрос для OData
	перРесурсНаСервере = "/DemoEnterprise2_4_3_145/hs/PrettyAPI/V1/";	
	перРесурсНаСервереФин = перРесурсНаСервере + 
	"ОстаткиИДоступностьТоваровПоСкладу?Ref_Key="+Склад;
	
	Попытка
		Если перПорт <= 0 Тогда 
			HTTPСоединение = Новый HTTPСоединение(перСервер,,перПользователь,перПароль);
		Иначе 
			HTTPСоединение = Новый HTTPСоединение(перСервер,перПорт,перПользователь,перПароль);
		КонецЕсли;
		
		HTTPЗапрос= Новый HTTPЗапрос(перРесурсНаСервереФин);
		HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
		
		РезультатМассив = Новый СписокЗначений;	
		Если HTTPОтвет.КодСостояния = 200 Тогда 
			Ответочка = HTTPОтвет.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);	
			Результат = Ответочка;	
			
			ЧтениеJSON = Новый ЧтениеJSON;
			ЧтениеJSON.УстановитьСтроку(Ответочка);
			Попытка
				//ДопДанные = ПрочитатьJSON(ЧтениеJSON, Ложь);
				МасДопДанные = ПрочитатьJSON(ЧтениеJSON);
			Исключение
				МасДопДанные = "";
			КонецПопытки;
				
			Если ТипЗнч(МасДопДанные) = Тип("Массив") Тогда
				Для Каждого ДопДанные из МасДопДанные Цикл 
					//"ИмяЗначение","Артикул","Guid","ДоступноСейчас","Остаток"
					Если ДопДанные.Свойство("ИмяЗначение") 
						И ДопДанные.Свойство("Guid") 
						И ДопДанные.Свойство("ДоступноСейчас") 
						И ДопДанные.Свойство("Остаток") Тогда
						новСтрока = ОстаткиИДоступность.Добавить();
						
						новСтрока.Наименование 		= ДопДанные.ИмяЗначение;
						новСтрока.Идентификатор		= ДопДанные.Guid;
						новСтрока.Доступно		 	= ДопДанные.ДоступноСейчас;
						новСтрока.Остаток		 	= ДопДанные.Остаток;
						новСтрока.Артикул           = ?(ДопДанные.Свойство("Артикул"),ДопДанные.Артикул,"");
					КонецЕсли;
				КонецЦикла;	
			Иначе 
				//не смогли прочитать
			КонецЕсли;	

		КонецЕсли;
	Исключение
		Сообщить("Подключится к ERP не получилось: "+ОписаниеОшибки());	
	КонецПопытки;
	
	HTTPСоединение = Неопределено;
КонецПроцедуры

 

Внешний вид формы:

Проверяем результат:

Вторую часть заканчиваю. Мы рассмотрели с Вами как можно смешивать разные технологии. Я думал, в этой части поговорить про другие методы, но вышло громоздко, поэтому в следующей части поговорим о других методах и длительных операциях.

Статьи из данного цикла:

HTTP Сервисы: Путь к своему сервису. Часть 1

HTTP Сервисы: Путь к своему сервису. Часть 3

HTTP Сервисы: Путь к своему сервису. Часть 4

Скачать файлы

Наименование Файл Версия Размер
Расширение с http-сервисами из примера

.cfe 23,20Kb
13.08.18
20
.cfe 0.0.2 23,20Kb 20 Скачать
Обработка из примера: ПолучитьОстаткиИДоступностьТоваров.epf

.epf 8,65Kb
13.08.18
23
.epf 1.0.0 8,65Kb 23 Скачать

Специальные предложения

Оставьте свое сообщение

См. также

Безопасная работа с транзакциями во встроенном языке Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Разбираемся с опасностями использования транзакций во встроенном языке 1С. Познаем ошибку "В данной транзакции уже происходили ошибки". Учимся защищаться от них.

1 стартмани

25.03.2019    36117    tormozit    54    

Cбор и анализ ошибок при помощи Sentry, или как упростить жизнь себе и пользователям

Практика программирования Интеграция v8 Абонемент ($m)

Цель данной статьи - сделать процесс сбора и анализа ошибок, происходящих в базе, максимально простым, быстрым и удобным, собирать статистику по ошибкам, местам их возникновения и частоте их появления, а также в деталях разобрать все тонкости по интеграции 1С с Sentry.

1 стартмани

09.10.2020    2805    hexhoc    12    

Программная корректировка при выводе отчета СКД

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Большинство отчетов на СКД, требующих программной корректировки, реализуются с помощью программной настройки СКД или обработки табличного документа уже после вывода отчета. Но во многих случаях более оптимально будет выполнять программную корректировку в процессе вывода отчета. Для этого существуют программные объекты, о которых я расскажу в данной статье.

1 стартмани

08.10.2020    3449    dabu-dabu    8    

Библиотека программного изменения формы (УФ)

Инструментарий разработчика Работа с интерфейсом Универсальные функции v8 1cv8.cf Абонемент ($m)

Нам часто приходится дорабатывать различные управляемые формы. Проще внести изменения непосредственно на самой форме, но, для дальнейшего поддержания конфигурации, удобнее вносить все изменения на форме программно. Предлагаю Вам библиотеку для программного изменения управляемых форм, которую можно внедрить в конфигурацию либо совсем бесшовно, либо практически бесшовно.

1 стартмани

07.08.2020    4594    BuriyLesha    17    

Как выполнить отчет на СКД через COM и получить данные отчета? Промо

Практика программирования v8 УПП1 Россия Абонемент ($m)

Для чего это нужно. Например, нужно в одной базе получить какой-либо показатель из другой базы. Этот показатель вычисляется в каком-либо сложном отчете, который написан на СКД. Можно, конечно, "скопипастить" текст запроса из другой базы, немного подправить его и выполнять в том же COM подключении. Но с этим теряется гибкость: если отчет изменился, то нужно помнить о том, что где-то есть его "немного модифицированная" копия. В статье будет рассмотрен пример получения данных из базы ЗУП.

2 стартмани

08.05.2018    27231    wowik    3    

Загрузка, скачивание, удаление файлов с помощью НачатьПомещениеФайлаНаСервер() и НачатьПолучениеФайлаССервера()

Практика программирования v8 1cv8.cf Абонемент ($m)

В платформе 8.3.15 появились новые методы НачатьПомещениеФайлаНаСервер() и НачатьПолучениеФайлаССервера(). В данной статье рассмотрено готовое решение проверенное и прекрасно работающее на тонком и веб-клиенте.

1 стартмани

25.07.2020    3880    Flashill    10    

Параллельные вычисления расчета факториала числа N

Практика программирования v8 1cv8.cf Абонемент ($m)

Распараллеливание алгоритма с помощью фоновых заданий (асинхронные вычисления)

1 стартмани

29.06.2020    2872    Rustig    17    

Перевод кода и метаданных конфигурации на английский язык: часть 2

Инструментарий разработчика EDT Локализация решений v8 1cv8.cf Абонемент ($m)

Практический пример подготовки словаря для перевода кода и модели конфигурации УНФ 1.6 на английский язык с использованием существующих словарей и плагина EDT Language Tool. В статье приводятся готовые скрипты и алгоритмы сборки и нормализации словаря.

1 стартмани

05.04.2020    2395    vanjushkin    0    

Как нарисовать граф на 1С Промо

Практика программирования v8 Абонемент ($m)

Описывается реализация на языке запросов 1С метода расположения вершин графа на плоскости, основанного на использовании электромеханической аналогии. При этом вершины графа представляются одноименными электрическими зарядами, дуги - пружинками. Силы взаимодействия вершин в этой системе переводят их из случайного начального в нужное конечное положение. Приведена обработка рисования графов "ГрафОграф", реализующая данный подход, показывающая также динамику процесса. Граф можно задать списком ребер вручную, выбрать из нескольких предопределенных примеров или сформировать по данным информационной базы.

1 стартмани

09.08.2013    70734    ildarovich    117    

Перевод кода и метаданных конфигурации на английский язык с помощью плагина EDT: Language Tool

EDT Локализация решений v8 1cv8.cf Абонемент ($m)

Использование регулярных выражений для парсинга .mdo-файлов и составления русско-английского словаря метаданных. Перевод кода и метаданных конфигурации по словарю с помощью нового инструмента 1С - плагина EDT: Language Tool на примере УНФ 1.6

1 стартмани

03.04.2020    2175    vanjushkin    10    

Методика обновления формы объекта данных при изменении объекта

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

В формах объектов данных часто встречаются элементы, косвенно связанные с объектом. Логику обновления этих элементов при изменении объекта обычно вызывают из обработчиков ПриСозданнииНаСервере и ПриОткрытии, забывая про наличие других способов изменения объекта. В статье предложена методика для обычных и управляемых форм, учитывающая все способы.

1 стартмани

09.03.2020    8952    tormozit    13    

Отправка уведомлений с помощью командной строки, Оповещения с сервера на клиент с помощью командной строки

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Отправка уведомлений с помощью команды командной строки msg. Оповестить пользователей из серверного модуля или регламентного задания, с помощью командной строки msg.

1 стартмани

05.03.2020    5930    user5300    3    

Простой способ индексирования интервалов Промо

Практика программирования v8 Абонемент ($m)

Предлагается простой способ индексирования интервалов для решения задач выборки записей, включающих заданный момент времени, пересекающихся с заданным интервалом или множеством интервалов. Способ основан на добавлении к исходной таблице особого числового индексированного поля, рассчитываемого по специальной формуле. Приведен код функций, необходимых для расчетов поля поиска и параметров поисковых запросов. Приведены также результаты тестирования метода, доказывающие его высокую эффективность.

1 стартмани

28.09.2016    39867    ildarovich    22    

Вывод сообщений в HTML поле средствами 1С

Практика программирования v8 v8::УФ Абонемент ($m)

Пример использования вывода большого количества сообщений в поле HTML. С возможностью открывать ссылочные объекты и создавать новые объекты передавая параметры прямо из HTML поля. Протестировано на релизах 8.3.12 и 8.3.15+

2 стартмани

31.01.2020    6073    burni4    16    

Краткое руководство по внесению изменений в конфигурацию

Практика программирования v8 1cv8.cf Абонемент ($m)

Кратко описаны основополагающие моменты при старте групповой разработки конфигурации несколькими программистами. Полезно для проектной документации как требование к разработчикам или сопровождающей компании.

1 стартмани

13.01.2020    17751    sapervodichka    41    

Универсальные функции: разложение произвольной строки адреса в структуру

Практика программирования Универсальные функции v8 1cv8.cf Абонемент ($m)

Процедуры и функции раскладывают произвольную строку адрес в структуру по ключевым словам.

1 стартмани

30.12.2019    3946    vik070777    10    

Бесплатная проверка контрагентов в ФНС (общий модуль с алгоритмом). На примере выводим статус в список справочника контрагентов Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Если вам интересно проверить контрагенте в ФНС, вам поможет данная публикация. Весь алгоритм работы строится на основе данных, полученных с сервиса http://npchk.nalog.ru совершенно бесплатно.

1 стартмани

01.02.2018    35302    rpgshnik    49    

"Живые" картинки со Snap.SVG

Практика программирования WEB Работа с интерфейсом v8 Абонемент ($m)

В статье рассмотрен пример использования http-сервисов для визуализации данных

1 стартмани

24.10.2019    13746    blackhole321    7    

RLS - дубли условий в запросах к СУБД

Практика программирования Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

"Подводные камни", возникающие при бездумном копировании ролей с ограничениями RLS, как это отражается на производительности, разбор примера и инструмент для анализа.

1 стартмани

07.10.2019    8572    geron4    4    

Полное копирование одной формы в другую

Практика программирования Универсальные обработки Работа с интерфейсом v8 1cv8.cf Абонемент ($m)

Однажды я столкнулся с необходимостью открыть форму ЛЮБОГО документа с определенными изменениями, не зависящими от структуры объекта (например, заблокировать все кнопки). В интернете решения я не нашел. Обычно на форумах на запросы подобного рода отвечают чем-то вроде "покажи первоначальную задачу, а не спрашивай как реализовать то, что ты придумал". Тем не менее, мне стало интересно, как это можно сделать.

1 стартмани

03.10.2019    5362    nekit_rdx    23    

БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному Промо

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

Очень много попадается странных решений, которые можно решить через БСП:Дополнительные отчеты и обработки. Я бы вообще БСП из-за этой подсистемы переименовал в «Большое Спасибо Программистам». Поработаем с подсистемой в части написания регламентных заданий.

1 стартмани

10.05.2018    45643    dsdred    43    

Многопоточная обработка данных на примере перепроведения документов

Обработка документов Практика программирования v8 ERP2 УТ11 КА2 Абонемент ($m)

Дальнейшее развитие темы фоновой обработки данных - проведение документов в потоках. Настройка параметров и запуск основного процесса (менеджера потоков). Разбивка документов для проведения на не связанные друг с другом наборы и запуск дополнительных фоновых заданий для отдельных потоков. Отслеживание выполнения каждого потока в родительском сеансе.

1 стартмани

17.09.2019    9491    ids79    46    

Отображение истории выполнения по всем задачам комплексного процесса в документообороте

Документооборот и делопроизводство Практика программирования v8 ДО Абонемент ($m)

Коллеги, предлагаю вашему вниманию доработку для вывода полной истории в задачах комплексного процесса.

1 стартмани

15.09.2019    7038    pavelpribytkin96    8    

Хороший заказчик - плохой заказчик

О жизни Россия Бесплатно (free)

Лайфхак о том, как стать легендарным клиентом.

13.09.2019    7991    dsdred    24    

Некоторая работа с данными через COM Промо

Практика программирования v8 Абонемент ($m)

В статье приведены примеры работы с Платформой 8.X через COM (точнее, через объект COMConnector). Примеры кода были использованы при реализации прикладных задач в процессе трудовой деятельности.

2 стартмани

05.12.2012    57800    wowik    32    

Самый примитивный HTTP-сервис в мире

WEB v8 Бесплатно (free)

Пошаговый пример создания простейшего HTTP-сервиса, который генерирует HTML-страницу для поиска товара, а также реализует асинхронное получение данных из базы.

12.09.2019    22176    YPermitin    26    

Описание формата внутреннего представления данных 1С в контексте обмена данными

Практика программирования Внешние источники данных v8 v8::УФ 1cv8.cf Абонемент ($m)

Фирма 1С не рекомендует использовать внутреннее представление данных для любых целей, которые отличны от обмена с 1С:Предприятием 7.7. Но сама возможность заглянуть на "внутреннюю кухню" платформы с помощью функций ЗначениеВСтрокуВнутр(), ЗначениеВФайл(), ЗначениеИзСтрокиВнутр() и ЗначениеИзФайла(), дала возможность сообществу программистов 1С разработать новые приемы разработки и анализа. Так, именно на использовании внутреннего представления был построен алгоритм "быстрого массива", который позволяет практически мгновенно создать массив в памяти на основании строки с разделителями. С помощью разбора внутреннего представления можно "на лету" программным кодом выполнить анализ обычной формы и даже сделать редактор графической схемы. Во внутреннем формате сохраняют свои данные между сеансами различные популярные внешние обработки. А еще это возможность сделать быстрый обмен с внешними системами.

1 стартмани

06.09.2019    19726    Dementor    30    

1С и PowerShell - обновление из хранилища

Администрирование данных 1С Инструментарий разработчика v8 Абонемент ($m)

Пример скрипта, упрощающего работу.

1 стартмани

29.08.2019    8853    Jokemas    31    

Работа со схемой запроса Промо

Инструментарий разработчика Практика программирования v8 v8::Запросы Абонемент ($m)

Стандартом взаимодействия с реляционной базой данных стал язык SQL. Приемником SQL в 1С является язык запросов. Язык запросов, также как и SQL, является структурированным. Составляющие структуры запроса отвечают на разные вопросы о том, какие данные требуется получить и какие манипуляции с множествами данных необходимо произвести при получении. В простых случаях текст запроса можно написать вручную, однако в сложных случаях, а также при программном формировании, - лучше воспользоваться объектной моделью запроса и использовать объект "Схема запроса". В статье дается описание объектной модели и особенностей работы с ней, а также приводится решение, упрощающее взаимодействие с объектом "Схема запроса".

1 стартмани

24.04.2018    44805    kalyaka    35    

Удобный просмотр результата запроса с большим количеством временных таблиц

Практика программирования v8 Абонемент ($m)

Если Вам часто приходится просматривать в отладчике сложные пакетные запросы с большим количеством временных таблиц, то эта статья для Вас.

1 стартмани

27.08.2019    11046    ids79    21    

Запуск фонового задания во внешней обработке. Отключение предупреждений защиты от опасных действий в фоновом задании

Практика программирования v8 1cv8.cf Абонемент ($m)

Как запустить фоновое задание из модуля внешней обработки используя БСП. Как отключить безопасный режим и сообщения защиты от опасных действий независимо от профиля безопасности пользователя в фоновом задании во внешней обработке.

2 стартмани

24.08.2019    11424    BenGunn    22    

Изменяющееся контекстное меню в 1С 8.3

Практика программирования Работа с интерфейсом Разработка v8 v8::УФ Абонемент ($m)

В одной практической задаче мне пришлось разрабатывать контекстное меню таблицы управляемой формы, которое должно было меняться в зависимости от данных, находящихся в этой таблице. Ниже приведен мой способ решения этой задачи.

1 стартмани

06.08.2019    16453    signum2009    16    

Многопоточность. Универсальный «Менеджер потоков» (фреймворк) с отслеживанием зависимости объектов Промо

Практика программирования Математика и алгоритмы Универсальные функции Производительность и оптимизация (HighLoad) v8 1cv8.cf Россия Абонемент ($m)

Восстановление партий, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

26.05.2017    49356    DarkAn    86    

Менеджер потоков: реализация "любой" задачи в потоках

Производительность и оптимизация (HighLoad) Инструментарий разработчика v8 Абонемент ($m)

Менеджер потоков – один их новых инструментов, который упрощает работу разработчиков. Насколько легко с ним, на конференции Infostart Event 2018 Education показал начальник отдела автоматизации 1С Иван Филимонов компании «Трансстроймеханизация».

01.08.2019    9755    DarkAn    6    

Процедура ПриКомпоновкеРезультата

Практика программирования v8 1cv8.cf Абонемент ($m)

Коллекция кода

1 стартмани

26.07.2019    40980    vasilev2015    64    

10 способов получить модуль числа (а может, и больше)

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

Пишем функцию вычисления модуля числа. Сколько способов существует? Давайте посчитаем!

1 стартмани

11.07.2019    8816    sam441    29    

Новый запрос и новая таблица значений как функции Промо

Практика программирования v8 Абонемент ($m)

Предлагается две простые функции, использование которых уменьшает объем кода в конфигурациях на платформе «1С:Предприятие 8». Эти функции можно добавлять к своему общему модулю, что сделает процесс программирования более эффективным.

1 стартмани

27.11.2012    45376    ildarovich    46    

Ловец дедлоков СУБД

Производительность и оптимизация (HighLoad) Практика программирования Разработка v8 Россия Абонемент ($m)

Анализ простейшего дедлока СУБД в рабочей базе с использованием ЦУП (центра управления производительностью) и profiler MS SQL (Microsoft SQL Server). Эта статья будет полезна людям, изучающим вопросы оптимизации работы 1С, или тем, у кого возникают дедлоки в рабочей базе. UPD 09.07.2019 добавлено воспроизведение блокировки в случае установки управляемой блокировки перед чтением набора записей регистра сведений. UPD 10.07.2019 добавлена тестовая база с примером.

1 стартмани

08.07.2019    11291    azazana    79    

Мониторинг производительности и искусственный интеллект

Производительность и оптимизация (HighLoad) Практика программирования Разработка v8 Абонемент ($m)

Расскажем и покажем практически, как использовать искусственный интеллект на страже мониторинга производительности. У вас появится возможность создать собственного помощника Ларису, которая возьмет на себя вопросы по контролю и диагностике состояния обслуживаемой системы.

1 стартмани

01.07.2019    9422    ivanov660    28    

"Убер на складе": динамический расчет маршрутов с учетом реальных расстояний

Учет ТМЦ Практика программирования Учет ТМЦ v8 УУ Абонемент ($m)

Представляю методику и инструмент для динамического расчета маршрутов отбора на высоконагруженных складах для максимального повышения эффективности склада, ускорения проходимости и, как следствие, экономии денег. Это методика и обработка для интеграции в WMS решения. Тестировалось на 1С 8.3.14.1565.

3 стартмани

24.06.2019    16372    informa1555    17    

Уровни, глубина, прародители, циклы и аналоги запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

В продолжение публикации «Транзитивное замыкание запросом» [http://infostart.ru/public/158512/] добавлены другие варианты использования того же приема. Приведены запросы для быстрого определения уровней всех элементов справочника, максимальной глубины справочника, прародителей произвольных элементов справочника, запрос для быстрого определения циклов (на примере справочника спецификаций «1С:Управление производственным предприятием») и определения множеств аналогов номенклатуры (также на примере конфигурации «1С:Управление производственным предприятием»).

1 стартмани

13.11.2012    112936    ildarovich    98    

1С:Ассемблер. Немного летнего веселья!

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

Все вы, наверное, слышали, что 1С-ники жалуются на свою систему, считая язык 1С недостаточно низкоуровневым, скучным и т.п. Все они с тоской поглядывают в сторону "настоящих" языков программирования. Так вот, господа, они неправы. В системе 1С есть места, где можно размять программерский мозг и получить удовольствие от низкоуровневой техники. Предлагаю вам погрузиться в недра виртуальной машины 1С и понять, как она работает. Там есть свой "ассемблер" и мы попробуем его в действии!

1 стартмани

21.06.2019    29678    Evil Beaver    130    

Простые примеры сложных отчетов на СКД

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Подписи в отчете. Особенности соединения наборов: как соединить несоединяемое. Остатки на дату и обороты по месяцам в одном отчете. Курс валюты на каждую дату без группировок и соединений в запросе. Отчет с произвольными колонками и с произвольной последовательностью. "Неадекватный отчет".

1 стартмани

12.06.2019    30496    Hatson    31    

Создание внешней печатной формы в формате документа Word

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

В статье написано, как создать внешнюю печатную форму (для конфигураций с БСП) в формате Word.

1 стартмани

17.05.2019    14669    ВикторП    21    

Неоплаченные долги при распределении оплаты по правилу ФИФО одним запросом и намного быстрее, чем Вы думали Промо

Практика программирования Дебиторская и кредиторская задолженность Дебиторская и кредиторская задолженность v8 v8::СКД КА1 УТ10 УПП1 УУ Абонемент ($m)

Предлагается метод для быстрого нахождения неоплаченных долгов при распределении оплаты по правилу ФИФО, основанный на дихотомии. Описывается реализация метода в виде достаточно простого запроса, решающего за линейное время указанную задачу, считавшуюся ранее существенно более трудоемкой. Приводятся примеры использования запроса в отчетах на СКД для конфигураций УТ, КА, УПП.

1 стартмани

28.02.2014    68615    ildarovich    125    

Пример настройки шаблонов и реализации печати отчетов в документ MS Word используя функциональную часть "Библиотеки Стандартных Подсистем 1С" (БСП)

Практика программирования Разработка v8 Россия Абонемент ($m)

В конфигурации выбраны и использованы только необходимые объекты библиотеки стандартных подсистем для реализации вывода отчёта, с табличными частями, в документ MS Word. Показан пример создания необходимых областей в шаблоне для вывода параметров в отчёт.

1 стартмани

23.04.2019    6480    olegpkc    11    

Ops средствами 1С:Предприятие

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

В статье описан программный пакет "Автоматизация ИТ-процессов" (АИТП), позволяющий автоматизировать задачи по администрированию, управлению и обслуживанию ИТ-инфраструктуры.

1 стартмани

23.04.2019    17522    blackhole321    28    

1C + Python + Django Rest Framework + Vue.js. Опыт несложной full-stack разработки

Практика программирования Внешние источники данных Обмен через XML WEB Разработка v8 1cv8.cf Абонемент ($m)

В этой статье мы рассмотрим путь и основные моменты создания небольшого вэб-сервиса, который мы называем "Онлайн Прайс-лист". Выгрузка из 1С, бэкенд, фронтенд, получение заказов в 1С.

1 стартмани

22.04.2019    33982    riposte    65    

Транзитивное замыкание запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

В частности, показывается, как одним пакетным запросом найти ВСЕХ предков (потомков) в иерархическом справочнике. Аналогично можно определять входимость деталей в узлы и готовые изделия по их спецификациям, определять подмножества аналогичных запчастей по цепочке аналогов, решать другие подобные задачи. Приложен файл с примером отчета для замыкания иерархии произвольного справочника, позволяющий протестировать быстродействие запроса в разных условиях.

1 стартмани

29.10.2012    86303    ildarovich    118    

Вывод вариантов СКД в таблицы на управляемой форме

Практика программирования Работа с интерфейсом v8 v8::УФ v8::СКД 1cv8.cf Абонемент ($m)

Задача стояла такая: есть 2 различных запроса, результаты которых выгружаются на форму обработки в таблицы значений (далее ТЗ) и программно "соприкасаются" между собой определенным образом (как именно- в рамках данной статьи неважно). Нюанс в том, что запросы должны иметь свой компоновщик настроек и могут интерактивно на форме изменяться пользователем. На оригинальность публикации не претендую - изначально в рамках поставленной задачи пытался найти что-то подобное (уже готовый шаблон) на инфостарте, возможно "плохо искал" ;)

05.04.2019    11501    artkor    1    

[EnterpriseData] Антисвертка характеристик номенклатуры при выгрузке в Бухгалтерию

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 v8::ПВХ КД УНФ БП3.0 Россия БУ Абонемент ($m)

Рассмотрена выгрузка каждой пары значений Номенклатура - Характерстика из УНФ 1.6 в отдельную номенклатуру в Бухгалтерию 3.0 путём доработки правил обмена в формате EnterpriseData.

1 стартмани

27.03.2019    4765    nforce    6    

Программное создание реквизита управляемой формы с помощью механизма расширений

Практика программирования Разработка v8 v8::УФ 1cv8.cf Абонемент ($m)

В ЗУП 3 возникла задача добавить реквизит в справочник не внося изменений в конфигурацию. БСП с механизмом дополнительных реквизитов использовать было нежелательно, поэтому был использован механизм расширений. Для вывода данного реквизита на форму добавлять саму форму в расширение не хотелось по ряду причин, описанных ниже. Создание реквизита и элемента формы, соответствующего данному реквизиту было решено сделать программно в самом расширении, следуя принципу минимального воздействия на конфигурацию.

1 стартмани

12.03.2019    38001    ni_cola    31