Уведомления о неактивных расширениях формируются на уровне платформы, и в 1C нет описанных механизмов работы с ними, однако удалось зацепиться за встроенную функцию "ПолучитьСообщенияПользователю()", в которую оказывается попадают тексты уведомлений. При запуске она содержит тексты о неактивных расширениях в виде сообщений пользователю. Очистив которые, пропадают и уведомления.
В результате было найдено решение:
Процедура ОтключитьОповещенияОНеактивныхРасширениях()
ИсходныеСообщения = ПолучитьСообщенияПользователю();
ПолучитьСообщенияПользователю(Истина); // Очищаем сообщения пользователю
ИменаРасширений = Новый Массив;
ИменаРасширений.Добавить("Имя: СинонимРасширения1");
ИменаРасширений.Добавить("Имя: СинонимРасширения2");
ИменаРасширений.Добавить("Имя: СинонимРасширения3");
ОтобранныеСообщения = Новый Массив;
// Отбираем сообщения не содержащие указанные расширения
Для каждого Сообщение Из ИсходныеСообщения Цикл
СообщениеСодержитИмяРасширения = Ложь;
Для каждого ИмяРасширения Из ИменаРасширений Цикл
Если СтрНайти(Сообщение.Текст, ИмяРасширения) Тогда
СообщениеСодержитИмяРасширения = Истина;
Прервать;
КонецЕсли;
КонецЦикла;
Если Не СообщениеСодержитИмяРасширения Тогда
ОтобранныеСообщения.Добавить(Сообщение);
КонецЕсли;
КонецЦикла;
// Выводим отобранные сообщения пользователю
Для каждого Сообщение Из ОтобранныеСообщения Цикл
Сообщение.Сообщить();
КонецЦикла;
КонецПроцедуры
Данная процедура удаляет только уведомления об указанных нами расширениях и оставляет все остальные, например если активное расширение не применилось из-за конфликта. Имена расширений указываются в массиве "ИменаРасширений" с префиксом "Имя: " для большей точности, т.к. именно в таком виде они содержатся в тексте сообщения.
Поместить процедуру можно в любой удобный модуль на сервере при запуске. В моем случае положил в расширение в процедуру "СтандартныеПодсистемыСервер.УстановкаПараметровСеанса" с аннотацией "&Перед" и проверкой, чтобы запускалась только 1 раз при запуске:
ПриЗапуске = ИменаПараметровСеанса = Неопределено;
Если ПриЗапуске Тогда
ОтключитьОповещенияОНеактивныхРасширениях();
КонецЕсли;
Таким же образом можно выборочно удалять другие ненужные уведомления.
Тестирование проводилось на платформе 8.3.25.1374 и базе ERP 2.5
Вступайте в нашу телеграмм-группу Инфостарт
