Гарантированный обмен 1С с внешними системами через сервер очередей Microsoft MSMQ

Процедура ЗаписатьСообщениеСИзменениями(Знач НастройкиРаботы = Неопределено)

	Попытка
		РезультатЗаписи = ЗаписатьНовоеСообщениеВСтроку(ФильтрВыборки);
		ПоместитьДанныеОбменаВОчередьMSMQ(РезультатЗаписи.СтрокаХМЛ, РезультатЗаписи.НомерСообщения);
	Исключение
		ОписаниеПроблемы = "Ошибка записи сообщения для Система1: "+ ОписаниеОшибки();
	КонецПопытки;

КонецПроцедуры

Функция ЗаписатьНовоеСообщениеВСтроку(Знач ФильтрВыборки = Неопределено)

	НомерСообщения = 0;
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	ЗаписьXML.ЗаписатьОбъявлениеXML();

	// Создаем новое сообщение
	ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
	ЗаписьСообщения.НачатьЗапись(ЗаписьXML, Ссылка);

	// Для сокращения размера файла сообщения записываем соответствие пространств имен, необязательно
	ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("xsd", "http://www.w3.org/2001/XMLSchema");
	ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("xsi", "http://www.w3.org/2001/XMLSchema-instance");
	ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("v8", "http://v8.1c.ru/data");

	НомерСообщения = ЗаписьСообщения.НомерСообщения;
	ПолучательСообщения = ЗаписьСообщения.Получатель;

	ЗаписьXML.ЗаписатьНачалоЭлемента("Info");
	ЗаписьXML.ЗаписатьАтрибут("содержание", "ОписаниеПередаваемыхДанныхДопущений");
	ЗаписьXML.ЗаписатьТекст("Произвольная строка для внешней системы");
	ЗаписьXML.ЗаписатьКонецЭлемента();

	ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(ЗаписьСообщения.Получатель,НомерСообщения,ФильтрВыборки);

	Пока ВыборкаИзменений.Следующий() Цикл
		ЗаписатьXML(ЗаписьXML, ВыборкаИзменений.Получить()); // Записываем данные с помощью стандартного метода
	КонецЦикла;

	// Завершаем запись сообщения, Блокировка с записи узла плана обмена снимается и сообщение считается отправленным
	ЗаписьСообщения.ЗакончитьЗапись();

	Возврат Новый Структура("НомерСообщения,СтрокаХМЛ",НомерСообщения,ЗаписьXML.Закрыть());

КонецФункции

Процедура ПоместитьДанныеОбменаВОчередьMSMQ(СтрокаXML)

	MQ_SEND_ACCESS 	= 2;
	MQ_DENY_NONE 	= 0;
	qinfo = Новый COMОбъект("MSMQ.MSMQQueueInfo");

	// Формируем путь к очереди на удаленном компьютере, Вариант по имени
	ОчередьОбменаMSMQ 	= "ИмяУдаленногоЛокальногоКомпьютера\PRIVATE$\ИмяИсходящейОчередиИз1С";
	qinfo.FormatName 	= "DIRECT=OS:"+ОчередьОбменаMSMQ; // по IP строка вида: DIRECT=TCP:192.168.0.1\PRIVATE$\ИмяОчереди
	Очередь = qinfo.Open(MQ_SEND_ACCESS, MQ_DENY_NONE);

	Сообщение = Новый COMОбъект("MSMQ.MSMQMessage");	
	Сообщение.Label = "Message" + СокрЛП(УзелИсточник.Код) + "_" + СокрЛП(УзелПриемник.Код) + СокрЛП(Постфикс) + ".xml";
	Сообщение.Body 	= СтрокаXML;

	Сообщение.Send(Очередь); // Помещаем сообщение в очередь

	Очередь.Close();

КонецПроцедуры

Процедура ПолучитьПрочитатьСообщениеИзОчередиMSMQ()

	MQ_DENY_NONE = 0; MQ_RECEIVE_ACCESS = 1; MQ_NO_TRANSACTION = 0;

	qinfo = Новый COMОбъект("MSMQ.MSMQQueueInfo");
	qinfo.FormatName = "DIRECT=OS:"+"ИмяКомпьютера\PRIVATE$\ИмяВходящейОчередиДля1С";
	MSMQQueue = qinfo.Open(MQ_RECEIVE_ACCESS, MQ_DENY_NONE);
	СообщениеВрем = Новый COMОбъект("MSMQ.MSMQMessage"); // Временный объект необходим для поиска последнего сообщения

	счетчик = 0;
	СообщениеВрем = MSMQQueue.Peek(0, , 0, 0);
	СообщениеВрем = MSMQQueue.PeekCurrent(0,,0,0);

	// Если получили сообщение, разбираем его и передаем данные обмена дальше для обработки
	Пока (СообщениеВрем <> Неопределено) Цикл

		счетчик 	= счетчик+1;
		Сообщение 	= СообщениеВрем;
		Успешно 	= ПрочитатьНовоеСообщение(Сообщение.Label, Сообщение.Body);

		Если Успешно Тогда
			// удалить текущее сообщение как успешное
			СообщениеВрем = MSMQQueue.ReceiveCurrent(MQ_NO_TRANSACTION, , , 0);
			// происходит смещение курсора - нормально
			СообщениеВрем = MSMQQueue.ReceiveByLookupId(Сообщение.LookupId, MQ_NO_TRANSACTION, , , 0);
		КонецЕсли;

		СообщениеВрем = MSMQQueue.PeekNext(0,,0,0);
	КонецЦикла;

	MSMQQueue.Close();

КонецПроцедуры

Функция ПрочитатьНовоеСообщение(ИмяСообщения, СтрокаДляРазбора)

	Успех 		= Ложь;
	ЧтениеXML 	= Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(СтрокаДляРазбора);
	ЧтениеСообщения = ПланыОбмена.СоздатьЧтениеСообщения();

	Попытка
		ЧтениеСообщения.НачатьЧтение(ЧтениеXML);
		НомерСообщения = ЧтениеСообщения.НомерСообщения;

		Если ЧтениеСообщения.Отправитель <> Ссылка Тогда
			ВызватьИсключение "Неверный узел отправителя. Ошибка маршрутизации."; // Сообщение предназначено не для этого узла
		КонецЕсли;

		Пока ВозможностьЧтенияДанных(ЧтениеXML) Цикл
			Данные = ПрочитатьXML(ЧтениеXML); // Пытаемся прочесть значение из объекта ЧтениеXML стандартным образом

			Если ЗначениеЗаполнено(Данные) Тогда
				ПланыОбмена.УдалитьРегистрациюИзменений(Ссылка, Данные);
			КонецЕсли;
		КонецЦикла;

		ЧтениеСообщения.ЗакончитьЧтение(); //когда заканчиваем успешно чтение счетчик сообщений общих увеличивается +1
		Успех = Истина;

	Исключение
		ОшибкаЧтения = ОписаниеОшибки();
		ЧтениеСообщения.ПрерватьЧтение();
		Успех = Ложь;
	КонецПопытки;

	ЧтениеXML.Закрыть();
	Возврат Успех;

КонецФункции

Функция ВозможностьЧтенияДанных(ЧтениеXML)

	ТипXML = ПолучитьXMLТип(ЧтениеXML);  // Получаем тип данных XML, который может быть считан в данный момент
	Если ТипXML = Неопределено Тогда
		Возврат Ложь;
	КонецЕсли;

	Возврат ВозможностьЧтенияXML(ЧтениеXML);

КонецФункции