Чтение csv файлов

Функция РазложитьСрокуCSVВМассивподстрок(Строка, Разделитель = ",") Экспорт 

	Длина = СтрДлина(Строка);
	
	ПредыдущийСимволКавычка = Ложь;
	ОткрытаКавычка = Ложь;
	
	МассивСлов = Новый Массив;
	Слово = "";
	
	Для Сч = 1 По Длина Цикл      
		
		Симв = Сред(Строка, Сч, 1);    
		
		Если Симв = """" Тогда  
			
			Если ПредыдущийСимволКавычка Тогда  
				Слово = Слово + """"; 
				ПредыдущийСимволКавычка = Ложь;
			ИначеЕсли ОткрытаКавычка Тогда
				ПредыдущийСимволКавычка = Истина;
			Иначе
				ОткрытаКавычка = Истина;
			КонецЕсли;
			
		Иначе  
			
			Если ПредыдущийСимволКавычка Тогда 
				ОткрытаКавычка = Ложь;   
				ПредыдущийСимволКавычка = Ложь;
			КонецЕсли;
			
			
			Если ОткрытаКавычка Тогда    
				Слово = Слово + Симв; 
			Иначе
				Если Симв = Разделитель Тогда 
					МассивСлов.Добавить(Слово);
					Слово = "";    
				Иначе 
					Слово = Слово + Симв;
				КонецЕсли;
			КонецЕсли;
			
		КонецЕсли; 
		
	КонецЦикла;
	
	МассивСлов.Добавить(Слово); // Добавляем последнее встреченное слово


	Возврат МассивСлов;

КонецФункции // ()

Функция РегулярноеВыражениеДляCSV(Разделитель) Экспорт 
	
	//Шаблон = "(?:%1""|^"")(""|[\w\W]*?)(?=""%1|""$)|(?:%1(?!"")|^(?!""))([^%1]*?)(?=$|%1)|(\r\n|\n)" ;   
	Шаблон = "(?:(?<=%1)|^)(?:""([^""]*(?:""""[^""]*)*)""|([^""%1]*))";
	
	Возврат СтрШаблон(Шаблон, Разделитель);

КонецФункции // ()


Функция РазложитьСтрокуCSVВМассивПодстрок_Регулярка(Строка, РегулярноеВыражение) Экспорт   
	
	МассивРезультатов = СтрНайтиВсеПоРегулярномуВыражению(Строка, РегулярноеВыражение, Истина);  
	Массив = Новый Массив;
	
	Для каждого Результат Из МассивРезультатов Цикл 
		
		Значение = Результат.Значение; 
		Длина = Результат.Длина;
		
		Если СтрНачинаетсяС(Значение, """") Тогда  
			Значение = Прав(Значение, Длина - 1);  
			Длина = Длина - 1;
		КонецЕсли; 
		
		Если СтрЗаканчиваетсяНа(Значение, """") Тогда  
			Значение = Лев(Значение, Длина - 1);
		КонецЕсли;  
		
		Значение = СтрЗаменить(Значение, """""", """");
		
		Массив.Добавить(Значение);
		
	КонецЦикла;
	
	Возврат Массив;

КонецФункции // ()

Функция ФайлCSVВТаблицуЗначений(АдресФайлаВХ, Разделитель = ",", ДопПараметры = Неопределено) Экспорт      
	
	ДД = ПолучитьИзВременногоХранилища(АдресФайлаВХ);
	
	Поток = ДД.ОткрытьПотокДляЧтения();
	Чтение =  Новый ЧтениеТекста(Поток);
	
	Если ЗначениеЗаполнено(ОбщегоНазначенияКлиентСервер.СвойствоСтруктуры(ДопПараметры, "Шапка", Неопределено)) Тогда
		Шапка = ДопПараметры.Шапка;
	Иначе
		Шапка = Чтение.ПрочитатьСтроку();
	КонецЕсли;
	
	МассивКолонок = РазложитьСрокуCSVВМассивподстрок(Шапка, Разделитель);
	
	ТЗ = Новый ТаблицаЗначений;   
	
	КвСтроки = Новый КвалификаторыСтроки(999);
	КвЧисла  = Новый КвалификаторыЧисла(25, 2);
	КвДаты   = Новый КвалификаторыДаты(ЧастиДаты.ДатаВремя);
	
	ТипОбщий  = Новый ОписаниеТипов("Строка, Число, Дата, Булево", КвЧисла, КвСтроки, КвДаты);
	
	Для каждого Колонка Из МассивКолонок Цикл 
		
		Если ЗначениеЗаполнено(Колонка) Тогда  
			
			КолонкаТехИмя = СтроковыеФункцииКлиентСервер.ЗаменитьОдниСимволыДругими(""", !@#$%^&*()*-+=/\", Колонка, "");
			ТЗ.Колонки.Добавить(КолонкаТехИмя, ТипОбщий, Колонка);
			
		КонецЕсли;
		
	КонецЦикла;  
	
	
	КоличествоКолонок = ТЗ.Колонки.Количество(); 
	СчетОшибок = 0;    
	РегулярноеВыражение = РегулярноеВыражениеДляCSV(Разделитель);	
	
	ЧтениеПродолжается = Истина;
	Пока ЧтениеПродолжается Цикл     
		
		Строка = Чтение.ПрочитатьСтроку();
		
		Если Строка <> Неопределено Тогда  
			
			МассивЗначений = РазложитьСтрокуCSVВМассивПодстрок_Регулярка(Строка, РегулярноеВыражение);
			
			Если МассивЗначений.Количество() <> КоличествоКолонок Тогда
				
				СчетОшибок = СчетОшибок + 1;  
				ЗаписьЖурналаРегистрации("Не удалось разобрать csv строку!", УровеньЖурналаРегистрации.Предупреждение, ,, Строка);
				Продолжить;
				
			КонецЕсли;
			
			НовСтр = ТЗ.Добавить();
			Для НомКол = 0 По КоличествоКолонок - 1 Цикл        
				НовСтр[НомКол] = МассивЗначений[НомКол];            
			КонецЦикла;
			
		Иначе
			
			ЧтениеПродолжается = Ложь;
			Поток.Закрыть();
			
		КонецЕсли;
		
	КонецЦикла; 
	
	Возврат ТЗ;	
	
КонецФункции // ()