Оптимизация кода 1С: 6 частых ошибок и способы исправления

Оптимизация кода 1С: 6 частых ошибок и способы исправления
Оптимизация кода 1С: 6 частых ошибок и способы исправления
07.11.2026
2578

Запросы в цикле, скрытые обращения к базе, ошибки в настройке виртуальных таблиц: вместе с экспертом Игорем Засухой разбираем, что замедляет код 1С. В конце – задания для самостоятельной практики и обучения команды.

На INFOSTART TECH EVENT 2026 команда Инфостарт Обучения проводила на своем стенде активности для разработчиков и других специалистов 1С.

Разбор эксперта

Одну из них подготовил наш эксперт Игорь Засуха – архитектор 1С, преподаватель и директор компании «Айти-Гид». Участникам предлагалось изучить код учебных обработок, найти проблемные места и предложить варианты оптимизации.

После конференции мы попросили Игоря собрать ошибки, которые были в исходных версиях обработок. В конце статьи вы сможете скачать учебные задания, чтобы самостоятельно проверить свои навыки, разобрать код с коллегами или использовать обработки для обучения начинающих разработчиков.

Почему код начинает работать медленно

По наблюдениям Игоря, причины медленной работы кода в 1С часто повторяются: запрос в цикле, отбор не в том месте запроса и скрытые обращения к базе через точку.

Код, который на тестовой базе отрабатывает за секунду, на рабочей базе с сотнями тысяч позиций может выполнять сотни тысяч запросов вместо одного. Это увеличивает нагрузку на СУБД и может приводить к блокировкам и жалобам пользователей.

Ниже собраны шесть групп ошибок. Каждый пример разобран по одной схеме: в чем ошибка, как правильно и почему это верно.

1. Запрос в цикле

Запрос выполняется на каждой итерации обхода справочника, документов или табличной части.

Например, обработка перебирает контрагентов и отдельно получает обороты продаж по каждому из них:

ВыборкаКонтрагентов = Справочники.Контрагенты.Выбрать();

Пока ВыборкаКонтрагентов.Следующий() Цикл
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |    Обороты.СуммаОборот КАК Сумма
        |ИЗ
        |    РегистрНакопления.Продажи.Обороты(
        |        &НачалоПериода, &КонецПериода, , ) КАК Обороты
        |ГДЕ
        |    Обороты.Контрагент = &Контрагент";

    Запрос.УстановитьПараметр(
        "Контрагент",
        ВыборкаКонтрагентов.Ссылка
    );

    ...
КонецЦикла;

В чем ошибка. Каждый запрос – отдельное обращение сервера 1С к СУБД: разбор текста, построение плана, передача результата по сети. Тысяча контрагентов – тысяча обращений. При этом некоторые запросы вернут пустой результат, если у контрагента не было продаж.

Тот же подход встречается при проверке строк табличной части, когда остатки запрашиваются отдельно для каждой строки документа.

Как правильно. Выполнить один запрос, который сразу вернет нужный набор данных:

Вариант исправления
Запрос = Новый Запрос;
Запрос.Текст =
    "ВЫБРАТЬ
    |    Обороты.Контрагент КАК Контрагент,
    |    ПРЕДСТАВЛЕНИЕ(Обороты.Контрагент) КАК КонтрагентПредставление,
    |    СУММА(Обороты.СуммаОборот) КАК Сумма
    |ИЗ
    |    РегистрНакопления.Продажи.Обороты(
    |        &НачалоПериода, &КонецПериода, , ) КАК Обороты
    |СГРУППИРОВАТЬ ПО
    |    Обороты.Контрагент";

Запрос.УстановитьПараметр(
    "НачалоПериода",
    НачалоДня(НачалоПериода)
);

Запрос.УстановитьПараметр(
    "КонецПериода",
    КонецДня(КонецПериода)
);

Для строк документа Игорь предлагает выгрузить табличную часть во временную таблицу, свернуть по номенклатуре и соединить с остатками один раз.

Почему это верно. СУБД обрабатывает множество строк за один проход. В результат попадают строки с данными, а пустых обращений по каждому контрагенту нет.

Если нужен список всех элементов, в том числе без движений, источником становится справочник, а регистр присоединяется к нему левым соединением – в том же запросе.

Что изучить подробнее. На курсе «Язык запросов 1С: эффективное управление данными» можно углубиться в работу с выборками, виртуальными таблицами и другими механизмами языка запросов.

2. Скрытые обращения к базе

В коде конструкция Ссылка.Реквизит выглядит как обращение к полю. По словам Игоря, за таким обращением может скрываться чтение объекта из базы. Внутри цикла это способно создавать дополнительные обращения, которые не так заметны, как явно написанный запрос.

2.1. ПолучитьОбъект() ради чтения пары полей

ДокОбъект = ВыборкаДокументов.Ссылка.ПолучитьОбъект();

Сообщить(
    "Найден документ: "
    + ДокОбъект.Номер
    + " от "
    + ДокОбъект.Дата
);

В чем ошибка. Объект получают ради двух полей, которые уже есть в выборке. При этом ПолучитьОбъект() читает документ целиком и создает объект в памяти.

Как правильно. Для чтения использовать поля самой выборки или запроса:

Вариант исправления
ВыборкаДокументов.Номер
ВыборкаДокументов.Дата

Обращение Ссылка.Номер тоже работает, но в цикле Игорь рекомендует брать поля непосредственно из выборки. ПолучитьОбъект() нужен, когда дальнейшая работа требует самого объекта, например, его изменения и записи.

Почему это верно. Для получения номера и даты не требуется загружать весь объект документа с табличными частями.

2.2. Разыменование в цикле и «.Ссылка» у ссылки

Сообщить(Выборка.Контрагент.Ссылка.Наименование);

Сообщить(ВыборкаНоменклатуры.Ссылка.Артикул);

ВызватьИсключение
    "Не хватает товара "
    + СтрокаТЧ.Номенклатура.Наименование;

В чем ошибка. Контрагент уже является ссылкой, поэтому дополнительное .Ссылка к ней ничего не добавляет. Обращения к наименованию или артикулу внутри цикла могут приводить к дополнительному чтению данных элементов справочника.

Как правильно. Получать необходимые реквизиты в запросе:

Вариант исправления
|ВЫБРАТЬ
|    Обороты.Контрагент КАК Контрагент,
|    Обороты.Контрагент.Наименование КАК КонтрагентНаименование,
|    ПРЕДСТАВЛЕНИЕ(Обороты.Контрагент) КАК КонтрагентПредставление

Почему это верно. Обращение через точку в запросе обрабатывается на стороне СУБД. Для вывода данных пользователю Игорь рекомендует получать ПРЕДСТАВЛЕНИЕ(): оно учитывает настройки представления объекта.

2.3. Неявное приведение ссылки к строке

Сообщить(
    "Товар: "
    + Строка.Номенклатура
    + " итог: "
    + Строка.Сумма
);

В чем ошибка. При добавлении ссылки к строке платформа получает ее представление. В коде это действие не видно, и внутри цикла оно может приводить к дополнительным обращениям к базе.

Как правильно. Выбрать представление номенклатуры в запросе и выводить готовую строку:

Вариант исправления
ПРЕДСТАВЛЕНИЕ(Номенклатура) КАК НоменклатураПредставление

Почему это верно. Представления получаются вместе с остальными данными запроса.

3. Параметры виртуальных таблиц: отборы и даты

Виртуальные таблицы регистров – «Остатки», «Обороты», «СрезПоследних» – платформа формирует с учетом переданных параметров. Поэтому важно понимать, какие данные нужны обработке и где задаются условия отбора.

3.1. Отбор в ГДЕ вместо параметра «Условие»

|ИЗ
|    РегистрНакопления.Запасы.Остатки(, ) КАК Запасы
|ГДЕ
|    Запасы.Номенклатура = &Номенклатура

В чем ошибка. Как поясняет Игорь, при таком варианте платформа сначала рассчитывает остатки по товарам и складам, а затем отбрасывает лишнее.

Как правильно. Передать условие по номенклатуре в параметры виртуальной таблицы:

Вариант исправления
|ИЗ
|    РегистрНакопления.Запасы.Остатки(
|        , Номенклатура = &Номенклатура) КАК Запасы

Если значений много, в параметр можно передать подзапрос к временной таблице:

Вариант исправления
Номенклатура В (
    ВЫБРАТЬ
        Т.Номенклатура
    ИЗ
        ТабДок КАК Т
)

Почему это верно. Условие попадает внутрь расчета виртуальной таблицы. Игорь рекомендует условия на измерения передавать в параметры, а условия на рассчитанные ресурсы – размещать в ГДЕ или ИМЕЮЩИЕ.

3.2. Текущая дата в параметре остатков

|    РегистрНакопления.Запасы.Остатки(&Период) КАК Запасы

...

Запрос.УстановитьПараметр("Период", ТекущаяДата());

В чем ошибка. При указании даты платформа рассчитывает остатки на заданный момент. Если нужны актуальные остатки, такой расчет может быть лишним.

Как правильно. Для получения актуальных остатков использовать Остатки() без периода. Если дата все же нужна, например, для отчета «на сегодня» с учетом часового пояса, Игорь рекомендует ТекущаяДатаСеанса().

Почему это верно. Без указания периода используются текущие итоги. ТекущаяДатаСеанса() учитывает часовой пояс сеанса.

3.3. Конец периода без КонецДня

Запрос.УстановитьПараметр(
    "КонецПериода",
    Дата("20260101")
);

В чем ошибка. Дата может соответствовать началу суток – 00:00:00. В таком случае данные последнего дня после полуночи не попадут в выборку.

Как правильно.

Вариант исправления
Запрос.УстановитьПараметр(
    "НачалоПериода",
    НачалоДня(ДатаНачала)
);

Запрос.УстановитьПараметр(
    "КонецПериода",
    КонецДня(ДатаОкончания)
);

Почему это верно. Граница периода охватывает последний день целиком.

3.4. Дата вместо момента времени при контроле остатков

В чем ошибка. Для проверки остатков перед проведением документа в параметр передают Документ.Дата. При этом могут не учитываться документы, проведенные в ту же секунду раньше текущего.

Как правильно.

Вариант исправления
Запрос.УстановитьПараметр(
    "Граница",
    Новый Граница(
        ДокументОбъект.МоментВремени(),
        ВидГраницы.Исключая
    )
);

Почему это верно. Момент времени включает дату и ссылку на документ, поэтому остатки рассчитываются до текущего документа.

3.5. Срез последних без отбора по измерениям

|    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ) КАК Цены
|ГДЕ
|    Цены.Номенклатура = &Номенклатура

В чем ошибка. Срез возвращает последнюю запись по каждой комбинации измерений регистра. Если есть измерение «Вид цены», одному товару могут соответствовать несколько строк.

Как правильно.

Вариант исправления
|    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
|        &Период,
|        ВидЦен = &ВидЦен
|            И Номенклатура В (&СписокНоменклатуры)
|    ) КАК Цены

Почему это верно. Отбор в параметрах ограничивает расчет нужными значениями измерений и помогает получить ожидаемый результат.

Что изучить подробнее. Виртуальные таблицы и работа с условиями запросов разбираются на курсе «Язык запросов 1С: эффективное управление данными».

4. Обработка данных в коде вместо запроса

В этой группе примеров данные передаются на сервер приложений, а затем суммирование, группировка или отбор выполняются циклом на встроенном языке.

4.1. Суммирование в цикле

Пока Выборка.Следующий() Цикл
    ОбщаяСумма = ОбщаяСумма + Выборка.Сумма;
КонецЦикла;

В чем ошибка. Программа получает множество строк ради одного итогового значения.

Как правильно. Рассчитать сумму в запросе:

Вариант исправления
|ВЫБРАТЬ
|    ЕСТЬNULL(СУММА(Запасы.СуммаОстаток), 0) КАК ОбщаяСумма
|ИЗ
|    РегистрНакопления.Запасы.Остатки() КАК Запасы

Почему это верно. СУБД складывает значения там, где они хранятся, и возвращает одну строку. ЕСТЬNULL используется для обработки пустого результата.

4.2. Группировка через ТаблицаЗначений.НайтиСтроки

Пока ВыборкаДокументов.Следующий() Цикл

    Для Каждого СтрокаТЧ Из ВыборкаДокументов.Запасы Цикл

        НайденныеСтроки = ТаблицаИтогов.НайтиСтроки(
            Новый Структура(
                "Номенклатура",
                СтрокаТЧ.Номенклатура
            )
        );

        Если НайденныеСтроки.Количество() > 0 Тогда
            НайденныеСтроки[0].Сумма =
                НайденныеСтроки[0].Сумма + СтрокаТЧ.Сумма;
        Иначе
            ...

В чем ошибка. В примере сочетаются обращение к табличной части через выборку и повторяющийся поиск строк в таблице итогов.

Как правильно. Группировать данные запросом к табличной части:

Вариант исправления
|ВЫБРАТЬ
|    Т.Номенклатура КАК Номенклатура,
|    ПРЕДСТАВЛЕНИЕ(Т.Номенклатура) КАК НоменклатураПредставление,
|    СУММА(Т.Сумма) КАК Сумма
|ИЗ
|    Документ.РасходнаяНакладная.Запасы КАК Т
|ГДЕ
|    Т.Ссылка.Дата МЕЖДУ &НачалоПериода И &КонецПериода
|    И Т.Ссылка.Проведен
|СГРУППИРОВАТЬ ПО
|    Т.Номенклатура

Если данные уже находятся в таблице значений и пришли не из базы, Игорь предлагает использовать:

Вариант исправления
ТаблицаИтогов.Свернуть("Номенклатура", "Сумма");

Если поиск по таблице необходим, можно добавить индекс до цикла:

Вариант исправления
ТаблицаИтогов.Индексы.Добавить("Номенклатура");

Почему это верно. Группировка выполняется средствами СУБД, а повторяющийся поиск в коде исключается.

4.3. Фильтр в коде вместо условия запроса

ВыборкаДокументов =
    Документы.РасходнаяНакладная.Выбрать(
        ДатаНачала,
        ДатаОкончания
    );

Пока ВыборкаДокументов.Следующий() Цикл

    Если ВыборкаДокументов.Договор.ВидДоговора =
        Перечисления.ВидыДоговоров.СПокупателем Тогда

В чем ошибка. Обработка читает все документы за период, а проверяет нужный вид договора уже в коде.

Как правильно. Перенести условие в запрос:

Вариант исправления
ГДЕ
    Т.Договор.ВидДоговора =
        ЗНАЧЕНИЕ(Перечисление.ВидыДоговоров.СПокупателем)

Почему это верно. СУБД возвращает документы, которые соответствуют условию.

4.4. Выгрузить() ради одного обхода

ТаблицаИтогов = Запрос.Выполнить().Выгрузить();

Для Каждого Строка Из ТаблицаИтогов Цикл

В чем ошибка. Результат полностью выгружается в таблицу значений, хотя нужен только последовательный проход.

Как правильно.

Вариант исправления
Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
    ...
КонецЦикла;

Почему это верно. Для последовательного обхода не требуется создавать таблицу значений со всем результатом. Выгрузить() оправдан, когда таблица нужна дальше, например, для поиска, передачи в другой запрос или в форму.

Что изучить подробнее. Если похожие задачи возникают при создании отчетов, обратите внимание на «Систему компоновки данных для разработки отчетов в 1С:Предприятии». Для тех, кто уже умеет писать запросы и создавать простые отчеты, есть курс «Углубленное изучение СКД в 1С».

5. Конкатенация строк вместо СтрШаблон

Склейка строк через + – привычка, которую легко не заметить при ревью:

Сообщить(
    "У контрагента "
    + Выборка.Контрагент.Наименование
    + " продажи на сумму: "
    + Выборка.Сумма
);

Сообщить(
    "Время выполнения: "
    + ВремяВыполненияСек
    + " сек."
);

ВызватьИсключение
    "Не хватает товара "
    + СтрокаТЧ.Номенклатура.Наименование;

В чем ошибка. По словам Игоря, при таком подходе:

  • создаются промежуточные строки;
  • фраза разбивается на части, что усложняет перевод;
  • значения разных типов приводятся к строке неявно;
  • можно потерять пробел на стыке частей сообщения.

Как правильно.

Вариант исправления
Шаблон = НСтр(
    "ru = 'У контрагента %1 продажи на сумму: %2'"
);

Сообщить(
    СтрШаблон(
        Шаблон,
        Выборка.КонтрагентПредставление,
        Формат(Выборка.Сумма, "ЧДЦ=2")
    )
);

Сообщить(
    СтрШаблон(
        НСтр("ru = 'Время выполнения: %1 сек.'"),
        ВремяВыполненияСек
    )
);

ВызватьИсключение СтрШаблон(
    НСтр("ru = 'Не хватает товара %1'"),
    Выборка.НоменклатураПредставление
);

Почему это верно. Фраза читается и переводится целиком, а форматирование значений задается явно через Формат().

Если требуется собрать много фрагментов в цикле, например текст файла или длинный протокол, Игорь предлагает использовать массив и СтрСоединить().

6. Другие частые ошибки оптимизации

6.1. Серверный вызов в цикле на клиенте

&НаКлиенте
Процедура ЗаполнитьЦены(Команда)

    Для Каждого Строка Из Объект.Товары Цикл
        Строка.Цена =
            ПолучитьЦенуНаСервере(Строка.Номенклатура);
    КонецЦикла;

КонецПроцедуры

В чем ошибка. Каждый вызов сервера – отдельный обмен по сети. Сто строк могут привести к ста обращениям.

Как правильно. Собрать параметры и выполнить один вызов, который получит данные для всех строк:

Вариант исправления
&НаКлиенте
Процедура ЗаполнитьЦены(Команда)

    ЗаполнитьЦеныНаСервере(); // один вызов

КонецПроцедуры


&НаСервере
Процедура ЗаполнитьЦеныНаСервере()

    // Один запрос цен по всем товарам табличной части,
    // затем заполнение строк из соответствия
    // Номенклатура U94; Цена.

КонецПроцедуры

Почему это верно. Вместо множества клиент-серверных вызовов выполняется один. Если данные формы не нужны, необходимые значения можно передать параметром в функцию &НаСервереБезКонтекста.

6.2. Обращение через точку к полю составного типа

|ВЫБРАТЬ
|    Движения.Регистратор.Контрагент КАК Контрагент

В чем ошибка. Если поле может ссылаться на множество типов документов, запрос может включать большое число соединений.

Как правильно. Явно указать нужный тип:

Вариант исправления
ВЫРАЗИТЬ(
    Движения.Регистратор
    КАК Документ.РасходнаяНакладная
).Контрагент

Почему это верно. Указание конкретного типа позволяет ограничить необходимые соединения.

6.3. Поиск в массиве внутри цикла

Для Каждого Элемент Из БольшойСписок Цикл

    Если ОбработанныеЭлементы.Найти(Элемент) = Неопределено Тогда
        ОбработанныеЭлементы.Добавить(Элемент);
    КонецЕсли;

КонецЦикла;

В чем ошибка. Массив.Найти() перебирает массив. При повторяющемся поиске внутри цикла время работы растет вместе с объемом данных.

Как правильно. Использовать соответствие, где ключ – искомое значение:

Вариант исправления
Если ОбработанныеЭлементы[Элемент] = Неопределено Тогда
    ОбработанныеЭлементы.Вставить(Элемент, Истина);
КонецЕсли;

Для таблицы значений можно рассмотреть индекс по колонке поиска.

Почему это верно. Поиск по ключу соответствия позволяет избежать повторного последовательного перебора массива.

6.4. Длинные транзакции

В чем ошибка. В транзакцию попадают обращение к внешнему сервису, формирование файла, ожидание ответа или обработка большого количества документов. Пока транзакция открыта, могут удерживаться блокировки.

Как правильно. Игорь рекомендует оставлять в транзакции необходимые чтение и запись, а остальные операции по возможности выполнять до нее или после. Массовую обработку можно разделить на порции, а блокировки устанавливать с отбором по конкретным значениям.

Почему это верно. Чем короче транзакция и уже область блокировки, тем меньше вероятность конфликтов между пользователями.

6.5. Лишние поля и тяжелые временные таблицы

В чем ошибка. В запросе выбираются поля «на всякий случай», временная таблица собирается без отбора, а затем соединяется с другими таблицами.

Как правильно. Выбирать нужные поля, отбирать данные до помещения во временную таблицу и использовать ИНДЕКСИРОВАТЬ ПО для полей соединения с большими таблицами.

Почему это верно. Программа читает и передает меньше данных, а индекс помогает при соединении таблиц.

Для разработчиков, которые хотят подробнее изучить интеграции, в каталоге также есть курс «Обмен данными в системе 1С:Предприятие». Он посвящен работе с файлами, веб-сервисами и другими способами обмена.

Чек-лист перед ревью

Игорь предлагает проверить обработку по следующим пунктам:

  • Нет запросов, ПолучитьОбъект() и обращений через точку внутри циклов.
  • Условия на измерения переданы в параметры виртуальной таблицы.
  • Для актуальных остатков период не передается; для контроля документа используется граница с моментом времени.
  • Конец периода задан через КонецДня(), текущая дата – через ТекущаяДатаСеанса().
  • Виртуальные таблицы сворачиваются по ключу соединения, нет лишних дублей по складам и видам цен.
  • Агрегаты обработаны с помощью ЕСТЬNULL.
  • Представления ссылок получены в запросе через ПРЕДСТАВЛЕНИЕ().
  • Строки собираются через СтрШаблон и НСтр, формат чисел и дат задается явно.

Скачайте задания с конференции

Хотите попробовать самостоятельно найти ошибки и предложить варианты оптимизации? Скачайте учебные обработки, которые использовались во время активности на стенде Инфостарт Обучения.

Задания можно использовать для самостоятельной практики, обучения Junior-разработчиков, проверки навыков или обсуждения решений внутри команды. Сначала попробуйте найти проблемные места самостоятельно, а затем сравните свои выводы с разбором Игоря.

Скачать файлы заданий

Что важно помнить после оптимизации

Многие ошибки возникают там, где работа с данными переносится в повторяющиеся циклы на встроенном языке: запрос выполняется для каждой строки, отбор происходит после получения данных, а обращения к реквизитам через ссылку остаются незаметными при первом чтении кода.

Убрать явный запрос из цикла – только часть работы. Нужно также проверить скрытые обращения к базе, параметры виртуальных таблиц и границы периода.

Быстрая версия должна давать тот же результат, что и исходная. Замер времени без сверки данных показывает только скорость, поэтому после изменений важно проверить корректность решения.

Подпишитесь на наши каналы

Следите за новостями, полезными материалами и анонсами курсов Инфостарт Обучения.

Если вам удобнее смотреть новости в телеграме, то вот наша группа – ИНФОСТАРТ.

Автор:
Алёна Духовна

См. также

До 31 декабря можно записаться на партнерские курсы Инфостарта в 2027 году по цене 2026. Рассказываем, какие курсы участвуют в акции, когда они стартуют и кому подойдут.

11.11.2026    1115    aduhovna    0       

1

Как проводить интервью, находить противоречия в информации и готовить требования, с которыми сможет работать команда. Рассказываем о курсе «Системный сбор требований и работа с информацией» и задачах аналитика и бизнеса, которые он помогает решать.

09.11.2026    1247    aduhovna    0       

1

Какие задачи решает Junior-разработчик 1С, когда специалиста можно назвать Middle и чем от него отличается Senior? Вместе с экспертом Инфостарт Обучения разбираемся, как оценивать грейд, какие навыки развивать дальше и какие курсы могут в этом помочь.

06.11.2026    2384    aduhovna    1       

18

В ноябре в Инфостарт Обучение запускает программы для тех, кто хочет развить навыки аналитика 1С: научиться работать с платформой, собирать и управлять требованиями, готовить проектную документацию и сопровождать разработку. Собрали ближайшие запуски и курсы, к которым можно присоединиться.

05.11.2026    1337    aduhovna    0       

1

На INFOSTART TECH EVENT 2026 разработчики соревновались в оптимизации кода 1С. Какие ошибки повторялись, что помогает ускорять запросы и как превратить такой батл в полезное упражнение для команды – рассказываем в материале.

30.10.2026    1415    aduhovna    0       

3

Департаменту закупок понадобился инструмент для анализа встреч с поставщиками. Александр Свойкин рассказывает, почему выбрал документ вместо регистров сведений и как с помощью Cursor, Grok и Spec Kit за две итерации довел решение до рабочей базы

23.10.2026    1814    aduhovna    1       

16

Может ли бюджетная ИИ-модель создать рабочее расширение для 1С? На вебинаре Александр Свойкин сравнил шесть инструментов на одной практической задаче. Рассказываем о результатах эксперимента, работе с SDD, качестве кода и выборе инструментов.

14.10.2026    3776    aduhovna    31       

16

Мы открыли отдельную партнерскую витрину с программами 1С:Учебного центра №1. В ней можно выбрать курс, посмотреть ближайшие потоки и специальные предложения, оплатить обучение и передать доступ коллеге или сотруднику.

12.10.2026    428    aduhovna    0       

1

Комментарии

Инфостарт бот
1. sapervodichka 07.11.26 14:32 Сейчас в теме
+100500 Вот только думаю, что такому уже в вузах должны учиться, а на реальную работу уже подготовленными приходить.
Даёшь курсы студентам в вузы! ))
2. gybson 07.11.26 22:34 Сейчас в теме
(1) Такие теперь ВУЗы, настолько деградировали?
3. sapervodichka 08.11.26 01:01 Сейчас в теме
(2) Предлагаешь ещё раньше, в школе, этому учить?
4. gybson 08.11.26 11:49 Сейчас в теме
(3) Я предлагаю оставить это на курсах вне ВУЗов, как 28 лет назад
5. sapervodichka 08.11.26 13:07 Сейчас в теме
(4) знаешь многое изменилось за 28 лет. Программы и разработку в 1с уже давненько изучают в вузах и на практику студентов отправляют во франчайзи 1с. Они видят в 1с будущий заработок в профессии. А про школу я писал, т.к. и в школе уже начинают 1с программы запускать. Вот такие пироги.
16. gybson 09.11.26 20:43 Сейчас в теме
(5) Ну тогда такие азы точно должны уже быть в программе.
Я в свое время учился у практикующих программистов 1С, которые закончили мой же факультет, но раньше. Сами готовили себе будущих коллег. Такой вариант более оптимальный я думаю, чем прям уж в ВУЗе преподавать.
6. dhurricane 09.11.26 00:01 Сейчас в теме
В чем ошибка. Для проверки остатков перед проведением документа в параметр передают Документ.Дата. При этом могут не учитываться документы, проведенные в ту же секунду раньше текущего.
Почему это верно. Момент времени включает дату и ссылку на документ, поэтому остатки рассчитываются до текущего документа.
Так вроде нет никакой гарантии, что ссылки на документы монотонно возрастающие и зависят от того, какая из транзакций началась раньше.

Почему это верно. Без указания периода используются текущие итоги.
Формально правильный ответ, и при этом совершенно не раскрывающий проблему. В данном контексте совершенно непонятно, чем "текущие остатки" отличаются от "актуальных остатков" и от "остатков на заданный момент", где этот самый момент равен текущему дате и времени. :)
7. NikolaevSergey1C 09.11.26 08:36 Сейчас в теме
что за слоп,?
Как правильно. Игорь рекомендует оставлять в транзакции необходимые чтение и запись
8. Трактор 09.11.26 11:37 Сейчас в теме
(7)
слоп

Слабая попытка обогатить русский язык новым словом. кг/ам, как говорили тролли предшествующего поколения.

Статья написана на основе рекомендаций Игоря Засухи, который в свою очередь, взял их с ИТС.
9. booksfill 09.11.26 11:37 Сейчас в теме
Для получения актуальных остатков использовать Остатки() без периода.

Не надо так, никто не гарантирует, что у вас что-то не провели будущей датой. Но, да, так быстрей.
Как говорится, у каждой проблемы есть простое, понятное и абсолютно неверное решение.

Конец периода без КонецДня

Во-первых, как это попало в оптимизацию, во-вторых, откуда коварное предложение приводить к концу дня, ну, давайте приведем к концу месяца. Кстати, во многих отчетах требуется и такое поведение.

Получение представления в запросе

Если помнить как 1С получает представление, то вот вам мой совет - НЕ получайте представление в запросе, если вам достаточно, например, наименования. Мало того, что облегчите жизнь 1С по получению представления, так еще и не нарветесь на тот самый запрос в цикле в обработке события получения представления, если его автор не очень понимал, что делает.

Дальше читать не стал, на 100% уверен, что нам в 100500 раз расскажут про составной тип и запросы в цикле, а также почему выборка хорошо, а выгрузить в тз не очень.
Вообще же статья,не утверждаю!, очень напоминает работу ИИ, слишком много "надо делать хорошо и не надо плохо", но на примитивном уровне. Увы, ИИ плохо умеет в 1С.
kuzyara; mrChOP93; Трактор; +3 – Ответить
10. triviumfan 09.11.26 12:28 Сейчас в теме

|ВЫБРАТЬ
| ЕСТЬNULL(СУММА(Запасы.СуммаОстаток), 0) КАК ОбщаяСумма
|ИЗ
| РегистрНакопления.Запасы.Остатки() КАК Запасы

Зачем тут агрегация и проверка на NULL?
dhurricane; +1 – Ответить
12. Трактор 09.11.26 15:33 Сейчас в теме
(10)
ЕСТЬNULL(СУММА(Запасы.СуммаОстаток)

Бывают ситуации, но именно так писать криво. Лучше так

СУММА(ЕСТЬNULL(Запасы.СуммаОстаток, 0))
13. dhurricane 09.11.26 16:43 Сейчас в теме
(12) Не бывает таких ситуаций. Виртуальная таблица всегда возвращает одну строку с числовым значением, если в выборке нет измерений. Ни группировка, ни приведение к 0 не требуется, виртуальная таблица уже об этом позаботилась.
14. Трактор 09.11.26 17:35 Сейчас в теме
(13) Бывает. Например нам нужно сказать сколько товара не можем отгрузить потому что к ним нет серий.
К табличной части документа присоединяем остатки по сериям. При этом остатки группируем по номенклатуре.
Вот навскидку
ВЫБРАТЬ
	ТЧ.Номенклатура КАК Номенклатура,
	СУММА(ЕСТЬNULL(Запасы.СуммаОстаток, 0) - ТЧ.Количество) КАК Нехватка
ИЗ
	Документ.Накладная.Товары КАК ТЧ
	ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Запасы.Остатки() КАК Запасы
	По Запасы.Серия = ТЧ.Серия
СГРУППИРОВАТЬ По
	ТЧ.Номенклатура
ИМЕЮЩИЕ
	СУММА(ТЧ.Количество - ЕСТЬNULL(Запасы.СуммаОстаток, 0)) < 0

Показать
15. dhurricane 09.11.26 17:52 Сейчас в теме
(14) Ну так здесь есть в запросе поле измерения от виртуальной таблицы. В отличие от примера в посте. Уберите использование измерений виртуальной таблицы остатков и попробуйте добиться того, чтобы ресурс оказался не свернутым и не числом.
11. coollerinc 09.11.26 13:31 Сейчас в теме
Небольшой нюанс с моментом времени в таблице остатков:
Особого смысла предавать границу вместо момента времени нет. При проведении, если получаете остатки, то надо просто очищать движения текущего документа и указывать МоментВремени(). Т.к. я могу изменить, дату документа вперед и тогда в документе учтутся движения текущего документа.
17. capitan 10.11.26 18:06 Сейчас в теме
3.4. Дата вместо момента времени при контроле остатков
Вы удивитесь, но в СУБД понятия не имеет что такое МоментВремени() в 1С
Это из экзамена на Спеца пример, там за указание времени снимут балл, но к оптимизации он какое отношение имеет?
Для отправки сообщения требуется регистрация/авторизация