HTTP Сервисы: Путь к своему сервису. Часть 2

10.10.18

Разработка - Инструментарий разработчика

Продолжение статьи «HTTP Сервисы: Путь к своему сервису. Часть 1». В этой части будет "Микс" из OData+HTTP-Сервис(Get)+СКД. Наш пример будет работать как в браузере, так и в написанной нами обработке. Работать будем с разными версиями платформ.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование SM По подписке [?] Купить один файл
Расширение с http-сервисами из примера
.cfe 23,20Kb
47
47
1 SM
Скачать Купить за 1 850 руб.
Обработка из примера: ПолучитьОстаткиИДоступностьТоваров.epf
.epf 8,65Kb
51
51
1 SM
Скачать Купить за 1 850 руб.

В первой части мы создали каркас для Get метода в расширении конфигурации. Как Вы помните, мы получали через один метод список или конкретный документ, давайте рассмотрим еще один инструмент, позволяющий без особого труда и без доработок конфигурации получать те же данные. Как Вы догадались, начнем разговор с OData, далее смиксуем OData с нашим сервисом который будет возвращать данные на основе СКД. 

Как и в предыдущей статье http-сервис будет в расширении конфигурации ERP 2.4.3.145 на платформе 8.3.10.2650, а вот посылать запросы и получать ответы будем в Демо конфигурации БСП 3.0.1.231 на платформе 8.3.12.1567. Специально чтобы версии платформы отличались.

Начнем.

Немножко про OData.

Для начала дам ссылки, где можно почитать про использование OData в 1с:

  1. Глава 17.2.1. Cтандартный интерфейс OData
  2. Приложение 12. Описание сущностей, предоставляемых через стандартный интерфейс OData
  3. Способы интеграции с 1С

Давайте кратенько пройдем по основным пунктам.

 
1 Как опубликовать OData? 

 В конфигураторе Администрирование/Публикация на веб-сервере...

 
2 Из чего складывается URL OData? 

http://host/base/odata/standard.odata/ПрефиксИмени_ИмяОбъектаКонфигурации_СуффиксИмени/Параметры?Параметры&УсловияОтбора

host – IP адрес или доменное имя веб сервера.

base – Имя базы. Указывается при публикации.

odata/standard.odata - Признак обращения к стандартному интерфейсу OData.

ПрефиксИмени - Представление объекта конфигурации для указания в URL (Объекты доступные в OData и их префиксы описаны в главе 17.2.1.4. Правила формирования имени ресурса, а так же можно посмотреть с помощью обработки Доступный состав стандартного интерфейса OData).

ИмяОбъектаКонфигурации - свойство Имя объекта конфигурации, как оно задано при разработке прикладного решения в конфигураторе.

СуффиксИмени - предназначено для уточнения имени ресурса и является необязательной частью имени. В качестве суффикса имени могут выступать следующие выражения:

  • Имя табличной части объекта;
  • Имя реквизита табличной части или набора записей;
  • Имя виртуальной таблицы регистра;
  • RowType;
  • RecordType.

Праметры и УсловияОтбора – В качестве параметров обращения выступают параметры в виде, принятом для HTTP-запросов: ?ключ=значение&ключ2=значение2.
При обращении к ресурсу могут использоваться специальные ключевые слова, имеющие специальное назначение:

  • $format - указывает, в каком формате необходимо получить данные. Если ключевое слово не указано, данные получаются в формате atom-xml.
  • $format=atom - возвращает данные в формате atom-xml.
  • $format=json - возвращает данные в формате json. Для указания того, что данные должны возвращаться в формате json, можно указать MIME-тип application/json в заголовке Accept HTTP-запроса на получение данных.
  • $metadata - указывает, что требуется получить описание стандартного интерфейса OData.
  • $filter - описывает отбор, применяемый при получении данных.
  • $select - описывает перечень свойств сущности, которые получаются при обращении к стандартному интерфейсу OData. 
 
 3 Какие HTTP-методы используется в OData?
  • GET - Получение данных;
  • POST - Создание объекта;

Обновление данных:

  • PATCH - в этом случае можно указывать только те свойств, которые необходимо обновить;
  • PUT - в этом случае необходимо указывать все свойства сущности;
  • DELETE - Удаление данных.

Лично я использую только GET, так как изменение, добавление и тем более удаление данных через OData считаю неправильным (потенциально опасным) для Учетных систем. Данные методы могут быть хороши для конфигурации разработанной например под мобильный клиент, ну или под сайт.

Давайте узнаем, сколько элементов в справочнике Склады в Демо конфигурации ERP 2.4.3.145.

Для этого мы будем использовать параметр $count. Наш запрос: 

http://127.0.0.1/DemoEnterprise2_4_3_145/odata/standard.odata/Catalog_Склады/$count

Как мы видим, получить данные не удалось. В чем же дело?

Дело в том, что начиная с версии платформы 8.3.5.1068 необходимо использовать метод УстановитьСоставСтандартногоИнтерфейсаOData для того чтобы объекты конфигурации были доступны для использования в OData. Давайте воспользуемся обработкой Доступный состав стандартного интерфейса OData и дадим доступ к нужному нам справочнику.

Проверяем наш запрос еще раз.

Как мы видим в конфигурации 49 элементов справочника Склады.

 

Давайте нарисуем сервис по получению остатков на складе, при этом в ЕРП мы будем брать за основу отчет «ОстаткиИДоступностьТоваров» и на основании СКД макета будем получать данные и возвращать их в формате JSON (Реализовано в версии 8.3.6.1977). Обращаться к сервису будем с помощью обработки из конфигурации на платформе 8.3.12.

Хочу сразу сказать json выбран из-за своей компактности, удобочитаемости и легкости работы с данным форматом.

 
Для примера сравните atom-xml и json, я вывел один и тот же элемент в этих форматах. 

Для начала нам нужно получить в обработку перечень складов (наименование и идентификатор), при этом склады должны быть элементами, не помеченными на удаление.

Проверим сколько таких элементов: http://127.0.0.1/DemoEnterprise2_4_3_145/odata/standard.odata/Catalog_Склады/$count?$select=Ref_Key,Description&$filter=DeletionMark eq false and IsFolder eq false&$format=json;odata=nometadata

38 это немного, нас это вполне устраивает, будем создавать на форме реквизит cклад, и заполнять список данными полученными по OData.

Создаем обработку «ПолучитьОстаткиИДоступностьТоваров.epf», добавляем форму и добавляем на нее реквизит «Склад» с типом строка и команду ЗагрузитьСклады

 
 Текст команды ЗагрузитьСклады
&НаКлиенте
Процедура ЗагрузитьСклады(Команда)
	ПолучитьСписокСкладовНаСервере();	
КонецПроцедуры
&НаСервере
Процедура ПолучитьСписокСкладовНаСервере()
	//Чистим список
	Элементы.Склад.СписокВыбора.Очистить();
	
	//В тестовых обработках так делать можно, но когда делаете в рабочей такие вещи НЕДОПУСТИМЫ!
	//Храните логины и пароли в недоступных для глаз местах! (https://its.1c.ru/db/v8std#content:2149184389:hdoc) 
	перПорт = 0;
	перСервер = "127.0.0.1";
	перПользователь = "Администратор (ОрловАВ)";
	перПароль = "";

	//Формируем запрос для OData
	перРесурсНаСервере = "/DemoEnterprise2_4_3_145/odata/standard.odata/";	
	перРесурсНаСервереФин = перРесурсНаСервере + 
	"Catalog_Склады?$select=Ref_Key,Description&$filter=DeletionMark eq false and IsFolder eq false&$format=json;odata=nometadata";
	
	Попытка
		Если перПорт <= 0 Тогда 
			HTTPСоединение = Новый HTTPСоединение(перСервер,,перПользователь,перПароль);
		Иначе 
			HTTPСоединение = Новый HTTPСоединение(перСервер,перПорт,перПользователь,перПароль);
		КонецЕсли;
		
		HTTPЗапрос= Новый HTTPЗапрос(перРесурсНаСервереФин);
		HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
		
		РезультатМассив = Новый СписокЗначений;	
		Если HTTPОтвет.КодСостояния = 200 Тогда 
			Ответочка = HTTPОтвет.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);	
					
			ЧтениеJSON = Новый ЧтениеJSON;
			ЧтениеJSON.УстановитьСтроку(Ответочка);
			Попытка
				ДопДанные = ПрочитатьJSON(ЧтениеJSON);
			Исключение
				ДопДанные = "";
			КонецПопытки;
				
			Если ТипЗнч(ДопДанные) = Тип("Структура") Тогда
				//Заполняем список Складов
				Если ДопДанные.Свойство("Ref_Key") и ДопДанные.Свойство("Description") Тогда 
					Элементы.Склад.СписокВыбора.Добавить(ДопДанные.Ref_Key,ДопДанные.Description);
				ИначеЕсли ДопДанные.Свойство("value") Тогда
					ДопДанные = ДопДанные.value;
					
					Если ТипЗнч(ДопДанные) = Тип("Массив") Тогда	
						Для Каждого элМассива из ДопДанные Цикл 
							Если ТипЗнч(элМассива) = Тип("Структура") Тогда
								Если элМассива.Свойство("Ref_Key") и элМассива.Свойство("Description") Тогда 
									Элементы.Склад.СписокВыбора.Добавить(элМассива.Ref_Key,элМассива.Description);	
								Иначе
									//Нет Ref_Key
								КонецЕсли;
							КонецЕсли
						КонецЦикла;
					КонецЕсли;
				Иначе
					//Нет Ref_Key
				КонецЕсли;	
			Иначе 
				//не смогли прочитать
			КонецЕсли;	

		КонецЕсли;
	Исключение
		Сообщить("Подключится к ERP не получилось: "+ОписаниеОшибки());	
	КонецПопытки;
	
	HTTPСоединение = Неопределено;

КонецПроцедуры

 

У реквизита Склад делаем РежимВыбораИзСписка

Первая часть сделана, давайте перейдем к нашему отчету в ЕРП.

Мы видим следующую картину:

Это значит, что при попытке программно получить данные из СКД в ДеревоЗначений мы получим ошибку.

 
 Ошибка при вызове метода контекста (Выполнить)

        МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновки, НастройкиКомпоновки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

по причине:

Ошибка компоновки макета

по причине:

Ошибка генерации макета

по причине:

Не поддерживается вывод таблиц и диаграмм в универсальную коллекцию значений

Есть несколько путей решения данной проблемы, я пойду самым простым. В расширение добавлю отчет и создам в нем нужный мне макет.

Теперь можно создать новый метод «ОстаткиИДоступностьТоваровПоСкладу». Подготовлю почву под следующую часть данного цикла статей и создам модуль «PAPI_ОбработкаУниверсальныхМетодов»

 
 Код модуля PAPI_ОбработкаУниверсальныхМетодов
#Область Методы
Процедура ПолучитьОстаткиИДоступностьТоваровПоСкладу(СтруктураОтвет,СтруктураВхПараметров) Экспорт 
	//ПраметрыЗапроса - number
	Склад_Key = СтруктураВхПараметров.ПараметрыЗапроса.Получить("Ref_Key");

	Если не Склад_Key = Неопределено Тогда
		//Получаем Склад
		Попытка
			Склад = XMLЗначение(Тип("СправочникСсылка.Склады"), Склад_Key); 
		Исключение
			Склад = Неопределено;
		КонецПопытки;
		
		Если ЗначениеЗаполнено(Склад) Тогда 
			//Получаем схему компоновки и вариант отчета
			//СхемаКомпоновки = Отчеты.ОстаткиИДоступностьТоваров.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
			//ВариантНастроеки = СхемаКомпоновки.ВариантыНастроек.Найти("ОстаткиИДоступностьТоваров");	
			СхемаКомпоновки = Отчеты.PAPI_ХранилищеМакетов.ПолучитьМакет("СКД_ОстаткиИДоступностьТоваров_HTTP");
			ВариантНастроеки = СхемаКомпоновки.ВариантыНастроек.Найти("ОстаткиИДоступностьТоваровНеТаблица");
			НастройкиКомпоновки = ВариантНастроеки.Настройки;	
				
			//Взято из модуля отчета.ОстаткиИДоступностьТоваров "ПриКомпоновкеРезультата"++	
			ТекстЗапроса = СхемаКомпоновки.НаборыДанных.Основной.Запрос;

			ТекстЗапроса = СтрЗаменить(
				ТекстЗапроса, 
				"&ТекстЗапросаВесНоменклатуры", 
				Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки("Набор.Номенклатура.ЕдиницаИзмерения", "Набор.Номенклатура"));
					
			ТекстЗапроса = СтрЗаменить(
				ТекстЗапроса, 
				"&ТекстЗапросаОбъемНоменклатуры", 
				Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаОбъемУпаковки("Набор.Номенклатура.ЕдиницаИзмерения", "Набор.Номенклатура"));

			СхемаКомпоновки.НаборыДанных.Основной.Запрос = ТекстЗапроса;
			//Взято из модуля отчета.ОстаткиИДоступностьТоваров "ПриКомпоновкеРезультата"--                           	
					
			ПрараметрОтбора = НастройкиКомпоновки.Отбор.Элементы;
			СкладПолеКомпоновки = Новый ПолеКомпоновкиДанных("Склад");
			Для Каждого СтрокаОтбора из ПрараметрОтбора Цикл 
				Если СтрокаОтбора.ЛевоеЗначение = СкладПолеКомпоновки  Тогда
					СтрокаОтбора.Использование 	= Истина;
					СтрокаОтбора.ВидСравнения 	= ВидСравненияКомпоновкиДанных.Равно;
					СтрокаОтбора.ПравоеЗначение = Склад; 	
				КонецЕсли;
			КонецЦикла;	
						
			КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
			
			МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновки, НастройкиКомпоновки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
				
			ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;     
			ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,,,Истина);
			
			ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;     
			ДеревоЗначений = Новый ДеревоЗначений;     
			ПроцессорВывода.УстановитьОбъект(ДеревоЗначений);         	
			ПроцессорВывода.Вывести(ПроцессорКомпоновки);
				
			//Обходим дерево и формируем РезультатОтвет
			РезультатОтвет = Новый Массив;
			Для Каждого ВерхнийУровеньДерева Из ДеревоЗначений.Строки Цикл	
				Для Каждого ПодчиненныйУровеньДерева Из ВерхнийУровеньДерева.Строки Цикл	
					Если ЗначениеЗаполнено(ПодчиненныйУровеньДерева.Номенклатура) 
						И ТипЗнч(ПодчиненныйУровеньДерева.Номенклатура) = Тип("СправочникСсылка.Номенклатура") 
					Тогда 
						РезультатОтвет.Добавить(Новый Структура("ИмяЗначение,Артикул,Guid,ДоступноСейчас,Остаток",
						ПодчиненныйУровеньДерева.Номенклатура.Наименование +
							?(ЗначениеЗаполнено(ПодчиненныйУровеньДерева.Характеристика),
								","+Строка(ПодчиненныйУровеньДерева.Характеристика),""),
						ПодчиненныйУровеньДерева.НоменклатураАртикул,
						XMLСтрока(ПодчиненныйУровеньДерева.Номенклатура),
						ПодчиненныйУровеньДерева.ДоступноСейчас,
						ПодчиненныйУровеньДерева.ВНаличии));
					КонецЕсли;	
				КонецЦикла;
			КонецЦикла;
				
			//РезультатОтвет в JSON
			ПараметрыJSON	= Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет, " " , Истина, ЭкранированиеСимволовJSON.Нет, Ложь, Ложь, Ложь, Ложь);
			ЗаписьJSON		= Новый ЗаписьJSON;
			ЗаписьJSON.ПроверятьСтруктуру = Истина;
			ЗаписьJSON.УстановитьСтроку(ПараметрыJSON);

			ЗаписатьJSON(ЗаписьJSON, РезультатОтвет);
			Результат = ЗаписьJSON.Закрыть();
				
			СтруктураОтвет.ДанныеОтвета = Результат;
			
			СтруктураОтвет.Вставить("ФорматОтвета",PAPI_ОбщиеПроцедурыИФункции.ФорматОтветаJSON());
		Иначе
			PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Не заполнен или неверно заполнен параметр ""Ref_Key""",ложь,"");	
		КонецЕсли;	
	Иначе
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Отсутствует параметр ""Ref_Key""",ложь,"");	
	КонецЕсли;	
КонецПроцедуры	
#КонецОбласти

 

Так же добавим модуль PAPI_ОбщиеПроцедурыИФункции

 
 Код модуля PAPI_ОбщиеПроцедурыИФункции
//Заполняем структуру ответа
Процедура ЗаполнитьСтруктуруОтвета(СтруктураОтвет,КодОтвета,ТекстОшибки,Отработало,ДанныеОтвета) Экспорт
	СтруктураОтвет.КодОтвета 	= КодОтвета;
	СтруктураОтвет.ТекстОшибки	= ТекстОшибки;
	СтруктураОтвет.Отработало	= Отработало;
	СтруктураОтвет.ДанныеОтвета = ДанныеОтвета;	
КонецПроцедуры


#Область ФорматыОтвета
Процедура ВозвращаемНужныйФорматОтвета(Ответ,СтруктураОтвет) Экспорт
	
	Если СтруктураОтвет.Свойство("ФорматОтвета") Тогда 
		ФорматОтвета = СтруктураОтвет.ФорматОтвета;
	Иначе
		ФорматОтвета = "";
	КонецЕсли;	

	Если ВРег(ФорматОтвета) = Врег(ФорматОтветаJSON()) Тогда 
		Ответ.Заголовки.Вставить("Content-Type","application/json; charset=utf-8");
	Иначе 	
		Ответ.Заголовки.Вставить("Content-Type","text/html; charset=utf-8");
	КонецЕсли;
КонецПроцедуры

Функция ФорматОтветаJSON() Экспорт 
	Возврат "JSON";	
КонецФункции
#КонецОбласти

 

Подредактируем модуль PAPI_ОбработкаМетодовGET, добавим в него новый метод "ОстаткиИДоступностьТоваровПоСкладу" и уберем процедуру "ЗаполнитьСтруктуруОтвета"

 
 Код модуля PAPI_ОбработкаМетодовGET
//Функция экспортная, специально чтобы можно было отлаживать как по HTTP(https://its.1c.ru/db/metod8dev#content:5756:hdoc)
//Так и через внешнюю обработку
Функция PAPI_ОбработкаМетодовGET(СтруктураВхПараметров) Экспорт
	//структура ответа. Собственна нужна для формирования ответа
	СтруктураОтвет = Новый Структура("ДанныеОтвета,Отработало,ТекстОшибки,КодОтвета","",Истина,"",200);
	
	//Переправляем на нужный метод
	Если ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("Список") Тогда
		
		ПолучитьСписок(СтруктураОтвет,СтруктураВхПараметров);	
		
	ИначеЕсли ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("Документ") Тогда

		ПолучитьДокумент(СтруктураОтвет,СтруктураВхПараметров);
		
//Получаем доступные остатки по складу в формате JSON	
	ИначеЕсли ВРег(СтруктураВхПараметров.ИмяМетода) = ВРег("ОстаткиИДоступностьТоваровПоСкладу") Тогда
		
		PAPI_ОбработкаУниверсальныхМетодов.ПолучитьОстаткиИДоступностьТоваровПоСкладу(СтруктураОтвет,СтруктураВхПараметров);	
		
	Иначе
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,501,"Отсутствует Метод " + ?(СтруктураВхПараметров.ИмяМетода=Неопределено,"",СтруктураВхПараметров.ИмяМетода),ложь,"");
	КонецЕсли;
	Возврат СтруктураОтвет;	
КонецФункции

#Область Методы
Процедура ПолучитьСписок(СтруктураОтвет,СтруктураВхПараметров)
	Результат = "Расходная накладная, 1, 01.01.2014
	|Расходная накладная, 2, 01.01.2014";
	СтруктураОтвет.ДанныеОтвета = Результат;
КонецПроцедуры	

Процедура ПолучитьДокумент(СтруктураОтвет,СтруктураВхПараметров)
	//ПраметрыЗапроса - number
	ПарНомер = СтруктураВхПараметров.ПараметрыЗапроса.Получить("number");

	Номер = Число(?(ПарНомер=Неопределено,0,ПарНомер));
	Если Номер > 2 Тогда
		PAPI_ОбщиеПроцедурыИФункции.ЗаполнитьСтруктуруОтвета(СтруктураОтвет,404,"Отсутствует документ с номером: " + Номер,ложь,"");
	Иначе	
		Если Номер = 1 Тогда
			Результат = "Расходная накладная, 1, 01.01.2014";
		Иначе
			Результат = "Расходная накладная, 2, 01.01.2014";
		КонецЕсли;
		СтруктураОтвет.ДанныеОтвета = Результат;	
	КонецЕсли;
КонецПроцедуры	

#КонецОбласти

 

Добавим одну строчку в обработчик метода Get.

 
 Код PrettyAPIGET
Функция PrettyAPIGET(Запрос)
	СтруктураВхПараметров = Новый Структура;
	//Получаем имя метода
	перИмяМетода  = Запрос.ПараметрыURL["ИмяМетода"];    
	//Помещаем имя метода в структуру
	СтруктураВхПараметров.Вставить("ИмяМетода",перИмяМетода);  
	
	//Забираем параметры из запроса
	ВхПараметрыЗапроса = Новый Соответствие;
	Для каждого Параметр Из Запрос.ПараметрыЗапроса Цикл
        ВхПараметрыЗапроса.Вставить(Параметр.Ключ,Параметр.Значение);
    КонецЦикла;
	СтруктураВхПараметров.Вставить("ПараметрыЗапроса",ВхПараметрыЗапроса);
	
	//Передаем входящие параметры (Модуль для метода GET)
	СтруктураОтвет = PAPI_ОбработкаМетодовGET.PAPI_ОбработкаМетодовGET(СтруктураВхПараметров);
	
	//Создаем ответ с кодом состояния
	Ответ = Новый HTTPСервисОтвет(СтруктураОтвет.КодОтвета);
	Если СтруктураОтвет.Отработало Тогда 
	    Ответ.УстановитьТелоИзСтроки(СтруктураОтвет.ДанныеОтвета,КодировкаТекста.UTF8);
	Иначе
		Ответ.УстановитьТелоИзСтроки(СтруктураОтвет.ТекстОшибки,КодировкаТекста.UTF8);
	КонецЕсли;	
	
	//В зависимости от формата меняем "Content-Type"
	PAPI_ОбщиеПроцедурыИФункции.ВозвращаемНужныйФорматОтвета(Ответ,СтруктураОтвет);
	
	Возврат Ответ;
КонецФункции

 

На этом подготовка ЕРП окончена. Проверим через браузер результат, выполним следующий запрос:

http://127.0.0.1/DemoEnterprise2_4_3_145/hs/PrettyAPI/V1/ОстаткиИДоступностьТоваровПоСкладу?Ref_Key=3ae74af9-e911-11e6-b7b5-bcaec56cc144

Наш сервис готов! Давайте теперь дорисуем обработку и будем подводить итоги.

Добавим в обработку реквизит "Результат" с типом строка. В него мы просто будем выводить текст ответа.

Добавим ТаблицуЗначений "ОстаткиИДоступность":

  • Наименование (Строка)
  • Артикул (Строка)
  • Доступно (Число(15,3))
  • Остаток (Число(15,3))
  • Идентификатор (Строка)

Добавим команду "ПолучитьРезультат"

 
 Код команды ПолучитьРезультат
&НаКлиенте
Процедура ПолучитьРезультат(Команда)
	ОчиститьСообщения();
	Если Не ЗначениеЗаполнено(Склад) Тогда 
		Сообщить("Склад не заполнен!");
		Возврат;
	КонецЕсли;	
	
	ОстаткиИДоступность.Очистить();
	ПолучитьРезультатНаСервере();
КонецПроцедуры
&НаСервере
Процедура ПолучитьРезультатНаСервере()
	перПорт = 0;
	перСервер = "127.0.0.1";
	перПользователь = "Администратор (ОрловАВ)";
	перПароль = "";

	//Формируем запрос для OData
	перРесурсНаСервере = "/DemoEnterprise2_4_3_145/hs/PrettyAPI/V1/";	
	перРесурсНаСервереФин = перРесурсНаСервере + 
	"ОстаткиИДоступностьТоваровПоСкладу?Ref_Key="+Склад;
	
	Попытка
		Если перПорт <= 0 Тогда 
			HTTPСоединение = Новый HTTPСоединение(перСервер,,перПользователь,перПароль);
		Иначе 
			HTTPСоединение = Новый HTTPСоединение(перСервер,перПорт,перПользователь,перПароль);
		КонецЕсли;
		
		HTTPЗапрос= Новый HTTPЗапрос(перРесурсНаСервереФин);
		HTTPОтвет = HTTPСоединение.Получить(HTTPЗапрос);
		
		РезультатМассив = Новый СписокЗначений;	
		Если HTTPОтвет.КодСостояния = 200 Тогда 
			Ответочка = HTTPОтвет.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);	
			Результат = Ответочка;	
			
			ЧтениеJSON = Новый ЧтениеJSON;
			ЧтениеJSON.УстановитьСтроку(Ответочка);
			Попытка
				//ДопДанные = ПрочитатьJSON(ЧтениеJSON, Ложь);
				МасДопДанные = ПрочитатьJSON(ЧтениеJSON);
			Исключение
				МасДопДанные = "";
			КонецПопытки;
				
			Если ТипЗнч(МасДопДанные) = Тип("Массив") Тогда
				Для Каждого ДопДанные из МасДопДанные Цикл 
					//"ИмяЗначение","Артикул","Guid","ДоступноСейчас","Остаток"
					Если ДопДанные.Свойство("ИмяЗначение") 
						И ДопДанные.Свойство("Guid") 
						И ДопДанные.Свойство("ДоступноСейчас") 
						И ДопДанные.Свойство("Остаток") Тогда
						новСтрока = ОстаткиИДоступность.Добавить();
						
						новСтрока.Наименование 		= ДопДанные.ИмяЗначение;
						новСтрока.Идентификатор		= ДопДанные.Guid;
						новСтрока.Доступно		 	= ДопДанные.ДоступноСейчас;
						новСтрока.Остаток		 	= ДопДанные.Остаток;
						новСтрока.Артикул           = ?(ДопДанные.Свойство("Артикул"),ДопДанные.Артикул,"");
					КонецЕсли;
				КонецЦикла;	
			Иначе 
				//не смогли прочитать
			КонецЕсли;	

		КонецЕсли;
	Исключение
		Сообщить("Подключится к ERP не получилось: "+ОписаниеОшибки());	
	КонецПопытки;
	
	HTTPСоединение = Неопределено;
КонецПроцедуры

 

Внешний вид формы:

Проверяем результат:

Вторую часть заканчиваю. Мы рассмотрели с Вами как можно смешивать разные технологии. Я думал, в этой части поговорить про другие методы, но вышло громоздко, поэтому в следующей части поговорим о других методах и длительных операциях.

Статьи из данного цикла:

HTTP Сервисы: Путь к своему сервису. Часть 1

HTTP Сервисы: Путь к своему сервису. Часть 3

HTTP Сервисы: Путь к своему сервису. Часть 4

HTTP-сервис API JSON IIS http web apache сервис Публикатор Линк PAPI Pretty API atom-xml XML oData Код состояния Get Post Patch

См. также

Инструментарий разработчика Роли и права Запросы СКД Программист Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 руб.

02.09.2020    141233    775    391    

803

Пакетная печать Печатные формы Инструментарий разработчика Программист Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:Конвертация данных 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

18000 руб.

06.10.2023    11695    31    6    

62

Инструментарий разработчика Программист Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Инструмент для написания и отладки кода в режиме «1С:Предприятие». Представляет собой консоль кода с возможностью пошаговой отладки, просмотра значений переменных любых типов, использования процедур и функций, просмотра стека вызовов, вычисления произвольных выражений на встроенном языке в контексте точки останова, синтаксического контроля и остановки по ошибке. В консоли используется удобный редактор кода с подсветкой, контекстной подсказкой, возможностью вызова конструкторов запроса и форматной строки.

5400 руб.

17.05.2024    14288    36    29    

80

Инструменты администратора БД Инструментарий разработчика Роли и права Программист Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.

10000 руб.

10.11.2023    7359    27    4    

51

SALE! %

Инструментарий разработчика Инструменты администратора БД Системный администратор Программист Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.

3600 2880 руб.

14.01.2013    182085    1104    0    

876

Инструментарий разработчика Программист Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Восстановление партий или взаиморасчетов, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

5000 руб.

07.02.2018    101217    243    97    

304

Инструментарий разработчика Перенос данных 1C Программист Платформа 1С v8.3 Платные (руб)

В процессе работы в 1С часто возникает потребность получить данные из другой базы. Обычно это делается через COM-соединение, и время выполнения запроса при этом оставляет желать лучшего. В данной публикации представлено универсальное решение для 1С, позволяющее практически моментально выполнить произвольный код или запрос с параметрами в другой информационной базе через Web-сервис.

2400 руб.

24.09.2019    24550    17    15    

34

Инструментарий разработчика Программист Платформа 1С v8.3 Управляемые формы Платные (руб)

"Фреймворк для Расширений 1С" это универсальное и многофункциональное решение, упрощающее разработку и поддержку создаваемых Расширений. Поставляется в виде комплекта из нескольких Расширений с открытым исходным кодом. Работает в любых Конфигурациях в режиме Управляемого приложения с режимом совместимости 8.3.12 и выше без необходимости внесения изменений в Конфигурацию.

3000 руб.

27.08.2019    19503    7    8    

42
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. konyavka 38 16.05.22 15:16 Сейчас в теме
Добрый день.
При получении в тексте обработки возвращает все время HTTPОтвет.КодСостояния = 401.

При вводе той же строки в браузере возвращает список складов:
перРесурсНаСервере = "/DemoEnterprise2_4_3_145/odata/standard.odata/";
перРесурсНаСервереФин = перРесурсНаСервере + "Catalog_Склады?$select=Ref_Key,Description&$filter=DeletionMark eq false and IsFolder eq false&$format=json;odata=nometadata";

Не подскажите в чем может быть дело?
2. dsdred 3487 16.05.22 15:47 Сейчас в теме
(1) 401 ошибка авторизации.
Как вариант возможно логин и пароль сделать на английском.

Или вы не поправили то что было у меня приведено под себя

Процедура ПолучитьРезультатНаСервере()
перПорт = 0;
перСервер = "127.0.0.1";
перПользователь = "Администратор (ОрловАВ)";
перПароль = "";
Оставьте свое сообщение