Шаблон разработки печатных форм и подключения к конфигурациям на БСП 2.х и БСП 3.0

Публикация № 1130749

Разработка - Печать - Печатные формы документов

печатные формы БСП паттерн шаблон расширения УНФ макет устойчивый

80
«Вместо поставки внешних печатных форм в виде внешних обработок рекомендуется вести их разработку с помощью расширений конфигурации.» [ИТС, БСП гл. 3.38 Печать] У меня задачи типа «Требуется разработать печатную форму …» появляются регулярно, но с временными интервалами. Что бы вести разработку единообразно, для конфигураций на БСП, я заготовил шаблон для таких задачек, который позволяет мне сразу приступить к разработке макета и алгоритма формирования печатной формы, а «обертка» из БСП уже готова.

Шаблон я заготовил еще на БСП 2.х, сейчас актуальна БСП 3.0.х – шаблон менял с развитием БСП. Сравнивая шаблоны получилось очень наглядно как «1С» реализует концепцию «вести разработку как бы сбоку, оставляя типовые объекты на поддержке, а в идеале на замке». Для этого развивает программный интерфейс подсистем БСП, что позволяет свести к минимуму количество объектов в расширении конфигурации.

Для БСП 2.х и БСП 3.0 макет табличного документа и алгоритм формирования печатной формы располагаю в объекте обработка, расширения конфигурации. «Обычно макет печатной формы располагается при объекте, но если макет является общим для двух и более объектов, то либо его следует располагать в обработке, либо это должен быть общий макет.» [ИТС, БСП гл. 3.38 Печать]. Для меня важно оставить конфигурацию «девственной» и минимум объектов заимствовать в расширение конфигурации, поэтому в обработке.

Если на БСП 2.х укладываемся в 7 шагов:

  1. Создаем Расширение;
  2. Создаем обработку;
  3. Создаем макет в обработке;
  4. Заимствуем сам объект (например, документ), для которого требуется добавить команду печати;
  5. Заимствуем Группу команд – «Печать»;
  6. Создаем команду у обработки и определяем свойства «Тип параметра команды» (шаг 4) и «Группа» (шаг 5);
  7. В модуле менеджера Обработки располагаем процедуру с кодом формирования печатной формы и методы подсистемы Печать.

После этого в командной панели формы объекта (например, документа) и формы журнала, в меню «Печать» появится созданная команда. 

 

Рис. 1 Расширение конфигурации на БСП 2.х

 

то на БСП 3.0 получаем желаемое за 4-е шага

  1. Создаем Расширение;
  2. Создаем обработку;
  3. Создаем макет в обработке;
  4. В модуле менеджера Обработки располагаем процедуру с кодом формирования печатной формы и методы подсистемы Печать.

Благодаря развившемуся программному интерфейсу подсистемы «Печать» в расширении конфигурации ничего заимствовать более не нужно.

 

Рис. 2 Расширение конфигурации на БСП 3.0

 

Повинуясь ИТС, подсистему «ПодключаемыеОтчетыИОбработки» заимствуем и в нее включаем созданную обработку.

Вот тот программный интерфейс БСП 3.0, благодаря которому нет более надобности заимствовать «Группу команд», «Документ» и создавать команды у обработки. Следующие процедуры, располагаем в модуле менеджера обработки.

#Область ПрограммныйИнтерфейс

// Определяет состав программного интерфейса для интеграции с конфигурацией.
//
// Параметры:
//   Настройки - Структура - Настройки интеграции этого объекта.
//       См. возвращаемое значение функции ПодключаемыеКоманды.НастройкиПодключаемыхОтчетовИОбработок().
//
Процедура ПриОпределенииНастроек(Настройки) Экспорт
	
    Настройки.Размещение.Добавить(Метаданные.Документы.РасходнаяНакладная);
    Настройки.ДобавитьКомандыПечати = Истина;
	
КонецПроцедуры

// Заполняет список команд печати.
//
// Параметры:
//   КомандыПечати - ТаблицаЗначений - Подробнее см. в УправлениеПечатью.СоздатьКоллекциюКомандПечати().
//
Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт
	
	Команда = КомандыПечати.Добавить();
	Команда.Представление = НСтр("ru = 'Акт передачи на комиссию (из расширения)'");
	Команда.Идентификатор = "АктПередачиНаКомиссию";
	Команда.ПроверкаПроведенияПередПечатью = Истина;
	Команда.Порядок = 1;
	
КонецПроцедуры

// Формирует печатные формы.
//
// Параметры:
//  МассивОбъектов - Массив - ссылки на объекты, которые нужно распечатать;
//  ПараметрыПечати - Структура - дополнительные настройки печати;
//  КоллекцияПечатныхФорм - ТаблицаЗначений - сформированные табличные документы (выходной параметр)
//  ОбъектыПечати - СписокЗначений - значение - ссылка на объект;
//                                            представление - имя области, в которой был выведен объект (выходной параметр);
//  ПараметрыВывода - Структура - дополнительные параметры сформированных табличных документов (выходной параметр).
//
Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	
	ПолноеИмя = Создать().Метаданные().ПолноеИмя();
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АктПередачиНаКомиссию") Тогда
		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АктПередачиНаКомиссию", "Акт передачи на комиссию (из расширения)", ПечатнаяФорма(МассивОбъектов, ОбъектыПечати, ПолноеИмя, "АктПередачиНаКомиссию"));
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

Процедуру формирования печатной формы располагаем в ММ обработки

До процедуры с кодом формирования конкретного табличного документа, я заворачиваю в метод «обертку» ПечатнаяФорма(), в который вынес общие действия характерные для формирования любого табличного документа и обработки массива ссылок, которые нужно распечатать.

В самой процедуре формирования печатной формы я придерживаюсь следующей структуры:

  1. Определяю параметры печати и макет табличного документа;
  2. Запросом выбираю нужные данные;
  3. Результатами выборки заполняю структуру ДанныеПечати  и таблицы значений данными табличных частей. Причем, имена ключей структуры и полей таблицы значений совпадают с именами параметров макета;
  4. Области макета собираю в массив и обхожу его заполняя параметры макета из созданных коллекций на предыдущем шаге, на каждом витке цикла выводя в результирующий табличный документ. Для повышения устойчивости кода заполняю методом ЗаполнитьЗначенияСвойств().

Такой прием позволяет в дальнейшем передвигать параметры по областям макета, не меняя код в процедуре и выглядит элегантно.

#Область СлужебныеПроцедурыИФункции

// Сформировать печатные формы объектов
//
// Параметры:
//	МассивОбъектов - Массив - ссылки на объекты, которые нужно распечатать;
//  ОбъектыПечати - СписокЗначений - значение - ссылка на объект;
// 	ПолноеИмя - имя объекта при котором располагается макет печатной формы
//  ИмяМакета
//
Функция ПечатнаяФорма(МассивОбъектов, ОбъектыПечати, ПолноеИмя, ИмяМакета)
	
	УстановитьПривилегированныйРежим(Истина);
	ТабличныйДокумент = Новый ТабличныйДокумент;
	ПервыйДокумент = Истина;
	
	Для Каждого ТекущийДокумент Из МассивОбъектов Цикл
		
		Если Не ПервыйДокумент Тогда
			ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
		КонецЕсли;
		ПервыйДокумент = Ложь;
		НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;

		Если ИмяМакета = "АктПередачиНаКомиссию" Тогда
			ПечатьАктПередачиНаКомиссию(ТабличныйДокумент, ТекущийДокумент, ПолноеИмя, ИмяМакета);
		//ИначеЕсли ИмяМакета = "СпецификацияНаКомиссию" Тогда
			//...
		КонецЕсли;
		
		УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ТекущийДокумент);
		
	КонецЦикла;
		
	ТабличныйДокумент.АвтоМасштаб = Истина;
	Если ПривилегированныйРежим() Тогда
		УстановитьПривилегированныйРежим(Ложь);
	КонецЕсли;
	
	Возврат ТабличныйДокумент;
		
КонецФункции // ПечатнаяФорма()

// Процедура печати документа.
//
// Параметры:
// 	ТабличныйДокумент - формируемый табличный документ (выходной параметр).
// 	ТекущийДокумент - ссылка на печатыемый объект
// 	ПолноеИмя - текст - имя объекта при котором располагается макет печатной формы
//	ИмяМакета - текст - анализируя этот параметр, удобно бывает немного изменить печатную форму 
//
Процедура ПечатьАктПередачиНаКомиссию(ТабличныйДокумент, ТекущийДокумент, ПолноеИмя, ИмяМакета = "АктПередачиНаКомиссию")
		
	//Параметры печати и макет таблицы
	ТабличныйДокумент.КлючПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_РасходнаяНакладная_АктПередачиНаКомиссию";
	Макет = УправлениеПечатью.МакетПечатнойФормы(ПолноеИмя + ".ПФ_MXL_АктПередачиНаКомиссию");
	
	//Выборка данных для печати
	ТекстЗапроса =
	"ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	РасходнаяНакладная.Дата КАК ДатаДокумента,
	|	РасходнаяНакладная.Номер КАК Номер,
	|	РасходнаяНакладная.Организация КАК Организация,
	|	РасходнаяНакладная.БанковскийСчет КАК БанковскийСчет,
	|	РасходнаяНакладная.Контрагент КАК Контрагент,
	|	РасходнаяНакладная.БанковскийСчетКонтрагента КАК БанковскийСчетКонтрагента,
	|	РасходнаяНакладная.Договор.НомерДоговора КАК НомерДоговора,
	|	РасходнаяНакладная.Договор.ДатаДоговора КАК ДатаДоговора,
	|	РасходнаяНакладная.ВалютаДокумента,
	|	РасходнаяНакладная.СуммаВключаетНДС,
	|	РасходнаяНакладная.НДСВключатьВСтоимость,
	|	РасходнаяНакладная.Запасы.(
	|		Номенклатура.Наименование КАК Товар,
	|		ЕдиницаИзмерения,
	|		Количество,
	|		Цена,
	|		Сумма,
	|		СтавкаНДС,
	|		СуммаНДС,
	|		Всего,
	|		НомерСтроки,
	|		Номенклатура
	|	) КАК Товары
	|ИЗ
	|	Документ.РасходнаяНакладная КАК РасходнаяНакладная
	|ГДЕ
	|	РасходнаяНакладная.Ссылка = &ТекущийДокумент";
	
	Запрос = Новый Запрос(ТекстЗапроса);
	Запрос.УстановитьПараметр("ТекущийДокумент", ТекущийДокумент);
	
	Шапка = Запрос.Выполнить().Выбрать();
	
	Шапка.Следующий();
	
	//Структура с данными для заполнения параметров макета
	ДанныеПечати = Новый Структура;
	
	ДанныеПечати.Вставить("НомерДоговора",	Шапка.НомерДоговора);
	ДанныеПечати.Вставить("ДатаДоговора",	Формат(Шапка.ДатаДоговора, "ДЛФ=DD"));
	ДанныеПечати.Вставить("ДатаДокумента",	Формат(Шапка.ДатаДокумента, "ДЛФ=DD"));
	ДанныеПечати.Вставить("Номер",			ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(Шапка.Номер, Истина));
	
	//ТЧ
	ТаблицаТовары = Шапка.Товары.Выгрузить();
	ДанныеПечати.Вставить("Всего",		ТаблицаТовары.Итог("Всего"));
	ДанныеПечати.Вставить("ВсегоНДС",	ТаблицаТовары.Итог("СуммаНДС"));
	ДанныеПечати.Вставить("Сумма",		ТаблицаТовары.Итог("Сумма"));
	
	ДанныеПечати.Вставить("ИтоговаяСумма",	ДанныеПечати.Сумма + ?(Шапка.СуммаВключаетНДС, 0, ДанныеПечати.ВсегоНДС));
	ДанныеПечати.Вставить("СуммаПрописью",	ЧислоПрописью(ДанныеПечати.ИтоговаяСумма, ,Шапка.ВалютаДокумента.ПараметрыПрописи));
	ДанныеПечати.Вставить("НДСПрописью",	ЧислоПрописью(ДанныеПечати.ВсегоНДС, ,Шапка.ВалютаДокумента.ПараметрыПрописи));
	
	ДанныеПечати.Вставить("ИтоговаяСтрока", 
	СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
	НСтр("ru = 'Общая стоимость партии товара, переданного на реализацию в соответствии с настоящей Спецификацией составляет: %1, в том числе НДС: %2'"),
	ДанныеПечати.СуммаПрописью, ДанныеПечати.НДСПрописью));
	ДанныеПечати.Вставить("НДС", ?(Шапка.СуммаВключаетНДС, НСтр("ru = 'В том числе НДС:'"), НСтр("ru = 'Сумма НДС:'")));
	
	СведенияОКомитенте = УправлениеНебольшойФирмойСервер.СведенияОЮрФизЛице(Шапка.Организация, Шапка.ДатаДокумента, , Шапка.БанковскийСчет);
	ДанныеПечати.Вставить("Комитент",		УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомитенте, "ПолноеНаименование"));
	ДанныеПечати.Вставить("КомитентУНП",	УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомитенте, "ИНН"));
	ДанныеПечати.Вставить("КомитентАдрес",	УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомитенте, "ФактическийАдрес"));
	ДанныеПечати.Вставить("КомитентБанк",	УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомитенте, "НомерСчета,Банк,БИК,КоррСчет"));
	
	СведенияОКомиссионере = УправлениеНебольшойФирмойСервер.СведенияОЮрФизЛице(Шапка.Контрагент, Шапка.ДатаДокумента, , Шапка.БанковскийСчетКонтрагента);
	ДанныеПечати.Вставить("Комиссионер",		УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомиссионере, "ПолноеНаименование"));
	ДанныеПечати.Вставить("КомиссионерУНП",		УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомиссионере, "ИНН"));
	ДанныеПечати.Вставить("КомиссионерАдрес",	УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомиссионере, "ФактическийАдрес"));
	ДанныеПечати.Вставить("КомиссионерБанк",	УправлениеНебольшойФирмойСервер.ОписаниеОрганизации(СведенияОКомиссионере, "НомерСчета,Банк,БИК,КоррСчет"));
	
	//Макет
	МассивОбластейМакета = Новый Массив;
	
	МассивОбластейМакета.Добавить("ЗаголовокАкт");
	МассивОбластейМакета.Добавить("Заголовок");
	МассивОбластейМакета.Добавить("Комитент");
	МассивОбластейМакета.Добавить("ШапкаТаблицы");
	МассивОбластейМакета.Добавить("Строка");
	МассивОбластейМакета.Добавить("Итого");
	МассивОбластейМакета.Добавить("Товар");
	МассивОбластейМакета.Добавить("ПодвалАкта");
	
	//Заполняем макет, устойчивый код
	Для Каждого ИмяОбласти Из МассивОбластейМакета Цикл
		ОбластьМакета = Макет.ПолучитьОбласть(ИмяОбласти);
		Если ИмяОбласти <> "Строка" Тогда
			ЗаполнитьЗначенияСвойств(ОбластьМакета.Параметры, ДанныеПечати);
			ТабличныйДокумент.Вывести(ОбластьМакета);
		Иначе
			Для Каждого СтрокаТаблицы Из ТаблицаТовары Цикл
				ОбластьМакета.Параметры.Заполнить(СтрокаТаблицы);
				ТабличныйДокумент.Вывести(ОбластьМакета);
			КонецЦикла;
		КонецЕсли;
	КонецЦикла;
		
КонецПроцедуры

#КонецОбласти

После того как я себе «зарубил на носу» разрабатывать «так», когда приходят задачи изменить печатные формы не «так» разработанные (например, мной давно) теперь я испытываю когнитивный диссонанс J. Собрал этот паттерн для себя, может, кто еще проникнется.

80

Скачать файлы

Наименование Файл Версия Размер
Расширение для конфигурации на БСП 3.0
.cfe 12,50Kb
03.10.19
9
.cfe 12,50Kb 9 Скачать
Расширение для конфигурации на БСП 2.х
.cfe 15,10Kb
03.10.19
2
.cfe 15,10Kb 2 Скачать

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. d.samsonov92y 04.10.19 12:44 Сейчас в теме
«Вместо поставки внешних печатных форм в виде внешних обработок рекомендуется вести их разработку с помощью расширений конфигурации.» [ИТС, БСП гл. 3.38 Печать]
а как они данный тезис закрепили? для мотивации юзать новый функционал или какие то проблемы не решаемые с привычным способом создания внешних печатных форм?
за статью спс)
4. Кадош 06.10.19 11:17 Сейчас в теме
(1) разработчики отказались от развития подсистемы допотчетов и допобработок по причинам безопасности и отсутствия модулей менеджера.
2. SarethDark 04.10.19 15:55 Сейчас в теме
Запрос в цикле? Сомнительное решение... Правильнее одним запросом выбрать данные по всем объектам, а потом в цикле обходить группировки.
simy4; kadild; +2 1 Ответить
9. tolX5 80 22.10.19 08:49 Сейчас в теме
(2)С этим не поспоришь, если формировать больше одного табличного документа, рекомендуется получить данные до формирования табличных документов. Я чаще сталкиваюсь с задачей много печатных форм у одного документа, обработку массива сохранил т.к. подсистема «Печать» позволяет. Вот доработка нарисовалась, спасибо за дельное замечание.
3. feva 294 04.10.19 20:48 Сейчас в теме
Уххх сразу флэшбэки ловить начал. "Джони эти расширения по всюду, они даже во внешних обработках, Джони..". А Так спасибо!)
5. user633533_encantado 4 08.10.19 21:35 Сейчас в теме
Весь модуль менеджера документа тащить в расширение ?
10. tolX5 80 22.10.19 08:57 Сейчас в теме
(5)Сама «соль» в том, что документ и его модуль менеджера «ваще» не трогаем, все в модуле обработки созданной в расширении.
6. motorkuzbassa.it 100 09.10.19 17:40 Сейчас в теме
для УРБД это провал, расширения потребуется включать в обмен, в котором они будут ездить всегда, в отличии от допов, которые уезжают только при изменении...
Lapitskiy; +1 Ответить
11. tolX5 80 22.10.19 09:00 Сейчас в теме
(6) ушел от УРБД очень давно, неужели если нет изменений в расширении поедет в узел?
12. motorkuzbassa.it 100 22.10.19 15:12 Сейчас в теме
7. simy4 12 13.10.19 16:08 Сейчас в теме
Подскажите пожалуйста, а если перед печатью нужно вывести диалоговое окно, как быть?
8. tolX5 80 22.10.19 08:48 Сейчас в теме
(7)Можно дать «круголя» в клиентский контекст, запросить у пользователя интерактивно доп. параметры перед печатью и вернуться назад на сервер в процедуру Печать модуля менеджера вот так:
1. В процедуре ДобавитьКомандыПечати определяем в параметре КомандыПечати.Обработчик имя Клиентской функции, в которую перенаправим управление;
2. Добавляем эту Клиентскую функцию в модуль формы обработки или общий клиентский модуль;
3. Из клиентского контекста возвращаем управление на сервер вызовом метода УправлениеПечатьюКлиент.ВыполнитьКомандуПечати
Например, вот так (1):
Команда.Обработчик = "ПечатьАктПередачиНаКомиссиюКлиент";

(2) (3) Например так, в форме запрашиваем реквизит «Автомобиль» и передаем в процедуру формирования табличного документа на сервер.
&НаКлиенте
Перем ПараметрыФормы;

&НаКлиенте
Функция ПечатьАктПередачиНаКомиссиюКлиент(ПараметрыПечати) Экспорт
	
	ПараметрыФормы = ПараметрыПечати;
	
	ЭтотОбъект.РежимОткрытияОкна = РежимОткрытияОкнаФормы.БлокироватьОкноВладельца;
	ЭтотОбъект.Открыть();
	
КонецФункции

&НаКлиенте
Процедура ПриЗакрытии(ЗавершениеРаботы)
	
	ДополнительныеПараметрыПечати = Новый Структура;
	ДополнительныеПараметрыПечати.Вставить("Автомобиль", ЭтаФорма.Автомобиль);
	
	УправлениеПечатьюКлиент.ВыполнитьКомандуПечати(ПараметрыФормы.МенеджерПечати, ПараметрыФормы.Идентификатор,
		ПараметрыФормы.ОбъектыПечати, ПараметрыФормы.Форма, ДополнительныеПараметрыПечати);
	
КонецПроцедуры
Показать
15. simy4 12 23.10.19 10:02 Сейчас в теме
(8)благодарю. у меня получилось следующим образом:
Менеджер обработки:
Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт
	
	Команда = КомандыПечати.Добавить();
	Команда.Представление = НСтр("ru = 'ТЕстовая печать (расширение)'");
	Команда.Идентификатор = "ТестовыйИдентификатор";
	Команда.ПроверкаПроведенияПередПечатью = Истина;
	Команда.Порядок = 1;
	Команда.Обработчик	= "ОткрытьФормуПечати";
	Команда.МенеджерПечати= "Обработка.ТестоваяПечать";
	
КонецПроцедуры
Показать


Форма обработки:
&НаКлиенте
Функция ОткрытьФормуПечати(ПараметрыПечати) Экспорт //процедура
	//кешируем параметры печати в реквизиты формы

	АдресОбъектовПечати = ПоместитьВоВременноеХранилище(ПараметрыПечати.ОбъектыПечати, УникальныйИдентификатор);
	МенеджерПечати	 	= ПараметрыПечати.МенеджерПечати;
	ИменаМакетов		= ПараметрыПечати.Идентификатор;
	Открыть();
  
 
КонецФункции


&НаКлиенте
Процедура Печать(Команда)
	
	ОбъектыПечати = ПолучитьИзВременногоХранилища(АдресОбъектовПечати);
	УправлениеПечатьюКлиент.ВыполнитьКомандуПечати(МенеджерПечати, ИменаМакетов, ОбъектыПечати, ЭтотОбъект, Новый Структура("Тест"));

КонецПроцедуры
Показать
13. motorkuzbassa.it 100 22.10.19 15:13 Сейчас в теме
(7)Используйте типовые шаблоны внешек БСП , они более чем , покрывают все потребности. и с предварительным окном и пр...
14. simy4 12 23.10.19 09:58 Сейчас в теме
(13)спасибо за совет. видимо я не до конца точно выразился.
...как быть, при условии работы в расширении с конфигурациями на БСП 3.
Оставьте свое сообщение

См. также

Трудовой договор, Дополнительное соглашение, Лист ознакомления, Договор о материальной ответственности, Договор о коммерческой тайне, Согласие на обработку персональных данных для ЗУП 3.1 17

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::СПР ЗУП3.x Россия БУ Зарплата Управление персоналом (HRM) Абонемент ($m) Печатные формы документов

Комплект печатных форм для отдела кадров для документов Прием на работу и Кадровый перевод: Трудовой договор, Доп. соглашение к трудовому договору, Лист ознакомления с локальными нормативными актами, Договор о полной материальной ответственности, Договор о неразглашении коммерческой тайны, Согласие на обработку персональных данных.

2 стартмани

12.03.2019    6995    56    Asenka    3       

Использование подсистемы БСП "Заполнение объектов" 134

Статья Программист Расширение (cfe) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем)

Применение механизмов БСП для добавления новых команд заполнения к формам различных объектов. Использование расширений конфигурации для доработки. Шаблоны для реализации собственных команд заполнения.

1 стартмани

23.11.2018    13117    8    ids79    22       

Отправка электронной почты с помощью локального почтового клиента из 1С, развернутой под удаленным рабочим столом 13

Инструменты и обработки Программист Пользователь Архив с данными v8 КА1 БП2.0 УТ10 УПП1 Windows Абонемент ($m) Печатные формы документов Универсальные функции Email

Решение для интерактивной (нажал-отредактировал) отправки электронных писем и печатных форм через почтовый клиент (Thunderbird, Outlook) находящийся на локальном компьютере, из конфигурации 1С, развернутой под удаленным рабочим столом (RDP, remote-app). Подходит также для локального развертывания 1С. Представлен пример быстрой интеграции с конфигурациями "Управление торговлей 10.3", "Управление производственным предприятием 1.3", "Комплексная автоматизация 1.1", "Бухгалтерия предприятия 2.0".

1 стартмани

21.09.2018    11262    10    stvorl    0       

БСП: Дополнительная обработка (Регламенты) + Расширения, примеры от сложного к универсальному 71

Статья Программист Архив с данными v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования БСП (Библиотека стандартных подсистем)

Продолжение статьи «БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному». Пойдем от финального примера той статьи и сделаем несколько шагов навстречу к универсальному решению.

2 стартмани

21.05.2018    12171    12    dsdred    17       

БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному 236

Статья Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Практика программирования БСП (Библиотека стандартных подсистем)

Очень много попадается странных решений, которые можно решить через БСП:Дополнительные отчеты и обработки. Я бы вообще БСП из-за этой подсистемы переименовал в «Большое Спасибо Программистам». Поработаем с подсистемой в части написания регламентных заданий.

1 стартмани

10.05.2018    26488    24    dsdred    34       

Трудовой договор, Дополнительное соглашение, Материальная ответственность, Коллективная материальная ответственность, Кадровый перевод, Индексация, Т-53 для ЗУП 3 внешние (7 печатных форм). Создание ведомостей по каждому сотруднику одной кнопкой 26

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::СПР ЗУП3.x БУ Зарплата Управление персоналом (HRM) Абонемент ($m) Печатные формы документов

1. Комплект из 6 печатных форм для документов: Прием на работу, Индексация, Кадровый перевод, Кадровый перевод списком для ЗУП 3.1.10 и более ранних Трудовой договор, дополнительное соглашение, договор личной материальной ответственности, договор коллективной материальной ответственности, индексация, Ведомость Т-53 без лишних строк. Не требуется изменения конфигурации. Подключается через стандартное подключение внешних обработок. 2. Обработка для создания ведемостей из начисления зарплаты. 3. Расширение конфигурации для ЗУП 3.1.10 и КА 2.4.6 для редактирования стажа как в ЗУП 2.5 (Из трудовой деятельности сотрудника. Если ввели строки трудовой деятельности, то стаж считается до даты приема сотрудника).

1 стартмани

26.01.2018    29542    498    p.ugrumov    86       

Расширение возможностей печати: Вывод произвольного нижнего и верхнего колонтитула 8

Отчеты и формы Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Печатные формы документов Практика программирования Универсальные функции

Расширяем функционал вывода нижнего / верхнего колонтитула. Стандартно 1С имеет достаточно ограничений по выводу и наполнению колонтитулов содержимым, взять хотя бы такие, как вывод только текста и отсутствие ограничения на номер конечной страницы. А при разработке кода сталкиваешься с тем, что свой блок с нижним колонтитулом нужно прижимать к низу страницы. Казалось бы быстро решаемый вопрос, но и в нем есть нюансы. Сейчас я расскажу о том, как решалась эта задача. UPD 15.02.2018. Добавлен вывод верхнего колонтитула; Вывод колонтитулов на первой и последней странице управляется параметрами; Научился считать страницы: Добавлено заполнение переменных аналогичных стандартным из колонтитулов; Задаются форматы даты и времени. Ограничения прежние: 1. Повторно сформировать табличный документ после смены параметров страницы интерактивно.; 2. Передавать данные для более плотной печати как можно более мелко нарезанными кусками.

1 стартмани

29.12.2017    21586    21    agent00mouse    0       

Остатки товаров на складах по выбранным документам 9

Отчеты и формы Бухгалтер Руководитель проекта Внешняя обработка (ert,epf) v8 ERP2 УТ11 УУ Учет ТМЦ Абонемент ($m) Печатные формы документов

Печатная форма подключается к документам. Даёт возможность быстро оценить остатки товара на складе по номенклатуре, указанной в документе, и ответить на вопрос, хватает ли остатков, чтобы отгрузить счет? На каких складах продукция по этому документу?

2 стартмани

09.11.2017    30515    24    A7758735    4       

Решение проблемы ПроверитьВывод() для огромных документов 49

Статья Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Печатные формы документов Практика программирования

Пример того, как я ускорил вывод большого табличного документа(100+ страниц)

2 стартмани

06.11.2017    16158    2    SITR-utyos    17       

Счет-фактура+УПД+УКД с 01.10.2017 в редакции Постановления Правительства РФ от 19.08.2017 № 981. Для всех конфигураций на 1С 8 48

Отчеты и формы Бухгалтер Архив с данными v8 БП2.0 УТ10 УПП1 УНФ БП3.0 УТ11 БУ НУ Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Внешние печатные формы с автоматической регистрацией для документа "Счет-фактура выданный" в редакции Постановления Правительства РФ №981 от 19.08.2017 года. Новые счета-фактуры № 981 применяются с 01.10.2017 года. Так же для УТ 10 очень старых релизов применяется сч.фактура в файле.

2 стартмани

18.09.2017    66232    1341    Kontakt    90       

Внешние печатные формы Счет-фактура, УПД, УКД образца 2017 г. (ПП от 19.08.2017 № 981) для УПП 1.3, КА 1.1, БП 2.0 22

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 КА1 БП2.0 УПП1 БУ Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Внешние печатные формы "Счет-фактура", "Универсальный передаточный документ", "Универсальный корректировочный документ" (в редакции постановления Правительства Российской Федерации от 19.08.2017 № 981) для типовых конфигураций УПП 1.3, КА 1.1, БП 2.0.

1 стартмани

30.06.2017    41374    712    Tavalik    63       

Счет-фактура с 01.07.2017 от 25.05.2017 №625 для ВСЕХ конфигураций 1С 8.х (БП 2.0, БП 2.0 КОРП, БАУ 2.0, БАУ 2.0 КОРП, КА 1.1, ПД 1.0, Розница 1.0, УНФ 1.3, УПП 1.3, УТ 11, УТ 10.3) 14

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::БУ КА1 БП2.0 УТ10 Розница УПП1 УНФ БП3.0 БАУ УТ11 Россия БУ Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

С июля 2017 года применяется новая печатная форма счет-фактуры в редакции Постановления Правительства РФ от 25.05.2017 № 625. В публикации собраны внешние печатные формы для всех популярных конфигураций 1С. Будет актуально для 90% организаций, которые не ведут учет по гос. контрактам, так как новое поле не заполняется, а вместо номера гос. контракта установлен прочерк по умолчанию.

1 стартмани

29.06.2017    34427    455    a.kapustin    43       

Упрощение работы с актами сверки в УТ/КА/УПП - вывод номеров счетов в документе и печатной форме 3

Инструменты и обработки Бухгалтер Внешняя обработка (ert,epf) v8 КА1 УТ10 УПП1 БУ УУ Дебиторская и кредиторская задолженность Абонемент ($m) Обработка документов Печатные формы документов

Обычно акт сверки с клиентами содержат информацию о документах реализации товаров (накладных) и выполненных платежах. Но платежи делаются на основании счетов, номера которых отсутствуют в актах, что затрудняет собственно сверку. Данная обработка находит соответствующие расходным накладным счета/заказы, показывает их в форме документа и выводит в печатную форму акта.

2 стартмани

12.05.2017    11774    2    denmax    2       

Управление задачами: Канбан доска 235

Инструменты и обработки Программист Архив с данными v8 Windows Абонемент ($m) Инструментарий разработчика БСП (Библиотека стандартных подсистем)

Конфигурация "Управление задачами" с использованием БСП. Канбан доска. Открытый код.Загрузка изменений из хранилища конфигураций 1С и связь с задачами. Проект выложен на github (ссылка в публикации). Управляемые формы. Рассылка уведомлений.

1 стартмани

02.10.2016    47675    465    BlizD    284       

БСП 2.3 и БСП 3.0: Просто про выполнение внешней обработки в фоне (c индикацией прогресса выполнения) 185

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Windows Абонемент ($m) Инструментарий разработчика Практика программирования БСП (Библиотека стандартных подсистем)

Простое пояснение о том, как сделать внешнюю обработку с фоновым выполнением и индикацией процесса для любой конфигурации на основе БСП 2.3.2. UPDATE 20/09/19: добавлен вариант обработки с индикацией процента выполнения и статусом выполнения для БСП 3.0.

1 стартмани

18.05.2016    45919    136    rozer    52       

Печатная форма Счет-Фактура от 01.10.2017, УПД 01.10.2017, Торг-12, Счет на оплату, ТТН (1-Т) БП 3.0 ОРИГИНАЛЬНЫЕ 10

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::БУ БП3.0 БУ Windows Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Набор внешних печатных форм: Счет-Фактура, УПД, Торг-12, ТТН, Счетна оплату для 1С: БП 3.0. Формы взяты из релиза 3.0.54.20 бухгалтерии предприятия. Печатные формы (УПД и счет-фактуры) приведены в соответствие постановления 625 от 25.05.2017 И В РЕДАКЦИИ ПОСТАНОВЛЕНИЯ 981 ОТ 19.08.2017 в формах выводится "Идентификатор госконтракта" и прочие изменения.

1 стартмани

04.05.2016    36912    378    A7758735    3       

Вывод печатных форм с запросом данных в форму "Печать документов" из подсистемы БСП "Печать". 76

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Практика программирования БСП (Библиотека стандартных подсистем)

Все не раз видели, как в типовых конфигурациях, построенных на основе БСП (Библиотека стандартных подсистем), печатные формы, построенные на основе Табличного документа, выводятся в специальную форму "ПечатьДокументов". Эта форма входит в состав подсистемы "Печать" из БСП. При разработке своих печатных форм, иногда необходимо запросить у пользователя дополнительные данные необходимые для печати. Тут встает вопрос, как в этом случае вывести печатную форму в форму "Печать документа". В этой статье я рассмотрю, как реализовать вывод печатной формы в упомянутую форму из подсистемы "Печать", в случае если мы хотим перед выводом печатной формы запросить у пользователя дополнительные данные. Здесь будут рассмотрены два случая: когда реализуется печатная форма с использованием подсистемы "Дополнительные отчеты и обработки" и когда печатная форма добавляется в конфигурацию в режиме конфигуратора, т.е. вносятся изменения в типовую конфигурацию.

1 стартмани

29.03.2016    63703    146    lopatin    12       

УФ + БСП: копирование строк табличных частей (даже между разными инфобазами) 47

Инструменты и обработки no Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Windows Абонемент ($m) Обработка документов БСП (Библиотека стандартных подсистем)

Внешняя обработка для конфигураций на БСП, работает на управляемых формах (включая Такси) в толстом клиенте, тонком клиенте и веб-клиенте

1 стартмани

23.03.2016    18191    88    Cyberhawk    30       

Отображение прогресса выполнения длительных операций в БСП и их отладка в текущем сеансе. 160

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Windows Абонемент ($m) Практика программирования БСП (Библиотека стандартных подсистем)

В статье описан способ исполнения длительных операций в конфигурациях, в которых используется библиотека стандартных подсистем, с визуализацией прогресса исполнения и отображения хода обработки данных. Также дается краткое описание процесса отладки длительных операций в текущем сеансе.

1 стартмани

17.02.2016    40461    143    balanton    20       

Печатные формы для БП 3.0: УПД, ТОРГ-12, Акт, Счет-фактура, Доверенность, Счет 25

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::БУ БП3.0 Россия БУ Windows Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Внешние печатные формы УПД, ТОРГ-12, Акта об оказании услуг, Счет-фактуры, Доверенности и Счета на оплату покупателю, актуализированы на последний релиз 3.0.71, поддерживают типовые факсимиле (новую галочку "Подпись и печать"), не содержат ошибок с новой ставкой НДС. В публикации также представлены печатные формы для устаревших релизов.

1 стартмани

28.01.2016    55588    762    config    42       

Легкое создание пользователем внешних печатных форм методом Drag & Drop 135

Отчеты и формы Программист Бухгалтер Руководитель проекта Внешняя обработка (ert,epf) v8 1cv8.cf Windows Абонемент ($m) Универсальные печатные формы Печатные формы документов

Универсальная внешняя печатная форма (ПФ), которая позволяет пользователю, без знаний программирования и не заходя в конфигуратор, создать ПФ любого документа или справочника в Microsoft Word или OpenOffice Writer методом перетаскивания (Drag & Drop). Можно создавать любые ПФ с выводом табличных частей, реквизитов документа, а также вложенных реквизитов и контактной информации. Не требует изменения конфигурации. Работает на версии платформы 8.3 в типовых конфигурациях на управляемых формах (например, Бухгалтерия 3.0, УТ 11, УНФ, Розница, Документооборот), а также и в других конфигурациях на УФ, построенных на БСП.

2 стартмани

04.01.2016    28215    180    CyberCerber    35       

Внешняя печатная форма «Счет на оплату покупателю» для документа «Реализация товаров и услуг» 2

Отчеты и формы Бухгалтер Архив с данными v8 БП2.0 Windows Оптовая торговля Абонемент ($m) Печатные формы документов

Внешняя печатная форма «Счет на оплату покупателю» для документа «Реализация товаров и услуг»

5 стартмани

07.09.2015    16993    2    trendy    0       

[x1c.ru] MXL Stamps - Печати и подписи в макетах печатных форм в несколько кликов 3

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Печатные формы документов Универсальные обработки

Обработка позволяет быстро создавать поля текста из ячеек печатных форм и добавлять "под них" подписи и печати. Работает в конфигурациях на управляемых формах.

1 стартмани

22.08.2015    26734    23    GusevNA    6       

Конструктор трудовых договоров WORD для типовой конфигурации 1C: Зарплата и управление персоналом 3.1 82

Отчеты и формы Программист Бухгалтер Внешняя обработка (ert,epf) v8 v8::СПР ЗУП3.x Россия БУ Windows Зарплата Управление персоналом (HRM) Абонемент ($m) Универсальные печатные формы Пакетная печать Печатные формы документов

Внешняя печатная форма или обработка "Конструктор трудовых договоров на основе документов формата Word". Конструктор автоматически подставляет реквизиты в документ формата Word. Подходит для типовой конфигурации 1С: ЗУП 3.1.

1 стартмани

14.07.2015    46661    581    ni032mas    97       

Счет на оплату покупателю с выбором изображения факсимильной печати и подписей для конфигурации "Бухгалтерия предприятия 3.0" 5

Отчеты и формы Бухгалтер Руководитель проекта Внешняя обработка (ert,epf) v8 БП2.0 Россия Windows Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Как известно, типовая конфигурация предоставляет возможность формирования счета с подписями и печатью. Это удобно, т.к. сразу, без вывода на печать и сканирования можно сохранить факсимильное изображение документа в pdf формате и отправить контрагенту. Создание и добавление картинки производится при редактировании справочника "Организации". Здесь же предлагается шаблон и понятная инструкция по созданию файла картинки. Что же можно улучшить?

1 стартмани

10.07.2015    19108    34    Олег Ящеров    5       

Создание связных объектов, как аналог "Создания на основании" в конфигурациях на основе БСП 36

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Обработка документов Практика программирования

Не все знают, что конфигурации на основе БСП (УТ 11, БП 3.0, ЗУП 3.0 и т.д.) имеют механизм, который позволяет создавать связанные объекты, что в какой-то мере является аналогом создания на основании.

1 стартмани

26.06.2015    22357    19    Diversus    10       

Инвентаризационные описи 0504087 и 0504086 согласно приказу №139 от 08.03.08 МО РФ 1

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::БУ БГУ Государственные, бюджетные структуры Россия БУ Windows Учет ОС и НМА Абонемент ($m) Печатные формы документов

Внешние печатные формы 0504087 и 0504086 от НПЦ Прогтехника 1С:Воинская часть 8 с моими изменениями согласно приказу МО РФ №139

1 стартмани

12.06.2015    20503    13    alfaservice    1       

Товарный чек с логотипом для конфигурации "Бухгалтерия предприятия 3.0.30-3.0.40.27" 4

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 БП2.0 БУ Windows Розничная торговля Абонемент ($m) Печатные формы документов

Печатная форма "Товарный чек" "Бухгалтерия предприятия 3.0", документов "Реализация" и "Отчет о розничных продажах"

1 стартмани

08.06.2015    14800    8    Alexsur    1       

Печатные формы УПД ("Универсальный передаточный документ") и Счета-Фактуры для ЛЮБЫХ версий УТ 10.3 (Управление торговлей ред.10.3) (с изменениями 2017 года) 9

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::ОУ УТ10 Россия БУ Windows Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Печатные формы "УПД" и "Счет-фактура с 2012 года" для документов "РеализацияТоваровУслуг" и "СчетФактураВыданный" для старых и новых версий УТ10.3 (с изменениями 2017 года в июле и октябре)

2 стартмани

01.06.2015    33405    191    aserg    34       

Отправка пакета документов по электронной почте (в формате PDF/XLS/HTML/MXL/ODS) 17

Инструменты и обработки Бухгалтер Руководитель проекта Внешняя обработка (ert,epf) v8 БП2.0 КА1 УПП1 УТ10 Россия БУ Windows Оптовая торговля Абонемент ($m) Печатные формы документов Пакетная печать Email

С помощью обработки можно нажатием одной кнопки отправить пакет документов контрагенту по электронной почте. Теперь не надо заходить в каждый документ, формировать нужную печатную форму, сохранять на диск, а потом собирать в одном письме. Все это за вас сделает программа самостоятельно. Все, что требуется от пользователя - просто выбрать документ в программе! Доступны варианты обработки для обычного и управляемого приложения!

2 стартмани

22.04.2015    40630    3    trendy    18       

УПД за поставщика c подписями и факсимиле для БП 3.0 39

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::БУ БП3.0 Россия БУ Windows Документооборот и делопроизводство Оптовая торговля Абонемент ($m) Печатные формы документов

Внешняя печатная форма для печати - "Универсальный передаточный документ" за поставщика. ВПФ (с формой и без) в форме заполняются должности и фамилии и происходит заполнение полей 10,13, 15,18.Так же есть возможность хранить и выводить на печать подписи руководителя и глав.бухгалтера поставщика. Внесены изменения под требования конфигураций выше 3.0.67.38 (НДС20%). Версия 0.2 без формы выбора подписантов(будет полезна тем у кого ответственные лица неизменные).

5 стартмани

19.03.2015    68896    953    kn    96       

Использование общих модулей "Длительные операции" из состава БСП или асинхронное выполнение серверных процедур без блокировки пользовательского интерфейса 128

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Практика программирования Производительность и оптимизация (HighLoad) Универсальные функции БСП (Библиотека стандартных подсистем)

В статье кратко описан способ использования процедур общих модулей "Длительные операции" из состава библиотеки стандартных подсистем (БСП). Статья будет полезна программистам и администраторам, работающих с объемными клиент-серверными базами, конфигурации которых включают в себя БСП. К длительным операциям можно отнести, например, такие процедуры как групповое проведение документов, формирование объемистых отчетов, работа с внешними источниками данных.

1 стартмани

17.03.2015    55361    163    Bassgood    15       

Дополнительные отчеты и обработки для конфигураций, основанных на БСП. Часть 1. Заполнение объектов. 101

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Россия Абонемент ($m) Практика программирования

В статье приводится аргументация за использование во внешних отчетах и обработках только одного варианта использования - ОткрытиеФормы, и приводится пример обработки заполнения объекта, которая подключается к любой конфигурации ко всем объектам. Обработку легко отлаживать и можно использовать в качестве шаблона для создания других обработок заполнения объектов.

1 стартмани

08.01.2015    32015    153    acrk    23       

Инвентаризационная опись 0504087 с группировкой по счету для БГУ 1.0 1

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 БГУ Россия БУ Windows Учет ОС и НМА Учет ТМЦ Абонемент ($m) Печатные формы документов

Внешняя печатная форма предназначена для печати ф. 0504087 с группировкой по счёту учёта для документов:"Инвентаризация ОС (НМА,НПА) на балансовых счетах", "Инвентаризация основных средств (забалансовый учет)", "Инвентаризация ОС в оперативном учете", "Инвентаризация материалов на счете 105", "Инвентаризация материалов (забалансовый учет)".

5 стартмани

22.12.2014    26555    5    agospodarin    2       

Внешняя печатная форма "Качественное удостоверение" к 1С:Бухгалтерия 3.0 2

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 БП2.0 Россия БУ Windows Оптовая торговля Абонемент ($m) Печатные формы документов

Внешняя печатная форма "Качественное удостоверение" к 1С:Бухгалтерия 3.0 на управляемых формах без изменения конфигурации с доп. сведениями в номенклатуре: "Сертификат соответствия" и "Срок хранения"

1 стартмани

03.12.2014    20215    42    dialogsoft    3       

Создание внешней печатной формы под УП с возможностью передачи параметров (для конфигураций на БСП) 35

Отчеты и формы Программист Внешняя обработка (ert,epf) v8 1cv8.cf Windows Абонемент ($m) Печатные формы документов

В статье будет широко рассмотрен вопрос создания внешней печатной формы под управляемым приложением с возможностью передачи параметров. Предложено два способа распечатать ВПФ и передать в нее нужные параметры.

1 стартмани

07.08.2014    40160    118    signum2009    8       

Создание внешних печатных форм под управляемым приложением с нуля 550

Статья Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Windows Абонемент ($m) Печатные формы документов

Когда мне пришлось создавать внешние печатные формы под приложения на БСП ("1С: Бухгалтерия предприятия 3.0", "1С: Управление торговлей 11"), я обнаружил, что нет грамотных инструкций. Те, что имелись, использовали так называемые шаблоны: готовые обработки, в которых необходимо выполнять определенные корректировки. Но как создать сам шаблон, конкретных мануалов не было, справочную информацию я нашел на сайте ИТС и, обработав ее, написал статью, где подробно и понятно объясняются все этапы создания внешней печатной формы для управляемого приложения на примере конфигурации "1С: Бухгалтерия предприятия 3.0"

1 стартмани

05.06.2014    227277    557    signum2009    119       

Прогресс-бар длительных серверных операций (БСП) 45

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Инструментарий разработчика Работа с интерфейсом

Простой и удобный шаблон для подобного рода задач в виде внешней обработки. Используется технология, предлагаемая в БСП (Библиотеке Стандартных Подсистем), практически без ноу-хау. Доработано таким образом, что обработка может быть как встроенной в конфигурацию, так и внешней.

1 стартмани

23.04.2014    24164    255    herfis    14       

ТОРГ-12 с выбором грузополучателя, печатью КПП и тары отдельными строками для УТ 11 6

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 v8::ОУ УТ11 УУ Windows Оптовая торговля Абонемент ($m) Печатные формы документов

Внешняя печатная форма ТОРГ-12 с выбором грузополучателя, с возможностью печати КПП и вывода тары отдельными строками для Управления торговлей 11

2 стартмани

18.04.2014    27714    25    lok78    1       

Счет-фактура в конфигурации Управление торговлей 11.1 2

Отчеты и формы Бухгалтер Внешняя обработка (ert,epf) v8 УТ10 Россия БУ Windows Оптовая торговля Производство готовой продукции (работ, услуг) Абонемент ($m) Печатные формы документов

Внешняя печатная форма "Счет-фактура" к документу "Реализация товаров и услуг" Конфигурация Управление торговлей 11.1 (11.1.2.22)

1 стартмани

06.02.2014    19403    65    sdn-1    2       

Шаблон внешней печатной формы в управляемом приложении. Пример создания печатной формы. 71

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 БП2.0 Windows Абонемент ($m) Печатные формы документов Практика программирования

Данная статья посещена для тех, кто пытается сделать внешнюю печатную форму в 1С на основе типовых форм. Отладка печатной формы в клиент-серверном варианте из под тонкого клиента.

1 стартмани

10.01.2014    63073    661    Leoway    25       

Счет на оплату с печатью и подписью к документу "Заказ клиента" в конфигурации Управление торговлей 11.1 9

Отчеты и формы no Внешняя обработка (ert,epf) v8 УТ10 Windows Оптовая торговля Абонемент ($m) Печатные формы документов

Внешняя печатная форма "Счет на оплату" с печатью и подписью для нескольких фирм к документу "Заказ клиента" Конфигурация Управление торговлей 11.1 (11.1.2.10)

1 стартмани

10.01.2014    35892    189    sdn-1    21