ЭВОТОР: выгрузка и загрузка в онлайн кассу в соответствии с требованием 54-ФЗ (54ФЗ). 1С: 7.7 ТиС

//
//******************************************************************************
//  глПересчет(Сумма,ВалютаНач,ПоКурсуВалютыНач,ВалютаКон,ПоКурсуВалютыКон,ПоКратностиВалютыНач,ПоКратностиВалютыКон)
//
// Параметры:      
//	Сумма                - сумма, которую следует пересчитать
// 	ВалютаНач            - валюта (элемент справочника "Валюты"), из которой считаем
// 	ВалютаКон            - валюта (элемент справочника "Валюты"), в которую считаем
// 	ПоКурсуВалютыНач     - курс или дата курса валюты нач
// 	ПоКурсуВалютыКон     - курс или дата курса валюты кон
// 	ПоКратностиВалютыНач - кратность валюты нач
// 	ПоКратностиВалютыКон - кратность валюты кон
//
// Возвращаемое значение: 
//  Сумма, пересчитанная в другую валюту
//
// Описание: 
// 	Эта функция пересчитывает сумму из ВалютаНач и возвращает значение Сумма в 
// 	ВалютаКон в параметрах ПоКурсуВалютыНач и ПоКурсуВалютыКон могут передаваться
// 	либо сами курсы либо даты
//
Функция глПересчет(Сумма,ВалютаНач,ПоКурсуВалютыНач,ВалютаКон,ПоКурсуВалютыКон,ПоКратностиВалютыНач = 1,ПоКратностиВалютыКон = 1) Экспорт
	
	Если ВалютаНач = ВалютаКон Тогда
		// ну, тут и считать нечего...
		Возврат Сумма;
	КонецЕсли;

	ТипЗн=ТипЗначенияСтр(ПоКурсуВалютыНач);
	
	Если ТипЗн = "Число" Тогда
		КурсВалютыНач      = ПоКурсуВалютыНач;
		КратностьВалютыНач = ПоКратностиВалютыНач;
		КратностьВалютыНач = ?(КратностьВалютыНач = 0,1,КратностьВалютыНач);
		
	ИначеЕсли ТипЗн = "Дата" Тогда
		КурсВалютыНач      = глКурсДляВалюты(ВалютаНач,ПоКурсуВалютыНач);
		КратностьВалютыНач = глКратностьДляВалюты(ВалютаНач,ПоКурсуВалютыНач);
		
	Иначе
		Сообщить("глПересчет():Неверный тип параметра ПоКурсуВалютыНач!");
		Возврат Сумма;
		
	КонецЕсли;

	ТипЗн = ТипЗначенияСтр(ПоКурсуВалютыКон);
	
	Если ТипЗн = "Число" Тогда
		КурсВалютыКон      = ПоКурсуВалютыКон;
		КратностьВалютыКон = ПоКратностиВалютыКон;
		КратностьВалютыКон = ?(КратностьВалютыКон = 0,1,КратностьВалютыКон);
		
	ИначеЕсли ТипЗн = "Дата" Тогда
		КурсВалютыКон      = глКурсДляВалюты(ВалютаКон,ПоКурсуВалютыКон);
		КратностьВалютыКон = глКратностьДляВалюты(ВалютаКон,ПоКурсуВалютыКон);
		
	Иначе
		Сообщить("глПересчет():Неверный тип параметра ПоКурсуВалютыКон!");
		Возврат Сумма;
		
	КонецЕсли;

	Если (КурсВалютыНач = 0) 
	 ИЛИ (КурсВалютыКон = 0) Тогда
		Сообщить("При пересчете валюты обнаружен нулевой курс валюты "
		+?(КурсВалютыНач = 0,ВалютаНач,ВалютаКон));
		Возврат Сумма;
	КонецЕсли;

	Возврат Сумма * ((КурсВалютыНач / КратностьВалютыНач) / (КурсВалютыКон / КратностьВалютыКон));
	
КонецФункции // глПересчет()

//2 фунция

//******************************************************************************
// глОкруглить(Числ, ПорядокОкругления)
//
// Параметры:
//  Числ              - исходное число
//  ПорядокОкругления - элемент перечисления Порядки окгугления: 
//  "шаг" округления (0.01 (арифметическое), 0.01, 0.05, 0.1, 0.5, 1, 5, 10, 50, 100)
//
// Возвращаемое значение:
//  Округленное по заданному порядку значение
//
// Описание:
//  Округляет число вверх по заданному порядку. Т.е число 123.37 при порядке
//  округление 0.5 превратиться в 123.50, а число 0.1 при порядке округления
//  5 станет равным 5.
//  Если значение перечисления ОкрТочно, то округляет арифметически до 0.01
//
Функция глОкруглить(Числ, ПорядокОкругления) Экспорт
	Перем Рез;
	
	Если ПорядокОкругления = Перечисление.ПорядкиОкругления.ОкрТочно Тогда
		
		// арифметическое округление до 2-х знаков после запятой
		Рез = Окр(Числ, 2);
	Иначе
		// округление к верхней границе по заданному порядку
		
		// преобразуем порядок округления число
		Порядок			= Число(Строка(ПорядокОкругления));
		
		// вычислим количество интервалов, входящих в число
		КолвоИнтервал	= Числ / Порядок;
		
		// вычислим целое количество интервалов.
		КолвоИнтервалЦел= Цел(КолвоИнтервал);
		
		Если КолвоИнтервал = КолвоИнтервалЦел Тогда
			// Числа поделились нацело. Округлять не нужно.
			Рез	= Числ;
		Иначе
			Рез	= Порядок * (КолвоИнтервалЦел + 1);
		КонецЕсли;
		
	КонецЕсли;
	
	Возврат Рез;
КонецФункции // глОкруглить()

//3 функция


// глВернутьЦену1(Номенклатура, ТипЦены, ДатаЦены, ЦенаЦены, ЕдЦены, ВалЦены, НаценкаЦены, НайденнаяЦена) 
//
// Параметры: 
//  Номенклатура  - элемент справочника "Номенклатура"
//  ТипЦены       - элемент справочника "ТипыЦен"
//  ДатаЦены      - дата, на которую надо получить цену
//  ЦенаЦены      - переменная, которую надо заполнитиь значением (число) полученной цены
//  ЕдЦены        - переменная, которую надо заполнитиь значением 
//                  (элемент справочника Единицы) единицы, за которую дается цена
//  ВалЦены       - переменная, которую надо заполнитиь значением валюты, в которой выражена цена 
//  НайденнаяЦена - переменная, которую надо заполнить найденным элементом справочника цен
//
// Возвращаемое значение:
//  1 - если есть такая цена, пераметры цены заполнены
//  0 - нет такой цены
// -1 - есть только цены, помеченные на удаление
//
// Описание:
//  Формирует ценовые характеристики номенклатурной единицы по заданному типу цен. 
//
Функция глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены = 0, ЦенаЦены = 0, ЕдЦены = 0, ВалЦены = 0, НаценкаЦены = 0, НайденнаяЦена = 0) Экспорт
	Перем ЦеныНоменклатуры;
	Перем Рассчетная;
	Перем НужныйТипЦен;
	Перем ЕстьУдаленные;
	
	
	Рез = 1;
	НайденнаяЦена = ПолучитьПустоеЗначение("Справочник.Цены");
	
	Если ПустоеЗначение(ДатаЦены) = 1 Тогда
		ДатаЦены = РабочаяДата();
	КонецЕсли;
	
	// Найдет или нужную цену в справочнике
	// если она рассчитывается, то найдем базовую цену 
	Рассчетная		= ТипЦены.Рассчитывается;
	НужныйТипЦен	= ?(ПустоеЗначение(Рассчетная) = 1, ТипЦены, ТипЦены.БазовыйТипЦен);
	
	ЦеныНоменклатуры= СоздатьОбъект("Справочник.Цены");
	ЦеныНоменклатуры.ИспользоватьВладельца(Номенклатура); 
	ЦеныНоменклатуры.ВыбратьЭлементы();
	
	Пока ЦеныНоменклатуры.ПолучитьЭлемент()  = 1 Цикл    
		Если ЦеныНоменклатуры.ТипЦен <> НужныйТипЦен Тогда
			Продолжить;
		КонецЕсли;
		
		НайденнаяЦена = ЦеныНоменклатуры.ТекущийЭлемент();
		
		Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда
			Рез = - 1; // Цена есть, но помечена на удаление
			Продолжить;
		Иначе
			Прервать;
		КонецЕсли;
		
	КонецЦикла;       
	
	Если ПустоеЗначение(НайденнаяЦена) = 1 Тогда
		
		// Нет такой цены
		Возврат 0;
	КонецЕсли;
	
	// Заполним все ценовые характериситики 
	
	// если не задана единица цены на эту дату, то потом придется обрабатывать случай нулевого коэффициента у  пустой единицы
	ЕдЦены		= НайденнаяЦена.Единица.Получить(ДатаЦены); 
	
	Если ПустоеЗначение(Рассчетная) = 1 Тогда 
		
		//Если цена не рассчитывается
		ЦенаЦены	= НайденнаяЦена.Цена.Получить(ДатаЦены);
	    //Рез=ЦенаЦены;
		// элемент справочника существует Валюту и Наценку возьмем из него
		ВалЦены		= НайденнаяЦена.Валюта;
		НаценкаЦены	= НайденнаяЦена.Процент;
	Иначе
		//Если цена рассчитывается
		БазоваяЦена 	= НайденнаяЦена.Цена.Получить(ДатаЦены);
		БазоваяВалюта	= НайденнаяЦена.Валюта;
		
		// Цены у базового типа могут отличаться
		ЦенаЦены    = глПересчет(БазоваяЦена, БазоваяВалюта, ДатаЦены, ТипЦены.Валюта, ДатаЦены);
		ЦенаЦены    = глОкруглить(ЦенаЦены * (100 + ТипЦены.Процент) / 100, ТипЦены.ПорядокОкругления);
	    
		// элемент справочника Цены не существует (расчетный). Валюту и Наценку возьмем из типа цены
		ВалЦены		= ТипЦены.Валюта;
		НаценкаЦены	= ТипЦены.Процент;
	КонецЕсли;
	
	Возврат Рез;
КонецФункции // глВернутьЦену()