Дублирование значений в полях табличных частей (CTRL+D)

&НаСервере
Функция СоздатьКомандуДублироватьЗначение()
НоваяКоманда = Команды.Добавить("ДублироватьЗначение");
НоваяКоманда.Действие= "ДублироватьЗначение";
НоваяКоманда.Заголовок= "Дублировать значение";
НоваяКоманда.ИзменяетСохраняемыеДанные = ?(найти(нрег(этаформа.ИмяФормы),"обработка")>0,Ложь,Истина);
НоваяКоманда.Отображение= ОтображениеКнопки.Картинка;
НоваяКоманда.Подсказка= "Дублируется значение предыдыущего поля, аналогично Excel. В т.ч. и выделенные строки";
НоваяКоманда.СочетаниеКлавиш= Новый СочетаниеКлавиш(Клавиша.D, , Истина); // Ctrl+D

// Опытным путем выявлено, что вызов команды сочетаниемклавиш не работает без кнопки
// при этом кнопка должна быть на форме, Видимость=Истина
// также замечено, что нажатие сочетанийклавишь активизирует кнопку
// из-за чего ЭтаФорма.ТекущийЭлемент вернет кнопку
// поэтому убираем кнопку в допМеню, этот фокус позволит получить именно текущий элемент
НоваяКнопка=Элементы.Добавить("ДублироватьЗначение",Тип("КнопкаФормы"),ЭтаФорма.КоманднаяПанель);
НоваяКнопка.вид=ВидКнопкиФормы.КнопкаКоманднойПанели;
НоваяКнопка.ИмяКоманды="ДублироватьЗначение";
НоваяКнопка.ПоложениеВКоманднойПанели=ПоложениеКнопкиВКоманднойПанели.ВДополнительномПодменю;
КонецФункции

&НаКлиенте
Функция ДублироватьЗначение()
Если Типзнч(этаформа.ТекущийЭлемент)=Тип("ТаблицаФормы") Тогда //работаем только с таблицами
ИмяТФ=этаформа.ТекущийЭлемент.Имя; // имя ТаблицыФормы
ИмяТЗ=ПолучитьПутьКДанным(ИмяТФ); // имя элемента формы может отличатся от имени реквизита
ТЗнаФорме=Вычислить(ИмяТЗ); // данные формы коллекция
ВыделенныеСтроки=Элементы[ИмяТФ].ВыделенныеСтроки;
// Определяем источник - строка предшествующая первой выделенной
// При удалении, перемещении строк, их идентификатор не меняется, и очень похож на номер строки
// при этом индекс строки меняется
ИндексСтрокиИсточника=9999999;
Для каждого ИдСтроки ИЗ ВыделенныеСтроки Цикл
ИндексСтроки=ТЗнаФорме.Индекс(ТЗнаФорме.НайтиПоИдентификатору(ИдСтроки));
ИндексСтрокиИсточника=?(ИндексСтрокиИсточника>ИндексСтроки,ИндексСтроки,ИндексСтрокиИсточника);
КонецЦикла;
ИндексСтрокиИсточника=ИндексСтрокиИсточника-1;

Если ИндексСтрокиИсточника>=0 Тогда
// опять же, имя элемента формы может отличатся от имени реквизита
// при этом ПутьКДанным колонки содержит и ПутьКДанным таблицы, исключаем
// обращатся к колонке по индексу также не стоит, т.к. порядок на форме может отличаться от порядка реквизитов
ИмяТекКолонки=стрзаменить(ПолучитьПутьКДанным(Элементы[ИмяТФ].ТекущийЭлемент.Имя),""+ИмяТЗ+".","");

ЗначениеИсточника=ТЗнаФорме[ИндексСтрокиИсточника][ИмяТекКолонки];

Для Каждого СтрТЧ ИЗ ВыделенныеСтроки Цикл
// ВыделенныеСтроки хранит не индекс строк, а их иденитфикаторы
// при удалении строк из середины обновляется индекс, но не номер строки
ТЗнаФорме.НайтиПоИдентификатору(СтрТЧ)[ИмяТекКолонки]=ЗначениеИсточника;
КонецЦикла;
Элементы[ИмяТФ].Обновить(); //обновляем данные в ТаблицеФормы
КонецЕсли;
КонецЕсли;
КонецФункции

&НаСервере
Функция ПолучитьПутьКДанным(ИмяЭлемента)
Возврат(Элементы[ИмяЭлемента].ПутьКДанным);
КонецФункции
 

&НаСервере
Функция СоздатьКомандуДублироватьЗначение()
	НоваяКоманда = Команды.Добавить("ДублироватьЗначение");
	НоваяКоманда.Действие= "ДублироватьЗначение";
	НоваяКоманда.Заголовок= "Дублировать значение";
	НоваяКоманда.ИзменяетСохраняемыеДанные = ?(найти(нрег(этаформа.ИмяФормы),"обработка")>0,Ложь,Истина);
	НоваяКоманда.Отображение= ОтображениеКнопки.Картинка;
	НоваяКоманда.Подсказка= "Дублируется значение предыдыущей ячейки, аналогично Excel. В т.ч. и выделенные строки";
	НоваяКоманда.СочетаниеКлавиш= Новый СочетаниеКлавиш(Клавиша.D, , Истина); // Ctrl+D
	
	// Опытным путем выявлено, что вызов команды сочетаниемклавиш не работает без кнопки
	// при этом кнопка должна быть на форме, Видимость=Истина
	// также замечено, что нажатие сочетанийклавишь активизирует кнопку
	// из-за чего ЭтаФорма.ТекущийЭлемент вернет кнопку
	// поэтому убираем кнопку в допМеню, этот фокус позволит получить именно текущий элемент
	НоваяКнопка=Элементы.Добавить("ДублироватьЗначение",Тип("КнопкаФормы"),ЭтаФорма.КоманднаяПанель);
	НоваяКнопка.вид=ВидКнопкиФормы.КнопкаКоманднойПанели;
	НоваяКнопка.ИмяКоманды="ДублироватьЗначение";
	НоваяКнопка.ПоложениеВКоманднойПанели=ПоложениеКнопкиВКоманднойПанели.ВДополнительномПодменю;
КонецФункции

&НаКлиенте
Функция ДублироватьЗначение()
	Если Типзнч(этаформа.ТекущийЭлемент)=Тип("ТаблицаФормы") Тогда     //работаем только с таблицами
		ИмяТФ=этаформа.ТекущийЭлемент.Имя;	// имя ТаблицыФормы
		ЭлементТФ=Элементы[ИмяТФ];
		ИмяТЗ=ПолучитьПутьКДанным(ИмяТФ);	// имя элемента формы может отличатся от имени реквизита
		ТЗнаФорме=Вычислить(ИмяТЗ);	// данные формы коллекция
		ВыделенныеСтроки=ЭлементТФ.ВыделенныеСтроки; // сохраняем выделенные строки

		// Определяем источник - строка предшествующая первой выделенной 
		// При удалении, перемещении строк, их идентификатор не меняется, и очень похож на номер строки
		// при этом индекс строки меняется
		ИндексСтрокиИсточника=9999999;
		Для каждого ИдСтроки ИЗ ВыделенныеСтроки Цикл
			ИндексСтроки=ТЗнаФорме.Индекс(ТЗнаФорме.НайтиПоИдентификатору(ИдСтроки));
			ИндексСтрокиИсточника=?(ИндексСтрокиИсточника>ИндексСтроки,ИндексСтроки,ИндексСтрокиИсточника);
		КонецЦикла;                                 
		ИндексСтрокиИсточника=ИндексСтрокиИсточника-1;
		
		Если ИндексСтрокиИсточника>=0 Тогда
			// опять же, имя элемента формы может отличатся от имени реквизита
			// при этом ПутьКДанным колонки содержит и ПутьКДанным таблицы, исключаем
			// обращатся к колонке по индексу также не стоит, т.к. порядок на форме может отличаться от порядка реквизитов
			ИмяТекКолонки=стрзаменить(ПолучитьПутьКДанным(ЭлементТФ.ТекущийЭлемент.Имя),""+ИмяТЗ+".","");

			// На форме может быть выведен реквизит объекта из другой колонки, исключаем такие варианты
			Если СтрНайти(ИмяТекКолонки,".")>0 Тогда
				Возврат(Ложь);
			Иначе
				ЗначениеИсточника=ТЗнаФорме[ИндексСтрокиИсточника][ИмяКолонкиТЗ];		
			КонецЕсли;

			ТекЭлемент=ЭлементТФ.ТекущийЭлемент; //сохраняем текущий элемент (колонка)
			ЭлементТФ.ТекущаяСтрока=0; //сбрасываем текущую строку, получили интересный эффект, если выделить несколько строк сверху вниз, то верхняя не изменяет значение О_О

			Для Каждого СтрТЧ ИЗ ВыделенныеСтроки Цикл
				// ВыделенныеСтроки хранит не индекс строк, а их иденитфикаторы
				// при удалении строк из середины обновляется индекс, но не номер строки
				ЭлементТФ.ТекущаяСтрока=СтрТЧ;
				ЭлементТФ.ТекущийЭлемент=ТекЭлемент;
				ЭлементТФ.ИзменитьСтроку();
				ИнтерактивноЗаписатьВЭлементУправленияЛкс(ЭлементТФ.ТекущийЭлемент, ЗначениеИсточника, ЭтаФорма);
				ЭлементТФ.ЗакончитьРедактированиеСтроки(Ложь);
			КонецЦикла;
		КонецЕсли;
	КонецЕсли;		
КонецФункции
&НаСервере
Функция ПолучитьПутьКДанным(ИмяЭлемента)
	Возврат(Элементы[ИмяЭлемента].ПутьКДанным);
КонецФункции

// Интерактивно записывает значение в элемент управления. Интерактивность заключается в срабатывании
// события ПриИзменении у элемента управления.
// //infostart.ru/1c/articles/16985/
//
// Параметры:
//  ЭлементУправления – ЭлементУправления – которому присваиваем значение;
//  Значение     – Произвольный – присваиваемое значение;
//  *ФормаИнициатор - Форма, УправляемаяФорма, *Неопределено - которая будет использована в качестве инициатора события;
//
&НаКлиенте
Функция ИнтерактивноЗаписатьВЭлементУправленияЛкс(ЭлементУправления, Знач Значение, Знач ФормаИнициатор = Неопределено) Экспорт
	
	СтарыйВладелец = ФормаИнициатор.ВладелецФормы;
	СтарыйЗакрыватьПриВыборе = ФормаИнициатор.ЗакрыватьПриВыборе;
	ФормаИнициатор.ВладелецФормы = ЭлементУправления;
	ФормаИнициатор.ЗакрыватьПриВыборе = Ложь;
	НовоеЗначение = ЭлементУправления.ОграничениеТипа.ПривестиЗначение(Значение);
	Если НовоеЗначение <> Значение Или ЭлементУправления.ТолькоПросмотр Тогда
		Возврат Ложь;
	КонецЕсли; 
	ФормаИнициатор.ОповеститьОВыборе(Значение); 
	Если СтарыйЗакрыватьПриВыборе <> Неопределено Тогда
		ФормаИнициатор.ВладелецФормы = СтарыйВладелец;
		ФормаИнициатор.ЗакрыватьПриВыборе = СтарыйЗакрыватьПриВыборе;
	КонецЕсли;
	
КонецФункции // ИнтерактивноЗаписатьВЭлементУправленияЛкс()

&НаСервере
Процедура ДЗ_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
		ДЗ_ОсновнойМодульСервер.СоздатьКомандуДублироватьЗначение(ЭтаФорма);
КонецПроцедуры

&НаКлиенте
Процедура ДублироватьЗначение()
	ДЗ_ОсновнойМодульКлиент.ДублироватьЗначение(ЭтаФорма);
КонецПроцедуры

&НаКлиенте
Функция ПолучитьЗначениеИсточника() Экспорт
	Возврат(ПолучитьЗначениеИсточникаСервер());
КонецФункции

&НаСервере
Функция ПолучитьЗначениеИсточникаСервер() 
	Возврат(ДЗ_ОсновнойМодульСервер.ПолучитьЗначениеСтрокойВыше(Объект,ЭтаФорма));
КонецФункции