IE2017

Добавить к дате рабочие дни в запросе

Программирование - Практика программирования

Был отчет, в котором к неким датам прибавлялось 15 дней функцией ДобавитьКДате(). Но вот понадобилось добавлять к дате не все дни, а только рабочие. Сделал запрос, может быть кому понадобится

 Собственно запрос получился такой: 

 ВЫБРАТЬ Даты.Дата,

	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК ДатаКалендаря,
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
		ПО (Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
			И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
		ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
ГДЕ
	(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
			ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
	Даты.Дата

ИМЕЮЩИЕ
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря

 Таблица "Даты" может содержать любые данные с датой в виде отдельного поля или в виде реквизита документа.   Параметр "ГлубинаДней"  определяет, как глубоко вперёд просматривать даты относительно входящих дат.

Вот пример работы для одной даты 28.11.2012

       
Дата КоличествоРабочихДней ДатаКалендаря ДатаКалендаряДляГруппировки  
28.11.2012 1 28.11.2012 28.11.2012  
28.11.2012 2 29.11.2012 29.11.2012  
28.11.2012 3 30.11.2012 30.11.2012  
28.11.2012 4 03.12.2012 03.12.2012  
28.11.2012 5 04.12.2012 04.12.2012  
28.11.2012 6 05.12.2012 05.12.2012  
28.11.2012 7 06.12.2012 06.12.2012  
28.11.2012 8 07.12.2012 07.12.2012  
28.11.2012 9 10.12.2012 10.12.2012  
28.11.2012 10 11.12.2012 11.12.2012  
28.11.2012 11 12.12.2012 12.12.2012  
28.11.2012 12 13.12.2012 13.12.2012  
28.11.2012 13 14.12.2012 14.12.2012  
28.11.2012 14 17.12.2012 17.12.2012  
28.11.2012 15 18.12.2012 18.12.2012  
28.11.2012 16 19.12.2012 19.12.2012  
28.11.2012 17 20.12.2012 20.12.2012  
28.11.2012 18 21.12.2012 21.12.2012  
28.11.2012 19 24.12.2012 24.12.2012  
28.11.2012 20 25.12.2012 25.12.2012  
28.11.2012 21 26.12.2012 26.12.2012  
28.11.2012 22 27.12.2012 27.12.2012  

 

В конец запроса осталось добавить условие

И КОЛИЧЕСТВО(РАЗЛИЧНЫЕРегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней

и отобрать данные по нужному количеству рабочих дней в параметре "РабочихДней"

Ну и в конце полная верия запроса, если захочется опробовать в консоли запросов

ВЫБРАТЬ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Дата
ПОМЕСТИТЬ Даты
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря В(&ВходящиеДаты)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Даты.Дата,
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК ДатаКалендаря,
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
		ПО (Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
			И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
		ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
ГДЕ
	(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
			ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
	Даты.Дата

ИМЕЮЩИЕ
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
	И КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней

 

См. также

Комментарии
1. Александр Медведев (anig99) 2544 17.12.12 11:05 Сейчас в теме
И в чём новизна? И здесь, и на других форумах тема широко обсуждалась... Данное решение - самое банальное.
2. INTECH RU (INTECH1) 17.12.12 11:10 Сейчас в теме
На новизну не претендовал, просто не нашел решение, когда понадобилось. Можно ссылку на обсуждение?
3. Александр Медведев (anig99) 2544 18.12.12 14:23 Сейчас в теме
4. Игор Мудрицкий (Zas1402) 20.12.12 17:16 Сейчас в теме
На новизну не претендовал, просто не нашел решение, когда понадобилось.

Полезная тема.
5. Антон Шелашский (Aesh) 26.12.12 15:40 Сейчас в теме
В том-то и оно, что обсуждалось, типа "Кури ...". Тут парень конкретно написал. Я помню раньше еще писал, но потом какое-то время не работал с 1С, сейчас на свое взглянул (а там еще с планом счетов связано), аж паника продернула, вспоминал бы дня два! Спасибо, ооочень выручил, так бы все писали, а не "Кури..."
Andreyyy; maxis33; +2 Ответить
6. Азбука Морзе 38 25.04.13 17:18 Сейчас в теме
Идея добавить к дате рабочие дни очень помогла при разработке отчетов, связанных с банковскими днями. Спасибо.
NazarovV; +1 Ответить
7. Роман Попов (popro) 20.06.13 16:59 Сейчас в теме
как правильно определить глубину дней чтобы не было слишком много или недостаточно?
8. INTECH RU (INTECH1) 20.06.13 17:08 Сейчас в теме
Ну здесь дело в праздниках, если взять, например, какое-нибудь 21.12.2012, то глубина 15 дней не достаточна из-за долгих январских праздников - вот только исходя из таких нюансов. Поэтому Глубина = 15 дней + Максимум количества праздников, вот как-то так
9. Павел (Yimaida) 32 19.08.13 18:56 Сейчас в теме
Немного допилил запрос, чтобы можно было отнять дату. Автору +, единственное внятное рабочее решение, которое я нашел в инете по этой теме ("скопировал и работает").

ВЫБРАТЬ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Дата
ПОМЕСТИТЬ Даты
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря В(&ВходящиеДаты)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Даты.Дата,
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
	ВЫБОР
		КОГДА &ОтнятьДни
			ТОГДА МИНИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ИНАЧЕ МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
	КОНЕЦ КАК ДатаКалендаря,
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
		ПО (ВЫБОР
				КОГДА &ОтнятьДни
					ТОГДА Даты.Дата >= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря
				ИНАЧЕ Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря
			КОНЕЦ)
			И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
		ПО (ВЫБОР
				КОГДА &ОтнятьДни
					ТОГДА РегламентированныйПроизводственныйКалендарь.ДатаКалендаря >= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
				ИНАЧЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
			КОНЕЦ)
ГДЕ
	(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
			ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
	Даты.Дата

ИМЕЮЩИЕ
	ВЫБОР
		КОГДА &ОтнятьДни
			ТОГДА МИНИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
		ИНАЧЕ МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
	КОНЕЦ И
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней
...Показать Скрыть


или так

ВЫБРАТЬ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Дата
ПОМЕСТИТЬ Даты
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
	РегламентированныйПроизводственныйКалендарь.ДатаКалендаря В(&ВходящиеДаты)
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Даты.Дата,
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
	ВЫБОР
		КОГДА &РабочихДней < 0
			ТОГДА МИНИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ИНАЧЕ МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
	КОНЕЦ КАК ДатаКалендаря,
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
	РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
		ПО (ВЫБОР
				КОГДА &РабочихДней < 0
					ТОГДА Даты.Дата >= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря
				ИНАЧЕ Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря
			КОНЕЦ)
			И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
		ПО (ВЫБОР
				КОГДА &РабочихДней < 0
					ТОГДА РегламентированныйПроизводственныйКалендарь.ДатаКалендаря >= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
				ИНАЧЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
			КОНЕЦ)
ГДЕ
	(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
			ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
	РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
	Даты.Дата

ИМЕЮЩИЕ
	ВЫБОР
		КОГДА &РабочихДней < 0
			ТОГДА МИНИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
		ИНАЧЕ МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
	КОНЕЦ И
	ВЫБОР
		КОГДА &РабочихДней < 0
			ТОГДА КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = -&РабочихДней
		ИНАЧЕ КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней
	КОНЕЦ
...Показать Скрыть
10. Денис Луцик (NAKIS) 4 18.12.13 17:23 Сейчас в теме
новое решение или старое - но мне помогло. Автору спасибо огромное))))
11. ghOst Bu (ilonnaa) 12.02.14 10:45 Сейчас в теме
Автору +, жаль для бух 3.0 не подходит)
12. INTECH RU (INTECH1) 12.02.14 11:58 Сейчас в теме
(11) ilonnaa, а что там не так, регистр календаря что-ли по-другому называется?
13. ghOst Bu (ilonnaa) 12.02.14 21:17 Сейчас в теме
(12) INTECH RU, Там регистр по другому называется, + производственный календарь это справочник) ну все получилось, чуть запрос переписав, выложить не могу сервер выключился что-то( завтра если не забуду.
14. qwertor (qwertor) 06.08.14 13:28 Сейчас в теме
оставлю для коллекции вариант для Бух.3
Функция  ОтсчитатьРабочиеДни(ДатаОтсчета,Отсрочка)
	
Запрос = Новый Запрос;
Запрос.Текст = "Select 
	|	ДанныеПроизводственногоКалендаря.ПроизводственныйКалендарь,
	|	ДанныеПроизводственногоКалендаря.Дата,
	|	ДанныеПроизводственногоКалендаря.Год,
	|	ДанныеПроизводственногоКалендаря.ВидДня,
	|	ДанныеПроизводственногоКалендаря.ДатаПереноса
	|
	|into 
	| cal	
	|from 
	|	РегистрСведений.ДанныеПроизводственногоКалендаря КАК ДанныеПроизводственногоКалендаря
	|where 
	|   ДанныеПроизводственногоКалендаря.Дата between &ДатаОтсчета
	|  and DateAdd(&ДатаОтсчета, день, &Отсрочка*2 + 12)
	|;
	|	
	|Select  
	|min(дата) датаОтсрочки  
	|from(
	|Select 
	|
	|c1.дата дата,
	|
	|count(*) -1 РабочихДней
	|
	|from cal c1
	|left join   cal c2
	|on (c2.ВидДня = value(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный) or c2.ВидДня = value(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))
	|and c1.дата>=c2.дата
	|group by c1.дата
	|having count(*)= &Отсрочка+1
	|) tt
	|group by  РабочихДней";
попытка	
Запрос.УстановитьПараметр("ДатаОтсчета", ДатаОтсчета);
Запрос.УстановитьПараметр("Отсрочка", Отсрочка);
Результат = Запрос.Выполнить().Выгрузить();
Возврат Результат[0].датаОтсрочки; 
исключение
конецпопытки;

конецФункции
...Показать Скрыть
u_n_k_n_o_w_n; +1 Ответить
15. Captain Obvious (Obvious) 06.08.14 13:46 Сейчас в теме
Идея ок. Но задачка редко стоит просто отсечь празники. Рекомендую брать с графиков работы. Так как бух вряд ли полезет править произв календарь (он заходит правит в графике. а произв календарь виржин) ИМХО
16. Наталья Касперович (nik-boss) 28.05.15 09:43 Сейчас в теме
Спасибо Вам большое! Очень помогло быстро сделать необходимый отчет!
17. Николай (Nikola1147) 12.02.16 11:21 Сейчас в теме
ко второму соединению
полезно будет добавить условие типа (отмечено жирным)

ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
И (ДОБАВИТЬКДАТЕ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря)


иначе много доп сведений (дат) добавляется, которые не очень-то нужны,
разница в скорострельности ощутима на 3-х значениях В (&ВходящиеДаты)

Автору спасибо, очень помогло
u_n_k_n_o_w_n; +1 Ответить
18. Алексей Чухланцев (AvalonE2008) 91 10.01.17 12:10 Сейчас в теме
Решение действительно простое, но подойти с этой стороны не догадался.Спасибо
19. aleec bard (alexvbard) 16 16.02.17 16:19 Сейчас в теме
Мне одному кажется что не совсем верно считается добавление количество рабочих дней?
Если по запросу установить входящую дату 22.02.2017 и попросить добавить к дате 2 рабочих дня то запрос выдает 27.02.2017.
Ну а должен наверно 28.02.2017
20. Дмитрий Иванов (whoo) 16.02.17 16:34 Сейчас в теме
(19) почему 28 то? 22 февраля 2017 (это среда) + два рабочих дня (четверг, пятница) = 22,23,24 февраля. 25 и 26 - выходные дни. Соответственно ближайший день 27 февраля выпадает. Откуда 28 должно быть?
21. aleec bard (alexvbard) 16 18.02.17 14:07 Сейчас в теме
23,24,25,26 февраля - это выходные дни... Соответственно ближайшие два рабочих дня это 27 и 28 число. Тогда даже не 28 а 1 марта....
(20)
22. Дмитрий Иванов (whoo) 20.02.17 10:02 Сейчас в теме
23. INTECH RU (INTECH1) 20.02.17 12:33 Сейчас в теме
(21) в статье есть табличка как пример работы, в ней видно, что сама входящая дата (если это рабочий день) тоже входит в количество добавляемых рабочих дней.
24. aleec bard (alexvbard) 16 20.02.17 20:27 Сейчас в теме
(23)
Понятно. В общем нужно поиграться чтобы получить нужный результат.
25. script Мальчинко (script) 198 15.05.17 12:35 Сейчас в теме
В общем работает что-то нет так

08.02.2015 + 7 дней получаю 13.02.2015 хотя явно должно быть 16.02.2015 (это если учитывать начальную дату 08.02.2015)
но эта дата является выходным днем, поэтому учитывать ее нельзя, а в этом случае результатом должен быть 17.02.2015
но ни как не 13.02.2015.
Короче не работает.
26. Олег Веселов (sml) 36 09.06.17 10:08 Сейчас в теме
а так будет оптимальнее (работает в 10 раз быстрее)
ВЫБРАТЬ
	ПК.Дата КАК Дата,
	ПК.ВидДня КАК ВидДня
ПОМЕСТИТЬ Рабочие
ИЗ
	РегистрСведений.ДанныеПроизводственногоКалендаря КАК ПК
ГДЕ
	ПК.Дата МЕЖДУ ДОБАВИТЬКДАТЕ(&тДата, МЕСЯЦ, -2) И ДОБАВИТЬКДАТЕ(&тДата, ДЕНЬ, 15)
	И ПК.ВидДня В (ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий), ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный))
;
ВЫБРАТЬ
	Даты.Дата,
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.Дата)-1 КАК КоличествоРабочихДней,
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.Дата) КАК ДатаКалендаря,
	РегламентированныйПроизводственныйКалендарь1.Дата КАК ДатаКалендаряДляГруппировки
ИЗ
	РегистрСведений.ДанныеПроизводственногоКалендаря КАК РегламентированныйПроизводственныйКалендарь
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Рабочие КАК Даты
		ПО (РегламентированныйПроизводственныйКалендарь.Дата Между Даты.Дата И ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, 20))
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ДанныеПроизводственногоКалендаря КАК РегламентированныйПроизводственныйКалендарь1
		ПО РегламентированныйПроизводственныйКалендарь.Дата <= РегламентированныйПроизводственныйКалендарь1.Дата
			И ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, 20) > РегламентированныйПроизводственныйКалендарь1.Дата
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.апкОбщиеНастройки КАК ЧасыОплатыЗаявки
		ПО (ЧасыОплатыЗаявки.Настройка = ЗНАЧЕНИЕ(ПланВидовХарактеристик.апкОбщиеНастройки.ЧасовОтСозданияЗаявкиДСДоВыполненияЗаказаРассылка))
ГДЕ
	РегламентированныйПроизводственныйКалендарь.ВидДня В (ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий), ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный))

СГРУППИРОВАТЬ ПО
	РегламентированныйПроизводственныйКалендарь1.Дата,
	Даты.Дата,
	ЧасыОплатыЗаявки.Значение

ИМЕЮЩИЕ
	МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.Дата) = РегламентированныйПроизводственныйКалендарь1.Дата
	И КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.Дата)-1 = ВЫРАЗИТЬ(ВЫРАЗИТЬ(ЧасыОплатыЗаявки.Значение КАК ЧИСЛО(10, 0))/24 КАК ЧИСЛО(10, 0))
...Показать Скрыть


добавил условие на соединение РегламентированныйПроизводственныйКалендарь1
Оставьте свое сообщение