Предыстория данной темы такова: заказчик потребовал, чтобы в отчёте, создаваемом по документу «Поступления товаров и услуг», каждая позиция номенклатуры печаталась в строках столько раз, сколько ожидается приходов палет. То есть если товар прибудет на трёх палетах, то строк с этим товаром должно быть три. Если на четырёх – четыре и т.д. Для того, чтобы посчитать количество палет, у каждой номенклатурной позиции ввели свойство «Количество на палете». Соответственно разделив общее количество пришедшего товара на значение, указанное в этом свойстве, получим количество палет. Причём остаток деления означает ещё плюс одну палету.
Походив по различным форумам, всё больше натыкался на решения в виде «Цикл внутри цикла» или «Результат запроса обработать и положить в результирующую таблицу». Ни одни из этих вариантов не устраивал, так как хотелось данные получить одним запросом, дабы использовать оные в отчете построенном с помощью СКД.
Отличным решением в данном случае являлось то, что в запросе при левом соединении можно увеличить количество строк, если одной строке левого запроса соответствует два и более (сколько потребуется) строк правого запроса. Пример данного запроса приведён ниже:
ВЫБРАТЬ
0 КАК Цифра
ПОМЕСТИТЬ ТабЦифр
ОБЪЕДИНИТЬ
ВЫБРАТЬ
1
ОБЪЕДИНИТЬ
ВЫБРАТЬ
2
ОБЪЕДИНИТЬ
ВЫБРАТЬ
3
ОБЪЕДИНИТЬ
ВЫБРАТЬ
4
ОБЪЕДИНИТЬ
ВЫБРАТЬ
5
ОБЪЕДИНИТЬ
ВЫБРАТЬ
6
ОБЪЕДИНИТЬ
ВЫБРАТЬ
7
ОБЪЕДИНИТЬ
ВЫБРАТЬ
8
ОБЪЕДИНИТЬ
ВЫБРАТЬ
9
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ТабЦифр1.Цифра + 10 * ТабЦифр2.Цифра + 100 * ТабЦифр3.Цифра + 1000 * ТабЦифр4.Цифра КАК СтрокаЧисла
ПОМЕСТИТЬ ВТМатрица
ИЗ
ТабЦифр КАК ТабЦифр1,
ТабЦифр КАК ТабЦифр2,
ТабЦифр КАК ТабЦифр3,
ТабЦифр КАК ТабЦифр4
ГДЕ
ТабЦифр1.Цифра + 10 * ТабЦифр2.Цифра + 100 * ТабЦифр3.Цифра + 1000 * ТабЦифр4.Цифра <> 0
ИНДЕКСИРОВАТЬ ПО
СтрокаЧисла
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ПоступлениеТоваровУслугТовары.Номенклатура,
ПоступлениеТоваровУслугТовары.Количество,
ЗначенияСвойствОбъектов.Значение,
ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2))) КАК КолВоПалет,
ВЫБОР
КОГДА ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2))) - ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2)))) > 0
ТОГДА ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2)))) + 1
ИНАЧЕ ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2))))
КОНЕЦ КАК КолВоСтрок
ПОМЕСТИТЬ ВТСписокСтрокПоступления
ИЗ
Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ПО ПоступлениеТоваровУслугТовары.Номенклатура = ЗначенияСвойствОбъектов.Объект
ГДЕ
ЗначенияСвойствОбъектов.Свойство = &Свойство
И ПоступлениеТоваровУслугТовары.Ссылка = &Ссылка
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТСписокСтрокПоступления.Номенклатура,
ВТСписокСтрокПоступления.Количество,
ВТСписокСтрокПоступления.Значение КАК НаПалете,
ВТСписокСтрокПоступления.КолВоПалет,
ВТСписокСтрокПоступления.КолВоСтрок,
ВТМатрица.СтрокаЧисла
ИЗ
ВТСписокСтрокПоступления КАК ВТСписокСтрокПоступления
ЛЕВОЕ СОЕДИНЕНИЕ ВТМатрица КАК ВТМатрица
ПО ВТСписокСтрокПоступления.КолВоСтрок >= ВТМатрица.СтрокаЧисла
В первых двух временных таблицах формируется матрица строк от 0 до 10 000. При желании матрицу можно сделать и меньше, если предполагается, что количество палет не может быть более 100.
Результат запроса приведён на скрине:
Колонки:
Номенклатура – элемент справочника Номенклатура
Количество – количество товара, пришедшее по документу
НаПалете – значение свойства «Количество на палете»
КолВоПалет – результат деления количества из документа на количество на палете
СтрокаЧисла – строка из матрицы чисел.
КолВоСтрок – результат деления количества из документа на количество на палете с добавлением единицы в случае, если есть остаток от деления (то есть нужен ещё один палет)
ВЫБОР КОГДА ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2))) - ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2)))) > 0 ТОГДА ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2)))) + 1 ИНАЧЕ ЦЕЛ(ПоступлениеТоваровУслугТовары.Количество / (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(15, 2)))) КОНЕЦ КАК КолВоСтрок
Главная связь в данном запросе показана в результирующей его части. Главное в полях, по которым идёт соединение табличной части документа и матрицы чисел, должно быть условие «Больше или равно». То есть соединить позиции номенклатуры со всеми строками, удовлетворяющими данному условию.
По сути дела во временной таблице «ВТСписокСтрокПоступления» должно быть как минимум два поля: Номенклатура и КолВоСтрок – определяющая, сколько раз требуется повторить строки с одной и той же товарной позицией.
Вступайте в нашу телеграмм-группу Инфостарт