() Не вижу препятствий, для тех, кому это действительно нужно ))
Тем более, что вопрос решается тривиальной отправкой POST-запроса.
Вот, например:
Функция Телеграм_ОтправитьКоманду(ИмяКоманды, ПараметрыКоманды, Таймаут = 60) Экспорт
Результат = Новый Структура("Успех, ОтветТГ, ТекстОшибки", Ложь, Неопределено, "Неизвестная ошибка");
Сервер = "api.telegram.org";
Порт = 443;
Токен = "<токен-телеграм-бота>"; // ОбщегоНазначенияПовтИсп.ПолучитьТокен();
Адрес = "/bot" + Токен + "/" + ИмяКоманды;
HTTPСоединение = Новый HTTPСоединение(Сервер, Порт,,,, Таймаут, Новый ЗащищенноеСоединениеOpenSSL);
HTTPЗапрос = Новый HTTPЗапрос(Адрес);
HTTPЗапрос.Заголовки.Вставить("Content-Type", "application/json");
ЗаписьJSON = Новый ЗаписьJSON;
ПараметрыЗаписиJSON = Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет);
ЗаписьJSON.УстановитьСтроку(ПараметрыЗаписиJSON);
ЗаписьJSON.ЗаписатьНачалоОбъекта();
Для Каждого КлючИЗначение Из ПараметрыКоманды Цикл
ЗаписьJSON.ЗаписатьИмяСвойства(КлючИЗначение.Ключ);
ЗаписьJSON.ЗаписатьЗначение(КлючИЗначение.Значение);
КонецЦикла;
ЗаписьJSON.ЗаписатьКонецОбъекта();
ПараметрыЗапроса = ЗаписьJSON.Закрыть();
HTTPЗапрос.УстановитьТелоИзСтроки(ПараметрыЗапроса);
//ДобавитьВЛог(СтрШаблон("Запрос (ТГ): %1;
// |Параметры:
// |%2", Адрес, ПараметрыЗапроса));
HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
ПараметрыОтвета = HTTPОтвет.ПолучитьТелоКакСтроку();
КодСостояния = HTTPОтвет.КодСостояния;
//ДобавитьВЛог(СтрШаблон("Ответ (ТГ): %1;
// |Параметры:
// |%2", HTTPОтвет.КодСостояния, ПараметрыОтвета));
Если КодСостояния <> 200 Тогда
Результат.ТекстОшибки = СтрШаблон("Ошибка отправки команды '%1'. Сервер вернул код состояния %2.", ИмяКоманды, КодСостояния);
Возврат Результат;
КонецЕсли;
ЧтениеJSON = Новый ЧтениеJSON;
ЧтениеJSON.УстановитьСтроку(ПараметрыОтвета);
ОтветТГ = ПрочитатьJSON(ЧтениеJSON);
ЧтениеJSON.Закрыть();
Если НЕ ОтветТГ.Ok Тогда
Результат.ТекстОшибки = СтрШаблон("Ошибка выполнения команды '%1'. Причина: %2.", ИмяКоманды, ОтветТГ.description);
Возврат Результат;
КонецЕсли;
Результат.Успех = Истина;
Результат.ОтветТГ = ОтветТГ;
Результат.ТекстОшибки = "";
Возврат Результат;
КонецФункции
Функция Телеграм_ОтправитьСообщение(ИдЧата, ТекстСообщения) Экспорт
Результат = Неопределено;
ИмяКоманды = "sendMessage";
ПараметрыКоманды = Новый Структура;
ПараметрыКоманды.Вставить("chat_id", ИдЧата);
ПараметрыКоманды.Вставить("text", ТекстСообщения);
РезультатОтправки = Телеграм_ОтправитьКоманду(ИмяКоманды, ПараметрыКоманды);
Если НЕ РезультатОтправки.Успех Тогда
//ДобавитьВЛог(РезультатОтправки.ТекстОшибки);
Возврат Неопределено;
КонецЕсли;
ОтветТГ = РезультатОтправки.ОтветТГ;
Результат = ОтветТГ.result.message_id;
Возврат Результат;
КонецФункции
Процедура ОтправитьВТелеграм()
ТекстСообщения = "Я к вам пишу — чего же боле?
|Что я могу еще сказать?";
Телеграм_ОтправитьСообщение(<идентификатор-чата>, ТекстСообщения);
КонецПроцедуры
Показать
