Мобильное приложение 1С: работа с push-уведомлениями Firebase Cloud Messaging

// формируем JWT-токен
ТокенJWT = Новый ТокенДоступа;
ТокенJWT.Эмитент = ДанныеЗакрытогоКлюча.client_email; // iss
ТокенJWT.ВремяСоздания = УниверсальноеВремя(ТекущаяДата()) - Дата(1970, 1, 1, 0, 0, 0); // iat
ТокенJWT.ВремяЖизни = 3600; // exp
ТокенJWT.ПолезнаяНагрузка.Вставить("scope", "https://www.googleapis.com/auth/firebase.messaging");
ТокенJWT.ПолезнаяНагрузка.Вставить("aud", "https://oauth2.googleapis.com/token");
ТокенJWT.ПолезнаяНагрузка.Вставить("sub", ДанныеЗакрытогоКлюча.client_email);
ТокенJWT.Подписать(АлгоритмПодписиТокенаДоступа.RS256, КлючОчищенный);

// отправляем готовый JWT в Google Auth для получения Access Token
Соединение = Новый HTTPСоединение("oauth2.googleapis.com",,,,,, Новый ЗащищенноеСоединениеOpenSSL());
Запрос = Новый HTTPЗапрос("/token");
ТелоЗапроса = "grant_type=urn:ietf:params:oauth:grant-type:jwt-bearer"
        + "&assertion=" + Строка(ТокенJWT);

Запрос.Заголовки.Вставить("Content-Type", "application/x-www-form-urlencoded");
Запрос.Заголовки.Вставить("Content-Charset", "utf-8");
Запрос.УстановитьТелоИзСтроки(ТелоЗапроса, КодировкаТекста.UTF8);
Попытка
    Ответ = Соединение.ОтправитьДляОбработки(Запрос);
    Если Ответ.КодСостояния = 200 Тогда
        СтруктураОтвета = ПрочитатьЗначениеJSON(Ответ.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8));
    Иначе
        ЗаписьЖурналаРегистрации("FCM.Ошибка", УровеньЖурналаРегистрации.Ошибка,,, Ответ.ПолучитьТелоКакСтроку());
        Возврат Неопределено;
    КонецЕсли;
Исключение
    ЗаписьЖурналаРегистрации("FCM.Ошибка", УровеньЖурналаРегистрации.Ошибка,,, ОписаниеОшибки());
    Возврат Неопределено;
КонецПопытки;

PrivateKeyInfo ::= SEQUENCE {
    version                 Version,
    privateKeyAlgorithm     PrivateKeyAlgorithmIdentifier,
    privateKey              PrivateKey,
    attributes          [0] IMPLICIT Attributes OPTIONAL }

Функция КонвертироватьPKCS8_в_PKCS1(Знач СтрокаPKCS8) Экспорт
    // очищаем текст файла ключа от заголовков и переносов, чтобы получить чистый Base64
    ЧистыйBase64 = СтрЗаменить(СтрокаPKCS8, "-----BEGIN PRIVATE KEY-----", "");
    ЧистыйBase64 = СтрЗаменить(ЧистыйBase64, "-----END PRIVATE KEY-----", "");
    ЧистыйBase64 = СтрЗаменить(ЧистыйBase64, Символы.ВК, "");
    ЧистыйBase64 = СтрЗаменить(ЧистыйBase64, Символы.ПС, "");
    ЧистыйBase64 = СокрЛП(ЧистыйBase64);

    // декодируем Base64 в двоичные данные и читаем в буфер
    ДвоичныеДанныеPKCS8 = Base64Значение(ЧистыйBase64);
    Буфер = ПолучитьБуферДвоичныхДанныхИзДвоичныхДанных(ДвоичныеДанныеPKCS8);

    Указатель = 0;

    // проверяем корневой тег Sequence (0x30)
    ТегSequence = Буфер.Прочитать(Указатель, 1)[0]; Указатель = Указатель + 1;
    Если ТегSequence <> 48 Тогда // 0x30 это 48
        ВызватьИсключение "Неверный формат ASN.1: Ожидался Sequence (0x30)";
    КонецЕсли;

    // читаем поле Version (Integer, обычно 0x02 0x01 0x00)
    ТегVersion = Буфер.Прочитать(Указатель, 1)[0]; Указатель = Указатель + 1;
    ДлинаVersion = ПрочитатьДлинуASN1(Буфер, Указатель);
    Указатель = Указатель + ДлинаVersion; // пропускаем значение версии

    // читаем поле AlgorithmIdentifier (Sequence, описывающий RSA алгоритм)
    ТегAlgId = Буфер.Прочитать(Указатель, 1)[0]; Указатель = Указатель + 1;
    ДлинаAlgId = ПрочитатьДлинуASN1(Буфер, Указатель);
    Указатель = Указатель + ДлинаAlgId; // пропускаем блок идентификатора алгоритма

    // читаем поле PrivateKey (тег Octet String = 0x04)
    ТегPrivateKey = Буфер.Прочитать(Указатель, 1)[0]; Указатель = Указатель + 1;
    Если ТегPrivateKey <> 4 Тогда // 0x04 = 4
        ВызватьИсключение "Неверный формат PKCS#8: Ожидался Octet String (0x04)";
    КонецЕсли;

    ДлинаPrivateKey = ПрочитатьДлинуASN1(Буфер, Указатель);

    // содержимое этого Octet String и есть наш PKCS#1 ключ (включая его собственный Sequence)
    БуферPKCS1 = Буфер.Прочитать(Указатель, ДлинаPrivateKey);

    // превращаем обратно в двоичные данные 1С
    ДвоичныеДанныеPKCS1 = ПолучитьДвоичныеДанныеИзБуфераДвоичныхДанных(БуферPKCS1);
    Base64PKCS1 = Base64Строка(ДвоичныеДанныеPKCS1);

    Возврат "-----BEGIN RSA PRIVATE KEY-----" + Символы.ПС + Base64PKCS1 + Символы.ПС + "-----END RSA PRIVATE KEY-----";
КонецФункции

Функция ПрочитатьДлинуASN1(Буфер, Указатель)
    ПервыйБайт = Буфер.Получить(Указатель);
    Указатель = Указатель + 1;

    // если старший бит не установлен (длина < 128), это и есть готовая длина
    Если ПервыйБайт < 128 Тогда
        Возврат ПервыйБайт;
    КонецЕсли;

    // в противном случае младшие 7 бит задают количество последующих байт
    КоличествоБайтДлины = ПервыйБайт - 128;
    РезультатДлина = 0;
    Для Счетчик = 1 По КоличествоБайтДлины Цикл
        РезультатДлина = (РезультатДлина * 256) + Буфер.Получить(Указатель);
        Указатель = Указатель + 1;
    КонецЦикла;

    Возврат РезультатДлина;
КонецФункции