Запись значения в поле ввода/формы со срабатыванием события ПриИзменении
Разработка - Универсальные функции
Для максимальной универсальности нужно создать пустую форму, разумнее всего общую. Назовем ее "Пустышка".
Вот 2 метода с поддержкой обычных и управляемых форм, решающие задачу.
// Интерактивно записывает значение в элемент управления. Интерактивность заключается в срабатывании
// события ПриИзменении у элемента управления.
// Для управляемой целевой формы требуется открытость (видимость), а для обычной не требуется.
// В управляемой форме не сработает внутри обработки события ПриИзменении поля формы. Иногда это допустимо обойти через обработчик ожидания.
//
// Параметры:
// ЭлементУправления – ЭлементУправления – которому присваиваем значение;
// Значение – Произвольный – присваиваемое значение;
// ФормаИнициатор - Форма, УправляемаяФорма - которая будет использована в качестве инициатора события;
// если не указана, то будет создана временная форма-пустышка.
//
Функция ИнтерактивноЗаписатьВЭлементУправленияЛкс(ЭлементУправления, Знач Значение, Знач ФормаИнициатор = Неопределено) Экспорт
Если ФормаИнициатор = Неопределено Тогда
ФормаИнициатор = ПолучитьОбщуюФорму("Пустышка", ЭлементУправления);
Иначе
СтарыйВладелец = ФормаИнициатор.ВладелецФормы;
СтарыйЗакрыватьПриВыборе = ФормаИнициатор.ЗакрыватьПриВыборе;
ФормаИнициатор.ВладелецФормы = ЭлементУправления;
ФормаИнициатор.ЗакрыватьПриВыборе = Ложь;
КонецЕсли;
НовоеЗначение = ЭлементУправления.ОграничениеТипа.ПривестиЗначение(Значение);
Если НовоеЗначение <> Значение Или ЭлементУправления.ТолькоПросмотр Тогда
Возврат Ложь;
КонецЕсли;
ФормаИнициатор.ОповеститьОВыборе(Значение);
Если СтарыйЗакрыватьПриВыборе <> Неопределено Тогда
ФормаИнициатор.ВладелецФормы = СтарыйВладелец;
ФормаИнициатор.ЗакрыватьПриВыборе = СтарыйЗакрыватьПриВыборе;
КонецЕсли;
КонецФункции
// Интерактивно записывает значение в элемент управления (только поле ввода/формы) колонки табличного поля или таблицы формы.
// Интерактивность заключается в срабатывании события ПриИзменении у элемента управления.
// Строка табличного поля или таблицы формы должна находиться в режиме редактирования,
// иначе никаких изменений данных не произойдет.
//
// Параметры:
// ТабличноеПоле - ТабличноеПоле, ТаблицаФормы - внутри него строка редактируется;
// Колонка – КолонкаТабличногоПоля, ПолеФормы – в ее ячейку будем помещать значение;
// Значение – Произвольный – присваиваемое значение;
// ФормаИнициатор - Форма, УправляемаяФормы - которая будет использована в качестве инициатора события;
// если не указана, то будет создана временная форма-пустышка;
// ВосстанавитьТекущуюКолонку – Булево
// ВключитьРежимРедактирования – Булево
//
Процедура ИнтерактивноЗаписатьВКолонкуТабличногоПоляЛкс(ТабличноеПоле, Знач Колонка, Знач Значение, Знач ФормаИнициатор = Неопределено,
Знач ВосстанавитьТекущуюКолонку = Истина, Знач ВключитьРежимРедактирования = Истина) Экспорт
Если ТипЗнч(Колонка) = Тип("ПолеФормы") Тогда
ЭлементУправления = Колонка;
Иначе
ЭлементУправления = Колонка.ЭлементУправления;
Если ТипЗнч(ЭлементУправления) <> Тип("ПолеВвода") Тогда
ЭлементУправления = Неопределено;
КонецЕсли;
КонецЕсли;
Если ЭлементУправления <> Неопределено Тогда
Если ВосстанавитьТекущуюКолонку Тогда
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
СтараяТекущаяКолонка = ТабличноеПоле.ТекущийЭлемент;
Иначе
СтараяТекущаяКолонка = ТабличноеПоле.ТекущаяКолонка;
КонецЕсли;
КонецЕсли;
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
ТабличноеПоле.ТекущийЭлемент = Колонка;
Иначе
ТабличноеПоле.ТекущаяКолонка = Колонка;
КонецЕсли;
Если ВключитьРежимРедактирования Тогда
ТабличноеПоле.ИзменитьСтроку();
КонецЕсли;
ИнтерактивноЗаписатьВЭлементУправленияЛкс(ЭлементУправления, Значение, ФормаИнициатор);
Если ВключитьРежимРедактирования Тогда
ТабличноеПоле.ЗакончитьРедактированиеСтроки(Ложь);
КонецЕсли;
Если ВосстанавитьТекущуюКолонку Тогда
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
ТабличноеПоле.ТекущийЭлемент = СтараяТекущаяКолонка;
Иначе
ТабличноеПоле.ТекущаяКолонка = СтараяТекущаяКолонка;
КонецЕсли;
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Если в контексте доступна какая то форма, то лучше ее передать в качестве параметра ФормаИнициатор, т.к. это будет быстрее, чем создавать каждый раз форму-пустышку.
Скорость изменения данных таким путем естественно будет заметно ниже, чем при прямой записи в данные, с которыми связан элемент управления, с вызовом обработчика.
Хочу заметить, что подобная техника не зря большей частью "закрыта" от разработчика. Ведь программное оперирование с интерактивными событиями требует хорошей обработки всех возможных ситуаций внутри обработчиков. Например, вы можете вызвать рекурсивный цикл интерактивных событий или просто исключительную ситуацию уровня приложения. Поэтому как можно тщательнее имитируйте действия пользователя с проверкой всех возможных ситуаций. И не прибегайте к таким приемам без необходимости.
Вступайте в нашу телеграмм-группу Инфостарт
ПриИзменении полеВвода полеФормы
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
Универсальные функции 1С 8.3 1С:Документооборот Россия Платные (руб)
ДО+ — расширение конфигурации, в котором собран постоянно пополняемый набор из 33 востребованных доработок для 1С:Документооборот КОРП 3.0: согласование задач прямо из мессенджеров MAX и Telegram, отзыв согласования и исполнения, гибкие повторные круги, эскалация с точностью до минут, контроль исполнительской дисциплины, выгрузка вложений в ZIP и склейка PDF, реестр документов в Excel, проверка дублей контрагентов и регистрационных номеров. Каждая возможность активируется отдельным флажком в режиме предприятия — включается только то, что нужно конкретной организации. Список функций расширяется с каждым релизом — текущая версия 2.1.0. Режим AddOn: типовая конфигурация не модифицируется, обновления ДО ставятся штатно, дополнительные лицензии и внешние компоненты не требуются. Внедрение силами администратора — около часа.
30000 руб.
09.07.2026 1482 1 0
Загрузка и выгрузка в Excel Универсальные функции Разработчик 1С:Предприятие 8 Россия Бесплатно (free)
Описанный ниже подход позволяет в три шага заполнять формулы в Excel файлы, вне зависимости от ОС сервера (MS Windows Server или Linux). Подход подразумевает отказ от работы с COM-объектом в пользу работы через "объектную модель документа" (DOM).
30.10.2025 8844 Abysswalker 11
Универсальные функции Работа с интерфейсом Разработчик 1С:Предприятие 8 Бесплатно (free)
Порой необходимо временно отключить расширение 1С, не удаляя его, чтобы не потерять данные. Но в этом случае при каждом запуске всем будет лезть уведомление о неактивном расширении, хотя очевидно, это техническая информация, которой не стоит лишний раз пугать пользователей.
14.05.2025 14633 DeerCven 16
Инструментарий разработчика Универсальные функции Запросы Разработчик 1С:Предприятие 8 1C:Бухгалтерия 1С:Бухгалтерия 3.0 1С:Зарплата и Управление Персоналом 3.x Бесплатно (free)
Внешняя обработка для создания запроса на основании табличных данных.
22.07.2024 12014 278 ixijixi 10
Универсальные функции Разработчик 1С:Предприятие 8 1C:Бухгалтерия Бесплатно (free)
Благодаря этим пяти строчкам можно больше не заморачиваться с загрузкой из внешних файлов. Пользуюсь везде, всегда и постоянно.
21.05.2024 69058 dimanich70 87
Универсальные функции Разработчик 1С:Предприятие 8 1C:Бухгалтерия Абонемент ($m)
Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.
1 стартмани
18.03.2024 9367 7 John_d 13
Универсальные функции Разработчик Стажер 1С:Предприятие 8 1C:Бухгалтерия Бесплатно (free)
Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.
12.02.2024 86076 atdonya 31
Универсальные функции Разработчик 1С:Предприятие 8 Бесплатно (free)
На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.
30.11.2023 13538 ke.92@mail.ru 18
установить текущую строку и текущую колонку и выполнить ИзменитьСтроку()?
извените. просто не смог запустить:) проблема оказалась в том что форма должна быть открыта:(
у меня только одна идея эмуляция ctrl+enter, но чтот не гут так извращаться
Делаю так:
ФормаДок.Элементы.Товары.ТекущаяСтрока = 0;
Получилось в качестве колонки пока только это скормить: ФормаДок.Товары.ПодчиненныеЭлементы.ТоварыЦенаСоСкидкой Но значение на форме не появилось
Процедура ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля(ТабличноеПоле, Колонка, Значение, ФормаИнициатор = Неопределено) Экспорт
ТабличноеПоле.ТекущаяКолонка = Колонка;
ТабличноеПоле.ИзменитьСтроку();
ЛксИнтерактивноЗаписатьВЭлементУправления(Колонка.ЭлементУправления, Значение, ФормаИнициатор);
КонецПроцедуры
Показать&НаКлиенте
Процедура ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля(ТабличноеПоле, Колонка, Значение, ФормаИнициатор = Неопределено) Экспорт
ТабличноеПоле.ТекущийЭлемент = Колонка;
ЛксИнтерактивноЗаписатьВЭлементУправления(ТабличноеПоле.ТекущийЭлемент, Значение, ФормаИнициатор);
КонецПроцедуры // ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля()
Сделал обработку с полями Партнер, Номенклатура и командой выполнить:
&НаКлиенте
Процедура Заполнить(Команда)
Форма = ОткрытьФорму("Документ.РеализацияТоваровУслуг.ФормаОбъекта");
Форма.ЛксИнтерактивноЗаписатьВЭлементУправления(Форма.Элементы.Партнер, Партнер, ЭтаФорма);
Форма.Элементы.Товары.ДобавитьСтроку();
Форма.ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля(Форма.Элементы.Товары, Форма.Элементы.Товары.ПодчиненныеЭлементы.ТоварыНоменклатура, Номенклатура, ЭтаФорма); //Форма.Элементы.ТоварыНоменклатура
Форма.ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля(Форма.Элементы.Товары, Форма.Элементы.Товары.ПодчиненныеЭлементы.ТоварыЦена, 100, ЭтаФорма); //Форма.Элементы.ТоварыЦена
Форма.ЛксИнтерактивноЗаписатьВКолонкуТабличногоПоля(Форма.Элементы.Товары, Форма.Элементы.Товары.ПодчиненныеЭлементы.ТоварыКоличествоУпаковок, 100, ЭтаФорма);
КонецПроцедуры
ПоказатьВ результате на форме заполнилось: Партнер,Контрагент
Номенклатура - пустое поле, Цена=100,Количество=100,Сумма=10 000.
Мне не понятен момент почему не заполнилась Номенклатура и не сработало событие "ПриИзменении", ведь для "Цены" и "Количества" это событие сработало.
Хотя воспроизвел, в чистой базе создал документ "РеализациятоваровУслуг" с Партнером и табличной частью Номенклатура,НоменклатураНаименование-строка, Цена, Количество, Сумма
сделал обработчики событий для Номенклатуры при изменении заполняется поле НоменклатураНаименование, для Цены и Количества обработчики при изменении расчета Суммы.
Запустил эту обработку НоменклатураНаименование заполнилось и сумма рассчиталась. Все обработчики событий сработали.
Странно, почему в УТ 11.2 не отработало
ИнтерактивноЗаписатьВКолонкуТабличногоПоляЛкс(ВладелецФормы.Элементы.Сотрудники,ВладелецФормы.Элементы.Сотрудники.ПодчиненныеЭлементы.СотрудникиКоличествоДней,10,,Ложь);и вылетает с дампом...
Причем вызов Тип("КолонкаТабличногоПоля") платформу не валит, выдается исключение, что тип не найден.
Переделал проверку, на Тип("ТаблицаФормы"), который доступен и в толстом, и в тонком - заработало.
Процедура ИнтерактивноЗаписатьВКолонкуТабличногоПоляЛкс(ТабличноеПоле, Знач Колонка, Знач Значение, Знач ФормаИнициатор = Неопределено,
Знач ВосстанавитьТекущуюКолонку = Истина, Знач ВключитьРежимРедактирования = Истина) Экспорт
Если ТипЗнч(Колонка) = Тип("ПолеФормы") Тогда
ЭлементУправления = Колонка;
Иначе
ЭлементУправления = Колонка.ЭлементУправления;
Если ТипЗнч(ЭлементУправления) <> Тип("ПолеВвода") Тогда
ЭлементУправления = Неопределено;
КонецЕсли;
КонецЕсли;
Если ЭлементУправления <> Неопределено Тогда
Если ВосстанавитьТекущуюКолонку Тогда
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
СтараяТекущаяКолонка = ТабличноеПоле.ТекущийЭлемент;
Иначе
СтараяТекущаяКолонка = ТабличноеПоле.ТекущаяКолонка;
КонецЕсли;
КонецЕсли;
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
ТабличноеПоле.ТекущийЭлемент = Колонка;
Иначе
ТабличноеПоле.ТекущаяКолонка = Колонка;
КонецЕсли;
Если ВключитьРежимРедактирования Тогда
ТабличноеПоле.ИзменитьСтроку();
КонецЕсли;
ИнтерактивноЗаписатьВЭлементУправленияЛкс(ЭлементУправления, Значение, ФормаИнициатор);
Если ВключитьРежимРедактирования Тогда
ТабличноеПоле.ЗакончитьРедактированиеСтроки(Ложь);
КонецЕсли;
Если ВосстанавитьТекущуюКолонку Тогда
Если ТипЗнч(ТабличноеПоле) = Тип("ТаблицаФормы") Тогда
ТабличноеПоле.ТекущийЭлемент = СтараяТекущаяКолонка;
Иначе
ТабличноеПоле.ТекущаяКолонка = СтараяТекущаяКолонка;
КонецЕсли;
КонецЕсли;
КонецЕсли;
КонецПроцедуры ПоказатьПоясню: есть у меня в УТ 11.4 документ Заявка на возврат товаров от клиента. Я добавил кнопку, по нажатию которой в ТЧ Возвращаемые товары и в ТЧ Заменяющие товары должны упасть одни и те же товары. А выполнить обработчик ПриИзменении мне нужно для колонки Номенклатура, причем для каждой ТЧ этой свой обработчик. Взял код отсюда, а он то работает, то нет. Поэтому пришлось программно менять текущую страницу, чтобы обработчики срабатывали.
Так что если у вас есть такие же проблемы, стоит уточнить этот момент.
P.S. ТаблицаФормы.ИзменитьСтроку() сработает только в том случае, если ТаблицаФормы.ТекущаяСтрока <> Неопределено. Если планируется добавлять строку в объект программно, нужно сперва эту строку установить, например:
Строка = Форма.Объект[ИмяТаблицы].Добавить();
ТаблицаФормы.ТекущаяСтрока = Строка.ПолучитьИдентификатор();
Эксперементирую в Управлении торговлей 11.4, УФ
Суть. Заранее имя формы не известно, но известно что она открыта у пользователя. Тип документа тоже не известен.
В качестве примера примем его как форму документа "Приобретение товаров и услуг"
Я пишу такую процедуру (см.ниже) во внешней обработке. Это простейший пример, все переменные заданы напрямую.
Она сканирует открытые окна, и если находит наш пример, работает с ним.
Задача. Получить значение в столбце "Сумма" - в обработке мы указываем цену и количество.
Ну вот не выходит аленькай цветок. ЧЯДНТ? Спс!!
&НаКлиенте
Процедура ТестИнфостарт()
ОкнаПриложения = ПолучитьОкна();
Форма = Неопределено;
Для Каждого Строка Из ОкнаПриложения Цикл
Если Лев(Строка.Заголовок, 29) = "Приобретение товаров и услуг " Тогда
Для Каждого Строка2 Из Строка.Содержимое Цикл
Если ТипЗнч(Строка2) = Тип("ФормаКлиентскогоПриложения") Тогда
Форма = Строка2;
Прервать;
КонецЕсли;
КонецЦикла;
Прервать;
КонецЕсли;
КонецЦикла;
Если Форма = Неопределено Тогда
Возврат;
КонецЕсли;
нСтр = Форма.Объект.Товары.Добавить();
Форма.Элементы.Товары.ТекущаяСтрока = нСтр.ПолучитьИдентификатор();
Форма.Элементы.Товары.ТекущийЭлемент = Форма.Элементы.Товары.ПодчиненныеЭлементы.Найти("ТоварыКоличествоУпаковок");
Форма.Элементы.Товары.ИзменитьСтроку();
нСтр.КоличествоУпаковок = 14.123;
Форма.Элементы.Товары.ТекущийЭлемент = Форма.Элементы.Товары.ПодчиненныеЭлементы.Найти("ТоварыЦенаЗаказа");
Форма.Элементы.Товары.ИзменитьСтроку();
нСтр.Цена = 154.321;
Форма.ТекущийЭлемент = Форма.Элементы.Товары;
Форма.Активизировать();
//пробовал, ессно, и из приведенных в шапке процедур, но тут вообще я запутался чаго куда передавать..
ИнтерактивноЗаписатьВКолонкуТабличногоПоляЛкс(Форма.Объект.Товары, Форма.Элементы.Товары.ПодчиненныеЭлементы.ТоварыКоличествоУпаковок, 24.123, ЭтаФорма,,Истина);
ИнтерактивноЗаписатьВКолонкуТабличногоПоляЛкс(Форма.Объект.Товары, Форма.Элементы.Товары.ПодчиненныеЭлементы.ТоварыЦенаЗаказа, 254.321, ЭтаФорма,,Истина);
КонецПроцедуры Показатьт.е. в моем случае перед добавлением строки должны стоять строки:
Форма.Активизировать();
Форма.ТекущийЭлемент = Форма.Элементы.Товары;
нСтр = Форма.Объект.Товары.Добавить();
.....Выше давали информацию, что надо активизировать вкладку. Это пробовал. Но не допер до активизации формы в самом начале.. - в большинстве случаев это своя же форма, потому в глаза не бросается. А вот когда берешь другую не активную.. ..
И еще. Не забываем завершать редактирование строки, а то так и остаемся в последнем поле без выхода из него:
Форма.Элементы.Товары.ЗакончитьРедактированиеСтроки(Ложь);Форма = ОткрытьФорму("Документ.ОказаниеУслуг.ФормаОбъекта", Новый Структура("Ключ", СсылкаНаДокумент));
Форма.Активизировать();
Форма.ТекущийЭлемент = Форма.Элементы.Работы;
Для Каждого СтрокаТЗ Из Форма.Объект.Работы Цикл
ИдентификаторСтроки = СтрокаТЗ.ПолучитьИдентификатор();
Форма.Элементы.Работы.ТекущаяСтрока = ИдентификаторСтроки;
Форма.Элементы.Работы.ТекущийЭлемент =
Форма.Элементы.Работы.ПодчиненныеЭлементы.Цена;
Форма.Элементы.Работы.ИзменитьСтроку();
// следующую процедуру взял 1в1 из сообщения автора, только закомментил строку ...ПолучитьОбщуюФорму("Пустышка"...
// 1000 - устанавливаемая цена
ИнтерактивноЗаписатьВЭлементУправленияЛкс(Форма.Элементы.Работы.ТекущийЭлемент, 1000, ЭтаФорма)
Форма.Элементы.Работы.ЗакончитьРедактированиеСтроки(Ложь);
Форма.Записать(Новый Структура("РежимЗаписи", РежимЗаписиДокумента.Проведение));
Форма.Закрыть();
КонецЦикла; Показать // Если тек.строка не установлена - значение все равно не установится (и вылетит по ошибке на "ТабличноеПоле.ИзменитьСтроку()")!..
Если ТабличноеПоле.ТекущаяСтрока = Неопределено Тогда Возврат КонецЕсли;
Любят 1С - ники делать расчеты в форме а не в объекте ц..ко!! Причем и на клиенте и на сервере
Взять хотя бы документ "Отпуск" из ЗУП 3.1 Это ЖЕСТЬ!!!!
Мало того что в форме сотни функций и несколько тысяч строк кода который весь выполняется, так еще форма эта гуляет по столькой же куче общих модулей, и там тоже чего - то рассчитывается. Причем не всегда можно сымитировать форму (я создал структуру "Форма" с идентичными реквизитами и таблицами значений), так там нужен именно тип "Форма клиентского приложения". Короче пришлось дергать процедуры из общего модуля в расширение... получилось больше 10 тыщ строк кода. И первое же обновление релиза разрушило все мои труды)))))))
Поэтому именно дергать событие и никак иначе
Иначе каждый релиз новый будешь дрчиться с изменениями в своем расширении)))))
В управляемой форме не сработает внутри обработки события ПриИзменении поля формы. Иногда это допустимо обойти через обработчик ожидания.
ЗУП, 8.3, УФ.
Мне нужно программно изменить значение одного реквизита основной части, чтобы для него выполнилась ПриИзменении.
Вот так примерно написал процедуру:
&НаКлиенте
Процедура ОбновитьРекв(Команда)
ТекДок=Объект.Документ;
Форма = ОткрытьФорму("Документ.Отпуск.ФормаОбъекта", Новый Структура("Ключ", ТекДок));
Форма.Активизировать();
Форма.Элементы.ПорядокВыплаты=Объект.СпособОпл;
//ИнтерактивноЗаписатьВЭлементУправленияЛкс(Форма.Элементы.Работы.ТекущийЭлемент, 1000, ЭтаФорма);
Форма.Элементы.ПорядокВыплаты.ЗакончитьРедактированиеСтроки(Ложь);
Форма.Записать(Новый Структура("РежимЗаписи", РежимЗаписиДокумента.Проведение));
//Форма.Закрыть();
КонецПроцедуры ПоказатьПолучаю ошибку:
Поле объекта недоступно для записи (ПорядокВыплаты)
{ВнешняяОбработка.ПроверкаПриИзменении.Форма.Форма.Форма(6)}:Форма.Элементы.ПорядокВыплаты=Объект.СпособОпл;
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 16985
Создание 11.07.07 00:00
Обновление 29.01.26 09:02
Просмотры 74029
Загрузки 0
Рейтинг
151
Комментарии 59
Код открыт Да
Рубрики Универсальные функции
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация Универсальные
Операционная система Не имеет значения
Страна Россия
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)