UPD. В новых типовых подобная функция есть, однако, ее нет в групповой обработке элементов и прочих инструментах, где используется отбор СКД, поэтому ниже будет описано, как добавить в старые типовые, нетиповые (оригинальные конфигурации) или в групповую обработку элементов. При этом, даже в новых типовых, к сожалению, нельзя составить список по файлу, если поле текстовое. Например, при попытке заполнить поле Номер договора (Договор.Номер), или номер документа вставкой из буфера система ругнется на "Индекс находится за границами массива".
Пользователи стали часто обращаться с просьбой ускорить им набор (ввод) тестовых значений как фильтр/отбор в стандартных отчетах, обработках или отборах на СКД (QR-коды, штрих-коды, коды ячеек, паллет, артикулы товаров, наименования товаров или ИНН покупателей), которые они получают от других отделов/поставщиков/покупателей в виде текстовых файлов или Excel таблиц. Третья версия Кронос: WMS от 2019 года, так же, как и все типовые 1C (БП, ERP, УТ, УПП, CRM, ...), построена на базе Библиотеки Стандартных Подсистем (БСП, SSL), поэтому мы решили доработать типовой механизм установки фильтров/отборов в отчетах, обработках или отборах на СКД.
Давайте посмотрим, как в пользовательском режиме демонстрационной конфигурации БСП это будет работать после наших изменений:
Теперь давайте разберемся, как Вам такое реализовать у себя в конфигурации или добавить в свою типовую 1С. Писать будем универсально, чтобы потом можно было легко переносить функции в общие модули для тиражирования в другие конфигурации и их метаданные.
В общей форме "ФормаНастроекОтчета" на страницу "СтраницаОтборы" добавим кнопку, которая открывает общую форму _СписокИзФайла с табличным документом для заполнения нужным нам отбором.
&НаКлиенте
Процедура _ЗаполнитьСписок(Команда)
ЗаполнениеСпискаПоФайлу(ЭтаФорма, Элементы.Отборы, Отборы, "ОбработчикЗаполненияСпискаПоФайлу");
КонецПроцедуры
&НаКлиенте
Процедура ЗаполнениеСпискаПоФайлу(Форма, ТаблицаФормы, Отбор, ИмяОбработчика="") экспорт
СтрокаТЧ = ТаблицаФормы.ТекущиеДанные;
Если СтрокаТЧ=Неопределено Тогда
Возврат;
КонецЕсли;
ПараметрыСтроки = Новый Структура();
ПараметрыСтроки.Вставить("Форма", Форма);
ПараметрыСтроки.Вставить("ИмяОбработчика", ИмяОбработчика);
ПараметрыСтроки.Вставить("Отбор", Отбор);
ПараметрыСтроки.Вставить("СтрокаТЧ", СтрокаТЧ);
ОбработчикЗаполнениеСпискаПоФайлу = Новый ОписаниеОповещения("ОбработчикЗаполнениеСпискаПоФайлу", ЭтотОбъект, ПараметрыСтроки);
ФормаЗаполнения = ОткрытьФорму("ОбщаяФорма._СписокИзФайла",,Форма,,,,ОбработчикЗаполнениеСпискаПоФайлу);
КонецПроцедуры
После заполнения табличного документа (вставка значений отбора/фильтра из буфера, из текстового файла или Excel) пользователь нажимает кнопку "Перенести в список" со следующей процедурой:
&НаКлиенте
Процедура ПеренестиВСписок(Команда)
НачальнаяСтрока = 2;
ВысотаТаблицы = ТаблицаФайла.ВысотаТаблицы;
Если ВысотаТаблицы>100000 Тогда
Сообщить("Количество строк превышает допустимое - "+ВысотаТаблицы);
Возврат;
КонецЕсли;
СписокДанных = Новый СписокЗначений();
Для НомерСтроки = НачальнаяСтрока По ВысотаТаблицы Цикл
ЗначениеЯчейки = СокрЛП(ТаблицаФайла.Область("R"+Формат(НомерСтроки,"ЧГ=")+"C"+Формат(1,"ЧГ=")).Текст);
Если НЕ ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
Продолжить;
КонецЕсли;
СписокДанных.Добавить(ЗначениеЯчейки);
КонецЦикла;
Закрыть(СписокДанных);
КонецПроцедуры
Иными словами, после нажатия кнопки "Перенести в список" будет осуществлен вызов процедуры оповещения, описанной нами при открытии формы - ОбработчикЗаполнениеСпискаПоФайлу.
Поэтому теперь необходимо описать процедуру ОбработчикЗаполнениеСпискаПоФайлу в общей форме "ФормаНастроекОтчета", чтобы перенести список значений в "Правое значение" (для БСП 3.1) или "Значение" (для старых БСП) отбора компоновки данных.
Процедура ОбработчикЗаполнениеСпискаПоФайлу(СписокЗаполнения, ДополнительныеПараметры) экспорт
Если НЕ ТипЗнч(СписокЗаполнения)=Тип("СписокЗначений") ИЛИ СписокЗаполнения.Количество()=0 Тогда
Возврат;
КонецЕсли;
Отбор = ДополнительныеПараметры.Отбор;
СтрокаТЧ = ДополнительныеПараметры.СтрокаТЧ;
ЭлементОтбора = Неопределено;
Если ТипЗнч(Отбор)=Тип("ОтборКомпоновкиДанных") Тогда
Для Каждого Элемент Из Отбор.Элементы Цикл
Если Элемент.ЛевоеЗначение=СтрокаТЧ.ЛевоеЗначение Тогда
ЭлементОтбора = Элемент;
Прервать;
КонецЕсли;
КонецЦикла;
Если ЭлементОтбора=Неопределено Тогда
Возврат;
КонецЕсли;
ОписаниеПоляКомпоновки = Отбор.ДоступныеПоляОтбора.НайтиПоле(ЭлементОтбора.ЛевоеЗначение);
Если НЕ ОписаниеПоляКомпоновки.Тип.СодержитТип(Тип("Строка")) Тогда
_ДиалогСервер.ТекстовыйСписокВСсылкиТипа(СписокЗаполнения, ОписаниеПоляКомпоновки.Тип);
КонецЕсли;
ПроверитьВидСравненияНаВСписке(ЭлементОтбора.ВидСравнения);
ЭлементОтбора.ПравоеЗначение = СписокЗаполнения;
ИначеЕсли ТипЗнч(Отбор)=Тип("ДанныеФормыДерево") Тогда
СтрокаТЧ = ДополнительныеПараметры.СтрокаТЧ;
ПроверитьВидСравненияНаВСписке(СтрокаТЧ.Условие);
Если НЕ СтрокаТЧ.ТипЗначения.СодержитТип(Тип("Строка")) Тогда
_ДиалогСервер.ТекстовыйСписокВСсылкиТипа(СписокЗаполнения, СтрокаТЧ.ТипЗначения);
КонецЕсли;
//для старых БСП
СтрокаТЧ.Значение = СписокЗаполнения;
//для БСП 3.1
//СтрокаТЧ.ПравоеЗначение = СписокЗаполнения;
КонецЕсли;
Если ПустаяСтрока(ДополнительныеПараметры.ИмяОбработчика) Тогда
Возврат;
КонецЕсли;
Попытка
Выполнить("ДополнительныеПараметры.Форма."+ДополнительныеПараметры.ИмяОбработчика+"();");
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецПроцедуры
Также опишем функцию, которая по строкам определит ссылки значений по списку текстовых значений:
(Кстати, функция небольшая и Вы можете легко её изменить для более специфичных и сложных алгоритмов поиска ссылки по тексту, например, использовать шаблоны, как в моей публикации Ускоряем медленный/долгий и тормозной стандартный поиск по динамическому списку, настраиваем его под себя)
Процедура ТекстовыйСписокВСсылкиТипа(СписокЗаполнения, ОписаниеТипа) экспорт
ТекстЗапроса = "";
Для Каждого ТипПоля Из ОписаниеТипа.Типы() Цикл
МД = Метаданные.НайтиПоТипу(ТипПоля);
ПолноеИмя = МД.ПолноеИмя();
Если Найти(ВРЕГ(ПолноеИмя), ВРЕГ("Документ"))=0 И Найти(ВРЕГ(ПолноеИмя), ВРЕГ("Справочник"))=0 Тогда
Продолжить;
КонецЕсли;
ГДЕ = ""; Добавка = "";
МассивПолей = СтрРазделить(МД.ВводПоСтроке, ",");
Для Каждого Поле Из МассивПолей Цикл
Если НЕ ЗначениеЗаполнено(Поле) Тогда
Продолжить;
КонецЕсли;
ГДЕ = ГДЕ + Добавка + " Объект."+СокрЛП(Поле)+" В(&СписокЗаполнения)";
Добавка = " ИЛИ ";
КонецЦикла;
Если ПустаяСтрока(ГДЕ) Тогда
Продолжить;
КонецЕсли;
ТекстЗапроса = ТекстЗапроса + ?(ПустаяСтрока(ТекстЗапроса), "", " ОБЪЕДИНИТЬ ВСЕ ");
ТекстЗапроса = ТекстЗапроса + "
|ВЫБРАТЬ
| Объект.Ссылка КАК Ссылка
|ИЗ
| "+ПолноеИмя+" КАК Объект
|ГДЕ " + ГДЕ + "
|";
КонецЦикла;
Если ПустаяСтрока(ТекстЗапроса) Тогда
Возврат;
КонецЕсли;
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("СписокЗаполнения", _ОбщегоНазначенияКлиентСервер.СписокВМассив(СписокЗаполнения));
Запрос.Текст = ТекстЗапроса;
Выборка = Запрос.Выполнить().Выбрать();
СписокЗаполнения = Новый СписокЗначений;
Пока Выборка.Следующий() Цикл
СписокЗаполнения.Добавить(Выборка.Ссылка);
КонецЦикла;
КонецПроцедуры
И опишем функцию обработчика изменения поля на форме:
&НаКлиенте
Процедура ОбработчикЗаполненияСпискаПоФайлу() экспорт
//В старой БСП
ТаблицыПолейИзменитьЗначение("Отборы");
//В БСП 3.1
//ОтборыПравоеЗначениеПриИзменении("");
КонецПроцедуры
Подправив чуть-чуть типовую функцию (старое БСП):
&НаКлиенте
Процедура ТаблицыПолейИзменитьЗначение(ТаблицаИмя)
СтрокаТаблицы = Элементы[ТаблицаИмя].ТекущиеДанные;
Если СтрокаТаблицы = Неопределено Тогда
Возврат;
КонецЕсли;
УзелКД = ТаблицыПолейНайтиУзел(ЭтотОбъект, ТаблицаИмя, СтрокаТаблицы);
ЭлементКД = УзелКД.ПолучитьОбъектПоИдентификатору(СтрокаТаблицы.ИдентификаторКД);
Если ЭлементКД = Неопределено Тогда
Возврат;
КонецЕсли;
Если СтрокаТаблицы.ЭтоПараметр Тогда
ЭлементКД.Значение = СтрокаТаблицы.Значение;
Иначе
ЭлементКД.ПравоеЗначение = СтрокаТаблицы.Значение;
ЭлементКД.ВидСравнения = СтрокаТаблицы.Условие;
КонецЕсли;
ЭлементКД.Использование = Истина;
СтрокаТаблицы.Использование = Истина;
ПользовательскиеНастройкиМодифицированы = Истина;
Если РасширенныйРежим = 1 Тогда
ВариантИзменен = Истина;
КонецЕсли;
КонецПроцедуры
А в новой БСП 3.1, процедура называется иначе, но ее тоже нужно немного подкорректировать:
&НаКлиенте
Процедура ОтборыПравоеЗначениеПриИзменении(Элемент)
Строка = Элементы.Отборы.ТекущиеДанные;
Если Строка = Неопределено Тогда
Возврат;
КонецЕсли;
Строка.Использование = Истина;
СвойствоЭлементаСтруктуры = СвойствоЭлементаСтруктурыНастроек(
Отчет.КомпоновщикНастроек, "Отбор", ИдентификаторЭлементаСтруктурыНастроек);
ЭлементНастройки = ЭлементНастройки(СвойствоЭлементаСтруктуры, Строка);
//Изменим это
//ЗаполнитьЗначенияСвойств(ЭлементНастройки, Строка, "Использование, ПравоеЗначение");
//на это
ЗаполнитьЗначенияСвойств(ЭлементНастройки, Строка, "ВидСравнения, Использование, ПравоеЗначение");
УстановитьМодифицированность();
УстановитьПредставлениеЗначения(Строка);
КонецПроцедуры
И всё, теперь Ваши пользователи смогут устанавливать фильтры или отборы по любому текстовому файлу или Excel файлу в любом отчете, отборах СКД или групповой обработке элементов Вашей конфигурации 1С, основанной на Библиотеке Стандартных Подсистем (УПП, БП, ERP, УТ, Кронос: WMS, ...) достаточно добавить кнопку и вызов универсальной функции заполнения.
Надеюсь, моя публикация была Вам полезна и сэкономит Ваше время, ссылка на все публикации SizovE.
Подписывайтесь на мой канал (наверху), будет много интересного бесплатного контента :)
