Практическое применение менеджера расчета для расчета зарплаты "на лету" через отчет за произвольное количество месяцев в конфигурации ЗУП 3.1 и ERP

Публикация № 1582815 11.01.22

Бухгалтерский учет - Зарплата

Менеджер расчет зарплата ЗУП УПП ФОТ планирование

Практическое применение менеджера расчета для расчета зарплаты "на лету" через отчет за произвольное количество месяцев в конфигурации ЗУП 3.1 и ERP. Реализовано внешним отчетом, не использует документов. Расчет происходит по организации за выбранный период.

Еще одна статья и пример практического применения менеджера расчета в подсистеме расчета зарплаты конфигураций ЗУП 3.1 и ERP. Ранее уже писал про менеджер расчета в статье Использование менеджера расчета для расчета зарплаты в ЗУП 3.1 и в Программное создание и расчет документов начисления зарплаты в конфигурации ЗУП 3.1 и ERP (по подразделениям). Но чтобы было понятнее, что же это такое, сделал еще один практический пример.

Например у нас гипотетическая задача сделать расчет ФОТ на год вперед, вам нужно посчитать затраты на зарплату на базе существующей системы, сотрудников, позиций штатного расписания и действующих плановых начислений. Для этой задачи не будем плодить сущностей и сделаем простой внешний отчет.

В итоге наш отчет выглядит примерно так:

 

 

"Период" - Произвольный период. При расчете дата начала и дата окончания приводятся к началу и окончанию месяца соответственно.

"Организация" и "подразделение" - ключевые параметры, по которым строим отчет.

"Использовать время за предыдущий период" - параметр отвечающий за время. Например в моей развернутой демобазе графики работы за 2022 год расчитаны и расчет зарплаты за этот период не вызывает проблем. А если сместить период на 2023 год, то графиков нет и в формулах расчета начислений НормаДней, НормаЧасов окажутся равными нулю, что вызовет ошибку расчета.

Данная галка позволяет расчитать время за предыдущий год и подставить фиксированными показателями период, где нет этих данных. В качестве времени выбрано только рабочее, поэтому это достаточно упрощенный пример. В полноценной системе расчета необходимо предусмотреть заполнение таких показателей как праздничные дни, отпуска и еще другие показатели, которые вы используете при расчете зарплаты за текущий период. 

А теперь к реализации.

Реализовано через отчет с простой схемой компоновки данных, использующую внешний набор данных.

 

 

Структура вывода СКД - в таблицу, где в колонках у нас выводится месяц и сумма.

 

 

Программный вывод СКД в отчет, думаю, тоже у вас не должен вызывать проблем

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	НастройкиКД = КомпоновщикНастроек.ПолучитьНастройки();

	ПараметрыРасчета = Новый Структура;
	
	Организация = ОтчетыКлиентСервер.НайтиПараметр(НастройкиКД,, "Организация").Значение;
	Период = ОтчетыКлиентСервер.НайтиПараметр(НастройкиКД,, "Период").Значение;
	ИспользоватьВремяЗаПредыдущийГод = ОтчетыКлиентСервер.НайтиПараметр(НастройкиКД,, "ИспользоватьВремяЗаПредыдущийГод").Значение;
	
	ПараметрПодразделение = ОтчетыКлиентСервер.НайтиПараметр(НастройкиКД,, "Подразделение");
	Если ПараметрПодразделение.Использование Тогда
		ПараметрыРасчета.Вставить("Подразделение", ПараметрПодразделение.Значение);
	КонецЕсли;
	
	ПараметрыРасчета.Вставить("Организация", Организация);
	ПараметрыРасчета.Вставить("Период", Период);
	ПараметрыРасчета.Вставить("ИспользоватьВремяЗаПредыдущийГод", ИспользоватьВремяЗаПредыдущийГод);
	ДанныеФОТ = ДанныеФОТ(ПараметрыРасчета);
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКД, ДанныеРасшифровки);
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, Новый Структура("НаборДанных", ДанныеФОТ), ДанныеРасшифровки, Истина);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
КонецПроцедуры

Создадим таблицу для СКД

	ДанныеФОТ = Новый ТаблицаЗначений;
	ДанныеФОТ.Колонки.Добавить("Сотрудник");	
	ДанныеФОТ.Колонки.Добавить("ДолжностьПоШтатномуРасписанию");	
	ДанныеФОТ.Колонки.Добавить("Подразделение");	
	ДанныеФОТ.Колонки.Добавить("Организация");	
	ДанныеФОТ.Колонки.Добавить("Начисление");	
	ДанныеФОТ.Колонки.Добавить("Период");	
	ДанныеФОТ.Колонки.Добавить("Результат");	

Получим сотрудников организации для расчета

	ПараметрыПолученияСотрудников = КадровыйУчет.ПараметрыПолученияСотрудниковОрганизацийПоСпискуФизическихЛиц();
	ПараметрыПолученияСотрудников.Организация	= ПараметрыРасчета.Организация;
	Если ПараметрыРасчета.Свойство("Подразделение") Тогда
		ПараметрыПолученияСотрудников.Подразделение = ПараметрыРасчета.Подразделение;
	КонецЕсли;
	ПараметрыПолученияСотрудников.НачалоПериода		= ПараметрыРасчета.Период.ДатаНачала;
	ПараметрыПолученияСотрудников.ОкончаниеПериода  = КонецМесяца(ПараметрыРасчета.Период.ДатаОкончания);
	КадровыйУчетРасширенный.ПрименитьОтборПоФункциональнойОпцииВыполнятьРасчетЗарплатыПоПодразделениям(ПараметрыПолученияСотрудников);

	КадровыйУчет.СоздатьВТСотрудникиОрганизации(Запрос.МенеджерВременныхТаблиц, Истина, ПараметрыПолученияСотрудников);

	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Сотрудники.Сотрудник КАК Сотрудник,
		|	Сотрудники.ФизическоеЛицо КАК ФизическоеЛицо
		|ИЗ
		|	ВТСотрудникиОрганизации КАК Сотрудники";
	
	Сотрудники = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Сотрудник");

 

Теперь инициализируем менеджер расчета

МенеджерРасчета = СоздатьМенеджерРасчета(ПараметрыРасчета.Период, ПараметрыРасчета.Организация);

Тут немного подробнее. Классическая инициализация происходит с помощью вызова метода РасчетЗарплатыРасширенный.СоздатьМенеджерРасчета

Но этот вызов инициализирует менеджер только за один месяц, что меня не устраивает. Поэтому напишем свой метод инициализации за период

Функция СоздатьМенеджерРасчета(ПериодРасчета, Организация) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	Если ЗарплатаКадры.ВыполнятьРасчетЗарплатыБезОптимизации() Тогда
		МенеджерРасчета = Обработки.МенеджерРасчетаЗарплатыАрхивный.Создать();
	Иначе
		МенеджерРасчета = Обработки.МенеджерРасчетаЗарплаты.Создать();
	КонецЕсли;	
		
	УстановитьПривилегированныйРежим(Ложь);
	
	МенеджерРасчета.Инициализировать(ПериодРасчета, Организация);
	
	Возврат МенеджерРасчета;
	
КонецФункции

 

Далее все просто. Заполняем настройки менеджера расчета по ранее полученным сотрудникам. С помощью вызова МенеджерРасчета.ЗаполнитьНачислениеЗарплаты заполняем все плановые начисления этих сотрудников

	МенеджерРасчета.НастройкиРасчета.Сотрудники = Сотрудники;
	МенеджерРасчета.НастройкиРасчета.РассчитыватьНачисления = Истина;
	МенеджерРасчета.НастройкиРасчета.ОкончательныйРасчет = Истина;
	МенеджерРасчета.НастройкиРасчета.РассчитыватьНДФЛ = Ложь;

	МенеджерРасчета.НастройкиНДФЛ.Сотрудники = Сотрудники;
	МенеджерРасчета.НастройкиНДФЛ.ОкончательныйРасчет = Истина;
	
	СотрудникиДляНачислений = МенеджерРасчета.ТаблицаСотрудников();
	
	МесяцНачисления = НачалоМесяца(ПараметрыРасчета.Период.ДатаНачала);
	Пока МесяцНачисления < ПараметрыРасчета.Период.ДатаОкончания Цикл
		Для Каждого Сотрудник Из Сотрудники Цикл
			НоваяСтрока = СотрудникиДляНачислений.Добавить();
			НоваяСтрока.Сотрудник = Сотрудник;
			НоваяСтрока.ДатаНачала = МесяцНачисления;
			НоваяСтрока.ДатаОкончания = КонецМесяца(МесяцНачисления);
		КонецЦикла;
		МесяцНачисления = ДобавитьМесяц(МесяцНачисления, 1);
	КонецЦикла;
		
	ОтборМенеджераРасчета = МенеджерРасчета.СоздатьОтборы();
	Если ПараметрыРасчета.Свойство("Подразделение") Тогда
		ОтборМенеджераРасчета.Подразделение = ПараметрыРасчета.Подразделение;
	КонецЕсли;
	
	МенеджерРасчета.ЗаполнитьНачислениеЗарплаты(СотрудникиДляНачислений, ОтборМенеджераРасчета);

И вызываем метод расчета зарплаты

МенеджерРасчета.РассчитатьЗарплату();

Итоговый результат перекладываем в ранее созданную таблицу для СКД

	Для Каждого СтрокаНачисления Из МенеджерРасчета.Зарплата.Начисления Цикл
		НоваяСтрока = ДанныеФОТ.Добавить();
		ЗаполнитьЗначенияСвойств(НоваяСтрока, СтрокаНачисления);
		НоваяСтрока.Период = СтрокаНачисления.ПериодРегистрации;
	КонецЦикла;	

В данном случае в таблице МенеджерРасчета.Зарплата.Начисления у нас все результаты расчета, а так же вспомогательные данные. Т.к. в отчете не использую расшифровок, то показатели у строк начисления нет необходимости сохранять.

 

Как я получаю время за предыдущий период в процедуре ЗаполнитьВремяПоПрошломуПериоду().

Создадим таблицу периодов

	ЗарплатаКадрыОбщиеНаборыДанных.СоздатьВТПериоды(
	    Запрос.МенеджерВременныхТаблиц,
	    НачалоМесяца(ПараметрыРасчета.Период.ДатаНачала),
	    КонецМесяца(ПараметрыРасчета.Период.ДатаОкончания),
	    "МЕСЯЦ",
	    "КонецМесяца",
	    "ВТМесяцы",
	    Истина);          

Получим промежуточную временную таблицу с сотрудниками и периодами за текущий и прошлый период для анализа

|ПОМЕСТИТЬ ВТСотрудники
|ИЗ
|	ВТСотрудникиОрганизации КАК ВТСотрудникиОрганизации
|       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТМесяцы КАК ВТМесяцы
|       ПО (ИСТИНА)		

Время получаем с помощью типового метода

ПараметрыПолученияДанныхОВремени = УчетРабочегоВремениРасширенный.ПараметрыДляСоздатьВТДанныеУчетаРабочегоВремениСотрудников();
УчетРабочегоВремениРасширенный.СоздатьВТДанныеУчетаРабочегоВремениСотрудников(Запрос.МенеджерВременныхТаблиц, Истина, ПараметрыПолученияДанныхОВремени);

А далее просто проверяем, что если для выбранного сотрудника и периода отсутствует время, то вручную устанавливаем показатели времени за предыдущий период с помощью метода МенеджерРасчета.ДобавитьИзвестноеЗначениеПоказателя()

ДанныеУчетаРабочегоВремени = Запрос.Выполнить().Выгрузить();

ДанныеУчетаРабочегоВремени.Индексы.Добавить("Сотрудник, Месяц");

Для Каждого СтрокаНачисления Из МенеджерРасчета.Зарплата.Начисления Цикл
	
	НайденныеСтроки = ДанныеУчетаРабочегоВремени.НайтиСтроки(Новый Структура("Сотрудник, Месяц", СтрокаНачисления.Сотрудник, СтрокаНачисления.ПериодРегистрации));
	Если НайденныеСтроки.Количество() = 0 Тогда
		НайденныеСтроки = ДанныеУчетаРабочегоВремени.НайтиСтроки(
			Новый Структура("Сотрудник, Месяц", СтрокаНачисления.Сотрудник, ДобавитьМесяц(СтрокаНачисления.ПериодРегистрации, -12)));
		Если НайденныеСтроки.Количество() Тогда
			МенеджерРасчета.ДобавитьИзвестноеЗначениеПоказателя(СтрокаНачисления, ПоказательВремяВДнях, НайденныеСтроки[0].Дней);
			МенеджерРасчета.ДобавитьИзвестноеЗначениеПоказателя(СтрокаНачисления, ПоказательНормаДнейПоГрафикуПолногоРабочегоВремени, НайденныеСтроки[0].НормаДней);
		КонецЕсли;
	КонецЕсли;
	
КонецЦикла;

Еще раз повторюсь, что в данном случае это очень упрощенный пример. В реальной системе используются более сложные алгоритмы по получению показателей по статистике за предыдущий период или по другим алгоритмам.

Как всегда уточняю, что все тестировалось в конфигурации Зарплата и управление персоналом КОРП, редакция 3.1 (3.1.20.71) на платформе 1С:Предприятие 8.3 (8.3.20.1613).

 

PS: И наверное просто уже добавлю вне статьи. Коллеги разработчики. Используйте в своих обработках типовые методы подключения внешних обработок. Не нужно изобретать методы как самим инициализировать возвращаемые параметры регистрации обработки. Есть прекрасный метод БСП ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке.

Тут даже документация не нужна, все описание есть в вызываемых методах функций и процедур. Ну и вообще, есть прекрасный документ Система стандартов и методик разработки конфигураций для платформы 1С:Предприятие 8

Скачать файлы

Наименование Файл Версия Размер
Практическое применение менеджера расчета для расчета зарплаты "на лету" через отчет за произвольное количество месяцев в конфигурации ЗУП 3.1 и ERP:

.erf 11,38Kb
3
.erf 11,38Kb 3 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. ubnkfl 14.01.22 11:32 Сейчас в теме
Однозначно плюс! И пропустил прошлые Ваши статьи, к сожалению. Спасибо.
Сам сталкивался с программной работой менеджера для программного расчета зарплаты за месяц без учета отклонений.
Суть задачи - сделать доплату до оклада при наличии болезней. Т.е. надо посчитать правильно зарплату за период, но без учета вытеснений (оклад вытесняется отпуском, отпуск вытесняет окладом и т.п.)
Я скопировал виды расчетов оклад / оклад по часам / РК и СН, очистив у них вытесняющие виды расчетов. И в менеджере расчета меняю вид расчета "Оплата по окладу" на технический "оплата по окладу", который ничего не вытесняет. Т.е. расчет получается 1 в 1 типовыми средствами.
2. Rustig 1407 16.01.22 00:16 Сейчас в теме

В реальной системе используются более сложные алгоритмы по получению показателей по статистике за предыдущий период или по другим алгоритмам.

Что значит статистика за предыдущий период?
3. maraty 215 16.01.22 13:01 Сейчас в теме
(2) Предположим мы считаем плановую зарплату на следующий год (бюджетирование ФОТ в зарплате). Помимо плановых начислений, у нас есть больничные, командировки, отпуска, праздничные дни и просто какие то выплаты по организации, которые сложно запланировать. В этом случае можно собрать статистику начислений за предыдущий период (год) и подставить в качестве фиксированных показателей, а то и просто фиксированных сумм в начисления.
Собрать статистику, имеется в виду собрать данные по начислениям.
4. Rustig 1407 16.01.22 17:32 Сейчас в теме
(3) ясно, спасибо.
а почему в ЗУПе не хранятся подобные сведения?
почему приходится для каждого отчета постоянно пересчитывать суммы?

...я так понял, само СКД тут мало при чем, можно было таблицу ФОТ вытащить в обработку со своей табличной частью "Начисления за период", а еще лучше в регистр сведений и регистр накопления сохранить один раз. И пересчитывать только в открытом периоде при определенных событиях...

Я подобные расчеты для контрагентов храню с 2006 года в самописной базе - и любой отчет очень быстро собирается за любой период по любым алгоритмам и сверкам. Пересчет запрограммировал на определенные события в базе....

В целом идея ЗУПа понятна - сделали программные экспортные функции расчета любого начисления - можно использовать в любых алгоритмах, но только не вяжется с тем, что приходится запрос в цикле использовать - в цикле по каждому периоду. Или я ошибаюсь?
o.nikolaev; +1 Ответить
5. maraty 215 16.01.22 18:34 Сейчас в теме
(4) Ну как сказать про циклы. С одной стороны я вызываю метод МенеджерРасчета.РассчитатьЗарплату() один раз для всех периодов. Но алгоритм менеджера расчета в любом случае будет рассчитывать за каждый месяц отдельно, так уж построена типовая логика

Процедура РассчитатьЗарплатуСлужебный()
...
	Для Каждого МесяцРасчета Из МесяцыРасчета Цикл
...

Так что да, часть типовой логики действительно считает в цикле. Но тут уж специфика конфигурации ЗУП, в первую очередь необходим расчет текущих данных.

А с хранением, уже рассчитанные данные по зп в системе хранятся, это типовой механизм и к этим данным можно обратится типовыми отчетами и их точно не стоит пытаться получить моим отчетом, т.к. он считает данные заново (естественно не трогая существующие), поэтому отчет не покажет ручных корректировок. Да и не у всех организаций есть необходимости считать зарплату на год вперед.
Сама идея отчета в том, чтобы 1) показать работу менеджера расчета. 2) показать принцип расчета за несколько периодов сразу. Практическое применение - построение системы бюджетирования ФОТ. И понятное дело, тут одним отчетом не обойтись.
Если в примере про расчет контрагентов имелись в виду расчеты будущим периодом, то в зуп такое реализовать сложнее, т.к. постоянно меняется кадровый состав, состав начислений, всевозможные отклонения.
6. Rustig 1407 16.01.22 20:29 Сейчас в теме
(5) ясно, спасибо за разъяснения.
Оставьте свое сообщение

См. также

Безопасная работа с транзакциями во встроенном языке Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Разбираемся с опасностями использования транзакций во встроенном языке 1С. Познаем ошибку "В данной транзакции уже происходили ошибки". Учимся защищаться от них.

1 стартмани

25.03.2019    47897    tormozit    59    

Доработка типового отчета на СКД с помощью расширения

Адаптация типовых решений Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Доработка типового отчета на СКД в БП 3.0 с помощью расширения конфигурации. Пример, как можно внести изменения в типовой отчет "Бухгалтерии предприятия" 3.0 без снятия конфигурации с поддержки. Описан пошаговый алгоритм действий и способы решения возникающих при этом проблем.

1 стартмани

09.01.2022    690    Spacer    8    

Пример создания документа с движениями в ERP 2.5.7

БСП (Библиотека стандартных подсистем) Практика программирования v8 ERP2 Россия УУ Абонемент ($m)

Пример создания документа с движениями в ERP 2.5.7, а также включение документа в основные подсистемы, а именно по управлению доступом, датам запрета изменения, контролю остатков, использованию характеристик и серий и прочее.

1 стартмани

10.08.2021    3014    maraty    10    

Работа с абстрактным массивом

Математика и алгоритмы Практика программирования v8 Россия Абонемент ($m)

Абстрактные типы данных и алгоритмы уверенно набирают популярность в языках общего назначения. Встроенный язык 1С является предметно-ориентированным и не спешит развиваться в сторону поддержки абстракций. Однако потребность в них существует, т.к. задачи, решаемые на платформе, не уступают разнообразию из других ЯП. Предлагаю рассмотреть вариант реализации абстрактного массива в 1С.

1 стартмани

07.07.2021    4114    kalyaka    56    

Как выполнить отчет на СКД через COM и получить данные отчета? Промо

Практика программирования v8 УПП1 Россия Абонемент ($m)

Для чего это нужно. Например, нужно в одной базе получить какой-либо показатель из другой базы. Этот показатель вычисляется в каком-либо сложном отчете, который написан на СКД. Можно, конечно, "скопипастить" текст запроса из другой базы, немного подправить его и выполнять в том же COM подключении. Но с этим теряется гибкость: если отчет изменился, то нужно помнить о том, что где-то есть его "немного модифицированная" копия. В статье будет рассмотрен пример получения данных из базы ЗУП.

2 стартмани

08.05.2018    35430    wowik    3    

Семеро одного не ждут? Асинхронное исследование асинхронности

Работа с интерфейсом Практика программирования v8 1cv8.cf Абонемент ($m)

Все уже, наверное, знают о появлении в новых версиях платформы асинхронных функций и конструкций Асинх/Ждать. Многие, возможно, уже их используют. Но что будет, если создать свои асинхронные функции, запустить и не дожидаться окончания их выполнения? Неужели можно запустить несколько процессов параллельно?

1 стартмани

08.06.2021    6107    Alxby    47    

Связи параметров выбора номенклатуры и характеристики в 1С 8.3

Практика программирования v8 v8::УФ 1cv8.cf УТ11 КА2 Россия Абонемент ($m)

Из этой статьи вы узнаете, как, используя системы стандартов и методик разработки 1С, правильно настроить связи параметров выбора номенклатуры и характеристики в новой табличной части.

1 стартмани

22.02.2021    1639    plotnikov1c    2    

Тайны расчета удержания по исполнительным листам. ЗУП 3.1

Зарплата v8::СПР 8.3.14 ЗУП3.x Россия БУ Абонемент ($m)

В ЗУП 3.1 изменился расчет удержания по исполнительным листам. В статье описывается алгоритм расчета удержания по исполнительным листам в случаях, когда база для расчета удержания по исполнительному листу не совпадает с базой для расчета НДФЛ. А также рассматривается расчет удержания по исполнительному листу в случаях, когда удержание действует неполный месяц.

1 стартмани

06.01.2021    13024    user_2010    43    

Как нарисовать граф на 1С Промо

Практика программирования v8 Абонемент ($m)

Описывается реализация на языке запросов 1С метода расположения вершин графа на плоскости, основанного на использовании электромеханической аналогии. При этом вершины графа представляются одноименными электрическими зарядами, дуги - пружинками. Силы взаимодействия вершин в этой системе переводят их из случайного начального в нужное конечное положение. Приведена обработка рисования графов "ГрафОграф", реализующая данный подход, показывающая также динамику процесса. Граф можно задать списком ребер вручную, выбрать из нескольких предопределенных примеров или сформировать по данным информационной базы.

1 стартмани

09.08.2013    73970    ildarovich    117    

Динамическая расшифровка СКД (на примере отчета)

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Предлагаю Вашему неподкупному вниманию вариант более-менее унифицированной реализации динамически формирующейся расшифровки СКД на примере простейшего отчета для конфигурации УТ 11.

1 стартмани

08.12.2020    1774    mr_sav    2    

СКД: все, что вы хотели знать о подмене схемы компоновки данных в отчетах и обработках

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Довольно часто на различных тематических форумах задается вопрос, можно ли использовать в отчете/обработке несколько схем компоновки данных, подменяя одну другой по мере надобности? При этом желательно, чтобы и пользовательские настройки при смене схемы менялись соответственно.

1 стартмани

07.12.2020    5725    user1502278    18    

Cбор и анализ ошибок при помощи Sentry, или как упростить жизнь себе и пользователям

Интеграция с сервисами Практика программирования v8 Абонемент ($m)

Цель данной статьи - сделать процесс сбора и анализа ошибок, происходящих в базе, максимально простым, быстрым и удобным, собирать статистику по ошибкам, местам их возникновения и частоте их появления, а также в деталях разобрать все тонкости по интеграции 1С с Sentry.

1 стартмани

09.10.2020    8522    hexhoc    12    

Простой способ индексирования интервалов Промо

Практика программирования v8 Абонемент ($m)

Предлагается простой способ индексирования интервалов для решения задач выборки записей, включающих заданный момент времени, пересекающихся с заданным интервалом или множеством интервалов. Способ основан на добавлении к исходной таблице особого числового индексированного поля, рассчитываемого по специальной формуле. Приведен код функций, необходимых для расчетов поля поиска и параметров поисковых запросов. Приведены также результаты тестирования метода, доказывающие его высокую эффективность.

1 стартмани

28.09.2016    42426    ildarovich    22    

Программная корректировка при выводе отчета СКД

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Большинство отчетов на СКД, требующих программной корректировки, реализуются с помощью программной настройки СКД или обработки табличного документа уже после вывода отчета. Но во многих случаях более оптимально будет выполнять программную корректировку в процессе вывода отчета. Для этого существуют программные объекты, о которых я расскажу в данной статье.

1 стартмани

08.10.2020    12519    dabu-dabu    16    

Корректировки выплаты в ЗУП 3.1/ЗГУ 3.1 (начиная с версии 3.1.10)

Зарплата v8 v8::СПР ЗКГУ3.0 ЗУП3.x Россия БУ НУ НДФЛ Абонемент ($m)

В этой статье поделюсь своим опытом по работе с корректировками выплаты в ЗУП 3.1 и ЗГУ 3.1: 1. Что такое корректировки выплаты; 2. Как они возникли, в каком состоянии на текущий момент; 3. Как выявить и исправить ошибки. Отчет по проверке работает на ЗУП 3.1, ЗГУ 3.1, начиная с версии 3.1.10.

1 стартмани

24.09.2020    14702    VinnieThePOOH    2    

Загрузка, скачивание, удаление файлов с помощью НачатьПомещениеФайлаНаСервер() и НачатьПолучениеФайлаССервера()

Практика программирования v8 1cv8.cf Абонемент ($m)

В платформе 8.3.15 появились новые методы НачатьПомещениеФайлаНаСервер() и НачатьПолучениеФайлаССервера(). В данной статье рассмотрено готовое решение проверенное и прекрасно работающее на тонком и веб-клиенте.

1 стартмани

25.07.2020    13611    Flashill    15    

Бесплатная проверка контрагентов в ФНС (общий модуль с алгоритмом). На примере выводим статус в список справочника контрагентов Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Если вам интересно проверить контрагенте в ФНС, вам поможет данная публикация. Весь алгоритм работы строится на основе данных, полученных с сервиса http://npchk.nalog.ru совершенно бесплатно.

1 стартмани

01.02.2018    39008    rpgshnik    59    

Методика обновления формы объекта данных при изменении объекта

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

В формах объектов данных часто встречаются элементы, косвенно связанные с объектом. Логику обновления этих элементов при изменении объекта обычно вызывают из обработчиков ПриСозданнииНаСервере и ПриОткрытии, забывая про наличие других способов изменения объекта. В статье предложена методика для обычных и управляемых форм, учитывающая все способы.

1 стартмани

09.03.2020    23550    tormozit    16    

Отправка уведомлений с помощью командной строки, Оповещения с сервера на клиент с помощью командной строки

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Отправка уведомлений с помощью команды командной строки msg. Оповестить пользователей из серверного модуля или регламентного задания, с помощью командной строки msg.

1 стартмани

05.03.2020    8532    user5300    3    

Вывод сообщений в HTML поле средствами 1С

Практика программирования v8 v8::УФ Абонемент ($m)

Пример использования вывода большого количества сообщений в поле HTML. С возможностью открывать ссылочные объекты и создавать новые объекты передавая параметры прямо из HTML поля. Протестировано на релизах 8.3.12 и 8.3.15+

2 стартмани

31.01.2020    13601    burni4    16    

БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному Промо

БСП (Библиотека стандартных подсистем) Практика программирования v8 1cv8.cf Абонемент ($m)

Очень много попадается странных решений, которые можно решить через БСП:Дополнительные отчеты и обработки. Я бы вообще БСП из-за этой подсистемы переименовал в «Большое Спасибо Программистам». Поработаем с подсистемой в части написания регламентных заданий.

1 стартмани

10.05.2018    56569    dsdred    46    

Краткое руководство по внесению изменений в конфигурацию

Практика программирования v8 1cv8.cf Абонемент ($m)

Кратко описаны основополагающие моменты при старте групповой разработки конфигурации несколькими программистами. Полезно для проектной документации как требование к разработчикам или сопровождающей компании.

1 стартмани

13.01.2020    23839    sapervodichka    41    

Универсальные функции: разложение произвольной строки адреса в структуру

Универсальные функции Практика программирования v8 1cv8.cf Абонемент ($m)

Процедуры и функции раскладывают произвольную строку адрес в структуру по ключевым словам.

1 стартмани

30.12.2019    6291    vik070777    12    

"Живые" картинки со Snap.SVG

WEB Работа с интерфейсом Практика программирования v8 Абонемент ($m)

В статье рассмотрен пример использования http-сервисов для визуализации данных

1 стартмани

24.10.2019    15418    blackhole321    7    

Некоторая работа с данными через COM Промо

Практика программирования v8 Абонемент ($m)

В статье приведены примеры работы с Платформой 8.X через COM (точнее, через объект COMConnector). Примеры кода были использованы при реализации прикладных задач в процессе трудовой деятельности.

2 стартмани

05.12.2012    60494    wowik    32    

Полное копирование одной формы в другую

Универсальные обработки Работа с интерфейсом Практика программирования v8 1cv8.cf Абонемент ($m)

Однажды я столкнулся с необходимостью открыть форму ЛЮБОГО документа с определенными изменениями, не зависящими от структуры объекта (например, заблокировать все кнопки). В интернете решения я не нашел. Обычно на форумах на запросы подобного рода отвечают чем-то вроде "покажи первоначальную задачу, а не спрашивай как реализовать то, что ты придумал". Тем не менее, мне стало интересно, как это можно сделать.

1 стартмани

03.10.2019    8657    nekit_rdx    25    

Многопоточная обработка данных на примере перепроведения документов

Обработка документов Практика программирования v8 ERP2 УТ11 КА2 Абонемент ($m)

Дальнейшее развитие темы фоновой обработки данных - проведение документов в потоках. Настройка параметров и запуск основного процесса (менеджера потоков). Разбивка документов для проведения на не связанные друг с другом наборы и запуск дополнительных фоновых заданий для отдельных потоков. Отслеживание выполнения каждого потока в родительском сеансе.

1 стартмани

17.09.2019    13566    ids79    46    

Отображение истории выполнения по всем задачам комплексного процесса в документообороте

Документооборот и делопроизводство Практика программирования v8 ДО УУ Абонемент ($m)

Коллеги, предлагаю вашему вниманию доработку для вывода полной истории в задачах комплексного процесса.

1 стартмани

15.09.2019    9094    pavelpribytkin96    8    

Многопоточность. Универсальный «Менеджер потоков» (фреймворк) с отслеживанием зависимости объектов Промо

Математика и алгоритмы Универсальные функции HighLoad оптимизация Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Восстановление партий, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

26.05.2017    51868    DarkAn    87    

Описание формата внутреннего представления данных 1С в контексте обмена данными

Внешние источники данных Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Фирма 1С не рекомендует использовать внутреннее представление данных для любых целей, которые отличны от обмена с 1С:Предприятием 7.7. Но сама возможность заглянуть на "внутреннюю кухню" платформы с помощью функций ЗначениеВСтрокуВнутр(), ЗначениеВФайл(), ЗначениеИзСтрокиВнутр() и ЗначениеИзФайла(), дала возможность сообществу программистов 1С разработать новые приемы разработки и анализа. Так, именно на использовании внутреннего представления был построен алгоритм "быстрого массива", который позволяет практически мгновенно создать массив в памяти на основании строки с разделителями. С помощью разбора внутреннего представления можно "на лету" программным кодом выполнить анализ обычной формы и даже сделать редактор графической схемы. Во внутреннем формате сохраняют свои данные между сеансами различные популярные внешние обработки. А еще это возможность сделать быстрый обмен с внешними системами.

1 стартмани

06.09.2019    22181    Dementor    31    

Удобный просмотр результата запроса с большим количеством временных таблиц

Практика программирования v8 Абонемент ($m)

Если Вам часто приходится просматривать в отладчике сложные пакетные запросы с большим количеством временных таблиц, то эта статья для Вас.

1 стартмани

27.08.2019    13418    ids79    22    

Запуск фонового задания во внешней обработке. Отключение предупреждений защиты от опасных действий в фоновом задании

Практика программирования v8 1cv8.cf Абонемент ($m)

Как запустить фоновое задание из модуля внешней обработки используя БСП. Как отключить безопасный режим и сообщения защиты от опасных действий независимо от профиля безопасности пользователя в фоновом задании во внешней обработке.

2 стартмани

24.08.2019    18378    BenGunn    26    

Новый запрос и новая таблица значений как функции Промо

Практика программирования v8 Абонемент ($m)

Предлагается две простые функции, использование которых уменьшает объем кода в конфигурациях на платформе «1С:Предприятие 8». Эти функции можно добавлять к своему общему модулю, что сделает процесс программирования более эффективным.

1 стартмани

27.11.2012    46747    ildarovich    49    

Изменяющееся контекстное меню в 1С 8.3

Практика программирования v8 v8::УФ Абонемент ($m)

В одной практической задаче мне пришлось разрабатывать контекстное меню таблицы управляемой формы, которое должно было меняться в зависимости от данных, находящихся в этой таблице. Ниже приведен мой способ решения этой задачи.

1 стартмани

06.08.2019    23803    signum2009    16    

Менеджер потоков: реализация "любой" задачи в потоках

Практика программирования v8 Абонемент ($m)

Менеджер потоков – один их новых инструментов, который упрощает работу разработчиков. Насколько легко с ним, на конференции Infostart Event 2018 Education показал начальник отдела автоматизации 1С Иван Филимонов компании «Трансстроймеханизация».

01.08.2019    11702    DarkAn    7    

Процедура ПриКомпоновкеРезультата

Практика программирования v8 1cv8.cf Абонемент ($m)

Коллекция кода

1 стартмани

26.07.2019    62760    vasilev2015    68    

Уровни, глубина, прародители, циклы и аналоги запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

В продолжение публикации «Транзитивное замыкание запросом» [http://infostart.ru/public/158512/] добавлены другие варианты использования того же приема. Приведены запросы для быстрого определения уровней всех элементов справочника, максимальной глубины справочника, прародителей произвольных элементов справочника, запрос для быстрого определения циклов (на примере справочника спецификаций «1С:Управление производственным предприятием») и определения множеств аналогов номенклатуры (также на примере конфигурации «1С:Управление производственным предприятием»).

1 стартмани

13.11.2012    121760    ildarovich    102    

10 способов получить модуль числа (а может, и больше)

Практика программирования v8 1cv8.cf Абонемент ($m)

Пишем функцию вычисления модуля числа. Сколько способов существует? Давайте посчитаем!

1 стартмани

11.07.2019    16194    sam441    35    

Мониторинг производительности и искусственный интеллект

HighLoad оптимизация Практика программирования Идеи и тренды в разработке v8 Абонемент ($m)

Расскажем и покажем практически, как использовать искусственный интеллект на страже мониторинга производительности. У вас появится возможность создать собственного помощника Ларису, которая возьмет на себя вопросы по контролю и диагностике состояния обслуживаемой системы.

1 стартмани

01.07.2019    10618    ivanov660    28    

"Убер на складе": динамический расчет маршрутов с учетом реальных расстояний

Склад и ТМЦ Склад и ТМЦ Практика программирования v8 УУ Абонемент ($m)

Представляю методику и инструмент для динамического расчета маршрутов отбора на высоконагруженных складах для максимального повышения эффективности склада, ускорения проходимости и, как следствие, экономии денег. Это методика и обработка для интеграции в WMS решения. Тестировалось на 1С 8.3.14.1565.

3 стартмани

24.06.2019    20130    informa1555    17    

Транзитивное замыкание запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

В частности, показывается, как одним пакетным запросом найти ВСЕХ предков (потомков) в иерархическом справочнике. Аналогично можно определять входимость деталей в узлы и готовые изделия по их спецификациям, определять подмножества аналогичных запчастей по цепочке аналогов, решать другие подобные задачи. Приложен файл с примером отчета для замыкания иерархии произвольного справочника, позволяющий протестировать быстродействие запроса в разных условиях.

1 стартмани

29.10.2012    93914    ildarovich    121    

1С:Ассемблер. Немного летнего веселья!

Практика программирования v8 1cv8.cf Абонемент ($m)

Все вы, наверное, слышали, что 1С-ники жалуются на свою систему, считая язык 1С недостаточно низкоуровневым, скучным и т.п. Все они с тоской поглядывают в сторону "настоящих" языков программирования. Так вот, господа, они неправы. В системе 1С есть места, где можно размять программерский мозг и получить удовольствие от низкоуровневой техники. Предлагаю вам погрузиться в недра виртуальной машины 1С и понять, как она работает. Там есть свой "ассемблер" и мы попробуем его в действии!

1 стартмани

21.06.2019    34742    Evil Beaver    150    

Еще раз о рабочих днях. Быстрый способ расчета в запросах

Практика программирования v8 Абонемент ($m)

В статье рассмотрен механизм учета производственных графиков и рабочих дней. Предложен простой и быстрый алгоритм решения типичных задач: добавление рабочих дней к дате и нахождение разницы между датами в рабочих днях. Все вычисления производятся исключительно запросом, т.е. решение пригодно для СКД и динамических списков.

1 стартмани

20.06.2019    15739    Alxby    15    

Простые примеры сложных отчетов на СКД

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Подписи в отчете. Особенности соединения наборов: как соединить несоединяемое. Остатки на дату и обороты по месяцам в одном отчете. Курс валюты на каждую дату без группировок и соединений в запросе. Отчет с произвольными колонками и с произвольной последовательностью. "Неадекватный отчет".

1 стартмани

12.06.2019    38101    Hatson    32    

Выразить строку как число и строку как дату в запросе Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Приведены и прокомментированы запросы, помогающие решать указанные задачи в составе пакетных запросов. Отличием от других известных решений является простая структура, относительная компактность, высокие быстродействие и устойчивость к ошибкам исходных данных. Применяется техника искусственных таблиц, изначально упомянутая в статье "Порождающий запрос" [http://infostart.ru/public/90367/].

1 стартмани

24.01.2013    99600    ildarovich    58    

Графики работы из БСП

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Не очень давно на канале 1С:БСП была опубликована заметка по использованию Графиков работы и Календарных графиков.

1 стартмани

23.05.2019    4422    fenixnow    0    

Создание внешней печатной формы в формате документа Word

Практика программирования v8 1cv8.cf Абонемент ($m)

В статье написано, как создать внешнюю печатную форму (для конфигураций с БСП) в формате Word.

1 стартмани

17.05.2019    26434    ВикторП    23    

Поле адреса в своем справочнике на примере 1С:Бухгалтерия 3

Практика программирования v8 v8::БУ БП3.0 Россия Абонемент ($m)

В публикации описано, как добавить поле адреса в свой справочник, чтобы вводить адрес через адресный классификатор.

1 стартмани

17.05.2019    9067    vasilievil    5    

Эффективная обработка данных в оперативной памяти за счет использования коллекции "соответствие" Промо

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Разработчики, перешедшие с 7-ки на 8-ку по привычке продолжают использовать универсальные коллекции "список значений", "таблица значений" в задачах, которые в 8-ке существенно быстрее решаются с использованием новой коллекции "соответствие". Эта статья для тех, кто еще не оценил всех преимуществ новой структуры данных. Статья позволит создавать Вам максимально быстрые программы. Приведено несколько примеров, в том числе, решение для задач на графах.

1 стартмани

11.12.2010    57149    ildarovich    40    

Пример настройки шаблонов и реализации печати отчетов в документ MS Word используя функциональную часть "Библиотеки Стандартных Подсистем 1С" (БСП)

Практика программирования v8 Россия Абонемент ($m)

В конфигурации выбраны и использованы только необходимые объекты библиотеки стандартных подсистем для реализации вывода отчёта, с табличными частями, в документ MS Word. Показан пример создания необходимых областей в шаблоне для вывода параметров в отчёт.

1 стартмани

23.04.2019    9399    olegpkc    11    

1C + Python + Django Rest Framework + Vue.js. Опыт несложной full-stack разработки

Практика программирования v8 1cv8.cf Абонемент ($m)

В этой статье мы рассмотрим путь и основные моменты создания небольшого вэб-сервиса, который мы называем "Онлайн Прайс-лист". Выгрузка из 1С, бэкенд, фронтенд, получение заказов в 1С.

1 стартмани

22.04.2019    42865    riposte    69    

Вывод вариантов СКД в таблицы на управляемой форме

Работа с интерфейсом Практика программирования v8 v8::УФ v8::СКД 1cv8.cf Абонемент ($m)

Задача стояла такая: есть 2 различных запроса, результаты которых выгружаются на форму обработки в таблицы значений (далее ТЗ) и программно "соприкасаются" между собой определенным образом (как именно- в рамках данной статьи неважно). Нюанс в том, что запросы должны иметь свой компоновщик настроек и могут интерактивно на форме изменяться пользователем. На оригинальность публикации не претендую - изначально в рамках поставленной задачи пытался найти что-то подобное (уже готовый шаблон) на инфостарте, возможно "плохо искал" ;)

05.04.2019    13575    artkor    1    

[EnterpriseData] Антисвертка характеристик номенклатуры при выгрузке в Бухгалтерию

Практика программирования v8 v8::ПВХ КД УНФ БП3.0 Россия БУ Абонемент ($m)

Рассмотрена выгрузка каждой пары значений Номенклатура - Характерстика из УНФ 1.6 в отдельную номенклатуру в Бухгалтерию 3.0 путём доработки правил обмена в формате EnterpriseData.

1 стартмани

27.03.2019    6107    nforce    6