() AndrewVVS, делать не долго.
Добавьте в модуль общей формы "СтруктураПодчиненности", например такой код:
&НаСервере
Процедура Действие(Док,Действие)
Попытка
Об = Док.ПолучитьОбъект();
Если Действие = "Проведение" Тогда
Если Об.ПометкаУдаления Тогда
Об.УстановитьПометкуУдаления(Ложь);
КонецЕсли;
Если Об.Проведен Тогда
Об.Записать(РежимЗаписиДокумента.ОтменаПроведения);
Иначе
Об.Записать(РежимЗаписиДокумента.Проведение);
КонецЕсли;
ИначеЕсли Действие = "ПометкаУдаления" Тогда
Об.УстановитьПометкуУдаления(Не Об.ПометкаУдаления);
КонецЕсли;
ОбновитьДеревоСтруктурыПодчиненности();
Исключение
Сообщить("Не удалось выполнить: " + Действие);
КонецПопытки;
КонецПроцедуры
&НаСервереБезКонтекста
Функция СтатусДокумента(Док)
Возврат Новый Структура("Проведен,ПометкаУдаления",Док.Проведен,Док.ПометкаУдаления);
КонецФункции
&НаКлиенте
Процедура ТаблицаОтчетаОбработкаДополнительнойРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
Статус = СтатусДокумента(Расшифровка);
СписокЗн = Новый СписокЗначений;
Если Статус.Проведен Тогда
АктивнаяСтрока =
СписокЗн.Добавить("Проведение","Отмена проведения",,БиблиотекаКартинок.ОтменаПроведения);
Иначе
АктивнаяСтрока =
СписокЗн.Добавить("Проведение","Проведение документа",,БиблиотекаКартинок.Провести);
КонецЕсли;
Если Статус.ПометкаУдаления Тогда
СписокЗн.Добавить("ПометкаУдаления","Снять пометку удаления",,БиблиотекаКартинок.ПометитьНаУдаление);
Иначе
СписокЗн.Добавить("ПометкаУдаления","Пометка удаления",,БиблиотекаКартинок.ПометитьНаУдаление);
КонецЕсли;
ВыбранныйЭлемент = СписокЗн.ВыбратьЭлемент("Действие:",АктивнаяСтрока);
Если ВыбранныйЭлемент = Неопределено Тогда
Возврат;
КонецЕсли;
Действие(Расшифровка,ВыбранныйЭлемент.Значение);
КонецПроцедуры
Показать
И не забудьте связать функцию ТаблицаОтчетаОбработкаДополнительнойРасшифровки() с событием обработка дополнительной расшифровки для элемента формы ТаблицаОтчета.
Тогда по правой кнопке мышки можно проводить/распроводить и изменять пометку удаления.
