Загрузка физических лиц, паспортных данных физических лиц из excel в ЗУП 3.1.

&НаКлиенте
Процедура ПутьКФайлуНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ДиалогВыбораФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	
	ДиалогВыбораФайла.Показать(Новый ОписаниеОповещения("ПутьКФайлуНачалоВыбораЗавершение", ЭтотОбъект));
	
КонецПроцедуры

&НаКлиенте
Процедура ПутьКФайлуНачалоВыбораЗавершение(ВыбранныеФайлы, ДополнительныеПараметры) Экспорт
	
	Если ВыбранныеФайлы = Неопределено Тогда
		Возврат;
	КонецЕсли;

	ПутьКФайлу = ВыбранныеФайлы[0];
	
КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьДанные(Команда)
	
	ТаблицаСотрудников.Очистить();
	ТаблицаФизическихЛиц.Очистить();
	
	АдресФайла = ПоместитьВоВременноеХранилище(Новый ДвоичныеДанные(ПутьКФайлу));
	
	ЗагрузитьДанныеНаСервере(АдресФайла);	
	
	УдалитьИзВременногоХранилища(АдресФайла);
	
КонецПроцедуры

&НаСервере
Процедура ЗагрузитьДанныеНаСервере(АдресФайла)
	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла("xlsx");
	
	ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресФайла);
	ДвоичныеДанные.Записать(ИмяВременногоФайла);
	
	//Вывод в табличный документ
	
	ТабличныйДокумент = Новый ТабличныйДокумент;
	
	ТабличныйДокумент.Прочитать(ИмяВременногоФайла, СпособЧтенияЗначенийТабличногоДокумента.Значение);
	
	//вывод в таблицу значений
	
	ПЗ = Новый ПостроительЗапроса;
	
	ПЗ.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабличныйДокумент.Область());
	
	ПЗ.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
	
	ПЗ.ЗаполнитьНастройки();
	
	ПЗ.Выполнить();
	
	ТаблицаЗначений = ПЗ.Результат.Выгрузить();	
			
	ФизическиеЛицаЗагрузка(ТаблицаЗначений);
			
	УдалитьФайлы(ИмяВременногоФайла);
	
КонецПроцедуры

&НаСервере
Процедура ФизическиеЛицаЗагрузка(ТаблицаЗначений)
	
	НачатьТранзакцию();
	
	Счетчик = 0;
	
	Для Каждого СтрокаТЗ Из ТаблицаЗначений Цикл
		
		//физические лица		
		ФИО = СокрЛП(СтрокаТЗ.Фамилия) + " " + СокрЛП(СтрокаТЗ.Имя) + " " + СокрЛП(СтрокаТЗ.Отчество);
		ДатаРождения = Дата(СтрокаТЗ.ДатаРождения + " " + "00:00:00");
		
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		|	ФизическиеЛица.Ссылка КАК Ссылка
		|ИЗ
		|	Справочник.ФизическиеЛица КАК ФизическиеЛица
		|ГДЕ
		|	ФизическиеЛица.ФИО = &ФИО
		|	И ФизическиеЛица.ДатаРождения = &ДатаРождения";
		Запрос.УстановитьПараметр("ФИО", ФИО);
		Запрос.УстановитьПараметр("ДатаРождения", ДатаРождения);
		
		Выборка = Запрос.Выполнить().Выбрать();
		
		Если Выборка.Следующий() Тогда
			
			ФизическоеЛицо = Выборка.Ссылка.ПолучитьОбъект();
			
		Иначе
			
			ФизическоеЛицо = Справочники.ФизическиеЛица.СоздатьЭлемент();
			
		КонецЕсли;
		
		ФизическоеЛицо.ФИО = ФИО;
		физическоеЛицо.Наименование = ФИО;
		физическоеЛицо.НаименованиеСлужебное = ВРег(ФИО);
		физическоеЛицо.Фамилия = СокрЛП(СтрокаТЗ.Фамилия);		
		ФизическоеЛицо.Имя = СокрЛП(СтрокаТЗ.Имя);
		ФизическоеЛицо.Отчество = СокрЛП(СтрокаТЗ.Отчество);
		ФизическоеЛицо.Пол = Вычислить("Перечисления.ПолФизическогоЛица." + СокрЛП(СтрокаТЗ.Пол));
		физическоеЛицо.ИНН = СокрЛП(СтрокаТЗ.ИНН);	
		ФизическоеЛицо.ДатаРождения = ДатаРождения;
		физическоеЛицо.СтраховойНомерПФР = СокрЛП(СтрокаТЗ.СтраховойНомерПФР);
		физическоеЛицо.МестоРождения = "0," + СокрЛП(СтрокаТЗ.МестоРождения);
		
		//Данные о адресах, прописке (контактная информация)		
		АдресСтруктура = УправлениеКонтактнойИнформацией.ОписаниеНовойКонтактнойИнформации(Перечисления.ТипыКонтактнойИнформации.Адрес);
		АдресСтруктура.value = СокрЛП(СтрокаТЗ.АдресПоПаспорту);
		АдресСтруктура.country = СтранаГражданства.Наименование;
		АдресСтруктура.countrycode = СтранаГражданства.Код;
		
		//Адрес по прописке {{
		АдресПоПрописке = ФизическоеЛицо.КонтактнаяИнформация.Найти(Справочники.ВидыКонтактнойИнформации.АдресПоПропискеФизическиеЛица,
		"Вид");
		
		Если АдресПоПрописке = Неопределено Тогда
			АдресПоПрописке = ФизическоеЛицо.КонтактнаяИнформация.Добавить();
		КонецЕсли;
		
		АдресПоПрописке.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес;
		АдресПоПрописке.Вид = Справочники.ВидыКонтактнойИнформации.АдресПоПропискеФизическиеЛица;
		АдресПоПрописке.Значение = УправлениеКонтактнойИнформациейСлужебный.СтруктураВСтрокуJSON(АдресСтруктура);
		АдресПоПрописке.Представление = СокрЛП(СтрокаТЗ.АдресПоПаспорту);
		
		ОбъектXDTOКонтактнаяАдрес = РаботаСАдресами.КонвертироватьАдресИзJSONВXML(АдресСтруктура, АдресПоПрописке.Представление);
		ЗаписьXML = Новый ЗаписьXML;
		ЗаписьXML.УстановитьСтроку();
		ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, ОбъектXDTOКонтактнаяАдрес);
		АдресПоПрописке.ЗначенияПолей = ЗаписьXML.Закрыть();
		//Адрес по прописке }}
		
		//фактический адрес {{
		АдресМестаПроживания = ФизическоеЛицо.КонтактнаяИнформация.Найти(Справочники.ВидыКонтактнойИнформации.АдресМестаПроживанияФизическиеЛица,
		"Вид");
		
		Если АдресМестаПроживания = Неопределено Тогда
			АдресМестаПроживания = ФизическоеЛицо.КонтактнаяИнформация.Добавить();
		КонецЕсли;
		
		АдресСтруктура.value = СокрЛП(СтрокаТЗ.АдресФактический);
		
		АдресМестаПроживания.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес;
		АдресМестаПроживания.Вид = Справочники.ВидыКонтактнойИнформации.АдресМестаПроживанияФизическиеЛица;
		АдресМестаПроживания.Значение = УправлениеКонтактнойИнформациейСлужебный.СтруктураВСтрокуJSON(АдресСтруктура);
		АдресМестаПроживания.Представление = СокрЛП(СтрокаТЗ.АдресФактический);
		
		ОбъектXDTOКонтактнаяАдрес = РаботаСАдресами.КонвертироватьАдресИзJSONВXML(АдресСтруктура, АдресПоПрописке.Представление);
		ЗаписьXML = Новый ЗаписьXML;
		ЗаписьXML.УстановитьСтроку();
		ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, ОбъектXDTOКонтактнаяАдрес);
		АдресПоПрописке.ЗначенияПолей = ЗаписьXML.Закрыть();
		//фактический адрес }}
				
		физическоеЛицо.Записать();
		
		//Фамилия, имя, отчество физического лица {{
		ФИОФИзическихЛиц = РегистрыСведений.ФИОФизическихЛиц.СоздатьМенеджерЗаписи();
		ФИОФИзическихЛиц.ФизическоеЛицо = ФизическоеЛицо.Ссылка;
		ФИОФИзическихЛиц.Период = ФизическоеЛицо.ДатаРождения;
		ЗаполнитьЗначенияСвойств(ФИОФИзическихЛиц, ФизическоеЛицо);
		
		ФИОФИзическихЛиц.Записать();
		//Фамилия, имя, отчество физического лица }}
		
		//Гражданство физ. лица
		ГражданствоМенеджерЗаписи = РегистрыСведений.ГражданствоФизическихЛиц.СоздатьМенеджерЗаписи();
		ДатаВыдачиПаспорта = СтрЗаменить(СтрокаТЗ.ДатаВыдачиПаспорта," ", "");
		Если ЗначениеЗаполнено(ДатаВыдачиПаспорта) Тогда
			ГражданствоМенеджерЗаписи.Период = Дата(СокрЛП(СтрокаТЗ.ДатаВыдачиПаспорта) + " " + "00:00:00");
		Иначе
			ГражданствоМенеджерЗаписи.Период = '19800101';
		КонецЕсли;
		ГражданствоМенеджерЗаписи.ФизическоеЛицо = ФизическоеЛицо.Ссылка;
		ГражданствоМенеджерЗаписи.ИНН = ФизическоеЛицо.ИНН;
		ГражданствоМенеджерЗаписи.Страна = СтранаГражданства;
		
		ГражданствоМенеджерЗаписи.Записать();
		
		//Паспортные данные физического лица {{
		ДокументыФизическихЛиц = РегистрыСведений.ДокументыФизическихЛиц.СоздатьМенеджерЗаписи();
		ДокументыФизическихЛиц.ЯвляетсяДокументомУдостоверяющимЛичность = Истина;
		ДокументыФизическихЛиц.Физлицо = ФизическоеЛицо.Ссылка;
		ДокументыФизическихЛиц.ВидДокумента = Справочники.ВидыДокументовФизическихЛиц.ПаспортРФ;
		
		//Особая обработка серии, формат должен быть следующим - 00 00 {{
		Серия = СокрЛП(СтрокаТЗ.СерияПаспорта);
		Серия = СтрЗаменить(Серия, " ", "");
		Серия = СтрЗаменить(Серия, Символы.НПП, "");
		
		ПервыеДвеЦифрыСерии = Лев(Серия, 2);
		ПоследниеДвеЦифрыСерии = Прав(Серия, 2);
		
		ДокументыФизическихЛиц.Серия = ПервыеДвеЦифрыСерии + " " + ПоследниеДвеЦифрыСерии;
		//Особая обработка серии, формат должен быть следующим - 00 00 }}
		
		//Номер паспорта {{
		Номер = СокрЛП(СтрокаТЗ.НомерПаспорта);
		Номер = СтрЗаменить(Номер, " ", "");
		Номер = СтрЗаменить(Номер, Символы.НПП, "");
		
		ДокументыФизическихЛиц.Номер = Номер;
		//Номер паспорта }}
		
		ДокументыФизическихЛиц.КемВыдан = СокрЛП(СтрокаТЗ.КемВыданПаспорт);
		ДокументыФизическихЛиц.КодПодразделения = СокрЛП(СтрокаТЗ.КодПодразделенияПоПаспорту);
		Если ЗначениеЗаполнено(ДатаВыдачиПаспорта) Тогда
			ДокументыФизическихЛиц.ДатаВыдачи = Дата(СокрЛП(СтрокаТЗ.ДатаВыдачиПаспорта) + " " + "00:00:00");
		Иначе
			ДокументыФизическихЛиц.ДатаВыдачи = '19800101';
		КонецЕсли;
		ДокументыФизическихЛиц.СтранаВыдачи = СтранаГражданства;
		ДокументыФизическихЛиц.Период = ДокументыФизическихЛиц.ДатаВыдачи;
		
		ДокументыФизическихЛиц.Записать();
		//Паспортные данные физического лица }}
		
		Счетчик = Счетчик + 1;
		
		Если СоздаватьСотрудников Тогда
			
			//Справочник "Сотрудники" {{
			Запрос.Текст = "ВЫБРАТЬ
			|	Сотрудники.Ссылка КАК Ссылка
			|ИЗ
			|	Справочник.Сотрудники КАК Сотрудники
			|ГДЕ
			|	Сотрудники.ФизическоеЛицо = &ФизическоеЛицо";
			Запрос.УстановитьПараметр("ФизическоеЛицо", ФизическоеЛицо.Ссылка);
			
			Выборка = Запрос.Выполнить().Выбрать();
			
			Если Выборка.Следующий() Тогда
				Сотрудник = Выборка.Ссылка.ПолучитьОбъект();
			Иначе
				Сотрудник = Справочники.Сотрудники.СоздатьЭлемент();
			КонецЕсли;
			
			Сотрудник.Наименование = ФИО;
			Сотрудник.ФизическоеЛицо = ФизическоеЛицо.Ссылка;
			Сотрудник.ГоловнаяОрганизация = ГоловнаяОрганизация;
			
			Если ЗначениеЗаполнено(СтрокаТЗ.ТабельныйНомер) Тогда
				ТабельныйНомер = СокрЛП(СтрокаТЗ.ТабельныйНомер);
				ТабельныйНомер = СтрЗаменить(ТабельныйНомер, Символы.НПП, "");
				Сотрудник.Код = ТабельныйНомер;				
			КонецЕсли;
			
			Сотрудник.Записать();
			//Справочник "Сотрудники" }}
			
			СтрокаТаблицаСотрудников = ТаблицаСотрудников.Добавить();
			СтрокаТаблицаСотрудников.Сотрудник = Сотрудник.Ссылка;
			
			СтрокаТаблицаФизЛиц = ТаблицаФизическихЛиц.Добавить();
			СтрокаТаблицаФизЛиц.ФизическоеЛицо = ФизическоеЛицо.Ссылка;
			
		КонецЕсли;
		
	КонецЦикла;
	
	ЗафиксироватьТранзакцию();
	
КонецПроцедуры