Всё началось с вопроса-задачи: необходимо сформировать отчет, в котором будет отражаться номенклатура (по выбранному складу и в указанной группе номенклатуры), которая есть на остатках (на указанную дату), но по которой не было никаких движений (по регистру накопления Продажи за указанный период). Кроме того, для такой номенклатуры необходимо вывести информацию по последнему поступлению (в указанный период поступления): количество и цену поступления, дату поступления и поставщика, а также цену реализации (указывается вид цены). Все пункты задания были выполнены – был разработан внешний отчет на СКД, в основу которого вошёл следующий пакет запросов:
ВЫБРАТЬ
Продажи.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ ВТ_Продажи
ИЗ
РегистрНакопления.Продажи КАК Продажи
ГДЕ
Продажи.Период МЕЖДУ &ДатаНачала И &ДатаОкончания
{ГДЕ
(Продажи.Регистратор.СтруктурнаяЕдиница = &СтруктурнаяЕдиница),
(Продажи.Номенклатура.Родитель В ИЕРАРХИИ (&Группа))}
ИНДЕКСИРОВАТЬ ПО
Номенклатура
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Номенклатура.Ссылка КАК Ссылка
ПОМЕСТИТЬ ВТ_Номен
ИЗ
Справочник.Номенклатура КАК Номенклатура
{ГДЕ
(Номенклатура.Родитель В ИЕРАРХИИ (&Группа))}
ИНДЕКСИРОВАТЬ ПО
Ссылка
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТ_Номен.Ссылка КАК Ссылка
ПОМЕСТИТЬ ВТ_непрод
ИЗ
ВТ_Номен КАК ВТ_Номен
ГДЕ
НЕ ВТ_Номен.Ссылка В
(ВЫБРАТЬ
ВТ_Продажи.Номенклатура
ИЗ
ВТ_Продажи)
СГРУППИРОВАТЬ ПО
ВТ_Номен.Ссылка
ИНДЕКСИРОВАТЬ ПО
Ссылка
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ЗапасыНаСкладахОстатки.Номенклатура КАК Номенклатура,
СУММА(ЗапасыНаСкладахОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ ВТ_Остатки
ИЗ
РегистрНакопления.ЗапасыНаСкладах.Остатки(
&ДатаОстатков,
Номенклатура В
(ВЫБРАТЬ
ВТ_непрод.Ссылка
ИЗ
ВТ_непрод)) КАК ЗапасыНаСкладахОстатки
ГДЕ
ЗапасыНаСкладахОстатки.КоличествоОстаток > 0
{ГДЕ
(ЗапасыНаСкладахОстатки.СтруктурнаяЕдиница = &СтруктурнаяЕдиница)}
СГРУППИРОВАТЬ ПО
ЗапасыНаСкладахОстатки.Номенклатура
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТ_непрод.Ссылка КАК Номенклатура,
СУММА(ЕСТЬNULL(ВТ_Остатки.КоличествоОстаток, 0)) КАК КоличествоОстаток
ПОМЕСТИТЬ ВТ_НоменклатураИсточник
ИЗ
ВТ_непрод КАК ВТ_непрод
ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
ПО ВТ_непрод.Ссылка = ВТ_Остатки.Номенклатура.Ссылка
ГДЕ
ВТ_Остатки.КоличествоОстаток > 0
СГРУППИРОВАТЬ ПО
ВТ_непрод.Ссылка
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
МАКСИМУМ(ПриходнаяНакладнаяЗапасы.Ссылка.Дата) КАК Дата,
ПриходнаяНакладнаяЗапасы.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ ВТ_ПоследниеПоступления
ИЗ
Документ.ПриходнаяНакладная.Запасы КАК ПриходнаяНакладнаяЗапасы
ГДЕ
ПриходнаяНакладнаяЗапасы.Ссылка.Проведен = ИСТИНА
И ПриходнаяНакладнаяЗапасы.Ссылка.Дата МЕЖДУ &ДатаНачалаПоступления И &ДатаОкончанияПоступления
И ПриходнаяНакладнаяЗапасы.Номенклатура В
(ВЫБРАТЬ
ВТ_НоменклатураИсточник.Номенклатура КАК Номенклатура
ИЗ
ВТ_НоменклатураИсточник)
И ПриходнаяНакладнаяЗапасы.Ссылка.ВидОперации = ЗНАЧЕНИЕ(Перечисление.ВидыОперацийПриходнаяНакладная.ПоступлениеОтПоставщика)
СГРУППИРОВАТЬ ПО
ПриходнаяНакладнаяЗапасы.Номенклатура
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ПриходнаяНакладнаяЗапасы.Номенклатура КАК Номенклатура,
ПриходнаяНакладнаяЗапасы.Цена КАК Цена,
ПриходнаяНакладнаяЗапасы.Количество КАК Количество,
ПриходнаяНакладнаяЗапасы.Ссылка.Контрагент КАК Контрагент,
ВТ_ПоследниеПоступления.Дата КАК Дата
ПОМЕСТИТЬ ВТ_НоменклатураПоступления
ИЗ
ВТ_ПоследниеПоступления КАК ВТ_ПоследниеПоступления
ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПриходнаяНакладная.Запасы КАК ПриходнаяНакладнаяЗапасы
ПО ВТ_ПоследниеПоступления.Дата = ПриходнаяНакладнаяЗапасы.Ссылка.Дата
И ВТ_ПоследниеПоступления.Номенклатура = ПриходнаяНакладнаяЗапасы.Номенклатура
ГДЕ
ПриходнаяНакладнаяЗапасы.Ссылка.Проведен = ИСТИНА
И ПриходнаяНакладнаяЗапасы.Ссылка.Дата МЕЖДУ &ДатаНачалаПоступления И &ДатаОкончанияПоступления
И ПриходнаяНакладнаяЗапасы.Номенклатура В
(ВЫБРАТЬ
ВТ_НоменклатураИсточник.Номенклатура КАК Номенклатура
ИЗ
ВТ_НоменклатураИсточник)
И ПриходнаяНакладнаяЗапасы.Ссылка.ВидОперации = ЗНАЧЕНИЕ(Перечисление.ВидыОперацийПриходнаяНакладная.ПоступлениеОтПоставщика)
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ЦеныНоменклатурыСрезПоследних.Номенклатура КАК Номенклатура,
ЦеныНоменклатурыСрезПоследних.Цена КАК ЦенаПродажи
ПОМЕСТИТЬ ВТ_ЦеныПродажи
ИЗ
РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
&ДатаОстатков,
ВидЦен = &ВидЦен
И Номенклатура В
(ВЫБРАТЬ
ВТ_НоменклатураИсточник.Номенклатура КАК Номенклатура
ИЗ
ВТ_НоменклатураИсточник)) КАК ЦеныНоменклатурыСрезПоследних
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТ_Остатки.Номенклатура КАК Номенклатура,
ВТ_Остатки.КоличествоОстаток КАК КоличествоОстаток,
ВТ_НоменклатураПоступления.Количество КАК Количество,
ВТ_НоменклатураПоступления.Цена КАК Цена,
ВТ_НоменклатураПоступления.Контрагент КАК Контрагент,
ВТ_ЦеныПродажи.ЦенаПродажи КАК ЦенаПродажи,
ВТ_НоменклатураПоступления.Дата КАК Дата
ИЗ
ВТ_Остатки КАК ВТ_Остатки
ЛЕВОЕ СОЕДИНЕНИЕ ВТ_НоменклатураПоступления КАК ВТ_НоменклатураПоступления
ПО ВТ_Остатки.Номенклатура = ВТ_НоменклатураПоступления.Номенклатура
ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ЦеныПродажи КАК ВТ_ЦеныПродажи
ПО ВТ_Остатки.Номенклатура = ВТ_ЦеныПродажи.Номенклатура
Данный пакет запросов можно взять в качестве набора данных и построить на нём свой собственный отчет. Если нет времени на самостоятельную разработку, то можно воспользоваться уже готовым решением, скачав внешний отчет.
Пример. В рассматриваемом случае анализируется период движения товаров за 2020 г. по выбранной группе номенклатуры «Вентиляция» и выбранной структурной единице «Маш 8». Среди номенклатуры, попавший в итоговый результат, есть «Воздуховод плоский прямоугольный 620ВП (60х204, L=0,5м) ПВХ», который есть на остатках в количестве 2 на дату формирования отчета (29.04.2021) и по которому в течение анализируемого периода (2020 г.) не было движений по регистру «Продажи». Данная номенклатура за анализируемый период поступлений (2018-2019 гг.) в последний раз поступала в организацию 11.07.2019 в количестве 2, по цене 137.40 от поставщика «СтройИнвестСибирь ООО (вентиляция)». Данный товар имеет продажную цену 180 руб. (для указанного вида цен «Розничная цена»).
Разработка и тестирование осуществлялись на конфигурации «1С:Управление нашей фирмой 1.6» (1.6.24.136) и платформе 1С:Предприятие 8.3 (8.3.18.1289).
