Использование менеджера расчета для расчета зарплаты в ЗУП 3.1

Публикация № 1495126 24.08.21

Учетные задачи - Зарплата

МенеджерРасчета ЗУП расчет зарплаты расчетные механизмы менеджер расчета

Пример использования менеджера расчета начислений и НДФЛ по сотруднику или организации. Будет полезен разработчикам, которые в ЗУП 3.1. залезли немного поглубже, чем при разработке печатных формы или отчетов.

Введение

Уже достаточно много появилось статей, посвященным механизмам конфигурации ЗУП 3.1, но при этом менеджер расчета обделен вниманием. В этой статье я приведу примеры работы с менеджером расчета и некоторым механизмам, связанным с ним.

По сути в конфигурации у нас три расчетных обработки

  • РасчетБазыНачисленийУдержаний - формирует базы начислений и удержаний, используемых для расчета
  • МенеджерДанныхУчетаВремениСотрудников - формирует данные по времени сотрудников
  • МенеджерРасчетаЗарплаты - основной менеджер расчета, который рассчитывает начисления, взносы, ндфл и прочее. Фактически при расчете зарплаты мы видим результат работы этого менеджера.

Инициализировать менеджер можно двумя способами:

При расчете зарплаты за месяц можно использовать типовой метод инициализации

МенеджерРасчета = РасчетЗарплатыРасширенный.СоздатьМенеджерРасчета(МесяцНачисления, Организация);

При нестандартных расчетах нам может понадобится инициализировать его по-своему, вызвав конструктор

МенеджерРасчета = Обработки.МенеджерРасчетаЗарплаты.Создать();
ПериодРасчета = Новый СтандартныйПериод;
ПериодРасчета.ДатаНачала = ДатаНачала ;
ПериодРасчета.ДатаОкончания = ДатаОкончания ;
МенеджерРасчета.Инициализировать(ПериодРасчета, Организация);

Разница в том, что во втором случае мы можем указать произвольный период, например год.

С релиза ЗУП 3.1.10 старый менеджер расчета был переименован в МенеджерРасчетаЗарплатыАрхивный и за его использование отвечает константа "Выполнять расчет зарплаты без оптимизации". Но на дворе 21 год, думаю в ближайших релизах от старых алгоритмов окончательно откажутся.

Основная логика работы с менеджером это

  1. Заполнить коллекцию начислений

  2. Рассчитать зарплату

  3. Перенести результат в форму/документ.

Разберем несколько примеров работы с менеджером расчета. Уточню что для примера я буду рассчитывать только начисления и НДФЛ с вычетами.

Расчет начисления по сотруднику.

Например, у нас на входе для расчета есть сотрудник, начисление и период, за который мы хотим посчитать это начисление.

//Инициализация менеджера расчета
МенеджерРасчета = РасчетЗарплатыРасширенный.СоздатьМенеджерРасчета(МесяцНачисления, Организация);
МенеджерРасчета.НастройкиРасчета.Сотрудники = Сотрудник;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНачисления = Истина;
МенеджерРасчета.НастройкиРасчета.ОкончательныйРасчет = Истина;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНДФЛ = Истина;

МенеджерРасчета.НастройкиНДФЛ.Сотрудники = Сотрудник;
МенеджерРасчета.НастройкиНДФЛ.ОкончательныйРасчет = Истина;

//Инициализация пустой таблицы для начислений
ТаблицаНачислений = МенеджерРасчета.ТаблицаИсходныеДанныеНачисленияЗарплатыПоНачислениям();

//Добавляем в таблицу сотрудника, интервал начисления и период
НовыйИнтервал = ТаблицаНачислений.Добавить();
НовыйИнтервал.Сотрудник = Сотрудник;
НовыйИнтервал.Начисление = Начисление;
НовыйИнтервал.ДатаНачала = МесяцНачисления;
НовыйИнтервал.ДатаОкончания = КонецМесяца(МесяцНачисления);	

//Заполняем коллекцию Зарплата.Начисления
МенеджерРасчета.ЗаполнитьНачисленияСотрудникаЗаПериод(Сотрудник, ТаблицаНачислений);

//Расчет
МенеджерРасчета.РассчитатьЗарплату();

//Перенос расчитанных данных в данные формы
ДанныеДляЗаполненияВДанныеФормы(МенеджерРасчета.Зарплата);

В результате в табличной части менеджера расчета Зарплата.Начисления у нас будут результаты расчета по сотруднику, а также все вспомогательные данные, которые использовались при расчете (показатели и их значения, нормы и фактическое время, график работы, подразделение).

В процедуре ДанныеДляЗаполненияВДанныеФормы у меня алгоритмы, для переноса данных менеджера расчета в данные формы. Т.к. этот алгоритм универсальный, я немного о нем расскажу после всех примеров по расчетам.

Расчет начисления по сотруднику, где один из показателей мы указываем самостоятельно.

Код для примера тот же, но для интервала мы указываем известное значение показателя, которое вы можете указать вручную с формы или рассчитать отдельно.

...
НовыйИнтервал.ДатаОкончания = КонецМесяца(МесяцНачисления);	
МенеджерРасчета.ДобавитьИзвестноеЗначениеПоказателя(НовыйИнтервал, Показатель, ЗначениеПоказателя);
...

Если в первом примере все показатели рассчитывались в процессе, то в текущем мы заранее подставляем в расчет известное значение показателя.

Расчет всех начислений по сотруднику за месяц

МенеджерРасчета = РасчетЗарплатыРасширенный.СоздатьМенеджерРасчета(МесяцНачисления, Организация);
МенеджерРасчета.НастройкиРасчета.Сотрудники = Сотрудник;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНачисления = Истина;
МенеджерРасчета.НастройкиРасчета.ОкончательныйРасчет = Истина;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНДФЛ = Истина;

МенеджерРасчета.НастройкиНДФЛ.Сотрудники = Сотрудник;
МенеджерРасчета.НастройкиНДФЛ.ОкончательныйРасчет = Истина;
	
Сотрудники = ОбщегоНазначенияКлиентСервер.ЗначениеВМассиве(Сотрудник);
	
МенеджерРасчета.НачисленияЗарплатыЗаПериод(Сотрудники, МесяцНачисления, КонецМесяца(МесяцНачисления));

ПериодРасчетаЗарплаты = Новый СтандартныйПериод;
ПериодРасчетаЗарплаты.ДатаНачала = МесяцНачисления;
ПериодРасчетаЗарплаты.ДатаОкончания = КонецМесяца(МесяцНачисления);

СотрудникиДляНачислений = МенеджерРасчета.ТаблицаСотрудников();
	
МенеджерРасчета.ЗаполнитьНачисленияСотрудникаЗаПериод(Сотрудник, СотрудникиДляНачислений, ПериодРасчетаЗарплаты);
	
МенеджерРасчета.РассчитатьЗарплату();       

ДанныеДляЗаполненияВДанныеФормы(МенеджерРасчета.Зарплата);

Тут мы видим разницу в вызове процедуры ЗаполнитьНачисленияСотрудникаЗаПериод.

Т.е. заранее мы не указываем какие начисления считать, а параметр ПериодРасчетаЗарплаты указывает процедуре, что необходимо выявить начисления сотрудника за месяц.

Расчет всех сотрудников по организации (подразделению)

ПараметрыПолученияСотрудников = КадровыйУчет.ПараметрыПолученияСотрудниковОрганизацийПоСпискуФизическихЛиц();
ПараметрыПолученияСотрудников.Организация  		= Организация;
ПараметрыПолученияСотрудников.Подразделение 	= Подразделение;
ПараметрыПолученияСотрудников.НачалоПериода		= МесяцНачисления;
ПараметрыПолученияСотрудников.ОкончаниеПериода  = КонецМесяца(МесяцНачисления);
КадровыйУчетРасширенный.ПрименитьОтборПоФункциональнойОпцииВыполнятьРасчетЗарплатыПоПодразделениям(ПараметрыПолученияСотрудников);

Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
КадровыйУчет.СоздатьВТСотрудникиОрганизации(Запрос.МенеджерВременныхТаблиц, Истина, ПараметрыПолученияСотрудников);
	
Запрос.Текст = 
"ВЫБРАТЬ
|	Сотрудники.Сотрудник КАК Сотрудник,
|	Сотрудники.ФизическоеЛицо КАК ФизическоеЛицо
|ИЗ
|	ВТСотрудникиОрганизации КАК Сотрудники";

Сотрудники = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Сотрудник");

МенеджерРасчета = РасчетЗарплатыРасширенный.СоздатьМенеджерРасчета(МесяцНачисления, Организация);
МенеджерРасчета.НастройкиРасчета.Сотрудники = Сотрудники;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНачисления = Истина;
МенеджерРасчета.НастройкиРасчета.ОкончательныйРасчет = Истина;
МенеджерРасчета.НастройкиРасчета.РассчитыватьНДФЛ = Истина;

МенеджерРасчета.НастройкиНДФЛ.Сотрудники = Сотрудники;
МенеджерРасчета.НастройкиНДФЛ.ОкончательныйРасчет = Истина;
	
СотрудникиДляНачислений = МенеджерРасчета.ТаблицаСотрудников();
Для Каждого Сотрудник Из Сотрудники Цикл
	НоваяСтрока = СотрудникиДляНачислений.Добавить();
	НоваяСтрока.Сотрудник = Сотрудник;
	НоваяСтрока.ДатаНачала = МесяцНачисления;
	НоваяСтрока.ДатаОкончания = КонецМесяца(МесяцНачисления);
КонецЦикла;

ОтборМенеджераРасчета = МенеджерРасчета.СоздатьОтборы();
ОтборМенеджераРасчета.Подразделение = Подразделение;
МенеджерРасчета.ЗаполнитьНачислениеЗарплаты(СотрудникиДляНачислений, ОтборМенеджераРасчета);
  	
МенеджерРасчета.РассчитатьЗарплату();
 
ДанныеДляЗаполненияВДанныеФормы(МенеджерРасчета.Зарплата);

Если вы уже работали с ЗУП 3.1 или читали описание по программным методам ЗУП, то думаю приведенный пример не вызовет вопросов. Вначале мы получили всех текущих сотрудников организации (а если указали подразделение, то по подразделению), затем передали список менеджеру расчета и инициализировали расчет.

Это базовые примеры работы с менеджером расчета. В зависимости от реализуемых задач, можно задействовать разный функционал менеджера расчета. Рекомендую просто пройтись отладчиком по менеджеру расчета, от метода "РассчитатьЗарплату". Посмотреть по какому принципу разбиваются строки начислений, каким образом рассчитываются показатели, в т.ч. базы для расчета начислений и удержаний.

Перенос результата расчета данные формы

Тут немного стоит рассказать в каком виде хранятся данные в документах и формах.

В менеджере расчета и в табличных частях документов начисления с данными формы практически совпадают. Разница в хранении показателей. В менеджере расчета и в документах показатели хранятся в отдельной ТЧ "Показатели", связанной с начислениями по реквизиту "ИдентификаторСтроки". А вот в формах к таблице начислений программно или вручную добавляются колонки "Показатель1", "Показатель2”… и "ЗначениеПоказателя1", "ЗначениеПоказателя2"…

Соответственно при чтении/открытии документа, а также после расчета данные показателей переносятся в созданные новые колонки. А при записи документа происходит обратный процесс переноса в ТЧ "Показатели".

Исходные требования для реализации примера:

В форме мы хотим видеть результаты начислений с расшифровкой по показателям, указанием отработанного времени. Т.е. все то, что мы привыкли видеть в любом типовом расчетом документе.

Приведу пример кода процедуры ДанныеДляЗаполненияВДанныеФормы, параметром в которую мы передаем результаты расчета для дальнейшего вывода в форму документа/обработки.

ТаблицыНачислений = РасчетЗарплатыРасширенныйФормы.ТаблицыНачисленийФормы();
ТаблицыНачислений.Начисления = Объект.Начисления;
РасчетЗарплатыРасширенныйФормы.РасчетЗарплатыНачисленияВДанныеФормы(ТаблицыНачислений, ДанныеЗаполнения.Начисления, Объект.Организация, Объект.МесяцНачисления);
РасчетЗарплатыРасширенныйФормы.РасчетЗарплатыНДФЛВДанныеФормы(Объект.НДФЛ, Объект.ПримененныеВычетыНаДетейИИмущественные, ДанныеЗаполнения.НДФЛ);
УчетНДФЛФормы.ЗаполнитьВторичныеДанныеТабличныхЧастей(ЭтаФорма);

МассивОписанийТаблицФормы = МассивОписанийТаблицФормы(ЭтаФорма);
ЗарплатаКадрыРасширенный.ВводНачисленийЗаполнитьВторичныеДанныеПоказателей(ЭтаФорма, МассивОписанийТаблицФормы);
ЗарплатаКадрыРасширенный.ПериодНачисленияЗаполнитьИспользованиеПериода(ЭтаФорма, МассивОписанийТаблицФормы);
ЗарплатаКадрыРасширенный.ЗаполнитьДоступностьМестаПолученияДохода(ЭтаФорма, МассивОписанийТаблицФормы);

Т.е. по факту мы используем типовые методы. Но тут своя магия. Чтобы этот код работал, мы должны правильно подготовить данные формы.

Например, в обработчике "ПриСозданииНаСервере" вызвать метод программного создания показателей и их значений в ТЧ Начисления

РасчетЗарплатыРасширенныйФормы.ДокументыВыполненияНачисленийДополнитьФорму(ЭтаФорма, ОписаниеТаблицыНачислений(ЭтаФорма), "Начисления");

А так же у нас должны быть созданы всевозможные служебные процедуры и функции, описывающие наш документ (ОписаниеТаблицыНачислений(), ОписаниеДокумента(), ОписаниеТаблицыНДФЛ(), ОписаниеПанелиВычетыНаСервере(), ОписаниеПанелиВычеты(), КонтролируемыеПоля()).

Думаю, просто нет смысла полностью приводить данный код. К статье прикладываю обработку, в которой реализовано все вышеописанное. С учетом того, что используются только типовые методы, вы можете самостоятельно посмотреть примеры использования на типовых документах.

При некоторой смекалке, можно адаптировать методы модулей РасчетЗарплатыРасширенныйФормы, УчетНДФЛФормы и аналогичные для того, чтобы полностью програмно формировать расчетные документы.

Текущий пример тестировался в ЗУП 3.1.18 и ERP 2.5.7.150

Скачать файлы

Наименование Файл Версия Размер
Использование менеджера расчета для расчета зарплаты в ЗУП 3.1:

.epf 22,12Kb
51
.epf 22,12Kb 51 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. leosoft 160 24.09.21 22:28 Сейчас в теме
Интересная информация! А где на практике это может потребоваться? Или это чисто академический интерес?
2. maraty 345 25.09.21 08:46 Сейчас в теме
(1) например свой расчетный документ, или разработка подсистемы планирования и прогнозирования ФОТ, где Фот считается на год вперёд. Да и в принципе любое программное формирование расчетных документов. Например у нас на входе (шина данных) есть сумма, а нам нужно получить рассчитанные страховые взносы, НДФЛ с вычетами или другие расчетные данные.
Student1C; +1 Ответить
3. biimmap 924 05.01.22 13:27 Сейчас в теме
Стоит наверно в статье дописать, что нужные таблицы и реквизиты, в т.ч. реквизиты формы, необходимо создать на форме обработки. Это собственно нужно, чтоб была форма, которую везде передают как параметр в программном интерфейсе. Слава богу в коде не проверяется принадлежность формы, поэтому зарплату можем и в справочнике посчитать)
4. maraty 345 09.01.22 12:41 Сейчас в теме
(3) Вот это как раз не обязательно. Можно обойтись вообще без формы. Тут https://infostart.ru/public/1576926/ я реализовал именно так. Но это конечно обход типового алгоритма, который рассчитан только на формы.
5. biimmap 924 09.01.22 12:51 Сейчас в теме
(4) поэтому и написал столь категорично, что это обход. У меня есть такой принцип: делаю максимально похоже на типовой запуск программного интерфейса. Т.е. нужна форма - держи форму обработки со всеми нужными реквизитами) Нужны таблицы - получаю их тем же способом что и типовая. Тогда программный интерфейс правильно работает. И нет нужды искать и исправлять ошибки. В общем лень заставляет делать правильно)))
6. maraty 345 09.01.22 12:58 Сейчас в теме
(5) Ну когда писал отдельные расчетные документы, делал тоже так. Но вот когда стоят задачи, вроде полностью автоматизированного расчета множества документов, то тут приходится заниматься таким творчеством :)
7. user1711730 04.03.22 14:03 Сейчас в теме
Пересчитать НДФЛ таким образом можно? В коде вместо МенеджерРасчета.РассчитатьЗарплату(); ставлю МенеджерРасчета.ПересчитатьНДФЛ(); результат неоднозначный. Задача пересчитать НДФЛ только по тем сотрудникам которые есть табличной части документа Начисление зарплаты.
8. maraty 345 04.03.22 14:25 Сейчас в теме
(7) В МенеджерРасчета.Зарплата.Начисления перед вызовом ПересчитатьНДФЛ() перенесли начисления документа?
Правила использования процедупы расчета выполнили?
//Требует обязательного заполнения НастройкиРасчета.Сотрудники или НастройкиРасчета.ФизическиеЛица

Я перечитывал НДФЛ по схеме: Заполняем Зарплата.Начисления, устанавливаем РассчитыватьНДФЛ = Истина, вызываем
РассчитатьЗарплату().
9. user1711730 04.03.22 14:43 Сейчас в теме
Все, кроме перенесения начислений документа сделала. Как начисления документа перенести?
10. user1711730 04.03.22 15:32 Сейчас в теме
Я так понимаю, что заполнение Зарплата.Начисления в этой части кода?

ОтборМенеджераРасчета = МенеджерРасчета.СоздатьОтборы();
ОтборМенеджераРасчета.Подразделение = Подразделение;
МенеджерРасчета.ЗаполнитьНачислениеЗарплаты(СотрудникиДляНачислений, ОтборМенеджераРасчета);

Мне нужно рассчитать НДФЛ по всем начислениям сотрудника, так что я использовала последний пример из статьи. Проблема в том, что я правлю суммы начислений в документе "Начисление зарплаты" и нужно рассчитать с учетом исправлений. Для этого устанавливаю параметр МенеджерРасчета.НастройкиРасчета.СохранятьИсправления = Истина; Однако суммы НДФЛ отличаются от сумм встроенного расчета НДФЛ по кнопке "Пересчитать НДФЛ".
11. maraty 345 04.03.22 16:21 Сейчас в теме
(10) Необходимо вручную перенести данные из табличной части документа Начисления в МенеджерРасчета.Зарплата.Начисления, только не 1:1, а дополнительно заполнив реквизит ТЧ ИдентификаторСтроки = ИдентификаторСтрокиВидаРасчета и возможно заполнить реквизит Сумма из Результат (сходу не помню).
Для Каждой строки установить ФиксСтрока = Истина (есть еще ФиксЗаполнение,ФиксРасчетВремени,ФиксРасчет, но фиксированной строки должно хватить).
Т.е. у нас менеджер расчета получит таблицу начислений с правильными суммами и не будет их пересчитывать, а рассчитает на основании текущих данных НДФЛ.
12. user1711730 15.03.22 09:57 Сейчас в теме
При выборе расчета по одному сотруднику по начислению, если сотрудник период отработал не полностью, выдает ошибку:
При расчете начисления «Ученический договор (прием)» за Февраль 2022 для сотрудника Бадьин Андрей Александрович возникла ошибка: Деление на 0
Формула, используемая при расчете: СуммаПоДоговору * ВремяВЧасах / НормаЧасов

{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(10923)}: ВызватьИсключение ТекстСообщения;
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(10755)}: Строка.Результат = РезультатПоФормуле(ИсходныеДанные, ФормулаДляВыполнения, ФормулаДляПредставления, Строка);
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(10179)}: РассчитатьРезультатНачисленияПоФормуле(
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(10126)}: РассчитатьНачисленияПоФормуле(ОчередностьРасчета.СтрокиОчередности);
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(10070)}: РассчитатьНачисленияОчередности();
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(9965)}: РассчитатьНачисления();
{Обработка.МенеджерРасчетаЗарплаты.МодульОбъекта(652)}: РассчитатьЗарплатуСлужебный();
{ВнешняяОбработка.ПримерИспользованияМенеджераРасчета.Форма.Форма.Форма(173)}: МенеджерРасчета.РассчитатьЗарплату();
{ВнешняяОбработка.ПримерИспользованияМенеджераРасчета.Форма.Форма.Форма(109)}: РасчитатьНачислениеПоСотрудникуНаСервере(Объект.МесяцНачисления, Объект.Организация, Сотрудник, Начисление);
13. maraty 345 15.03.22 13:52 Сейчас в теме
(12) НормаЧасов = 0.
Значит в расчетах есть какой то период, для которого не рассчитан график сотрудника. Если он уволен, попробуйте в таблице менеджера ограничить дату окончания датой увольнения.
15. VID1234 99 09.08.22 13:13 Сейчас в теме
(13)Здравствуйте. Я так понимаю, если скачаю эту обработку, то не смогу понять как без форм создать документ? мне нужно создать документы по подразделениям разовое начисление, с добавлением своего показателя! Или как можно реализовать, чтобы с регистра сведений подтянуть процент в документ разовое начисление. Допустим добавляю строку с сотрудником и у меня кроме подразделения, оклада и премии заполняется и мой показатель, с регистра сведений. а то приходится вручную его заполнять.
14. Matveev_VS 154 05.07.22 16:40 Сейчас в теме
16. Student1C 57 07.12.22 14:44 Сейчас в теме
А как-то можно рассчитать Размер по определенному Начислению? Для записи в РС Плановые начисления.
17. Eeeehhhh 06.03.23 20:49 Сейчас в теме
А как с помощью этой обработки рассчитать к примеру отдельный документ? Ту же премию?
Заранее спасибо за ответ.
Оставьте свое сообщение

См. также

Исправление "Видов доходов НДФЛ" при обновлении БП 3.0, ЗУП 3.1, КА 2.*

Зарплата Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет НДФЛ Абонемент ($m)

В топике https://forum.infostart.ru/forum86/topic274909/ "уже существует вид дохода НДФЛ" описана ошибка при обновлении. У меня было несколько баз разных конфигураций с такой же ошибкой - решил внешними обработками, написал в теме как, но решил упростить жизнь кому-нить, если очень нужно. 14.02.2022 Версия 2.0. Спасибо SotNick (и остальные, кто обратил внимание на этот вариант исправления ошибки) - в этой версии просто вызвал процедуру "Восстановить начальные значения" для справочника "Виды доходов НДФЛ" и потом удалил помеченные ей на удаления элементы. В который раз убедился - всё уже придумали до нас))))

1 стартмани

07.01.2022    23900    536    Alex_E    78    

29

Программное создание и расчет документов начисления зарплаты в конфигурации ЗУП 3.1 и ERP (по подразделениям)

Зарплата Адаптация типовых решений Платформа 1С v8.3 Сложные периодические расчеты 1С:ERP Управление предприятием 2 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Краткое описание типового механизма расчета зарплаты в конфигурации ЗУП 3.1 и ERP и описание разработанной обработки по программному расчету документов зарплаты в разрезе подразделений. Т.к. формирование документов происходит полностью программно, с минимумов параметров, его можно брать за основу для расчета документов по своим условиям, вплоть до создания по расписанию при необходимости.

10 стартмани

27.12.2021    8860    26    maraty    39    

24

Представления в ЗУП

Механизмы типовых конфигураций Платформа 1С v8.3 Сложные периодические расчеты Система компоновки данных 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Использование представлений вместо прямого чтения из регистров сведений в ЗУП.

5 стартмани

12.04.2021    16517    46    Gladkov_Anton    13    

43

Видеокурс-практикум: как подготовить и написать ТЗ, ЗНР, ЧТЗ. Промо

В курсе обобщен опыт работы аналитика на проектах в течение пяти лет, в нескольких фирмах. Подходы к написанию документов унифицированы и по возможности не привязаны к конфигурациям 1С.

3 500 рублей

Личный кабинет сотрудника для 1С: ЗУП (1С + Vue.js + Node.js)

Зарплата WEB-интеграция Кадровый учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

WEB приложение "Личный кабинет сотрудника" + расширение 1С для тех, кто не хочет публиковать 1С в интернет.

1 стартмани

20.05.2020    18810    19    ShiningPhoenix    41    

25

Выгрузка зарплаты из ЗУП 3 в БП 3 по принципу обмена ЗУП 2.5 в БП 3

Обмен между базами 1C Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Выгрузка отражения зарплаты из ЗУП 3 в Бухгалтерию 3 без настройки типового обмена! т.е. по принципу, как было в ЗУП 2.5.

10 стартмани

13.05.2020    11428    110    boobzx    43    

12

Фоновые задания: быстро получить большие данные в 1С

Инструментарий разработчика Механизмы типовых конфигураций Платформа 1С v8.3 Абонемент ($m)

На практическом примере показан один из вариантов применения фоновых заданий в 1С, когда требуется ускорить получение результата. Памятка по алгоритму использования фоновых заданий 1С.

1 стартмани

16.02.2020    11641    4    da_1c    0    

35

Помощник подготовки данных для СЗВ-ТД

Зарплата Обработка документов Документооборот и делопроизводство (СЭД) Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет ФОМС, ЕФС Абонемент ($m)

С 1 января 2020 г. начался переход на электронные трудовые книжки. Работодателям в 2020 г. предстоит выполнить ряд мероприятий для перехода на ЭТК, а также ежемесячно отчитываться в ПФР обо всех кадровых изменениях по форме СЗВ-ТД. В этой публикации размещена обработка, которая поможет быстро подготовить кадровые документы для заполнения СЗВ-ТД в программе 1С ЗУП 3.1, 1С ЗКГУ 3.1.

1 стартмани

23.01.2020    19121    115    Kaval88    62    

29

ЗУП 3.1.10 или когда пропадают элементы в отборах списком

Адаптация типовых решений Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

ЗУП 3.1.10 значительно изменил функционал формы отчетов по сравнению с 3.1.9, 3.1.8 и т.д.. В отчетах в отборах с видом сравнения: В списке, В группе из списка - неприятно, но стали пропадать из списков не отмеченные флажком элементы. Данное расширение решает проблему, не изменяя типовой функционал.

1 стартмани

31.07.2019    19109    7    sapervodichka    6    

28

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

Аванс с проверкой невыходов (Расширение для ЗУП 3.1 и ЗКГУ 3.1)

Обработка документов Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Проверка перед выплатой аванса в документе "Ведомость в банк" и "Ведомость в кассу" по отсутствующим сотрудникам. Тестировал на платформе 1С:Предприятие 8.3 (8.3.15.1489), конфигурации Зарплата и управление персоналом, редакция 3.1 (3.1.10.78) и Зарплата и кадры государственного учреждения, редакция 3.1 (3.1.10.78)

2 стартмани

26.07.2019    15373    55    APTEM_SLV    43    

8

Подсистема справок (ЗУП 3.х)

Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Подсистема справок внешней печатной формой для 1C: Зарплата и Управление Персоналом, редакция 3.х.

1 стартмани

25.04.2019    22765    27    🅵🅾️🆇    17    

33

Расчет Тарификации и зарплаты в средних общеобразовательных школах для ЗКГУ - 3.1 (релиз 3.1.24.408)

Зарплата Бюджетный учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Абонемент ($m)

Данная настройка конфигурации предназначена для расчета Тарификации педработников и расчета зарплаты в средних общеобразовательных учреждениях. Настройка сделана на базе Типовой конфигурации "Зарплата и кадры государственного учреждения" редакции 3.1.

2 стартмани

05.09.2018    50483    69    ivnik    24    

20

Распознавание и загрузка документов в 1С Промо

Универсальная программа-обработка для распознавания любых сканов или фото первичных документов в 1С (счета-фактуры, УПД, ТТН, акты и тд). Точность распознания до 98%.

от 11 рублей

Свертка 1С: ЗУП 3

Свертка базы Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Свертка 1С: Зарплата и управление персоналом 3 по трем регистрам. Когда у всех полетел НДФЛ в начале 2018 года, решили сделать обработку свертки ЗУП 3 с сохранением данных о среднем заработке для расчета пособий. 

5 стартмани

11.07.2018    32157    256    Bortkevich    44    

20

Собственные нумераторы для ЗУП, ЗГУ (расширение)

Обработка документов Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Управленческий учет Абонемент ($m)

Собственные нумераторы для «1С:Зарплата и управление персоналом, ред. 3», «1С:Зарплата и кадры государственного учреждения» (расширение). Любые виды документов, любое количество нумераторов. Сквозная нумерация кадровых приказов и не только.

1 стартмани

19.06.2018    26833    223    tomvlad    38    

23

Автоматическое заполнение графиков в ЗУП 3.1

Зарплата Учет рабочего времени Обработка справочников Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Данная разработка будет актуальна для организаций с большим количеством графиков (несколько десятков/сотен).

1 стартмани

05.05.2018    40119    24    notserioussam    2    

8

Выгрузка проводок из ЗУП 3.1 и загрузка в УПП 1.3

Обмен между базами 1C Зарплата Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Управление производственным предприятием 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Загрузка документов Отражение зарплаты в бухучете и Начисление оценочных обязательств из ЗУП 3.1 в УПП 1.3 с возможностью редактирования данных при загрузке.

1 стартмани

17.04.2018    21496    187    flyDrag    27    

23

1СПАРК РИСКИ. Сервис оценки благонадежности контрагентов. Промо

СПАРК помогает предотвратить мошенничество со стороны компаний и предпринимателей, благодаря актуальным сведениям о компаниях и системе выявления факторов риска.Сервис позволяет управлять налоговыми рисками и комплексно оценивать благонадежность контрагентов.

Синхронизация (выгрузка) данных ЗУП 3.1 - БП 2.0, УПП 1.3

Обмен между базами 1C Зарплата Платформа 1С v8.3 Бухгалтерский учет Сложные периодические расчеты 1С:Бухгалтерия 2.0 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Подобная выгрузка не была предусмотрена разработчиками 1С, поэтому и существует эта публикация. Поддерживается выгрузка оценочных обязательств и резервов отпусков. Непосредственная выгрузка в базу Бухгалтерии. Решение проблем с COM-соединением одной кнопкой.

3 стартмани

22.03.2018    66424    778    diso    227    

63

Готовые переносы данных из различных конфигураций 1C Промо

Рекомендуем готовые решения для переноса данных из различных конфигураций 1C. C техподдержкой от разработчиков и гарантией от Инфостарт.

Рассылка расчетных листков. ЗУП 3.1

Email рассылки Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Рассылка расчетных листков. Простая. С подбором списком и журналом рассылки сообщений.

1 стартмани

02.02.2018    32583    317    bgalin    67    

26

Проверка данных для расчета среднего заработка, перенесенных в ЗУП 3.х из ЗУП 2.5

Обработка документов Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

При переходе с ЗУП 2.5 на ЗУП 3.х часто возникают ошибки в переносе данных для расчета среднего заработка, а именно, неправильно учитывается отработанное количество календарных дней. Для исправления этих ошибок и предназначено данное решение. Применимо для ЗУП 3.х.

3 стартмани

30.01.2018    34817    92    ni_cola    12    

22

Правила переноса документов из ЗУП 2.5 в ЗУП 3.1

Обмен между базами 1C Зарплата Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Абонемент ($m)

Перенос документов из ЗУП 2.5 в ЗУП 3.1 - позволяет снизить объем работ при опытной эксплуатации ЗУП 3.1 параллельно с ЗУП 2.5.

1 стартмани

04.12.2017    46533    517    AntonH851    38    

34

Программы для исполнения 54-ФЗ Промо

С 01.02.2017 контрольно-кассовая техника должна отправлять электронные версии чеков оператору фискальных данных - правила установлены в 54-ФЗ ст.2 п.2. Инфостарт предлагает подборку программ, связанных с применением 54-ФЗ, ККТ и электронных чеков.

Обмен данными между программами "1С: Бухгалтерия предприятия" редакция 2.0 и "1С: Зарплата и управление персоналом" редакция 3.1

Обмен между базами 1C Зарплата Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 2.0 Россия Бухгалтерский учет Абонемент ($m)

В связи с отсутствием типовых правил обмена между конфигурациями БП 2.0 и ЗУП 3.1 (3.0) предлагается действующее решение в виде внешней обработки. Алгоритм построен на прямом подключении из базы БП к базе ЗУП. Для переноса данных используется COM-соединение с обработкой COM-объектов базы источника на стороне базы приемника.. Используется односторонний обмен - данные из ЗУП переносятся в БП.

1 стартмани

17.04.2017    35429    256    ivanovmi    38    

22

Поиск и исправление ошибок при заполнении 6-НДФЛ в ЗУП 2.5, Бухгалтерии 2.0, УПП 1.3 версия от 28.08.2018

Регламентированный учет и отчетность Анализ учета Зарплата Платформа 1С v8.3 Бухгалтерский учет Сложные периодические расчеты 1С:Бухгалтерия 2.0 1С:Зарплата и Управление Персоналом 2.5 1С:Управление производственным предприятием Россия Бухгалтерский учет НДФЛ Абонемент ($m)

Помощь в поиске и исправлении ошибок при заполнении отчёта 6-НДФЛ в ЗУП 2.5, Бухгалтерии 2.0 Просмотр всех записей регистров, имеющих отношение к учёту НДФЛ с детализаций до сотрудника и документа. Ручная корректировка основных регистров. Обновлённая версия от 02.07.2018г

3 стартмани

25.10.2016    51684    237    serge_msk    21    

22

Работа с 1С:Аналитика Промо

Онлайн-курс предусматривает изучение возможностей системы “1С:Аналитика”, которая работает как составная часть платформы “1С:Предприятие” и обеспечивает оперативный просмотр и анализ необходимых данных.

4500 рублей

Перенос данных из ЗУП 2.5 в ЗУП 3.1

Обмен между базами 1C Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 2.5 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Обработка предназначена для переноса некоторых данных из ЗУП 2.5 в ЗУП 3.1 через COM-соединения. Обработка была написана потому, что типовые правила переноса не предоставляют возможности переносить данные по отдельности, а некоторые данные не переносят вовсе. Тестировалась на версии 3.1.14.129 (8.3.15.1830).

2 стартмани

26.05.2016    60518    829    yojeeg    102    

55

Ещё один вариант свертки регистров учета НДФЛ (для ЗБУ/ЗКОУ/ЗКМУ ред. 1, ЗУП ред. 2.5)

Свертка базы Зарплата Платформа 1С v8.3 1С:Зарплата и Управление Персоналом 2.5 1С:Зарплата и кадры бюджетного учреждения Россия Налоговый учет НДФЛ Абонемент ($m)

С появлением формы 6-НДФЛ вопрос правильного ведения исчисленного/удержанного/перечисленного НДФЛ встал не просто остро, а сверхостро! Поможем расчетчикам чем сможем...

1 стартмани

10.03.2016    44404    283    GlebHappy    50    

30

Перечисление НДФЛ в бюджет РФ (13%, 30%)

Обработка документов Зарплата Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 2.5 Бухгалтерский учет Налоговый учет НДФЛ Абонемент ($m)

Внешняя обработка (табличных частей), предназначенная для корректного заполнения документа "Перечисление НДФЛ в бюджет РФ". Конфигурация: Зарплата и Управление Персоналом, редакция 2.5

1 стартмани

27.01.2016    50972    241    1kashak    23    

11