Согласование цен по заказу

//доработка+
Процедура НаСогласованиеПриИзменении(Элемент)
    Если НаСогласование Тогда
        ДокументСписок.Отбор.НаСогласование.Установить(Истина);
    Иначе
        ДокументСписок.Отбор.НаСогласование.Использование = Ложь;
    КонецЕсли;
КонецПроцедуры

//доработка+
Процедура ОбновлениеОтображения()

    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
    |   ЗаказПокупателя.Ссылка
    |ИЗ
    |   Документ.ЗаказПокупателя КАК ЗаказПокупателя
    |ГДЕ
    |   ЗаказПокупателя.НаСогласование = ИСТИНА
    |   И ЗаказПокупателя.ПометкаУдаления = ЛОЖЬ";

    Результат = Запрос.Выполнить();
    Выборка = Результат.Выбрать();
    ЭлементыФормы.НаСогласование.Заголовок = "На согласование" + ?(Выборка.Количество() = 0, "", " " + Выборка.Количество() + " док.");

КонецПроцедуры
 

Процедура ТоварыПриИзмененииФлажка(Элемент, Колонка)

    Если Колонка <> Элемент.Колонки.Согласовано Тогда
        Возврат;
    КонецЕсли;

    ТекДанные = Элемент.ТекущиеДанные;
    Если ТекДанные.Согласовано Тогда
        ТекДанные.ОтветственныйЗаСогласование = глЗначениеПеременной("глТекущийПользователь");
        ТекДанные.ДатаСогласования = ТекущаяДата();
        МодульДоработок.РассчитатьСуммуТабЧасти(ТекДанные, ЭтотОбъект);
    Иначе
        ТекДанные.ОтветственныйЗаСогласование = Неопределено;
        ТекДанные.ДатаСогласования = Неопределено;
        ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(ТекДанные, ЭтотОбъект);
    КонецЕсли;

    ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(ТекДанные, ЭтотОбъект);

КонецПроцедуры

Процедура ТоварыПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)
    ...

    //после согласования редактировать строку может только руководитель, который согласовал новую цену
    Если ДанныеСтроки.Согласовано И ДанныеСтроки.ОтветственныйЗаСогласование <> глЗначениеПеременной("глТекущийПользователь") Тогда

        ОформлениеСтроки.Ячейки.Номенклатура.ТолькоПросмотр     = Истина;
        ОформлениеСтроки.Ячейки.Количество.ТолькоПросмотр       = Истина;
        ОформлениеСтроки.Ячейки.Цена.ТолькоПросмотр             = Истина;
        ОформлениеСтроки.Ячейки.Сумма.ТолькоПросмотр            = Истина;
        ОформлениеСтроки.Ячейки.ЦенаНовая.ТолькоПросмотр        = Истина;
        ОформлениеСтроки.Ячейки.НаСогласование.ТолькоПросмотр   = Истина;
        ОформлениеСтроки.Ячейки.Согласовано.ТолькоПросмотр      = Истина;
        ОформлениеСтроки.Ячейки.СуммаНДС.ТолькоПросмотр         = Истина;
        ОформлениеСтроки.Ячейки.СтавкаНДС.ТолькоПросмотр        = Истина;
        ОформлениеСтроки.Ячейки.ПроцентСкидкиНаценки.ТолькоПросмотр = Истина;
        ОформлениеСтроки.Ячейки.Единица.ТолькоПросмотр          = Истина;

    Иначе

        ОформлениеСтроки.Ячейки.Номенклатура.ТолькоПросмотр     = Ложь;
        ОформлениеСтроки.Ячейки.Количество.ТолькоПросмотр       = Ложь;
        ОформлениеСтроки.Ячейки.Цена.ТолькоПросмотр             = Ложь;
        ОформлениеСтроки.Ячейки.Сумма.ТолькоПросмотр            = Ложь;
        ОформлениеСтроки.Ячейки.ЦенаНовая.ТолькоПросмотр        = Ложь;
        ОформлениеСтроки.Ячейки.НаСогласование.ТолькоПросмотр   = Ложь;
        ОформлениеСтроки.Ячейки.Согласовано.ТолькоПросмотр      = Ложь;
        ОформлениеСтроки.Ячейки.СуммаНДС.ТолькоПросмотр         = Ложь;
        ОформлениеСтроки.Ячейки.СтавкаНДС.ТолькоПросмотр        = Ложь;
        ОформлениеСтроки.Ячейки.ПроцентСкидкиНаценки.ТолькоПросмотр = Ложь;
        ОформлениеСтроки.Ячейки.Единица.ТолькоПросмотр          = Ложь;

    КонецЕсли;

КонецПроцедуры // ТоварыПриВыводеСтроки()

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)

    ...

    //доработка+
    НаСогласование = Ложь;
    Для Каждого Стр Из Товары Цикл

        Если Стр.НаСогласование И НЕ Стр.Согласовано Тогда
            НаСогласование = Истина;
            Прервать;
        КонецЕсли;

    КонецЦикла;

    //доработка+
    Для Каждого Стр Из Товары Цикл

        Если Стр.НаСогласование И Стр.ЦенаНовая = 0 Тогда
            Сообщить("Строка " + Стр.НомерСтроки + " - не задана цена на согласование!");
            Отказ = Истина;
            Возврат;
        КонецЕсли;

    КонецЦикла;

    //доработка+
    Для Каждого Стр Из Товары Цикл

        Если НЕ Стр.НаСогласование Тогда //все нормально
            Продолжить;
        КонецЕсли;

        ПараметрыОтбора = Новый Структура;
        ПараметрыОтбора.Вставить("Номенклатура", Стр.Номенклатура);
        НайденныеСтроки = Товары.НайтиСтроки(ПараметрыОтбора);
        Если НайденныеСтроки.Количество() = 1 Тогда //все нормально
            Продолжить;
        КонецЕсли;

        ЦеныРазные = Ложь;
        Для Каждого НайденнаяСтр Из НайденныеСтроки Цикл

            Если НайденнаяСтр.НомерСтроки = Стр.НомерСтроки Тогда
                Продолжить;
            КонецЕсли;

            Если НайденнаяСтр.ЦенаНовая<>Стр.ЦенаНовая
                ИЛИ НайденнаяСтр.Цена<>Стр.Цена
                ИЛИ НайденнаяСтр.НаСогласование<>Стр.НаСогласование
                ИЛИ НайденнаяСтр.Согласовано<>Стр.Согласовано Тогда
                ЦеныРазные = Истина;
                Прервать;
            КонецЕсли;

        КонецЦикла;

        ТекстСообщения = "Нельзя записывать заказ с разными ценами,"
        + Символы.ПС + " с разными ценами на согласование,"
        + Символы.ПС + " с разными отметками ""На согласование"" и ""Согласовано"" по одной номенклатуре!";
        ТекстСообщения = ТекстСообщения + Символы.ПС + Стр.Номенклатура + Символы.ПС + "строки " + Стр.НомерСтроки + " и " + НайденнаяСтр.НомерСтроки;

        Если ЦеныРазные Тогда
            Сообщить(ТекстСообщения);
            Отказ = Истина;
            Возврат;
        КонецЕсли;

    КонецЦикла;

    //доработка+
    ДатаМинимум = Дата(2100,1,1);
    НомерСтроки = 0;
    Для Каждого Стр Из Товары Цикл

        Если ЗначениеЗаполнено(Стр.ДатаСогласования) И Стр.Согласовано И Стр.ДатаСогласования<ДатаМинимум Тогда
            ДатаМинимум = Стр.ДатаСогласования;
            НомерСтроки = Стр.НомерСтроки;
        КонецЕсли;

    КонецЦикла;

    Если НомерСтроки<>0 И ДатаМинимум<>Дата(2100,1,1) И (НачалоДня(Дата) - ДатаМинимум)/3600/24 > 7 Тогда
        Отказ = Истина;
        Сообщить("Прошло более 7-и календарных дней - надо пересогласовать цену по строке " + НомерСтроки);
    КонецЕсли;

КонецПроцедуры // ПередЗаписью()
 

Функция ПодготовитьТаблицуТоваров(РезультатЗапросаПоТоварам, СтруктураШапкиДокумента)

    ...

    //доработка+
    Для Каждого Стр Из ТаблицаТоваров Цикл
        Если Стр.Согласовано Тогда
            Стр.Цена = Стр.ЦенаНовая;
        КонецЕсли;
    КонецЦикла;

    Возврат ТаблицаТоваров;

КонецФункции // ПодготовитьТаблицуТоваров()

 Процедура ПроверитьДопустимостьЦенОтпуска(ДокументОбъект, ИмяТабличнойЧасти, Отказ) Экспорт

    //доработка+
    Если (ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.СчетНаОплатуПокупателю")
        ИЛИ ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.ЗаказПокупателя")
        ИЛИ ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.РеализацияТоваровУслуг"))
        И ИмяТабличнойЧасти = "Товары" Тогда

        МодульДоработок.ПроверитьДопустимостьЦенОтпуска(ДокументОбъект, ИмяТабличнойЧасти, Отказ);
        Возврат;
    КонецЕсли;

    //остальной код типовой без изменений:
    ...

КонецПроцедуры

 Процедура ПроверитьДопустимостьЦенОтпуска(ДокументОбъект, ИмяТабличнойЧасти, Отказ) Экспорт

    Запрос = Новый Запрос;

    МетаданныеДокумента = ДокументОбъект.Метаданные();

    ИмяДокумента = МетаданныеДокумента.Имя;
    ЕстьХарактеристикаНоменклатуры = ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("ХарактеристикаНоменклатуры", МетаданныеДокумента, ИмяТабличнойЧасти);

    ДополнительныеПоля         = "";
    ЛевоеСоединение            = "";
    ПоляДляОбъединенияЗапросов = "";

    СписокФильтров = УправлениеПользователями.ПолучитьЗначениеПраваДляТекущегоПользователя(ПланыВидовХарактеристик.ПраваПользователей.НеОтпускатьТоварСЦенойНижеОпределенногоТипа, Неопределено);
    НомерТипаЦен = 0;
    Для Каждого ТипЦены Из СписокФильтров Цикл
        Если НЕ ЗначениеЗаполнено(ТипЦены.Значение) Тогда

            // Если хотя бы для одного набора прав не задан тип цен, ниже которого нельзя продавать,
            // то значит можно продавать по любой цене.
            Возврат;
        КонецЕсли;

        НомерТипаЦен = НомерТипаЦен + 1;

        Запрос.УстановитьПараметр("ДатаСреза", ДокументОбъект.Ссылка.Дата);
        Запрос.УстановитьПараметр("ЦенаВключаетНДС" + НомерТипаЦен, ТипЦены.Значение.ЦенаВключаетНДС);

        Если ТипЦены.Значение.Рассчитывается Тогда
            Запрос.УстановитьПараметр("ТипЦен" + НомерТипаЦен, ТипЦены.Значение.БазовыйТипЦен);
            Запрос.УстановитьПараметр("ТипЦенДинамический" + НомерТипаЦен, ТипЦены.Значение);
            Запрос.УстановитьПараметр("Коэффициент" + НомерТипаЦен, ТипЦены.Значение.ПроцентСкидкиНаценки);
        Иначе
            Запрос.УстановитьПараметр("ТипЦен" + НомерТипаЦен, ТипЦены.Значение);
            Запрос.УстановитьПараметр("Коэффициент" + НомерТипаЦен, 0);
        КонецЕсли;

        ЛевоеСоединение = ЛевоеСоединение + "
        |   ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, ТипЦен = &ТипЦен" + НомерТипаЦен + " И (Номенклатура" + ?(ЕстьХарактеристикаНоменклатуры, ", ХарактеристикаНоменклатуры", "") + ") В (ВЫБРАТЬ РАЗЛИЧНЫЕ Док.Номенклатура " + ?(ЕстьХарактеристикаНоменклатуры, ", Док.ХарактеристикаНоменклатуры", "")+ " ИЗ Документ." + ИмяДокумента + "."+ИмяТабличнойЧасти+" КАК Док ГДЕ Док.Ссылка = &ДокументСсылка)) КАК ЦеныКомпании" + НомерТипаЦен + "
        |   ПО ЦеныКомпании" + НомерТипаЦен + ".Номенклатура = Док.Номенклатура";
        Если ЕстьХарактеристикаНоменклатуры Тогда
            Запрос.УстановитьПараметр("ПустаяХарактеристикаНоменклатуры" , Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка());
            ЛевоеСоединение = ЛевоеСоединение + "
            |   И
            |   ЦеныКомпании" + НомерТипаЦен + ".ХарактеристикаНоменклатуры = Док.ХарактеристикаНоменклатуры
            |
            |   ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, ТипЦен = &ТипЦен" + НомерТипаЦен + " И (Номенклатура, ХарактеристикаНоменклатуры) В (ВЫБРАТЬ РАЗЛИЧНЫЕ Док.Номенклатура , ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) КАК ХарактеристикаНоменклатуры ИЗ Документ." + ИмяДокумента + "."+ИмяТабличнойЧасти+" КАК Док ГДЕ Док.Ссылка = &ДокументСсылка)) КАК ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + "
            |   ПО ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".Номенклатура = Док.Номенклатура
            |   И
            |   ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".ХарактеристикаНоменклатуры = &ПустаяХарактеристикаНоменклатуры
            |";

            ДополнительныеПоля = ДополнительныеПоля + "," + "
            |   &ЦенаВключаетНДС" + НомерТипаЦен +" КАК ЦенаВключаетНДС" + НомерТипаЦен +",
            |   &Коэффициент" + НомерТипаЦен +" КАК ПроцентСкидкиНаценкиИзСправочника" + НомерТипаЦен +",
            |   ВЫБОР КОГДА ЦеныКомпании" + НомерТипаЦен + ".Цена ЕСТЬ NULL ТОГДА
            |       ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".Цена
            |   ИНАЧЕ ЦеныКомпании" + НомерТипаЦен + ".Цена КОНЕЦ  КАК Цена" + НомерТипаЦен;
            Если ТипЦены.Значение.Рассчитывается Тогда
                ДополнительныеПоля = ДополнительныеПоля + "," + "
                |   ВЫБОР КОГДА ЦеныКомпании" + НомерТипаЦен + ".Цена ЕСТЬ NULL ТОГДА
                |       ВложенныйЗапросБезХарактеристики" + НомерТипаЦен +".ПроцентСкидкиНаценкиБезХарактеристики
                |   ИНАЧЕ ВложенныйЗапрос" + НомерТипаЦен +".ПроцентСкидкиНаценки КОНЕЦ  КАК ПроцентСкидкиНаценки" + НомерТипаЦен;
            КонецЕсли;
            ДополнительныеПоля = ДополнительныеПоля + "," + "
            |   ВЫБОР КОГДА ЦеныКомпании" + НомерТипаЦен + ".Цена ЕСТЬ NULL ТОГДА
            |       ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".Валюта
            |   ИНАЧЕ ЦеныКомпании" + НомерТипаЦен + ".Валюта КОНЕЦ КАК Цена" + НомерТипаЦен + "Валюта,
            |   ВЫБОР КОГДА ЦеныКомпании" + НомерТипаЦен + ".Цена ЕСТЬ NULL ТОГДА
            |       ЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".ЕдиницаИзмерения
            |   ИНАЧЕ ЦеныКомпании" + НомерТипаЦен + ".ЕдиницаИзмерения КОНЕЦ КАК Цена" + НомерТипаЦен + "Единица
            |";

        Иначе
            ДополнительныеПоля = ДополнительныеПоля + "," + "
            |   &ЦенаВключаетНДС" + НомерТипаЦен +" КАК ЦенаВключаетНДС" + НомерТипаЦен;

            Если ТипЦены.Значение.Рассчитывается Тогда
                ДополнительныеПоля = ДополнительныеПоля + "," + "
                |   ЦеныКомпании" + НомерТипаЦен + ".Цена * (1 + ВложенныйЗапрос" + НомерТипаЦен +".ПроцентСкидкиНаценки / 100) КАК Цена"   + НомерТипаЦен + ",
                |   ЦеныКомпании" + НомерТипаЦен + ".Валюта КАК Цена" + НомерТипаЦен + "Валюта,
                |   ЦеныКомпании" + НомерТипаЦен + ".ЕдиницаИзмерения КАК Цена" + НомерТипаЦен + "Единица";
            Иначе
                ДополнительныеПоля = ДополнительныеПоля + "," + "
                |   ЦеныКомпании" + НомерТипаЦен + ".Цена КАК Цена"   + НомерТипаЦен + ",
                |   ЦеныКомпании" + НомерТипаЦен + ".Валюта КАК Цена" + НомерТипаЦен + "Валюта,
                |   ЦеныКомпании" + НомерТипаЦен + ".ЕдиницаИзмерения КАК Цена" + НомерТипаЦен + "Единица";
            КонецЕсли;

        КонецЕсли;
        Если ТипЦены.Значение.Рассчитывается Тогда
            ЛевоеСоединение = ЛевоеСоединение + "
            |   ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            |       ДинамическиеЦеныКомпании" + НомерТипаЦен + ".ПроцентСкидкиНаценки КАК ПроцентСкидкиНаценки,
            |       ДинамическиеЦеныКомпании" + НомерТипаЦен + ".Номенклатура КАК Номенклатура";
            Если ЕстьХарактеристикаНоменклатуры Тогда
                ЛевоеСоединение = ЛевоеСоединение + ",
                |       ДинамическиеЦеныКомпании" + НомерТипаЦен + ".ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры";
            КонецЕсли;
            ЛевоеСоединение = ЛевоеСоединение + "
            |       ИЗ
            |       РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, ТипЦен = &ТипЦенДинамический" + НомерТипаЦен + " И (Номенклатура" + ?(ЕстьХарактеристикаНоменклатуры, ", ХарактеристикаНоменклатуры", "") + ") В (ВЫБРАТЬ РАЗЛИЧНЫЕ Док.Номенклатура " + ?(ЕстьХарактеристикаНоменклатуры, ", Док.ХарактеристикаНоменклатуры", "")+ " ИЗ Документ." + ИмяДокумента + "."+ИмяТабличнойЧасти+" КАК Док ГДЕ Док.Ссылка = &ДокументСсылка)
            |       ) КАК ДинамическиеЦеныКомпании" + НомерТипаЦен;

            ЛевоеСоединение = ЛевоеСоединение + "
            |   )КАК ВложенныйЗапрос" + НомерТипаЦен +"
            |   ПО ЦеныКомпании" + НомерТипаЦен + ".Номенклатура = ВложенныйЗапрос" + НомерТипаЦен +".Номенклатура";
            Если ЕстьХарактеристикаНоменклатуры Тогда
                ЛевоеСоединение = ЛевоеСоединение + "
                |   И ЦеныКомпании" + НомерТипаЦен + ".ХарактеристикаНоменклатуры = ВложенныйЗапрос" + НомерТипаЦен +".ХарактеристикаНоменклатуры";
            КонецЕсли;
            Если ЕстьХарактеристикаНоменклатуры Тогда
                ЛевоеСоединение = ЛевоеСоединение + "
                |   ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
                |       ДинамическиеЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".Номенклатура КАК Номенклатура,
                |       ДинамическиеЦеныКомпанииБезХарактеристики" + НомерТипаЦен + ".ПроцентСкидкиНаценки
                |       КАК ПроцентСкидкиНаценкиБезХарактеристики
                |       ИЗ
                |       РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, ТипЦен = &ТипЦенДинамический" + НомерТипаЦен + " И (Номенклатура, ХарактеристикаНоменклатуры) В (ВЫБРАТЬ РАЗЛИЧНЫЕ Док.Номенклатура , ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) КАК ХарактеристикаНоменклатуры ИЗ Документ." + ИмяДокумента + "."+ИмяТабличнойЧасти+" КАК Док ГДЕ Док.Ссылка = &ДокументСсылка)
                |       ) КАК ДинамическиеЦеныКомпанииБезХарактеристики" + НомерТипаЦен;

                ЛевоеСоединение = ЛевоеСоединение + "
                |   )КАК ВложенныйЗапросБезХарактеристики" + НомерТипаЦен +"
                |   ПО ЦеныКомпании" + НомерТипаЦен + ".Номенклатура = ВложенныйЗапрос" + НомерТипаЦен +".Номенклатура";
            КонецЕсли;
        КонецЕсли;

    КонецЦикла;

    ВалютаРегламентированногоУчета = глЗначениеПеременной("ВалютаРегламентированногоУчета");
    Запрос.УстановитьПараметр("ВалютаРеглУчета", ВалютаРегламентированногоУчета);
    Запрос.Текст = "
    |ВЫБРАТЬ
    |   Док.Номенклатура,
    |   "+?(ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("ЕдиницаИзмерения", МетаданныеДокумента, ИмяТабличнойЧасти),"Док.ЕдиницаИзмерения", "Док.Номенклатура.ЕдиницаХраненияОстатков")+" КАК ЕдиницаИзмерения,
    |   "+?(ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("СтавкаНДС", МетаданныеДокумента, ИмяТабличнойЧасти),"Док.СтавкаНДС,", "")+"
    |   ВЫБОР КОГДА Количество = 0 ТОГДА Док.Цена ИНАЧЕ Док.Сумма/Док.Количество КОНЕЦ КАК Цена,
    |   "+?(ОбщегоНазначения.ЕстьРеквизитДокумента("ВалютаДокумента", МетаданныеДокумента),"Док.Ссылка.ВалютаДокумента", "&ВалютаРеглУчета")
    +" КАК ВалютаДокумента,
    |   Док.НомерСтроки
    |" + ДополнительныеПоля + "
    |
    |ИЗ
    |   Документ." + ИмяДокумента + "."+ИмяТабличнойЧасти+" КАК Док
    |" + ЛевоеСоединение + "
    |ГДЕ
    |   Док.Ссылка = &ДокументСсылка
    |";

    // Установим параметры запроса.
    Запрос.УстановитьПараметр("ДокументСсылка" , ДокументОбъект.Ссылка);

    РезультатЗапроса = Запрос.Выполнить();

    ПроверилиНаличиеЦенВЗапросе = Ложь;

    СоответствиеКурсыВалют = Новый Соответствие;

    ТабличнаяЧастьТовары = Неопределено;
    Контрагент = Неопределено;
    Если ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.СчетНаОплатуПокупателю")
        ИЛИ ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.ЗаказПокупателя") Тогда

        ТабличнаяЧастьТовары = ДокументОбъект.Товары;
        Контрагент = ДокументОбъект.Контрагент;

    ИначеЕсли ЗначениеЗаполнено(ДокументОбъект.Сделка) Тогда //РеализацияТоваровУслуг, ДокументОбъект.Сделка - это Заказ

        ТабличнаяЧастьТовары = ДокументОбъект.Сделка.Товары;
        Контрагент = ДокументОбъект.Сделка.Контрагент;

    КонецЕсли;

    КатегорияЦенКонтрагента = Неопределено;
    Если ЗначениеЗаполнено(Контрагент) И ТипЗнч(Контрагент) = Тип("СправочникСсылка.Контрагенты") Тогда
        КатегорияЦенКонтрагента = Контрагент.КатегорияЦен;
    КонецЕсли;

    ТЗ = РезультатЗапроса.Выгрузить();
    ТЗ.Колонки.Добавить("НовыйМинимумЦены"); //при согласовании руководителем
    ТЗ.ЗаполнитьЗначения(0, "НовыйМинимумЦены");
    ТЗ.Колонки.Добавить("ЦенаКонтрагента");  //цена контрагента, если задана
    ТЗ.ЗаполнитьЗначения(1000000, "ЦенаКонтрагента");

    Если ТабличнаяЧастьТовары<>Неопределено Тогда

        //определим по документу-основанию согласованные цены
        Для Каждого Стр Из ТабличнаяЧастьТовары Цикл

            //при согласовании руководителем
            Если ЗначениеЗаполнено(Стр.ОтветственныйЗаСогласование) И Стр.Согласовано Тогда

                мНовыйМинимумЦены = МодульДоработок.ПолучитьНовыйМинимумЦены(Стр.ОтветственныйЗаСогласование, ДокументОбъект.Дата, Стр.Номенклатура);

                ПараметрыОтбора = Новый Структура("Номенклатура");
                ПараметрыОтбора.Вставить("Номенклатура", Стр.Номенклатура);
                НайденныеСтрокиТЗ = ТЗ.НайтиСтроки(ПараметрыОтбора);
                Для Каждого СтрТЗ Из НайденныеСтрокиТЗ Цикл
                    СтрТЗ.НовыйМинимумЦены = мНовыйМинимумЦены;
                КонецЦикла;

            КонецЕсли;

            //цена контрагента, если задана
            Если ЗначениеЗаполнено(КатегорияЦенКонтрагента) Тогда

                ОтборЦен = Новый Структура("ТипЦен, Номенклатура");
                //Прайсовые цены - Справочники.ТипыЦенНоменклатуры.НайтиПоКоду("УТ0000004")
                //подразумевается, что базовый тип цен для цен контрагента - прайсовые цены
                ОтборЦен.Вставить("ТипЦен", КатегорияЦенКонтрагента.БазовыйТипЦен);
                ОтборЦен.Вставить("Номенклатура", Стр.Номенклатура);
                ПрайсоваяЦена = РегистрыСведений.ЦеныНоменклатуры.ПолучитьПоследнее(ДокументОбъект.Дата, ОтборЦен).Цена;
                //или так:
                //Если ПрайсоваяЦена = 0 Тогда
                //  ЦенаКонтрагента = 0;
                //КонецЕсли;

                //или так:
                Если ПрайсоваяЦена = 0 Тогда
                    //ничего не проверяем
                    Продолжить;
                КонецЕсли;

                //округление по арифмет. правилам
                ЦенаКонтрагента = Окр(ПрайсоваяЦена * (1 + КатегорияЦенКонтрагента.ПроцентСкидкиНаценки / 100), 2);
                Если ЦенаКонтрагента>0 Тогда
                    ПараметрыОтбора = Новый Структура("Номенклатура");
                    ПараметрыОтбора.Вставить("Номенклатура", Стр.Номенклатура);
                    НайденныеСтрокиТЗ = ТЗ.НайтиСтроки(ПараметрыОтбора);
                    Для Каждого СтрТЗ Из НайденныеСтрокиТЗ Цикл
                        СтрТЗ.ЦенаКонтрагента = ЦенаКонтрагента;
                    КонецЦикла;
                КонецЕсли;

            КонецЕсли;

        КонецЦикла;

    КонецЕсли;

    //Выборка = РезультатЗапроса.Выбрать();
    //Пока Выборка.Следующий() Цикл
    Для Каждого Выборка Из ТЗ Цикл

        Если НЕ ПроверилиНаличиеЦенВЗапросе Тогда
            Если РезультатЗапроса.Колонки.Найти("Цена") <> Неопределено Тогда

                ПроверилиНаличиеЦенВЗапросе = Истина;

            Иначе

                Возврат;

            КонецЕсли;
        КонецЕсли;

        НомерТипаЦен = 1;

        ЦенаТовара   = ?(НЕ ЗначениеЗаполнено(Выборка.Цена), 0, Окр(Выборка.Цена,2));
        ВалютаТовара = Выборка.ВалютаДокумента;

        Если СоответствиеКурсыВалют[ВалютаТовара] = Неопределено Тогда
            СтруктураКурсаЦеныТовара             = МодульВалютногоУчета.ПолучитьКурсВалюты(ВалютаТовара, ДокументОбъект.Дата);
            КурсЦеныТовара                       = СтруктураКурсаЦеныТовара.Курс;
            КратностьЦеныТовара                  = СтруктураКурсаЦеныТовара.Кратность;
            СоответствиеКурсыВалют[ВалютаТовара] = СтруктураКурсаЦеныТовара;
        Иначе
            СтруктураКурсаЦеныТовара = СоответствиеКурсыВалют[ВалютаТовара];
            КурсЦеныТовара           = СтруктураКурсаЦеныТовара.Курс;
            КратностьЦеныТовара      = СтруктураКурсаЦеныТовара.Кратность;
        КонецЕсли;

        МинимальнаяЦена = 0;

        Пока НомерТипаЦен <> 0 Цикл

            Если РезультатЗапроса.Колонки.Найти("Цена" + НомерТипаЦен) <> Неопределено
                И РезультатЗапроса.Колонки.Найти("Цена" + НомерТипаЦен + "Валюта") <> Неопределено
                И РезультатЗапроса.Колонки.Найти("Цена" + НомерТипаЦен + "Единица") <> Неопределено Тогда

                ЦенаПроверки    = Выборка["Цена" + НомерТипаЦен];
                ВалютаПроверки  = Выборка["Цена" + НомерТипаЦен + "Валюта"];
                ЕдиницаПроверки = Выборка["Цена" + НомерТипаЦен + "Единица"];
                ЦенаВключаетНДС = Выборка["ЦенаВключаетНДС" + НомерТипаЦен];

                // Считаем, что если не задана цена или валюта цены
                // (нет цены данного типа для данной номенклатуры), то
                // проверка прошла
                Если НЕ ЗначениеЗаполнено(ВалютаПроверки)
                    Или НЕ ЗначениеЗаполнено(ЦенаПроверки) Тогда
                    МинимальнаяЦена = 0;
                    Прервать;
                КонецЕсли;

                Если РезультатЗапроса.Колонки.Найти("ПроцентСкидкиНаценки" + НомерТипаЦен) <> Неопределено Тогда
                    ПроцентСкидкиНаценки = Выборка["ПроцентСкидкиНаценки" + НомерТипаЦен];
                КонецЕсли;
                Если НЕ ЗначениеЗаполнено(ПроцентСкидкиНаценки)
                    И РезультатЗапроса.Колонки.Найти("ПроцентСкидкиНаценкиИзСправочника" + НомерТипаЦен) <> Неопределено Тогда
                    ПроцентСкидкиНаценки = Выборка["ПроцентСкидкиНаценкиИзСправочника" + НомерТипаЦен];
                КонецЕсли;
                Если НЕ ЗначениеЗаполнено(ПроцентСкидкиНаценки) Тогда
                    ПроцентСкидкиНаценки = 0;
                КонецЕсли;

                ЦенаПроверки = Окр(ЦенаПроверки * (1 + ПроцентСкидкиНаценки / 100), 2);

                Если СоответствиеКурсыВалют[ВалютаПроверки] = Неопределено Тогда
                    СтруктураКурсаЦеныПроверки             = МодульВалютногоУчета.ПолучитьКурсВалюты(ВалютаПроверки, ДокументОбъект.Дата);
                    КурсЦеныПроверки                       = СтруктураКурсаЦеныПроверки.Курс;
                    КратностьЦеныПроверки                  = СтруктураКурсаЦеныПроверки.Кратность;
                    СоответствиеКурсыВалют[ВалютаПроверки] = СтруктураКурсаЦеныПроверки;
                Иначе
                    СтруктураКурсаЦеныПроверки = СоответствиеКурсыВалют[ВалютаПроверки];
                    КурсЦеныПроверки           = СтруктураКурсаЦеныПроверки.Курс;
                    КратностьЦеныПроверки      = СтруктураКурсаЦеныПроверки.Кратность;
                КонецЕсли;

                ЦенаПроверки = Ценообразование.ПересчитатьЦенуПриИзмененииЕдиницы(ЦенаПроверки, ЕдиницаПроверки, Выборка.ЕдиницаИзмерения);

                ПересчитаннаяЦенаПроверки = МодульВалютногоУчета.ПересчитатьИзВалютыВВалюту(ЦенаПроверки,
                ВалютаПроверки,        ВалютаТовара,
                КурсЦеныПроверки,      КурсЦеныТовара,
                КратностьЦеныПроверки, КратностьЦеныТовара);

                ПересчитаннаяЦенаПроверки = Ценообразование.ПересчитатьЦенуПриИзмененииФлаговНалогов(ПересчитаннаяЦенаПроверки,
                Перечисления.СпособыЗаполненияЦен.ПоЦенамНоменклатуры,
                // ДокументОбъект.ТипЦен.ЦенаВключаетНДС,
                ЦенаВключаетНДС,
                ОбщегоНазначения.ЕстьРеквизитДокумента("УчитыватьНДС",МетаданныеДокумента)
                И ДокументОбъект.УчитыватьНДС,
                ОбщегоНазначения.ЕстьРеквизитДокумента("СуммаВключаетНДС",МетаданныеДокумента)
                И ДокументОбъект.СуммаВключаетНДС,
                ?(ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("СтавкаНДС",МетаданныеДокумента, ИмяТабличнойЧасти),
                УчетНДС.ПолучитьСтавкуНДС(Выборка.СтавкаНДС),0));

                ПересчитаннаяЦенаПроверки = Окр(ПересчитаннаяЦенаПроверки, 2);

                МинимальнаяЦена = ?(НомерТипаЦен = 1, ПересчитаннаяЦенаПроверки, Мин(МинимальнаяЦена, ПересчитаннаяЦенаПроверки));

                Если МинимальнаяЦена = 0 Тогда
                    НомерТипаЦен = 0;
                Иначе
                    НомерТипаЦен = НомерТипаЦен + 1;
                КонецЕсли;

            Иначе

                НомерТипаЦен = 0;

            КонецЕсли;

        КонецЦикла;

        МинимальнаяЦенаМенеджера    = МинимальнаяЦена; //или по категории или 0, если не задана
        МинимальнаяЦенаРуководителя = Выборка.НовыйМинимумЦены; //или по категории или 0, если не задана
        МинимальнаяЦенаКонтрагента  = Выборка.ЦенаКонтрагента; //или по категории или 1000000, если не задана

        МинимальноВозможнаяЦена = Мин( Мин(МинимальнаяЦенаМенеджера, МинимальнаяЦенаРуководителя), МинимальнаяЦенаКонтрагента);

        Если ЦенаТовара < МинимальноВозможнаяЦена Тогда
            ТекстСообщения = "Строка "      + Выборка.НомерСтроки + ": "
            + "Для товара " + Выборка.Номенклатура
            + Символы.ПС + "    цена за единицу ниже порогового значения (цена: "
            + Формат(ЦенаТовара, "ЧДЦ=2; ЧН=0") + " " + ВалютаТовара
            + ", минимально возможное значение должно быть: "
            + Формат(МинимальноВозможнаяЦена, "ЧДЦ=2; ЧН=0") + " " + ВалютаТовара
            + ")";
            ОбщегоНазначения.СообщитьОбОшибке(ТекстСообщения, Отказ);
        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

 Процедура РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ДокументОбъект, СпособРасчета = Неопределено) Экспорт

    ИмяТабличнойЧасти = ОбщегоНазначения.ПолучитьИмяТабличнойЧастиПоСсылкеНаСтроку(СтрокаТабличнойЧасти);

    МетаданныеДокумента = ДокументОбъект.Метаданные();

    Сумма = СтрокаТабличнойЧасти.ЦенаНовая * СтрокаТабличнойЧасти.Количество;
    СуммаСкидки = 0;

    Если (СпособРасчета = Неопределено)
     Или (СпособРасчета = Перечисления.СпособРасчетаСуммыДокумента.СУчетомВсехСкидок)
     Или (СпособРасчета = Перечисления.СпособРасчетаСуммыДокумента.БезУчетаРучнойСкидки) Тогда
        Если ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("ПроцентАвтоматическихСкидок", МетаданныеДокумента,
                                             ИмяТабличнойЧасти) Тогда
            СуммаСкидки = Сумма * СтрокаТабличнойЧасти.ПроцентАвтоматическихСкидок / 100;
        КонецЕсли;

        Если (СпособРасчета <> Перечисления.СпособРасчетаСуммыДокумента.БезУчетаРучнойСкидки)Тогда
            Если ОбщегоНазначения.ЕстьРеквизитТабЧастиДокумента("ПроцентСкидкиНаценки", МетаданныеДокумента, ИмяТабличнойЧасти) Тогда
                СуммаСкидки = СуммаСкидки + (Сумма * СтрокаТабличнойЧасти.ПроцентСкидкиНаценки / 100);
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;

    СтрокаТабличнойЧасти.Сумма = Сумма - СуммаСкидки;

КонецПроцедуры // РассчитатьСуммуТабЧасти()

Функция ПолучитьНовыйМинимумЦены(Пользователь, Дата, Номенклатура) Экспорт

    //1. получим категорию цен пользователя
    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
    |   ЗначенияДополнительныхПравПользователя.Значение
    |ИЗ
    |   РегистрСведений.ЗначенияДополнительныхПравПользователя КАК ЗначенияДополнительныхПравПользователя
    |ГДЕ
    |   ЗначенияДополнительныхПравПользователя.Пользователь = &Пользователь
    |   И ЗначенияДополнительныхПравПользователя.Право = &Право";

    Запрос.УстановитьПараметр("Пользователь", Пользователь);
    Запрос.УстановитьПараметр("Право", ПланыВидовХарактеристик.ПраваПользователей.НеОтпускатьТоварСЦенойНижеОпределенногоТипа);

    Результат = Запрос.Выполнить();
    Если Результат.Пустой() Тогда
        Возврат 0;
    КонецЕсли;

    Выборка = Результат.Выбрать();

    ТипЦен = Неопределено;
    Если Выборка.Следующий() Тогда
        ТипЦен = Выборка.Значение;
    КонецЕсли;

    //2. определим базовый тип цен, процент скидки и новый минимум цен
    НовыйМинимумЦены = 0;
    Если ЗначениеЗаполнено(ТипЦен) Тогда

        Если НЕ ТипЦен.Рассчитывается Тогда
            Сообщить("Обратитесь к программисту (укажите документ) - обнаружена ситуация, которая не обрабатывается алгоритмом");
            Возврат 0;
        КонецЕсли;

        Запрос = Новый Запрос;
        Запрос.Текст = "ВЫБРАТЬ
        |   ЦеныНоменклатурыСрезПоследних.Цена
        |ИЗ
        |   РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
        |           &Период,
        |           ТипЦен = &ТипЦен
        |               И Номенклатура = &Номенклатура) КАК ЦеныНоменклатурыСрезПоследних";

        Запрос.УстановитьПараметр("Период", Дата);
        Запрос.УстановитьПараметр("ТипЦен", ТипЦен.БазовыйТипЦен);
        Запрос.УстановитьПараметр("Номенклатура", Номенклатура);

        Результат = Запрос.Выполнить();
        Выборка = Результат.Выбрать();

        //округление по арифмет. правилам
        Если Выборка.Следующий() Тогда
            НовыйМинимумЦены = Окр(Выборка.Цена * (1 + ТипЦен.ПроцентСкидкиНаценки / 100), 2);
        КонецЕсли;

    КонецЕсли;

    Возврат НовыйМинимумЦены;

КонецФункции

 

//Выборка = РезультатЗапроса.Выбрать();

ТЗ = РезультатЗапроса.Выгрузить();
ТЗ.Колонки.Добавить("НовыйМинимумЦены"); //при согласовании руководителем
ТЗ.ЗаполнитьЗначения(0, "НовыйМинимумЦены");
ТЗ.Колонки.Добавить("ЦенаКонтрагента");  //цена контрагента, если задана
ТЗ.ЗаполнитьЗначения(1000000, "ЦенаКонтрагента");

Если ТабличнаяЧастьТовары<>Неопределено Тогда

    //определим по документу-основанию согласованные цены
    Для Каждого Стр Из ТабличнаяЧастьТовары Цикл

        //при согласовании руководителем
        Если ЗначениеЗаполнено(Стр.ОтветственныйЗаСогласование) И Стр.Согласовано Тогда

            мНовыйМинимумЦены = МодульДоработок.ПолучитьНовыйМинимумЦены(Стр.ОтветственныйЗаСогласование, ДокументОбъект.Дата, Стр.Номенклатура);

            ПараметрыОтбора = Новый Структура("Номенклатура");
            ПараметрыОтбора.Вставить("Номенклатура", Стр.Номенклатура);
            НайденныеСтрокиТЗ = ТЗ.НайтиСтроки(ПараметрыОтбора);
            Для Каждого СтрТЗ Из НайденныеСтрокиТЗ Цикл
                СтрТЗ.НовыйМинимумЦены = мНовыйМинимумЦены;
            КонецЦикла;

        КонецЕсли;

        //цена контрагента, если задана
        Если ЗначениеЗаполнено(КатегорияЦенКонтрагента) Тогда

            ОтборЦен = Новый Структура("ТипЦен, Номенклатура");
            //Прайсовые цены - Справочники.ТипыЦенНоменклатуры.НайтиПоКоду("УТ0000004")
            //подразумевается, что базовый тип цен для цен контрагента - прайсовые цены
            ОтборЦен.Вставить("ТипЦен", КатегорияЦенКонтрагента.БазовыйТипЦен);
            ОтборЦен.Вставить("Номенклатура", Стр.Номенклатура);
            ПрайсоваяЦена = РегистрыСведений.ЦеныНоменклатуры.ПолучитьПоследнее(ДокументОбъект.Дата, ОтборЦен).Цена;
            //или так:
            //Если ПрайсоваяЦена = 0 Тогда
            //  ЦенаКонтрагента = 0;
            //КонецЕсли;

            //или так:
            Если ПрайсоваяЦена = 0 Тогда
                //ничего не проверяем
                Продолжить;
            КонецЕсли;

            //округление по арифмет. правилам
            ЦенаКонтрагента = Окр(ПрайсоваяЦена * (1 + КатегорияЦенКонтрагента.ПроцентСкидкиНаценки / 100), 2);
            Если ЦенаКонтрагента>0 Тогда
                ПараметрыОтбора = Новый Структура("Номенклатура");
                ПараметрыОтбора.Вставить("Номенклатура", Стр.Номенклатура);
                НайденныеСтрокиТЗ = ТЗ.НайтиСтроки(ПараметрыОтбора);
                Для Каждого СтрТЗ Из НайденныеСтрокиТЗ Цикл
                    СтрТЗ.ЦенаКонтрагента = ЦенаКонтрагента;
                КонецЦикла;
            КонецЕсли;

        КонецЕсли;

    КонецЦикла;

КонецЕсли;

//Пока Выборка.Следующий() Цикл
Для Каждого Выборка Из ТЗ Цикл
    ...

    МинимальнаяЦенаМенеджера    = МинимальнаяЦена; //или по категории или 0, если не задана
    МинимальнаяЦенаРуководителя = Выборка.НовыйМинимумЦены; //или по категории или 0, если не задана
    МинимальнаяЦенаКонтрагента  = Выборка.ЦенаКонтрагента; //или по категории или 1000000, если не задана

    МинимальноВозможнаяЦена = Мин( Мин(МинимальнаяЦенаМенеджера, МинимальнаяЦенаРуководителя),      МинимальнаяЦенаКонтрагента);

    Если ЦенаТовара < МинимальноВозможнаяЦена Тогда
        ТекстСообщения = "Строка "      + Выборка.НомерСтроки + ": "
        + "Для товара " + Выборка.Номенклатура
        + Символы.ПС + "    цена за единицу ниже порогового значения (цена: "
        + Формат(ЦенаТовара, "ЧДЦ=2; ЧН=0") + " " + ВалютаТовара
        + ", минимально возможное значение должно быть: "
        + Формат(МинимальноВозможнаяЦена, "ЧДЦ=2; ЧН=0") + " " + ВалютаТовара
        + ")";
        ОбщегоНазначения.СообщитьОбОшибке(ТекстСообщения, Отказ);
    КонецЕсли;

КонецЦикла;