Упрощенная обработка по просмотру прав по ролям на объекты конфигурации

Публикация № 127188

Администрирование - Информационная безопасность

Обработка предназначена для получения «шахматки» прав по ролям и объектам метаданных. Написано для 8.1 но перекодировать в 8.2 проблемы нет (для использовании в 8.2 в текущем виде необходимо запускать ее в «обычном приложении»).

Преамбула :)

 

Конечно, это не первая подобная обработка, но тем не менее я все таки решил выложить поскольку считаю, что из-за своей простоты (ненавороченности) позволяет получить навыки работы

  1. С процедурой «ПравоДоступа» - основной процедурой определения прав
  2. С объектами метаданных (построениедерева метаданных и т.д.)
  3. С отчетами типа «шахматки»

 

В обрате отсутствуют какие-либо отборы и настройки. Если есть необходимость их можно доработать, но тут их нет именно потому, что обработку старались сделать как можно проще (на совершенство обработка не претендует :) )

 

Постановка задачи.

 

Необходимо получить отчет по доступу ролей к объектам метаданных (сегодня озадачили этим J). При этом рассматриваются только три возможных состояния:

  • Роли доступно свойство «Изменение» (другое не проверяется)
  • Роли доступно свойство «Чтение» (если изменение не доступно, т.е. «Изменение» имеет более высокий приоритет чем «Чтение»)
  • В остальных случаях считается что роли ничего не доступно.

 Действительно, если роли доступно «Редактирование» или «Пометка на удаление», то «Изменение» ей так же должно быть доступно, а если доступно «Просмотр», то обязательно доступно «Чтение». Поэтому, для читабельности отчета (иначе он просто потеряет читабельность) мы и контролируем эти два права (Изменение и Чтение).

 

Так же необходимо проверить права роли на работу с самой конфигурацией («Монопольный режим», «Администрирование» и т.д.)

 

Отчет должен быть представлен в виде шахматки:

  • Строки «Объекты метаданных»
  • Колонки «Роли»

 

Реализация задачи

 

В общем случае последовательность работ такая:

  1. Создаем список ролей
  2. Создаем список контролируемых прав (с учетом приоритета)
  3. Создаем список объектов метаданных
  4. Сравниваем все три параметра в процедуре «ПравоДоступа» и выводим результат.

 

Для реализации создадим новую обработку и форму, весь программный код поместим в модуль формы. На форме создадим «табличное поле» («ПолеТабличногоДокумента1») куда будем выводить отчет. Кроме того будут реквизиты формы:

дМетаданных – дерево метаданных (вывод нужно организовать с учетом иерархии). Конечно, от него можно отказаться и просто организовать обход по метаданным, но лучше его оставить, так как если потребуется поставить фильтр на  объекты в отчет оно может здорово пригодится (достаточно в дереве добавить новую колонку, проставить в нее соответствующий признак, и при выводе учитывать – в данной обработке не реализовано).

спРоли – список ролей в конфигурации. Так же при необходимости отборов добавляем на форму и используем свойство «Пометка».

спПрав – список контролируемых прав с учетом приоритетов (то что важнее заносится раньше).

 

Соответственно в форму при открытии укажем процедуры по заполнению всех нужных списков.

 

Процедура ПриОткрытии()

            Роли_ПолучитьСписок();

            Роли_СписокПрав();

            ДеревоМетаданных();

КонецПроцедуры

 

 Начнем с простого – список прав (их всего две), и список ролей

 

Процедура Роли_СписокПрав()

            спПрав.Добавить("Изменение");

            спПрав.Добавить("Чтение");

КонецПРоцедуры   

 

Процедура Роли_ПолучитьСписок()

            спРоли = новый СписокЗначений;

            Для каждого РОль Из Метаданные.Роли Цикл

                ОбработкаПрерыванияПОльзователя();

                        спРоли.Добавить(РОль,РОль_Описание(РОль));

            КонецЦикла;

 КонецПроцедуры    

 Функция РОль_Описание(Роль)

            Результат = РОль.Представление();

            Если Результат<>РОль.Имя Тогда

                        Результат = Результат+"["+Роль.Имя+"]";

            КонецЕсли;

            возврат Результат;

КонецФункции       

 

При формировании отчета мы хотим видеть пользовательское представление метаданных и ролей, а так же их представление в метаданных (поэтому и вводим Функцию  «РОль_Описание» - в принципе ее можно описать непосредственно в процедуре «Роли_ПолучитьСписок» - дело вкуса :) )

 

Если посмотреть в описании процедуры «ПравоДоступа» то такие права как «Администрирование» тоже по идеи нужно отнести в СписокПрав, но исходя из целесообразности и наглядности отчета мы  условно отнесем их к метаданным и занесем в дальнейшем в дМетаданные (что бы видеть их как строки – создадим отдельную ветку).

 

Дерево метаданных состоит из двух колонок «Описание» и «Представление»

 

Процедура ДеревоМетаданных() Экспорт

            дМетаданные.Колонки.Добавить("Объект");

            дМетаданные.Колонки.Добавить("Представление");

            ДеревоМетаданных_ДобавитьАдминистрирование();

            ДеревоМетаданных_Добавить("Справочники");

            ДеревоМетаданных_Добавить("Документы");

             ДеревоМетаданных_Добавить("ЖурналыДокументов","Журналы документов");

            ДеревоМетаданных_Добавить("Перечисления");

            ДеревоМетаданных_Добавить("Отчеты");

            ДеревоМетаданных_Добавить("Обработки");

    ДеревоМетаданных_Добавить("ПланыВидовХарактеристик","Планы видов характеристик");

            ДеревоМетаданных_Добавить("ПланыСчетов","Планы счетов");

    ДеревоМетаданных_Добавить("ПланыВидовРасчета","Планы видов расчета");

    ДеревоМетаданных_Добавить("РегистрыСведений","Регистры сведений");

    ДеревоМетаданных_Добавить("РегистрыНакопления","Регистры накопления");

    ДеревоМетаданных_Добавить("РегистрыБухгалтерии","Регистры бухгалтерии");

            ДеревоМетаданных_Добавить("РегистрыРасчета","Регистры расчета");

            ДеревоМетаданных_Добавить("БизнесПроцессы","Бизнес-процессы");

    ДеревоМетаданных_Добавить("Задачи");

           

КонецПроцедуры    

 

ПРоцедура ДеревоМетаданных_ДобавитьАдминистрирование()

            СтрокаГр = дМетаданные.Строки.Добавить();

            СтрокаГр.Объект = "Администрирование";

            СтрокаГр.Представление = "Права на конфигурацию в целом";

           

            мсПрав = новый СписокЗначений;

            мсПрав.Добавить("Администрирование","Администрирование");

            мсПрав.Добавить("МонопольныйРежим","Монопольный режим");

            мсПрав.Добавить("АктивныеПользователи","Просмотр списка активных пользователей");

            мсПрав.Добавить("ЖурналРегистрации","Журнал регистрации");

            мсПрав.Добавить("ВнешнееСоединение","Внешнее соединение");

            мсПрав.Добавить("Automation","Использование automation");

            мсПрав.Добавить("ИнтерактивноеОткрытиеВнешнихОбработок","Интерактивное открытие внешних обработок");

            мсПрав.Добавить("ИнтерактивноеОткрытиеВнешнихОтчетов","Интерактивное открытие внешних отчетов");

            мсПрав.Добавить("Вывод","Вывод на печать, запись и копирование в буфер обмена");

            мсПрав.Добавить("ОбновлениеКонфигурацииБазыДанных","Обновление конфигурации базы данных");

           

            Для каждого эл Из мсПрав  Цикл

                ОбработкаПрерыванияПОльзователя();

                       

                        НС = СтрокаГр.Строки.Добавить();

                        НС.Объект = Эл.Значение;

                        НС.Представление = Эл.Представление;

            КонецЦикла;

           

КонецПРоцедуры   

 

Процедура  ДеревоМетаданных_Добавить(что,Представление="")

            Первая = истина;

            Для каждого мет Из Метаданные[что] Цикл

                        Если Первая Тогда

                                   СтрокаГр = дМетаданные.Строки.Добавить();

                                   СтрокаГр.Объект = Что;

                                   Если ПустаяСтрока(Представление) Тогда

                                               СтрокаГР.Представление = Что;

                                   иначе 

                                               СтрокаГР.Представление = Представление;

                                   КонецЕсли;

                                  

            первая = Ложь;

                        КонецЕсли;

                       

                        строка = СтрокаГр.Строки.Добавить();

                        Строка.Объект                                 = Мет.Имя;

                        Строка.Представление        = Мет.Представление();

 

            КонецЦикла;

КонецПроцедуры                

 

Как было сказано для ряда прав мы создаем отдельную ветку «Администрирование» (процедура «ДеревоМетаданных_ДобавитьАдминистрирование()»), и определять эту ветку мы будем по объекту «Администрирование». Остальные возможные объекты метаданных мы добавляем с помощью процедуры ДеревоМетаданных_Добавить(,). При этом в процедуре ДеревоМетаданных_Добавить мы контролируем что бы хотя бы один объект такого типа есть (иначе ветка не нужна). Кроме того, если «Представление» в параметрах процедуры не задана, то считаем что прдеставление равно типу.

 

Далее, нам нужно будет создать макет, имеющий вертикальные и горизонтальные секции (для формирования шахматки). Кроме того, поскольку мы формируем шахматку с использованием разных процедур то в форме объявим две переменные: Макет и ТабДок (ТабДок – это результирующий отчет).

 

Дальше собственно формируем сам отчет с использованием (как уже несколько раз было сказано J ) процедуры «ПравоДоступа». Учтем один нюанс, если нам нужно получить права роли на какой-то отдельный объект метаданных (из нашего дерева), то мы должны передать в процедуру ПравоДоступа(,,), где «Право» из списка Прав. Но если нам нужно получить права ролей из ветки “Администрирование», то в качестве Метаданных используется сама конфигурация (т.е. просто МЕТАДАННЫЕ), а права у нас уходят в дерево Метаданных, и тогда нужно использовать ПравоДоступа(,Метаданные,), а результат уже просто доступно это право или нет.

 

Для этого создадим отдельную функцию:

 

Функция  РОль_Права(Мет,Роль)

            Результат = "";

           

            Если ТипЗнч(Мет)=Тип("Строка") Тогда

                        // это проверка Административных прав

                        Если ПравоДоступа(Мет,Метаданные,РОль) Тогда

                                   Результат = "Да";

                        иначе

                                   результат = "";

                        КонецЕсли;

                       

                        возврат Результат;

            КонецЕсли;

           

            Для каждого Право  Из спПрав Цикл

                ОбработкаПрерыванияПОльзователя();

                       

                        Если ПравоДоступа(Право.Значение,Мет,РОль) Тогда

                                   Результат = Право.Значение;

                                   прервать;

                        КонецЕсли;

                       

            КонецЦикла;

           

            возврат Результат;

КонецФункции       

 

В которую если у нас контролируется права на объект метаданных в качестве первого параметра и передаем этот объект (функция в этом случае возвращает значение права учетом приоритета), а если нужно право из ветки «Администрирование», то передаем строковую переменную с  именем этого права (функция возвращает «Да» или). По типу первого параметра и определяется, как использовать функцию ПравоДоступа.

 

Формирование самого отчета делаем при помощи процедур

 

Процедура Сфомировать_Вывод(ИмяСекции,данные=Неопределено)

            Сек     = Макет.ПолучитьОбласть(ИмяСекции+"|Начало");

            пСек   = Сек.Параметры;

            Уровень = 0;

           

            ЭтоАдминистирирование = ТипЗнч(Данные)=Тип("СтрокаДереваЗначений");

           

            Если ИмяСекции="С1" Тогда

                        уровень = 1;

                        пСек.Объект = данные;

                       

            ИначеЕсли ИмяСекции="С2" Тогда        

                        уровень = 2; 

                       

                        Если ЭтоАдминистирирование Тогда

                                   пСек.Объект = данные.Представление;

                                   пСек.Обозначение = данные.Объект;

                                  

                        иначе 

                                   пСек.Объект = данные.Представление();

                                    пСек.Обозначение = данные.Имя;

                                  

                                  

                        КонецЕсли;

            КонецЕсли;

           

            ТабДок.Вывести(Сек,Уровень);

           

            Для каждого Роль Из спРоли  Цикл

                ОбработкаПрерыванияПОльзователя();

                       

                        Сек     = Макет.ПолучитьОбласть(ИмяСекции+"|В1");

                        пСек   = Сек.Параметры;

 

                        Если ИмяСекции = "Ш1" Тогда

                                   пСек.РОль     = Роль.Представление;

                                  

                        иначеЕСли ИмяСекции = "С2" Тогда      

                                   Если ЭтоАдминистирирование Тогда

                                       Права                     = РОль_Права(данные.Объект,Роль.Значение);

                                   иначе 

                                               Права                         = РОль_Права(данные,Роль.Значение);

                                   КонецЕсли;

                                                                      

                                   Если Права = "Изменение" или Права="Да" тогда

                                               Сек.Область("ТекПрава").ЦветФона = WebЦвета.СветлоЗеленый;

                                   ИначеЕсли Права = "Чтение" тогда

                                               Сек.Область("ТекПрава").ЦветФона = WebЦвета.Желтый;

                                    КонецЕсли;

                                  

                                   пСек.Права = Права;

                                  

                        КонецЕсли;

                       

                        ТабДок.Присоединить(Сек);

            КонецЦикла; 

           

            ТабДок.Присоединить(Макет.ПолучитьОбласть(ИмяСекции+"|Конец"));

КонецПроцедуры    

 

Процедура Сфомировать(Кнопка)

            ТабДок = ЭлементыФормы.ПолеТабличногоДокумента1;

            ТабДок.Очистить();

           

    Макет = ПолучитьМакет("Макет");

    Сфомировать_Вывод("Ш1");

            ТабДок.ФиксацияСверху    = ТабДок.ВысотаТаблицы;

    ТабДок.ФиксацияСлева = 2;

            ТабДок.НачатьАвтогруппировкуСтрок();

           

            Для каждого Ст1 Из дМетаданные.Строки  Цикл

                ОбработкаПрерыванияПОльзователя();

                       

                        ЭтоАдминистирирование = Ст1.Объект = "Администрирование";

                        Если ЭтоАдминистирирование Тогда

                            Мет1 = Метаданные;

                        иначе 

                                   Мет1 = Метаданные[Ст1.ОБъект];

                        КонецЕсли;

                       

                        Сфомировать_Вывод("С1",Ст1.Представление);

                        Для каждого Ст2 Из Ст1.Строки Цикл

                            ОбработкаПрерыванияПОльзователя();

                                  

                                   Если ЭтоАдминистирирование Тогда

                                       Мет2 = Ст2;

                                   иначе 

                                               Мет2 = Мет1[СокрЛП(Ст2.ОБъект)];

                                   КонецЕсли;

                                  

                                   Сфомировать_Вывод("С2",Мет2);

                        КонецЦикла;

                       

            КонецЦикла;

           

            ТабДок.ЗакончитьАвтогруппировкуСтрок();

           

             Сфомировать_Вывод("И1");

 

КонецПроцедуры

 

Сфомировать – организует таблицу и обход по строкам

Сфомировать_Вывод – организует обход по колонкам

 

Ну и для красоты отчета те роли, которые имеют право «Изменение» или «Да» (для администрирования) окрашиваем зеленым, роли на «Чтение» - желтым. Для этого создали в секции специальную именованную область.

 

Собственно и все, может кому пригодится как исходная «точка» для написания нечто подобного, к примеру, если нужно получить права не по ролям а по пользователям, то список ролей меняем на список пользователей и в ПравоДоступа передаем не роль а конкретного пользователя.

 

Р.S. Надеюсь, не очень занудно получилось :) и подскажите, как в публикации выделить кусок текста как "код программы" (теги CODE как в сообщениях почему-то не работают, или я их не правильно использую).

Скачать файлы

Наименование Файл Версия Размер
Отчет "Права на объекты по ролям"

.epf 9,80Kb
174
.epf 9,80Kb 174 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. akku 14 04.03.16 10:47 Сейчас в теме
В 8.3 Бухгалтерия Казахстана то же конвертируется и работает, все отлично, спасибо!
Оставьте свое сообщение

См. также

Запуск 1С под любым пользователем (без необходимости указания пароля) Промо

Пароли v8 v8::Права 1cv8.cf Абонемент ($m)

Предназначается для запуска сеанса другого пользователя из своего сеанса 1С (если пароль вам неизвестен).

1 стартмани

02.07.2019    22855    240    sapervodichka    0    

Анализ ролей доступа

Роли и права v8 v8::Права ERP2 БП3.0 КА2 Абонемент ($m)

Быстрое определение, каких ролей доступа не хватает и на что влияет выбранная роль.

1 стартмани

06.01.2021    2536    49    yermak    9    

Разрешение изменять, проводить, распроводить документы только их авторам

Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

Расширение сделано по запросу клиента. Главный бухгалтер не хочет, чтоб пользователи у ней в базе могли изменять чужие документы (те, которые делали не они).

1 стартмани

18.12.2020    1361    4    al_zzz    0    

Групповое добавление и удаление ролей из списка профилей

Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

Подключаемая обработка. Помогает при конструировании профилей доступа пользователей (настройке прав пользователей), экономит время на добавлении/удалении одной и той же роли сразу в нескольких профилях.

1 стартмани

14.12.2020    3626    28    sapervodichka    8    

Анализ ролей и прав доступа Промо

Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

Отчет для анализа ролей и прав с использованием СКД. Формируется в разрезе объектов, ролей, пользователей и прав (чтение, просмотр и т.д.). Позволяет быстро узнать, какие пользователи или роли имеют конкретные права на объекты.

2 стартмани

09.01.2015    33499    2    kser87    7    

Анализ прав доступа на объекты метаданных 1С (быстрое получение списка только тех ролей, у которых есть соответствующий доступ). А так же получение списка ролей, которым дано право "Интерактивное удаление" (или другое, на выбор)

Роли и права v8 1cv8.cf Абонемент ($m)

Часто нужно получить набор ролей, в которых есть определенное право для объекта. Чтобы не перебирать все роли в поисках доступных прав, можно воспользоваться этой обработкой. Она покажет только те роли, в которых назначено нужное нам право. И конфигуратор открывать не нужно. Особенно полезно для анализа облачных баз. По просьбам трудящихся, дополняю функционал: теперь можно быстро найти те объекты и роли, у которых есть право "Интерактивное удаление" для этого есть специальная кнопка.

1 стартмани

08.11.2020    1910    22    akrelius    6    

Локальная файловая система из 1С, как это работает.

Информационная безопасность Универсальные обработки Файловые протоколы обмена, FTP v8 1cv8.cf Абонемент ($m)

Внешняя обработка для работы с файлами из 1С по типу FAR или Norton Commander, Total Commander и немного занудной философии. Работает 8.3.15 и выше. Работает в тонком, толстом, Web и мобильном клиенте. Поставляется отдельным файлом можно включить куда угодно, зависит только от платформы 1С.

1 стартмани

17.09.2020    12215    7    Patriot1S    9    

Подсистема прав доступа к объектам с гибкими отборами (расширение)

Роли и права v8 ERP2 БП3.0 УТ11 КА2 ЗУП3.x Абонемент ($m)

Возможность без доработок конкретизировать пользователям права Просмотра и Изменения объектов базы 1С, установив ограничения с помощью отборов системы компоновки данных.

2 стартмани

02.07.2020    11254    126    sapervodichka    56    

Просмотр прав пользователей Промо

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Обработка наглядно показывает права доступа конкретного пользователя или роли к конкретному объекту метаданных.

1 стартмани

19.10.2012    33590    306    NILS2009    17    

Настройка ограничений входа пользователей в базу (расширение)

Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

Настраиваем для пользователей 1С разрешенное количество открытых сеансов к текущей базе данных 1С в привязке к компьютерам. (У пользователя не будет возможности превысить допустимое количество сеансов или зайти с чужого компьютера).

2 стартмани

19.05.2020    9352    18    sapervodichka    14    

Менеджер подключений к удаленным рабочим столам (RDP)

Роли и права v8 Абонемент ($m)

Менеджер подключений к удаленным рабочим столам для организации доступа сотрудникам, без передачи паролей для доступа.

2 стартмани

19.11.2019    5153    7    Shalnov    1    

Обозреватель криптографии

Инструментарий разработчика Защита ПО v8 Абонемент ($m)

Отчет для просмотра доступных провайдеров и сертификатов криптографии на сервере и клиенте.

2 стартмани

21.10.2019    11678    14    YPermitin    10    

Отключение доступа уволенным пользователям Промо

Информационная безопасность Обработка справочников Администрирование данных 1С v8 v8::Права БП2.0 УПП1 Абонемент ($m)

Давно хотели навести порядок в пользователях? Надоело, что в списке мешаются давно уволенные сотрудники? Тогда эта обработка для Вас!

3 стартмани

15.10.2013    51793    109    VBod    17    

Завершение работы пользователей

Роли и права v8 1cv8.cf Россия Абонемент ($m)

Завершение работы пользователей с помощью подключения обработчика ожидания.

1 стартмани

02.10.2019    7376    15    user921814    6    

Расширение "Туманность" - помощник настройки профилей групп доступа. ERP 2.4.9+

Роли и права v8 v8::Права ERP2 Абонемент ($m)

Расширение позволяет настраивать профили групп доступа как комбинации из других профилей групп доступа.

1 стартмани

30.08.2019    4889    8    Brawler    0    

PowerShell из 1С: создание пользователя Active Directory

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Пример создания пользователя Active Directory с помощью PowerShell из 1С.

2 стартмани

27.08.2019    11116    17    wowik    13    

Права доступа ролей Промо

Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

Отчет по правам доступа ролей, выводит в удобной краткой форме права доступа в разрезе ролей на интересующие нас объекты метаданных или объекты метаданных, к которым есть доступ у интересующей нас роли. Показывает наличие RLS и позволяет сравнить роли. Отображает использование роли в профилях групп доступа/группах доступа.

1 стартмани

05.02.2018    19571    131    Serge R    2    

Сравнение доступа профилей, ролей, пользователей по всем объектам конфигурации 8.3, 8.2 (обычные формы "ОФ" и управляемые формы "УФ") (выборочно)(НАБОР УТИЛИТ)

Роли и права v8 v8::УФ v8::Права 1cv8.cf Абонемент ($m)

Сравнение профилей доступа по всем объектам конфигурации 8.3 (полноценно функционирует с версии 1С:Предприятия 8.1.10 - 8.3.X). Очень хотелось иметь обработку, которая бы показывала различия профилей доступа по каждому конкретному объекту конфигурации и по всем сразу. Желание было воплощено в данной обработке.

1 стартмани

23.06.2019    7577    28    AlexandrSmith    0    

Доступ пользователей только к собственным документам/сделкам

Информационная безопасность Оптовая торговля Оптовая торговля v8 v8::БУ БП3.0 Абонемент ($m)

Расширение блокирует доступ менеджеров по продажам к чужим документам. Ограничивает работу менеджера только собственными сделками, не позволяя просматривать сделки других менеджеров. Действует на счета, счета-фактуры и реализации.

2 стартмани

25.05.2019    9297    16    denmax    12    

Запуск 1С под другим пользователем без ввода пароля

Роли и права v8 v8::УФ v8::Права 1cv8.cf Абонемент ($m)

Для проверки настроек ролей и прав или для отладки можно использовать это решение.

1 стартмани

22.03.2019    8908    40    pridecom    0    

Регистры правил [Расширение] Промо

Инструментарий разработчика Информационная безопасность v8 v8::Права УТ11 Абонемент ($m)

Регистры правил - права доступа, запрет редактирования, автоподстановка реквизитов и т.д.

10 стартмани

15.03.2018    19264    28    33lab    3    

Наследование ролей в профилях групп доступа в конфигурациях на базе БСП

Практика программирования БСП (Библиотека стандартных подсистем) Роли и права v8 v8::Права 1cv8.cf Абонемент ($m)

С помощью данной доработки можно создать новый профиль групп доступа, с наследованием ролей от базового (поставляемого) профиля. В созданном профиле можно добавить или исключить какие-либо роли относительно базового профиля.

1 стартмани

15.03.2019    10839    14    ids79    1    

PasswordHashViewer - просмотр хэшей пользовательских паролей

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Программа для просмотра хэшей паролей пользователей в файловых и клиент-серверных базах 1С. Зачем это нужно? Для их проверки на криптостойкость.

1 стартмани

25.02.2019    6996    12    GeraltSnow    5    

Обезличивание базы ЗУП 3.1.*

Информационная безопасность Зарплата Управление персоналом (HRM) v8 v8::СПР ЗУП3.x Абонемент ($m)

Обработка по перемешиванию/скрытию конфиденциальной информации в базе ЗУП.

1 стартмани

05.02.2019    11802    69    Skin123    11    

Управление пользователями, редакция 3.0 Промо

Журнал регистрации Роли и права v8 1cv8.cf Абонемент ($m)

Программа создана для управления пользователями нескольких баз в одной программе. Управляемые формы, интерфейс такси.

10 стартмани

16.09.2015    26871    29    cyberintegration    13    

Наводим порядок в Active Directory с помощью ЗУП / ЗИКГУ 3.1 (идентификация, отключение и актуализация учетных записей пользователей)

Информационная безопасность Администрирование данных 1С v8 v8::СПР ЗКБУ ЗУП3.x Россия Абонемент ($m)

Продолжаем использовать ЗУП 3.1 совместно с LDAP во имя автоматизации работы системного администратора. В этот раз займемся аудитом учетных записей. Обработка производит сопоставление учетной записи с данными сотрудников из ЗУП, причем с учетом недавних событий (для перехода на ЗУП 3.1 чаще всего используется рекомендованный перенос, не включающий уволенных сотрудников) есть возможность использовать объединенные с помощью COM-соединения данные ЗУП 2.5 и ЗУП 3.1. Также в данной обработке есть возможность массовой корректировки, заполнения данных и отключения учетных записей. Перед использованием обработки для душевного спокойствия необходимо сделать резервную копию Active Directory любым удобным способом. Протестировано на ЗУП 3.1.6 - 3.1.8.

5 стартмани

01.02.2019    9958    44    Туки Туки    14    

1С: Документооборот. Роли, использующие объекты адресации. Конфигурация остается типовой (используется расширение)

Информационная безопасность v8 ДО Абонемент ($m)

Расширение функционала документооборота. Реализована возможность использования ролей с объектами адресации. Конфигурация остается типовой (используется расширение)

5 стартмани

10.01.2019    10801    22    sulig    27    

Получение логина и пароля ИТС из базы 1С

Информационная безопасность v8 v8::УФ 1cv8.cf Абонемент ($m)

Обработка показывает пароль от сайта https://releases.1c.ru прямо из базы 1С.

1 стартмани

02.11.2018    28870    140    Timur.V    21    

Включение и выключение регистрации отказа в доступе если "У пользователя не достаточно прав над операцией с базой данных". Промо

Информационная безопасность Журнал регистрации v8 1cv8.cf Абонемент ($m)

Включает (выключает) регистрацию событий отказа доступа в журнале регистрации.

1 стартмани

12.01.2011    36869    364    nexts    32    

Особенность при создании своих ролей в конфигурациях на управляемых формах

Информационная безопасность v8 v8::УФ v8::Права 1cv8.cf Россия Абонемент ($m)

Столкнулся с небольшой проблемкой при создании "своих" ролей в конфигураторе и добавлении их пользователям. Пользователю не добавляются созданные в конфигураторе роли, 1С 8.3, Управляемые формы. Гуглил много, ответа толкового не нашёл, поэтому пришлось разбираться самому и как результат, решил поделиться опытом. Возможно, кому-то пригодится.

1 стартмани

29.10.2018    16763    11    d.saladin    15    

Запрет на запуск более одного сеанса для одного пользователя в 1С: Предприятие 8.3 ЗУП, БП, КА, ERP, УАТ и т.д.

Информационная безопасность v8 1cv8.cf Россия Абонемент ($m)

Ограничение запуска 1С: Предприятие нескольких сеансов под одним пользователем. Функционал разработан через расширение, конфигурацию с поддержки снимать НЕ НУЖНО. Функционал работает в файловом и клиент-серверном варианте работы конфигурации. Платформа 8.3.12.1529 Конфигурации КА 2.4.5.71; ERP 2.4.5.54; БП 3.0.64.21; ЗУП 3.1.7.87 (это релизы на которых была произведена проверка, так же будет работать на всех стандартных конфигурациях 1С с режимом совместимости Версия 8.3.10)

1 стартмани

29.08.2018    18825    93    mityushov.vv    49    

[Расширения] Управление видимостью разделов для разных пользователей

Работа с интерфейсом Информационная безопасность v8 1cv8.cf Россия Абонемент ($m)

Как скрыть/показать раздел в управляемом приложении используя расширение, на примере БП 3.0

1 стартмани

05.07.2018    14247    14    Alex_E    10    

Права пользователей Промо

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Кросс-таблица прав пользователей (подсистема "Управление доступом")

1 стартмани

10.05.2016    29367    103    inspam    4    

Анализ и редактирование прав пользователей (управляемые формы)

Информационная безопасность v8 v8::УФ v8::Права 1cv8.cf Россия Абонемент ($m)

В обработке реализовано два отчета - матрица ролей (пересечение ролей и пользователей), и анализ прав на объекты в разрезе пользователей / ролей. Также есть запуск под пользователем с временной подменой пароля и редактирование прав непосредственно в матрице.

2 стартмани

03.07.2018    11436    68    axelerleo    4    

Анализатор прав и ролей

Роли и права v8 v8::Права 1cv8.cf Россия Абонемент ($m)

"Достали!" - именно с такой фразы началась разработка) Все кто сталкивались с последними мега конфигурациями (не будем показывать пальцем на ERP) и видели этот нереальный список ролей, от которого даже скролл дымился, то вам однозначно пригодится эта обработка. Основной целью было дополнить типовой функционал "Все роли" отборами для быстрого поиска нужных доступов. Возможности: просмотр по метаданным список их ролей и прав, просмотр по роли ее список метаданных, просмотр по правам ограничения (RLS).

1 стартмани

02.01.2018    10167    65    denacid    6    

Редактирование прав пользователя (анализ прав доступа)

Роли и права v8 v8::Права БП3.0 УТ11 Абонемент ($m)

Обработка для анализа и редактирования ролей пользователей 1С Предприятия.

1 стартмани

21.12.2017    14851    100    feniks_pro90    5    

Права по ролям Промо

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Отчет выводит установленные права

2 стартмани

16.09.2015    25304    75    nad11    1    

Запуск ИБ 1С под любым пользователем (только для разработчиков/администраторов)

Информационная безопасность v8 v8::Права 1cv8.cf Россия Абонемент ($m)

Когда ведете разработку нового функционала, то есть необходимость протестировать алгоритмы под разными правами. Тогда Вам нужна данная обработка, которая ускорит процесс входа в базу под нужным пользователем.

1 стартмани

28.11.2017    11302    40    Diagnostiks    7    

Считывание заданных параметров Интернет-поддержки

Информационная безопасность v8 ERP2 ЗКГУ3.0 БП3.0 УТ11 КА2 ЗУП3.x Россия Абонемент ($m)

Обработка для чтения указанных параметров интернет-поддержки продукта.

1 стартмани

25.10.2017    10825    22    kudlach    4    

Перенос настроек пользователей между базами 1С 8.3 (УФ)

Роли и права v8 v8::УФ 1cv8.cf Абонемент ($m)

Задача была – скопировать одну базу в другую, причем перенести список пользователей и настройки пользователей. Потому что в настройках пользователей было очень много хитроумных разукрашиваний и отборов, следовательно, повторять это руками было бы долго. Была написана обработка, которая выгружает настройки пользователей из одной базы в файлы и потом позволяет их загрузить из файлов в другую базу. Можно использовать и для переноса настроек между одними пользователями, если типовое копирование не нравится.

1 стартмани

13.10.2017    26009    274    fixin    30    

Анализ ролей доступа (обычная и УФ) Промо

Информационная безопасность v8 v8::УФ 1cv8.cf Абонемент ($m)

Анализ ролей доступа. Определяет доступность к справочникам, документам, отчетам и т.д. Не нужно пересматривать кучу ролей, чтобы понять, что Вам нужно.

1 стартмани

25.08.2015    28384    190    fugu    9    

Просмотр прав на объекты конфигурации по ролям, профилям групп пользователей и пользователям

Информационная безопасность v8::УФ v8::Права v8::СКД Розница ЗКГУ3.0 БП3.0 УТ11 ЗУП3.x Абонемент ($m)

Отчет формирует «шахматку» прав на объекты метаданных в разрезе ролей, профилей групп пользователей и пользователей.

3 стартмани

13.09.2017    11498    50    vladismi    0    

Выгрузка и загрузка пользователей между различными конфигурациями 1С 8.3, включая пароли (Управляемое приложение, обычное приложение, БСП)

Роли и права v8 v8::УФ v8::Права 1cv8.cf Абонемент ($m)

Предназначена для переноса пользователей между различными конфигурациями 1С 8.3, включая пароли. Только для БСП (библиотека стандартных подсистем). Проверено на "Документооборот 2.0", "Управление торговлей 11", БСП 2.3.

4 стартмани

07.07.2017    21192    115    TuneSoft    5    

Как помочь сисадмину при большой текучке кадров

Информационная безопасность v8 v8::СПР v8::Права ЗУП2.5 Россия Абонемент ($m)

Хотелось бы поделиться своим опытом создания пользователей AD из 1С:ЗУП 2.5.

1 стартмани

06.07.2017    14400    7    PhoenixAOD    31    

Запуск 1С под пользователем без сброса пароля Промо

Информационная безопасность v8 Россия Абонемент ($m)

Обработка позволяет запустить пользовательский режим 1С, не сбрасывая полностью пароль пользователя. Что очень удобно при отладке прав и RLS. Также есть возможность быстро установить пароль 123, и вернуть старый пароль вручную.

1 стартмани

18.11.2013    47629    715    mylogin    38    

Создание и удаление пользователей в конфигурациях с БСП

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Быстрое создание пользователей с заранее известными правами в интерактивном режиме и из файла. По одному и списком. Быстрое удаление списком пользователей ИБ и пометка на удаление элементов справочника Пользователи.

1 стартмани

20.06.2017    10729    31    user768334    1    

Отключение/включение защиты от опасных действий пользователей

Информационная безопасность v8 v8::УФ 1cv8.cf Абонемент ($m)

Обработка позволяет управлять настройкой "Защита от опасных действий" пользователей информационной базы.

1 стартмани

16.05.2017    13390    31    Brawler    8    

Просмотр ролей по объектам метаданных конфигурации на 1С 8.3

Роли и права v8 1cv8.cf Россия Абонемент ($m)

Универсальная обработка для просмотра ролей по любому из объектов конфигурации 1С 8.3.для настройки пользовательских интерфейсов по стандартным ролям в конфигурации ERP 2.4, ЗУП 3.1, БП 3.0 и т.д.

1 стартмани

13.04.2017    17855    122    mityushov.vv    11    

Отчет для анализа прав доступа в разрезах Право/Объект/Роль/Профиль/Пользователь Промо

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Удобный анализ прав доступа в различных разрезах, с промежуточным кэшированием набора данных. Только для конфигураций на БСП.

1 стартмани

16.04.2015    29540    363    unichkin    13    

Просмотр лицензий и сеансов пользователей

Информационная безопасность v8 1cv8.cf Абонемент ($m)

Просмотр лицензий и сеансов пользователей (тонкий, толстый клиент, управляемого или обычного приложения).

1 стартмани

01.03.2017    9038    23    diletant    7