Регистрация изменений для обмена данными запросом

При возникновении необходимости перевыгрузить типовым обменом список документов или элементов справочника, добавление на выгрузку нужных объектов при помощи типовой обработки "Регистрация изменений для обмена данными" создаёт неудобства ввиду того, что параметр отбора типа список нельзя просто скопировать и вставить, а нужно добавлять каждый элемент списка вручную.

Столкнувшись с подобной задачей, мне не удалось зарегистрировать изменения для обмена посредством процедуры "МеханизмРегистрацииОбъектовПередЗаписьюДокумента" общего модуля "ОбменДаннымиСобытия", который используется подпиской на событие "ПередЗаписью" у типовых объектов конфигурации, участвующих в обмене.

Код, представленный ниже - не "взлетел".

Процедура ЗарегистрироватьОбъектВТиповомОбмене(Источник) Экспорт
	
	Перем Отказ, РежимЗаписи, РежимПроведения;
	
	Отказ = Ложь;
	
	Источник.ДополнительныеСвойства.Вставить("ОтложеннаяЗапись", Истина);
	РежимЗаписи = РежимЗаписиДокумента.Запись;
	ОбменДаннымиСобытия.МеханизмРегистрацииОбъектовПередЗаписьюДокумента("СинхронизацияДанныхЧерезУниверсальныйФормат", Источник, Отказ, РежимЗаписи, РежимПроведения);
	
КонецПроцедуры //  ЗарегистрироватьОбъектВТиповомОбмене

Возможно, в дебрях БСП существует какая-то процедура, которая регистрирует в плане обмена переданную ей ссылку на объект, но на поверхности она не лежит, поэтому мною было принято решение доработать типовую обработку  "Регистрация изменений для обмена данными".

Суть доработки - это добавить возможность отбора запросом на форму обработки "ВыборОбъектовОтбором", На эту форму была добавлена Группа страницы, типовые элементы перенесены на страницу "СтраницаОтбор" и создана страница "СтраницаОтборЗапросом", также на форму были добавлены реквизиты "ТекстЗапроса" и "Список", и команда "КомандаВыбратьЗапросом".

За основу для написания логики обработчика команды "КомандаВыбратьЗапросом" была взята типовая процедура "ПроизвестиВыбор".

&НаКлиенте
Процедура КомандаВыбратьЗапросом(Команда)
	
	Перем ВыборкаДанных, Ссылка;
	
	ВыборкаДанных = КомандаВыбратьЗапросом_НаСервере();
	
	СтруктураПараметров = Новый Структура();
	СтруктураПараметров.Вставить("ИмяТаблицы", Параметры.ИмяТаблицы);
	СтруктураПараметров.Вставить("ДанныеВыбора", ВыборкаДанных);
	СтруктураПараметров.Вставить("ДействиеВыбора", Параметры.ДействиеВыбора);
	СтруктураПараметров.Вставить("СтруктураПолей", СтруктураДанных);
	ОповеститьОВыборе(СтруктураПараметров);
	
КонецПроцедуры

&НаСервере
Функция КомандаВыбратьЗапросом_НаСервере()
	
	Перем Запрос, Выборка, ВыборкаДанных, ТабДок, Сч, ВГраница, мСписок;

	мСписок = Новый Массив();
	
	ТабДок = ЭтаФорма.Список;
	ВГраница = ТабДок.ВысотаТаблицы;

	Для Сч = 2 По ВГраница Цикл
		
		Значение = СокрЛП(ТабДок.Область("R" + Формат(Сч, "ЧГ=0") + "C1").Текст);
		
		Если НЕ ЗначениеЗаполнено(Значение) Тогда
			Прервать;			
		КонецЕсли;
		
		мСписок.Добавить(Значение);
	КонецЦикла;	
	
	
	Запрос = Новый Запрос();
	Запрос.Текст = ЭтаФорма.ТекстЗапроса;
	Запрос.УстановитьПараметр("Список", мСписок);
	Выборка = Запрос.Выполнить().Выбрать();
	
	ВыборкаДанных = Новый Массив();
	
	Пока Выборка.Следующий() Цикл
		Элемент = Новый Структура(СтруктураДанных);
		Элемент.Ссылка = Выборка[0];
		ВыборкаДанных.Добавить(Элемент);
	КонецЦикла;
	
	Возврат ВыборкаДанных;
КонецФункции

Ещё в модуль формы была добавлена процедура "ИнициализироватьСтраницуОтборЗапросом", а в конец процедуры "ПриСозданииНаСервере" её вызов.

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	...


	ИнициализироватьСтраницуОтборЗапросом(ИмяТаблицыДанных, МетаИнфо);
КонецПроцедуры


&НаСервере
Процедура ИнициализироватьСтраницуОтборЗапросом(ИмяТаблицыДанных, МетаданныеОбъекта)
	
	Перем 	ОбъектОбработки, ИмяПоляОтбора, ОтборПоДате, ШаблонОтбора,
			Реквизит;
	
	ОбъектОбработки = РеквизитФормыВЗначение("Объект");
	ЭтаФорма.Список = ОбъектОбработки.ПолучитьМакет("ШаблонСписка");
	
	ИменаПолейИРеквизитов = Новый Массив();
	
	Для Каждого Реквизит Из МетаданныеОбъекта.СтандартныеРеквизиты Цикл
		ИменаПолейИРеквизитов.Добавить(Реквизит.Имя);	
	КонецЦикла;	
	
	ОтборПоДате = Ложь;
	
	Если ИменаПолейИРеквизитов.Найти("Номер") <> Неопределено Тогда
		ИмяПоляОтбора = "Номер";
		ОтборПоДате = Истина;
	ИначеЕсли ИменаПолейИРеквизитов.Найти("Код") <> Неопределено Тогда
		ИмяПоляОтбора = "Код";
	Иначе		
		ИмяПоляОтбора = "Наименование";
	КонецЕсли;
	
	ШаблонОтбора = "т." + ИмяПоляОтбора + " В (&Список)";
	
	ЭтаФорма.ТекстЗапроса = 
"ВЫБРАТЬ
|	т.Ссылка
|
|ИЗ " + ИмяТаблицыДанных + " КАК т
|ГДЕ
|		" + ?(ОтборПоДате, "т.Дата >= ДАТАВРЕМЯ(" + Формат(Год(ТекущаяДата()),"ЧГ=0") + ", 1, 1)", ШаблонОтбора) + " 
|	" + ?(ОтборПоДате, "И	" + ШаблонОтбора, "") + "
|"; 
	
КонецПроцедуры //  ИнициализироватьСтраницуОтборЗапросом

Собственно, вот и вся модернизация.

Ну а теперь о том, как это работает:

Открываем модернизированную обработку, выбираем нужный узел обмена, находим интересующий нас объект, жмём правую кнопку мыши и, в появившемся контекстном меню, выбираем пункт "Зарегистрировать изменения при помощи отбора"

Если отбор по номерам документов в текущем году, то просто копируем нужные номера документов в таблицу "Список", если нет, то правим текст запроса.

Далее жмём кнопку "Выбрать запросом" и вуаля:

Если у вас нет времени, чтобы самому вносить изменения в типовую обработку "Регистрация изменений для обмена данными", можете скачать модернизированную мною обработку, взятую из типовой конфигурации УТ11 (11.5.13.74).

Обработка тестировалась на платформе 1С 8.3.22.2106.