Дополнительный журнал регистрации (управляемые формы), сравнение реквизитов и табличных частей

Функция ОпределитьКлючевыеКолонкиТабличнойЧасти(МетаданныеОбъекта,ТабличнаяЧасть,ЕстьКлючевые,НаборЗаписей = Неопределено)//да
	
	//исключим колонки с несравнимыми типами данных, например, хранилище значения
	ИсключаемыеКолонки = Новый СписокЗначений;
	Если ТабличнаяЧасть = "НаборЗаписей" Тогда
		Для каждого Ресурс из МетаданныеОбъекта.Ресурсы Цикл
			Если Ресурс.Тип = Новый ОписаниеТипов("ХранилищеЗначения") Тогда
				ИсключаемыеКолонки.Добавить(Ресурс.Имя);
			КонецЕсли;
		КонецЦикла;
		
		Для каждого Реквизит из МетаданныеОбъекта.Реквизиты Цикл
			Если Реквизит.Тип = Новый ОписаниеТипов("ХранилищеЗначения") Тогда
				ИсключаемыеКолонки.Добавить(Реквизит.Имя);
			КонецЕсли;
		КонецЦикла;
	Иначе
		Если не МетаданныеОбъекта.Табличныечасти.Найти(ТабличнаяЧасть) = Неопределено Тогда //если такая ТЧ есть в метаданных
			Для каждого Колонка из МетаданныеОбъекта.ТабличныеЧасти[ТабличнаяЧасть].Реквизиты Цикл
				Если Колонка.Тип = Новый ОписаниеТипов("ХранилищеЗначения") Тогда
					ИсключаемыеКолонки.Добавить(Колонка.Имя);
				КонецЕсли;
			КонецЦикла;
		КонецЕсли;
	КонецЕсли;
	
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	               |	КлючевыеКолонкиТабличныхЧастей.ИмяКолонки,
	               |	КлючевыеКолонкиТабличныхЧастей.Ключевая КАК Ключевая
	               |ИЗ
	               |	РегистрСведений.КлючевыеКолонкиТабличныхЧастей КАК КлючевыеКолонкиТабличныхЧастей
	               |ГДЕ
	               |	КлючевыеКолонкиТабличныхЧастей.ИмяОбъектаМетаданных = &ИмяОбъектаМетаданных
	               |	И КлючевыеКолонкиТабличныхЧастей.ТабличнаяЧасть = &ТабличнаяЧасть
				   |    И КлючевыеКолонкиТабличныхЧастей.ИмяКолонки не в(&ИсключаемыеКолонки)
	               |
	               |УПОРЯДОЧИТЬ ПО
	               |	Ключевая УБЫВ";
	Запрос.УстановитьПараметр("ИмяОбъектаМетаданных",МетаданныеОбъекта.Имя);
	Запрос.УстановитьПараметр("ТабличнаяЧасть",ТабличнаяЧасть);
	Запрос.УстановитьПараметр("ИсключаемыеКолонки",ИсключаемыеКолонки);
	                                                         
	ТаблицаРезультат = Запрос.Выполнить().Выгрузить();
	
	Если ТаблицаРезультат.Количество() = 0 Тогда
		
		ТаблицаРезультат = Новый ТаблицаЗначений;
		ТаблицаРезультат.Колонки.Добавить("ИмяКолонки");
		ТаблицаРезультат.Колонки.Добавить("Ключевая",Новый ОписаниеТипов("Булево"));
		
		Если ТабличнаяЧасть = "НаборЗаписей" Тогда
			
			// все измерения регистра сведений являются ключевыми колонками
			Для каждого Измерение из МетаданныеОбъекта.Измерения Цикл
				НоваяСтрока = ТаблицаРезультат.Добавить();
				НоваяСтрока.ИмяКолонки = Измерение.Имя;
				НоваяСтрока.Ключевая = Истина;
			КонецЦикла;
					
			//Проверим на периодичность, если да, то Период тоже ключевое поле
			Если не Строка(МетаданныеОбъекта.ПериодичностьРегистраСведений) = "Непериодический" Тогда
				НоваяСтрока = ТаблицаРезультат.Добавить();
				НоваяСтрока.ИмяКолонки = "Период";
				НоваяСтрока.Ключевая = Истина;
			КонецЕсли;
			
			// получим структуру полей таблицы набора записей
			ТаблицаНабора = НаборЗаписей.Выгрузить();
			ТаблицаНабора.Очистить();
			
			// добьавим ресурсы и реквизиты в таблицу результат, они не ключевые
			Для каждого Колонка из ТаблицаНабора.Колонки Цикл
				ИмяКолонки = Колонка.Имя;
				
				//проигнорим исключаемые ресурсы и реквизиты
				Если не ИсключаемыеКолонки.НайтиПоЗначению(ИмяКолонки) = Неопределено Тогда
					Продолжить;
				КонецЕсли;
				
				Если ТаблицаРезультат.Найти(ИмяКолонки,"ИмяКолонки") = Неопределено Тогда //раньше не добавляли
					НоваяСтрока = ТаблицаРезультат.Добавить();
					НоваяСтрока.ИмяКолонки = ИмяКолонки;
					НоваяСтрока.Ключевая = Ложь;
				КонецЕсли;
			КонецЦикла;
			
			//Возврат ТаблицаРезультат;
			
		Иначе // не "НаборЗаписей"
			Если не МетаданныеОбъекта.Табличныечасти.Найти(ТабличнаяЧасть) = Неопределено Тогда //если такая ТЧ есть в метаданных
				Для каждого Колонка из МетаданныеОбъекта.ТабличныеЧасти[ТабличнаяЧасть].Реквизиты Цикл
					ИмяКолонки = Колонка.Имя;
					
					//проигнорим исключаемые колонки
					Если не ИсключаемыеКолонки.НайтиПоЗначению(ИмяКолонки) = Неопределено Тогда
						Продолжить;
					КонецЕсли;
					
					НоваяСтрока = ТаблицаРезультат.Добавить();
					НоваяСтрока.ИмяКолонки = ИмяКолонки;
					НоваяСтрока.Ключевая   = Колонка.ПроверкаЗаполнения  = ПроверкаЗаполнения.ВыдаватьОшибку;
					Если не ЕстьКлючевые Тогда
						ЕстьКлючевые = Колонка.ПроверкаЗаполнения  = ПроверкаЗаполнения.ВыдаватьОшибку;
					КонецЕсли;
				КонецЦикла;
			КонецЕсли;
			
		КонецЕсли;
	Иначе // запрос по ключевым колонкам дал результат
		Для каждого СтрокаРезультат из ТаблицаРезультат Цикл
			Если СтрокаРезультат.Ключевая Тогда //если есть хоть одна ключевая колонка, тогда все ОК
				ЕстьКлючевые = Истина ;
				Прервать;
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
	
	ТаблицаРезультат.Сортировать("Ключевая Убыв");
			
	Возврат ТаблицаРезультат;
	
КонецФункции // ОпределитьКлючевыеКолонкиТабличнойЧасти()