Процедура ПриКомпоновкеРезультата

 В процедуре это удобнее и нагляднее, чем в полях "Значение" и "Выражение" на закладке Параметры.

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
ЗначениеРасчета = "Заменить текст вычислением значения";	
КомпоновкаДанныхКлиентСервер.УстановитьПараметр(КомпоновщикНастроек, "СложныйАлгоритмРасчета", ЗначениеРасчета);

//альтернативный вариант, если нет модуля КомпоновкаДанныхКлиентСервер
//ПараметрРасчета = Новый ПараметрКомпоновкиДанных("СложныйАлгоритмРасчета");
//ЗначениеРасчета = "Заменить текст вычислением значения";	
//КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра(ПараметрРасчета, ЗначениеРасчета);
	
КонецПроцедуры

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

ТаблицаПредупреждение = Новый ТабличныйДокумент;
ОбластьПредупреждение = ТаблицаПредупреждение.Область(1,1,1,1);
	
ОбластьПредупреждение.Текст 	 = "В отчет не включены организации, имеющие метод оценки стоимости";
ОбластьПредупреждение.ЦветТекста = ЦветаСтиля.ЦветОтрицательногоЧисла;
	
ДокументРезультат.ВставитьОбласть(
	ОбластьПредупреждение,
	ДокументРезультат.Область(1,1,1,1),
	ТипСмещенияТабличногоДокумента.ПоВертикали);

ДокументРезультат.АвтоМасштаб = Истина;
	
КонецПроцедуры

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

ПолеСоставногоТипа = КомпоновкаДанныхКлиентСервер.ПолучитьПараметр(КомпоновщикНастроек,"ПолеСоставногоТипа");
	
//альтернативный вариант, если нет модуля КомпоновкаДанныхКлиентСервер
//НастройкиОтчета = КомпоновщикНастроек.ПолучитьНастройки();	
//ПолеСоставногоТипа = НастройкиОтчета.ПараметрыДанных.Элементы.Найти("ПолеСоставногоТипа").Значение;
	
ТекстЗапроса = СхемаКомпоновкиДанных.НаборыДанных.НаборДанных1.Запрос;
	
ИмяСоставногоТипа = ПолеСоставногоТипа.Значение.Метаданные().Имя;
ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "ПриобретениеТоваровУслуг", ИмяСоставногоТипа);

СхемаКомпоновкиДанных.НаборыДанных.НаборДанных1.Запрос = ТекстЗапроса;

КонецПроцедуры

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

НастройкиНовые = КомпоновщикНастроек.ПолучитьНастройки();
ЗначениеОтбора = 2;
Использование = Истина;

ДополнительныеПараметры = Новый Структура("ВПользовательскиеНастройки, ЗаменятьСуществующий", Истина, Истина);

КомпоновкаДанныхКлиентСервер.ДобавитьОтбор(
				НастройкиНовые, 
				Новый ПолеКомпоновкиДанных("Количество"),
				ЗначениеОтбора,
				ВидСравненияКомпоновкиДанных.БольшеИлиРавно,
				Использование,
				ДополнительныеПараметры);
				
КомпоновщикНастроек.ЗагрузитьНастройки(НастройкиНовые);
	
КонецПроцедуры

Большинство наших отчетов имеют обязательный отбор по подразделению. Процедура ПроверитьОбязательныйОтбор() - в общем модуле. Она содержит еще проверку прав доступа для значений отбора, но это уже не про СКД.

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	ПроверитьОбязательныйОтбор(КомпоновщикНастроек.ПолучитьНастройки().Отбор.Элементы, "Подразделение");

КонецПроцедуры

Процедура ПроверитьОбязательныйОтбор(ЭлементыОтбора, ПутьКДаннымПоля) Экспорт

ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ПутьКДаннымПоля);
ЗначениеОтбора = Неопределено;

Для каждого Элемент Из ЭлементыОтбора Цикл

	Если НЕ Элемент.Использование Тогда
		Продолжить;
	КонецЕсли;

	Если Элемент.ЛевоеЗначение = ЛевоеЗначение
	И (Элемент.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно
	ИЛИ Элемент.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке 
	ИЛИ Элемент.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСпискеПоИерархии 
	ИЛИ Элемент.ВидСравнения = ВидСравненияКомпоновкиДанных.ВИерархии) Тогда			

		ЗначениеОтбора = Элемент.ПравоеЗначение;
		Прервать;

	КонецЕсли;	

КонецЦикла;

Если ЗначениеОтбора = Неопределено Тогда
	ВызватьИсключение "Установите отбор по "+ПутьКДаннымПоля;
КонецЕсли;

КонецПроцедуры

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

ИсполняемаяСКД = КомпоновкаДанныхСервер.СкопироватьСхемуКомпоновкиДанных(СхемаКомпоновкиДанных);

ИсполняемыйКомпоновщик = Новый КомпоновщикНастроекКомпоновкиДанных;
ИсполняемыйКомпоновщик.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(ИсполняемаяСКД));
ИсполняемыйКомпоновщик.ЗагрузитьНастройки(КомпоновщикНастроек.ПолучитьНастройки());
ИсполняемыйКомпоновщик.Настройки.Структура.Очистить();
ГруппировкаСтруктуры = КомпоновкаДанныхКлиентСервер.ДобавитьГруппировкуВКореньСтруктуры(ИсполняемыйКомпоновщик, "");
//долго разбирался, что второй параметр должен быть "".
//в результате такой настройки - одна строка. "Количество" - ресурс.
КомпоновкаДанныхКлиентСервер.ОтключитьВыводОбщихИтогов(ИсполняемыйКомпоновщик.Настройки);

//подготовить аргумент функции
Аргумент = КомпоновкаДанныхСервер.ПараметрыВыгрузитьРезультатСКД();
Аргумент.СхемаКомпоновки = ИсполняемаяСКД;
Аргумент.НастройкиКомпоновки = ИсполняемыйКомпоновщик.ПолучитьНастройки();	
ТаблицаРезультата = КомпоновкаДанныхСервер.ВыгрузитьРезультатСКД(Аргумент);		

ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Итог, количество " + ТаблицаРезультата.Итог("Количество"));

КонецПроцедуры

//Элегантное решение от разработчиков.
Функция СкопироватьСхемуКомпоновкиДанных(ИсходнаяСхема) Экспорт
	
	Если ТипЗнч(ИсходнаяСхема) = Тип("СхемаКомпоновкиДанных") Тогда
		
		СхемаКомпоновкиДанных = СериализаторXDTO.ПрочитатьXDTO(СериализаторXDTO.ЗаписатьXDTO(ИсходнаяСхема));
		
	Иначе
		
		СхемаКомпоновкиДанных = Новый СхемаКомпоновкиДанных;
		
	КонецЕсли;
	
	Возврат СхемаКомпоновкиДанных;
	
КонецФункции

Примечание: похожий способ применяют для нахождения итогов по динамическому списку. Чтобы получить схему и настройку для списка, используют методы ПолучитьИсполняемуюСхемуКомпоновкиДанных(); ПолучитьИсполняемыеНастройкиКомпоновкиДанных(); 

  Знаю, много написано, повторяться не хотел. Но каждый раз приходится где-то искать. Пусть будет в одном месте.

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;
НастройкиКомпоновки = КомпоновщикНастроек.ПолучитьНастройки();	
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить( СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки );	
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать( МакетКомпоновки, ВнешниеНаборыДанных(), ДанныеРасшифровки, Истина, Ложь);
//количество аргументов различается в разных релизах платформы ?
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

Функция ВнешниеНаборыДанных()

Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|	ЗНАЧЕНИЕ(Справочник.Номенклатура.Пустаяссылка) КАК Номенклатура,
|	0 КАК Цена";

РезультатЗапроса = Запрос.Выполнить();	
Возврат Новый Структура( "ВнешняяТаблица", РезультатЗапроса.Выгрузить() );

Конецфункции

 //infostart.ru/public/575659/

В современных конфигурациях нестандартную обработку можно легко найти по ключевому слову "Процессор"

 //infostart.ru/public/1058110/

Стандартный способ изменять расшифровку - в форме.

Постановка задачи: в регистре «РегистрацияИзмененияВОбъектах» в измерении хранится уникальный идентификатор измененного объекта. Необходимо построить отчет СКД, содержащий ссылку на объект.
Решение: Создадим вспомогательный регистр «ИДОбъектов», содержащий поля Уникальный идентификатор, СсылкаОбъекта. Запрос СКД выглядит примерно так:

ВЫБРАТЬ
РегистрацияИзмененияВОбъектах.УникальныйИдентификатор,
РегистрацияИзмененияВОбъектах.Дата,
РегистрацияИзмененияВОбъектах.Пользователь,
ИДОбъектов.СсылкаОбъекта
ИЗ
РегистрСведений.РегистрацияИзмененияВОбъектах КАК РегистрацияИзмененияВОбъектах
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ИДОбъектов КАК ИДОбъектов
ПО РегистрацияИзмененияВОбъектах.УникальныйИдентификатор = ИДОбъектов.УникальныйИдентификатор
ГДЕ РегистрацияИзмененияВОбъектах.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания

Регистр ИДОбъектов можно заполнять регламентным заданием, но как ограничить выбор объектов и с какой частотой запускать ? Поэтому заполнение регистра сделал при формировании отчета. Можно было сделать отдельный запрос, не привязываясь к компоновке данных, но здесь формирование в коллекцию значений позволяет учитывать все установленные отборы СКД. Поля в исходном и заменяемом запросе совпадают. После заполнения вспомогательного регистра ИДОбъектов текст запроса возвращаем, происходит формирование основного отчета.

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

ВременныйТекст = 
"ВЫБРАТЬ
|	РегистрацияИзмененияВОбъектах.УникальныйИдентификатор
|	РегистрацияИзмененияВОбъектах.Дата,
|	РегистрацияИзмененияВОбъектах.Пользователь,
|	ИДОбъектов.СсылкаОбъекта
|ИЗ
|	РегистрСведений.РегистрацияИзмененияВОбъектах КАК РегистрацияИзмененияВОбъектах
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ИДОбъектов КАК ИДОбъектов
|		ПО (ИДОбъектов.УникальныйИдентификатор = РегистрацияИзмененияВОбъектах.УникальныйИдентификатор)
|ГДЕ
|	РегистрацияИзмененияВОбъектах.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания
|	И ИДОбъектов.СсылкаОбъекта ЕСТЬ NULL";

ТекстЗапроса = СхемаКомпоновкиДанных.НаборыДанных[0].Запрос;
СхемаКомпоновкиДанных.НаборыДанных[0].Запрос = ВременныйТекст;	
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
ГенераторМакета = Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений");
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки, , ГенераторМакета);
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);	
ОтсутствующиеИДНоменклатуры = Новый ТаблицаЗначений;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(ОтсутствующиеИДНоменклатуры);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных, Ложь);

Для каждого ОтсутствующийИдентификатор Из ОтсутствующиеИдентификаторы Цикл	
	
	ЗаписьРегистра = РегистрыСведений.ИДОбъектов.СоздатьМенеджерЗаписи();
	ЗаписьРегистра.УникальныйИдентификатор = ОтсутствующийИдентификатор.УникальныйИдентификатор;

	Попытка
		УникальныйИдентификатор = Новый УникальныйИдентификатор(ЗаписьРегистра.УникальныйИдентификатор);
		ЗаписьРегистра.СсылкаОбъекта = Справочники.Номенклатура.ПолучитьСсылку(УникальныйИдентификатор);
	Исключение
		Продолжить;
	КонецПопытки;

	ЗаписьРегистра.Записать();
	
КонецЦикла; 

СхемаКомпоновкиДанных.НаборыДанных[0].Запрос = ТекстЗапроса;

КонецПроцедуры

 Кроме всего вышеперечисленного, в процедуре «ПриКомпоновкеРезультата» можно устанавливать нужный вариант отчета или проверять права пользователя на доступ к отчету, но как правило, это выполняют раньше. В типовой конфигурации УТ разработчики чаще всего используют приемы 2-4, 7. Любопытно, что изменять табличный документ или данные расшифровки я догадался в самую последнюю очередь.

Файл с учебным примером прикреплен.

Обновление от 13/09/2019

Для ДинамическогоСписка обратите внимание на функции 

ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(),

ОбщегоНазначенияКлиентСервер.УстановитьПараметрДинамическогоСписка(),

ПолучитьИсполняемуюСхемуКомпоновкиДанных(),

ПолучитьИсполняемыеНастройкиКомпоновкиДанных().

Обновление от 26/12/2019

Для ограниченных прав можно проверять длительность периода отчета и полноту условий, например

ЭлементыОтбора = КомпоновщикНастроек.ПолучитьНастройки().Отбор.Элементы;
Если НЕ КомпоновкаДанныхКлиентСервер.ИспользуетсяОтбор(ЭлементыОтбора, "Склад") Тогда ...