Рассылка отчетов по запросу через телеграмм бот

 Задача доработки: в функции РассылкаОтчетов.ВыполнитьДоставку(ПараметрыЖурнала,...) перехватить полное имя файла отчета и вернуть в утилиту, и удобнее это сделать через параметр ПараметрыЖурнала.

&Вместо("ВыполнитьДоставку")
Функция хх_ВыполнитьДоставку(ПараметрыЖурнала, ПараметрыДоставки, Вложения)
	Если ПараметрыДоставки.ИспользоватьСетевойКаталог и Вложения.Количество()>0 Тогда 
		ПараметрыЖурнала.Вставить("ФайлОтчета",ПараметрыДоставки.СетевойКаталогWindows+Вложения[0].Ключ);
	КонецЕсли;
	Результат = ПродолжитьВызов(ПараметрыЖурнала, ПараметрыДоставки, Вложения);
	Возврат Результат;
КонецФункции

Выкладываю расширение - которое проверенно на УТ11.4, КА2.5, УНФ3.0, ЗУП3.0, РОЗН3.0, РОЗН2.1. (В БУХ3.0 немного по другому, но тоже работает). На других конфигурациях не проверял. Расширение выбирайте под режим совместимости 8.3.17 или 8.3.21. При загрузке может потребоваться смена языка.

назначение скрипта - вывод списка отчетов и передача готовых

выберите №отчета (0-список)
ЗаписьЖурналаРегистрации("tlg.cmd",УровеньЖурналаРегистрации.Информация,,,"Прилетело "+command+" ("+ПараметрыКоманды+") от "+username);
ТГЛсимв1 = РаскодироватьСтроку("%F0%9F%91%80",СпособКодированияСтроки.КодировкаURL);
ТГЛсимв2 = РаскодироватьСтроку("%F0%9F%91%89",СпособКодированияСтроки.КодировкаURL);
ТГЛсимв3 = РаскодироватьСтроку("%F0%9F%93%8E",СпособКодированияСтроки.КодировкаURL);
Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	АВТОНОМЕРЗАПИСИ() КАК код,
	|	РассылкиОтчетов.Ссылка КАК Отчет
	|ПОМЕСТИТЬ втОтчеты
	|ИЗ	Справочник.РассылкиОтчетов КАК РассылкиОтчетов
	|ГДЕ	РассылкиОтчетов.ИспользоватьСетевойКаталог;
	|ВЫБРАТЬ	втОтчеты.код,	втОтчеты.Отчет
	|ИЗ	втОтчеты КАК втОтчеты";
тзЗапроса = Запрос.Выполнить().Выгрузить();
СписокОтчетов = "";
Для каждого стрТЗ из тзЗапроса Цикл
	СписокОтчетов = СписокОтчетов + СтрШаблон("%1 • %2",стрТЗ.код,стрТЗ.Отчет) + Символы.ПС;
КонецЦикла;
МассивПараметров = Новый Массив();
Подстроки = СтрЗаменить(ПараметрыКоманды, ",", Символы.ПС);
Для Сч = 1 По СтрЧислоСтрок(Подстроки) Цикл
	Параметр = СокрЛП(СтрПолучитьСтроку(Подстроки, Сч));
	Если ЗначениеЗаполнено(Параметр) Тогда
		МассивПараметров.Добавить(Параметр);
	КонецЕсли;
КонецЦикла;
Если МассивПараметров.Количество() < 1 Тогда
	ДиалогСПараметрами = Истина;
	Заголовки = Новый Соответствие();
	Заголовки[0] = ТГЛсимв2+" введите № отчета: (0-список)"+Символы.ПС+СписокОтчетов;
	Результат = Заголовки[0];
Иначе
	Если МассивПараметров[0] = "0" Тогда
		Результат = СписокОтчетов+Символы.ПС+ТГЛсимв2+" выберите отчет:";
	Иначе
		Попытка
			выбОтчет = тзЗапроса[Число(МассивПараметров[0])-1];
			ПараметрыЖурнала = Новый Структура("ФайлОтчета,МассивОшибок",,Новый Массив);
			рез = РассылкаОтчетов.ВыполнитьРассылкуОтчетов(выбОтчет.Отчет,ПараметрыЖурнала);
			Если рез и ПараметрыЖурнала.Свойство("ФайлОтчета") Тогда
				ЗаписьЖурналаРегистрации("tlg.to",УровеньЖурналаРегистрации.Информация,,,"выслан "+ПараметрыЖурнала.ФайлОтчета+" > "+username);
				Результат_Файл = ПараметрыЖурнала.ФайлОтчета;
				Результат = ТГЛсимв3+" "+СокрЛП(выбОтчет.Отчет)+" #ot4";	//+" от "+Строка(CurrentSessionDate())
			Иначе
				Результат = ТГЛсимв1+" ошибка выбора "+МассивПараметров[0];
			КонецЕсли;
		Исключение
			Результат = ТГЛсимв1+" неверный отчет/номер "+ПараметрыКоманды;
		КонецПопытки;
	КонецЕсли;
КонецЕсли;

• сетевой ресурс должен быть доступен в Telemonitor
• у пользователя 1С обеспечить права и убрать "защиту от опасных действий"
• работает только под WINDOWS
• используется COM-соединение, требуется регистрация библиотеки comcntr.dll рабочей версии платформы 1С

• отправляет только первый файл отчета (ограничение инструмента), но можно включить архивирование, хотя это не удобно
• webhook не поддерживается
• интерфейс упрощенный, диалоги через replay
• после рассылки в сетевой папке остается мусор - его надо периодически очищать
• установка утилиты Telemonitor - в описании
• подключение расширения - в поиск
• настройка телеграмм-бота - в соответствующих источниках