Функции для преобразования справочников и документов в соответствие и обратно

Функция ЭтоЗначениеПростогоТипа(ТекЗначение) Экспорт
	Возврат ТипЗнч(ТекЗначение) = Тип("Число") 
	ИЛИ ТипЗнч(ТекЗначение) = Тип("Булево") 
	ИЛИ ТипЗнч(ТекЗначение) = Тип("Дата") 
	ИЛИ ТипЗнч(ТекЗначение) = Тип("Строка")
	ИЛИ ТекЗначение = Неопределено;
КонецФункции

Функция ПолучитьИмяСправочникаРасширения(ИмяСправочника) Экспорт
	//Соответствие = Новый Соответствие();
	//Можно расписать соответствия названий или для другого изменения имени справочника приемника
    //"Префикс_"+ИмяСправочника
	Возврат ИмяСправочника;
КонецФункции

Функция ПолучитьСоответствиеИзОбъекта(знач ТекОбъект,МассивЭлементов=Неопределено) Экспорт
	Если МассивЭлементов<>Неопределено И МассивЭлементов.Найти(ТекОбъект)<>Неопределено И НЕ ЭтоЗначениеПростогоТипа(ТекОбъект) Тогда
		Возврат Строка(ТекОбъект.Метаданные().ПолноеИмя()+"^"+ТекОбъект.УникальныйИдентификатор());
	ИначеЕсли МассивЭлементов = Неопределено Тогда
		МассивЭлементов = Новый Массив;
		МассивЭлементов.Добавить(ТекОбъект);
	КонецЕсли;
	МассивЭлементов.Добавить(ТекОбъект);
	Если ТипЗнч(ТекОбъект) = Тип("УникальныйИдентификатор") Тогда
		Возврат Строка(ТекОбъект);
	ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(ТипЗнч(ТекОбъект)) Тогда
		Возврат ТекОбъект.Метаданные().ПолноеИмя()+"."+Строка(ТекОбъект);
	КонецЕсли;
	
	Соответствие = Новый Соответствие(); /// реквизиты     
    Для каждого Реквизит из ТекОбъект.Метаданные().Реквизиты Цикл
		Если ЭтоЗначениеПростогоТипа(ТекОбъект[Реквизит.Имя])Тогда
			Соответствие.Вставить(Реквизит.Имя, ТекОбъект[Реквизит.Имя]);
		ИначеЕсли ТипЗнч(ТекОбъект[Реквизит.Имя]) = Тип("ХранилищеЗначения") Тогда
			Соответствие.Вставить(Реквизит.Имя, XMLСтрока(ТекОбъект[Реквизит.Имя]));
		Иначе
			Соответствие.Вставить(Реквизит.Имя, ПолучитьСоответствиеИзОбъекта(ТекОбъект[Реквизит.Имя],МассивЭлементов));
		КонецЕсли;
    КонецЦикла; /// таблицы     
	Для Каждого ТабличнаяЧасть из ТекОбъект.Метаданные().ТабличныеЧасти Цикл
		МассивСтрок = Новый Массив; ДанныеСтрокой = "";
		Для Каждого ТекСтрока Из ТекОбъект[ТабличнаяЧасть.Имя] Цикл
			СоответствиеСтроки = Новый Соответствие;
			Для Каждого ТекКолонка Из ТекОбъект.Метаданные().ТабличныеЧасти[ТабличнаяЧасть.Имя].Реквизиты Цикл
				Если ЭтоЗначениеПростогоТипа(ТекСтрока[ТекКолонка.Имя])Тогда
					СоответствиеСтроки.Вставить(ТекКолонка.Имя, ТекСтрока[ТекКолонка.Имя]);
				ИначеЕсли ТипЗнч(ТекСтрока[ТекКолонка.Имя]) = Тип("ХранилищеЗначения") Тогда
					СоответствиеСтроки.Вставить(ТекКолонка.Имя, XMLСтрока(ТекСтрока[ТекКолонка.Имя]));
				Иначе
					СоответствиеСтроки.Вставить(ТекКолонка.Имя, ПолучитьСоответствиеИзОбъекта(ТекСтрока[ТекКолонка.Имя],МассивЭлементов));
				КонецЕсли;
				ДанныеСтрокой = ДанныеСтрокой+"~"+Строка(СоответствиеСтроки[ТекКолонка.Имя]);
			КонецЦикла;
			МассивСтрок.Добавить(СоответствиеСтроки);
			ДанныеСтрокой = ДанныеСтрокой+Символы.ПС; 
		КонецЦикла;
		Соответствие.Вставить(ТабличнаяЧасть.Имя,МассивСтрок);
		Соответствие.Вставить(ТабличнаяЧасть.Имя+"Строкой",ДанныеСтрокой);  //Содержимое таб. части для облегчения отладки
    КонецЦикла;
    Соответствие.Вставить("ИмяМетаданныеОбъекта",ТекОбъект.Метаданные().ПолноеИмя());
   	Соответствие.Вставить("УникальныйИдентификатор",Строка(ТекОбъект.УникальныйИдентификатор()));
	Для Каждого стРеквизит Из ТекОбъект.Метаданные().СтандартныеРеквизиты Цикл
		Если ЗначениеЗаполнено(ТекОбъект[стРеквизит.Имя]) И стРеквизит.Имя<>"Предопределенный" И стРеквизит.Имя<>"Ссылка" Тогда
			Соответствие.Вставить(стРеквизит.Имя,ТекОбъект[стРеквизит.Имя]);
		КонецЕсли;
    КонецЦикла;		
	
	Возврат Соответствие;
КонецФункции

Функция ПолучитьОбъектИзСоостветствия(вхСоответствие) Экспорт
	
	ПолноеИмяОбъекта = вхСоответствие["ИмяМетаданныеОбъекта"];
	УникальныйИдентификатор = Новый УникальныйИдентификатор(вхСоответствие["УникальныйИдентификатор"]);
	Если СтрНайти(ПолноеИмяОбъекта,"Справочник") Тогда
		ИмяДляСоздания = ПолучитьИмяСправочникаРасширения(СтрЗаменить(ПолноеИмяОбъекта,"Справочник.",""));
		СсылкаНаОбъект = Справочники[ИмяДляСоздания].ПолучитьСсылку(УникальныйИдентификатор);
		Если ЗначениеЗаполнено(СсылкаНаОбъект) И СсылкаНаОбъект.ПолучитьОбъект()=Неопределено Тогда
			ТекОбъект = Справочники[ИмяДляСоздания].СоздатьЭлемент();
			ТекОбъект.УстановитьСсылкуНового(СсылкаНаОбъект);
		ИначеЕсли ЗначениеЗаполнено(СсылкаНаОбъект) Тогда
			ТекОбъект = СсылкаНаОбъект.ПолучитьОбъект();
		Иначе
			Возврат "";
		КонецЕсли;
	ИначеЕсли СтрНайти(ПолноеИмяОбъекта,"Документ") Тогда	
		ИмяДляСоздания = СтрЗаменить(ПолноеИмяОбъекта,"Документ.","");
		СсылкаНаОбъект = Документы[ИмяДляСоздания].ПолучитьСсылку(УникальныйИдентификатор);
		Если СсылкаНаОбъект.ПолучитьОбъект()=Неопределено Тогда
			ТекОбъект = Документы[ИмяДляСоздания].СоздатьДокумент();
			ТекОбъект.УстановитьСсылкуНового(СсылкаНаОбъект);
		Иначе
			ТекОбъект = СсылкаНаОбъект.ПолучитьОбъект();
		КонецЕсли;
	КонецЕсли;
	Для Каждого стРеквизит Из ТекОбъект.Метаданные().СтандартныеРеквизиты Цикл
		Если ЗначениеЗаполнено(вхСоответствие[стРеквизит.Имя]) И стРеквизит.Имя<>"Предопределенный" И стРеквизит.Имя<>"Ссылка" Тогда
			ТекОбъект[стРеквизит.Имя] = вхСоответствие[стРеквизит.Имя];
		КонецЕсли;
    КонецЦикла;		
		
	Для Каждого элСоответсвия Из вхСоответствие Цикл
		Если ТекОбъект.Метаданные().Реквизиты.Найти(элСоответсвия.Ключ)<>Неопределено Тогда
			Если ТипЗнч(элСоответсвия.Значение) = Тип("Соответствие") И ЗначениеЗаполнено(элСоответсвия.Значение.Получить("ИмяМетаданныеОбъекта")) Тогда
				ЗначениеЭлСоостветствия = ПолучитьОбъектИзСоостветствия(элСоответсвия.Значение);			
			ИначеЕсли ТипЗнч(элСоответсвия.Значение) = Тип("Строка") И СтрНайти(элСоответсвия.Значение,"^")<>0 Тогда
				МассивВхСтроки = СтрРазделить(элСоответсвия.Значение,"^");
				ПолноеИмяОбъекта = МассивВхСтроки[0];
				УникальныйИдентификатор = Новый УникальныйИдентификатор(МассивВхСтроки[1]);
				ИмяДляСоздания = ПолучитьИмяСправочникаРасширения(СтрЗаменить(ПолноеИмяОбъекта,"Справочник.",""));
				Если Метаданные.Справочники.Найти(ИмяДляСоздания)<>Неопределено Тогда
					ЗначениеЭлСоостветствия = Справочники[ИмяДляСоздания].ПолучитьСсылку(УникальныйИдентификатор);
				Иначе
					Продолжить;
				КонецЕсли;
			Иначе
				ЗначениеЭлСоостветствия = элСоответсвия.Значение
			КонецЕсли;
			ТекОбъект[элСоответсвия.Ключ] = ЗначениеЭлСоостветствия;	
		ИначеЕсли ТекОбъект.Метаданные().ТабличныеЧасти.Найти(элСоответсвия.Ключ)<>Неопределено Тогда
			ТекТабЧасть = элСоответсвия.Значение;
			ТекОбъект[элСоответсвия.Ключ].Очистить();
			Для Каждого СтрокаТабЧасти Из ТекТабЧасть Цикл
				НовСтрока = ТекОбъект[элСоответсвия.Ключ].Добавить();
				Для Каждого ТекКолонкаТабЧасти Из СтрокаТабЧасти Цикл
					Если ТипЗнч(ТекКолонкаТабЧасти.Значение) = Тип("Соответствие") И ЗначениеЗаполнено(ТекКолонкаТабЧасти.Значение.Получить("ИмяМетаданныеОбъекта")) Тогда
						ЗначениеЭлСоостветствия = ПолучитьОбъектИзСоостветствия(ТекКолонкаТабЧасти.Значение);	
					ИначеЕсли ТипЗнч(ТекКолонкаТабЧасти.Значение) = Тип("Строка") И СтрНайти(ТекКолонкаТабЧасти.Значение,"^")<>0 Тогда
						МассивВхСтроки = СтрРазделить(ТекКолонкаТабЧасти.Значение,"^");
						ПолноеИмяОбъекта = МассивВхСтроки[0];
						УникальныйИдентификатор = Новый УникальныйИдентификатор(МассивВхСтроки[1]);
						ИмяДляСоздания = ПолучитьИмяСправочникаРасширения(СтрЗаменить(ПолноеИмяОбъекта,"Справочник.",""));
						ЗначениеЭлСоостветствия = Справочники[ИмяДляСоздания].ПолучитьСсылку(УникальныйИдентификатор);
					Иначе
						ЗначениеЭлСоостветствия = ТекКолонкаТабЧасти.Значение
					КонецЕсли;
					НовСтрока[ТекКолонкаТабЧасти.Ключ] = ЗначениеЭлСоостветствия;
				КонецЦикла;
			КонецЦикла;
		КонецЕсли;
	КонецЦикла;
	
	ТекОбъект.Записать();
	Возврат ТекОбъект.Ссылка;
	
КонецФункции