Описание функции ВыгрузитьПоПравилу().
Функция ВыгрузитьПоПравилу() используется для выгрузки объекта в xml-узел и возвращает узел ссылки на этот объект.
В процессе выгрузки эта функция вызывается из:
ПВД, когда объект из выборки получен и необходимо произвести его конвертацию.
ПКО, когда необходимо выгрузить связанную с выгружаемым объектом информацию.
ПКС, когда свойство имеет ссылочный тип и необходимо выгрузить по ссылке из этого свойства объект.
Из функции ВыгрузитьПоПравилу() могут быть вызваны другие функции, выгружающие субконто, свойства и т.д. этого объекта, а из этих функций – рекурсивно может быть вызвана функция ВыгрузитьПоПравилу(). После того, как объект со всеми необходимыми свойствами выгружен, управление возвращается в то место кода, откуда функция была вызвана. Таким образом, вызов этой функции из обработчиков событий какого-либо правила (ПВД, ПКО, ПКС), не изменяет процесса выгрузки объекта по этому правилу.
Функция ВыгрузитьПоПравилу() имеет ряд параметров
ВыгрузитьПоПравилу(Источник,
Приемник,
ВходящиеДанные,
ИсходящиеДанные,
ИмяПКО,
УзелСсылки,
ТолькоПолучитьУзелСсылки,
ПКО,
ЭтоПравилоСГлобальнойВыгрузкойОбъектов,
ВыборкаДляВыгрузкиДанных)
Все эти параметры в функции имеют значения по умолчанию, и, как правило, передавать имеет смысл только параметр ИмяПКО, а также параметры Источник и/или ВходящиеДанные – в зависимости от того, как настроено ПКО.
ИмяПКО – строка, название ПКО, в которое передаем управление.
Источник – ссылка на элемент объекта-источника, который передаем для конвертации.
ВходящиеДанные – структура. Элементы в ней должны быть названы аналогично ПКС, у которых стоит флаг «Получить из входящих данных». Если таких ПКС нет, передавать этот параметр не нужно. Если в ПКО у всех ПКС стоит флаг «Получить из входящих данных», то, наоборот, необходимо передать структуру ВходящиеДанные, а Источник тогда передавать не нужно.
Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника.
Необходимость в такой задаче может возникнуть, когда объект "источника" и объект "приемника" имеют различную смысловую или функциональную структуру.
Например, документ "источника" позволяет вводить информацию по нескольким подразделениям предприятия, документ "приемника" позволяет вводить информацию только об одном подразделении предприятия.
Данная задача отлично решается при помощи произвольного алгоритма выборки в ПВД, но данное решение имеет два недостатка:
- Мы лишаемся механизма регистрации изменений;
- Алгоритм произвольной выборки отказывается работать в БСП.
БСП - библиотека стандартных подсистем. В частности, имеет своем составе подсистему "Обмен данными", данная подсистема реализует механизмы автоматической синхронизации данных между конфигурациями, по правилам написанным в Конвертации данных.
- Создаем ПВД со Стандартным алгоритмом выборки;
- Указываем объект выборки;
- Пишем обработчик "Перед выгрузкой"(хочу подчеркнуть, что нужно использовать именно этот обработчик). Например, следующего содержания:
//Начинаем отбор данных для выгрузки
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ РАЗЛИЧНЫЕ
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации КАК Подразделение,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Должность,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ЗанимаемыхСтавок КАК Ставка,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ДатаПриема,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник.ВидЗанятости КАК ВидЗанятости,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Дата,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Номер,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Проведен,
| ВЫБОР
| КОГДА ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета = ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОкладПоЧасам)
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК СдельнаяОплатаТруда,
| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета КАК ВидРасчета
|ИЗ
| Документ.ПриемНаРаботуВОрганизацию.РаботникиОрганизации КАК ПриемНаРаботуВОрганизациюРаботникиОрганизации
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриемНаРаботуВОрганизацию.ОсновныеНачисления КАК ПриемНаРаботуВОрганизациюОсновныеНачисления
| ПО ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = ПриемНаРаботуВОрганизациюОсновныеНачисления.Ссылка
| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник = ПриемНаРаботуВОрганизациюОсновныеНачисления.Сотрудник
|ГДЕ
| ВЫБОР
| КОГДА &ИспользоватьОтборПоПодразделениям ТОГДА
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации В ИЕРАРХИИ (&Подразделения)
| ИНАЧЕ
| ИСТИНА
| КОНЕЦ
| И ВЫБОР
| КОГДА &ИспользоватьОтборПоВидамРасчета ТОГДА
| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета В ИЕРАРХИИ (&ВидРасчета)
| ИНАЧЕ
| ИСТИНА
| КОНЕЦ
| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = &Ссылка";
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоВидамРасчета);
Запрос.УстановитьПараметр("Ссылка", Объект.Ссылка);
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоПодразделениям);
ВыбранныеДанные = Неопределено;
ПустаяТабличнаяЧасть = Неопределено;
Выполнить(Алгоритмы.ПолучитьСтруктуруВыгрузкиКадровыхДокументов);
РезультатЗапроса = Запрос.Выполнить().Выгрузить();
Сотрудники = ПустаяТабличнаяЧасть.Скопировать();
СтрокаДокумента = Неопределено;
Для Каждого СтрокаРезультата Из РезультатЗапроса Цикл
ДанныеИзВнешнихСистем = "Выгружено из ЗиКБУ, документ ""Прием на работу в организацию"" №" + СтрокаРезультата.Номер + " от " + Формат(СтрокаРезультата.Дата, "ДФ=dd.MM.yyyy") +
", " + СтрокаРезультата.Подразделение.Наименование;
СтрокаДокумента = ВыбранныеДанные.Найти(ДанныеИзВнешнихСистем);
Если СтрокаДокумента = Неопределено Тогда
СтрокаДокумента = ВыбранныеДанные.Добавить();
СтрокаДокумента.Дата = СтрокаРезультата.ДатаПриема;
СтрокаДокумента.Кафедра = СтрокаРезультата.Подразделение;
СтрокаДокумента.Проведен = СтрокаРезультата.Проведен;
СтрокаДокумента.ДокументСАктивнымиДолжностями = Истина;
СтрокаДокумента.ДанныеИзВнешнихСистем = ДанныеИзВнешнихСистем;
СтрокаДокумента.АктивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
СтрокаДокумента.НеактивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
КонецЕсли;
СтрокаРаботников = СтрокаДокумента.АктивныеДолжности.Добавить();
СтрокаРаботников.Должность = СтрокаРезультата.Должность;
СтрокаРаботников.Сотрудник = СтрокаРезультата.Сотрудник.Физлицо;
СтрокаРаботников.Ставка = СтрокаРезультата.Ставка * 100;
СтрокаРаботников.ВидНачисления = СтрокаРезультата.ВидРасчета;
СтрокаРаботников.ВидЗанятости = СтрокаРезультата.ВидЗанятости;
КонецЦикла;
//Переводим отобранные данные из Таблицы значений в Массив структур для дальнейшей передачи в ПКО
ДокументыЗакреплениеЗаКафедрой = Неопределено;
Выполнить(Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой);
//Обходим отобранные данные и выгружаем с помощью функции ВыгрузитьПоПравилу
Для каждого Документ Из ДокументыЗакреплениеЗаКафедрой Цикл
ВыгрузитьПоПравилу(,,Документ,,"ЗакреплениеЗаКафедройИзВходящихДанных");
КонецЦикла;
//Отменяем стандартную выгрузку объекта
Отказ = Истина;
Большую часть этого обработчика, как вы можете видеть, занимает отбор данных необходимых для выгрузки. Тут и множество фильтров: по подразделениям, по видам расчетов и механизм разбиения одного документа "источника" на несколько документов "приемника". Если коротко, то в данном примере табличная часть одного документа "источника" разносится по табличным частям нескольких документов "приемника", а значением разбиения данных является значение Подразделения.
Для удобства работы при отборе данных мы использовали Таблицу значений, наш алгоритм подразумевает ПКО с получением данных из "входящих данных", которые будут переданы в функцию ВыгрузитьПоПравилу, поэтому в соответсвующем алгоритме мы производим перевод Таблицы значений в Массив структур.
На следующем шаге мы обходим отобранные данные и вот уже в этом месте мы используем нашу функцию ВыгрузитьПоПравилу. Параметр Документ, здесь является структурой, которую мы передаем как входящие данные, а второй передаваемый нами параметр, это название ПКО, которому мы передаем наши данные.
В самом конце мы отменяем выполнение стандартной выгрузки, так как все необходимые данные связанные с объектом выборки мы уже выгрузили.
Тем самым мы сохраняем функциональность регистрации изменений - документ изменился, зарегистрировался для выгрузки, данные выгрузили. И в то же время делаем произвольный отбор необходимых нам данных.
В ПКО в этом случае для свойств необходимо указать, что они получаются из "Входящих данных".
Выгрузка Регистр сведений -> Регистр сведений с зависимостью от переноса другого объекта.
Типичным примером такой задачи является перенос контактной информации физического лица. Простейший способ решения задачи - это перенос всех "Физических лиц" и всего регистра сведений "Контактная информация" физических лиц. Что делать если нам необходимо переносить не всех физических лиц? Например, только тех физических лиц, которые упоминаются в каком-либо переносимом нами документе. В таком случае, как известно, ПКС документа вызывает ПКО справочника "Физические лица" и тем самым обеспечивается перенос физических лиц упоминаемых в документе.
В переносе "Контактной информации" физических лиц в данной ситуации может помочь функция ВыгрузитьРегистр, очень похожая на функцию ВыгрузитьПоПравилу.
Хочу отметить, что потребность в использовании функции ВыгрузитьРегистр у меня появилась, когда я начал адаптировать правила под БСП уже отлаженные на обработке Универсальный обмен XML. Регистры через обработку спокойно выгружались с использованием функции ВыгрузитьПоПравилу, но БСП ни как не хотело правильно понимать такую выгрузку, в результате чего пришлось переписывать код через ВыгрузитьРегистр.
В обработчике"После выгрузки в файл" ПКО "Физические лица", пишем код следующего вида:
//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| КонтактнаяИнформация.Представление,
| КонтактнаяИнформация.Вид,
| КонтактнаяИнформация.Тип,
| КонтактнаяИнформация.Объект
|ИЗ
| РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
|ГДЕ
| КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
| И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
| И КонтактнаяИнформация.Объект = &Объект";
Запрос.УстановитьПараметр("Объект", Источник);
Выборка = Запрос.Выполнить ().Выбрать ();
Пока Выборка.Следующий () Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "Объект";
СтрокаОтбора.Значение = Выборка.Объект;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Представление");
Строки.Колонки.Добавить("Вид");
Строки.Колонки.Добавить("Тип");
Строки.Колонки.Добавить("Объект");
Строка = Строки.Добавить();
Строка.Представление = Выборка.Представление;
Строка.Вид = Выборка.Вид;
Строка.Тип = Выборка.Тип;
Строка.Объект = Выборка.Объект;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");
КонецЦикла;
Как видно, в коде отбираются все записи регистра сведений, относящиеся к текущему выгружаемому Физическому лицу, а полученная выборка обходится в цикле.
Для того, чтобы выгрузить записи регистра сведений через функцию ВыгрузитьРегистр, необходимо подготовить структуру НаборЗаписей, которая имеет два поля: Отбор и Строки.
ПКО "КонтактнаяИнформация" имеет следующий вид:
Выгрузка Табличная часть -> Регистр сведений.
По своему решению задача аналогична предыдущей. С той лишь разницей, что информацию для регистра сведений "приемника" брать придется из других объектов "источника", а точнее табличной части того объекта, который на данный момент выгружается. Если бы на стороне "приемника" была так же табличная часть, то задача легко решалась бы в виде ПГКС. Поэтому снова воспользуемся функцией ВыгрузитьРегистр.
Рассмотрим пример переноса информации по ученым степеням Физического лица. Опять создаем код в обработчике "После выгрузки в файл" ПКО "Физические лица". Так как задача аналогичная предыдущей привожу только, код отбора и выгрузки данных из обработчика:
///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ФизическиеЛицаУченыеСтепени.Ссылка,
| ФизическиеЛицаУченыеСтепени.УченаяСтепень,
| ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
| ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
| ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
|ИЗ
| Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
|ГДЕ
| ФизическиеЛицаУченыеСтепени.Ссылка = &ФизЛицо";
Запрос.УстановитьПараметр("ФизЛицо", Источник);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "ФизическоеЛицо";
СтрокаОтбора.Значение = Выборка.Ссылка;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Ссылка");
Строки.Колонки.Добавить("ФизическоеЛицо");
Строки.Колонки.Добавить("УченаяСтепень");
Строки.Колонки.Добавить("Специальность");
Строки.Колонки.Добавить("НомерДиплома");
Строки.Колонки.Добавить("Период");
Строка = Строки.Добавить();
Строка.ФизическоеЛицо = Выборка.Ссылка;
Строка.УченаяСтепень = Выборка.УченаяСтепень;
Строка.Специальность = Выборка.ОтрасльНауки;
Строка.НомерДиплома = Выборка.ДипломСерияНомер;
Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");
КонецЦикла;
Выгрузка Табличная часть -> Документ.
Предположим, в "источнике" информация для переноса хранится в менее детализированном виде, чем в приемнике, но достаточном для переноса. Например, мной решалась задача по переносу информации об образовании физических лиц из ЗиКБУ в Университет. Понятно, что на стороне кадровой программы нужна минимальная информация об образовании физических лиц, главное что сотрудник обладает необходимой квалификацией и хватит. А вот на стороне университета, информация об образовании, а точнее о дипломах хранится куда более подробно, в связи со спецификой учереждения.
И опять задача решается, при помощи все той же функции ВыгрузитьПоПравилу.
Вот пример выгрузки Дипломов физических лиц. Все тот же обработчик "После выгрузки в файл" ПКО "Физические лица", пишем следующий код:
///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ФизическиеЛицаОбразование.Ссылка КАК Студент,
| ФизическиеЛицаОбразование.ВидОбразования,
| ФизическиеЛицаОбразование.УчебноеЗаведение,
| ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
| ФизическиеЛицаОбразование.Диплом,
| ФизическиеЛицаОбразование.ГодОкончания,
| ФизическиеЛицаОбразование.Квалификация
|ИЗ
| Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
|ГДЕ
| ФизическиеЛицаОбразование.Ссылка = &ФизЛицо";
Запрос.УстановитьПараметр("ФизЛицо", Источник);
РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
ВходящиеДанные = Новый Структура;
ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
СерияДиплома = "";
НомерДиплома = "";
Выполнить(Алгоритмы.ПолучитьСериюИНомер);
ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
Иначе
ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
КонецЕсли;
ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;
Тут мы отбираем данные из табличной части и формируем входящие данные для документа на стороне "приемника", после чего при помощи функции ВыгрузитьПоПравилу, передаем входящие данные ПКО ДипломИзВходящихДанных, которое имеет следующий вид:
В общем, как вы понимаете, можно приводить еще много вариаций перегрузок: справочники, документы, регистры. Главное, надо понимать, что не стоит фанатично бросаться на функции ВыгрузитьПоПравилу и ВыгрузитьРегистр.
Замечания по перегрузке.
1. У меня возникли сложности при использовании правил в БСП, в части выгрузки объектов по ссылкам, проблема решилась принудительной установкой параметра ВыгрузитьОбъект в значение Истина, для каждого ПКС ссылочного типа:
2. Надо помнить, что при выгрузке через указанные функции, зачастую отсутствует УникальныйИдентификатор объекта, например, когда объект для выгрузки собирается по частям в виде структуры ВходящихДанных, поэтому поиск по уникальному идентификатору придется отключить.
Подводим итоги. Когда использовать эти функции?
- Вам необходимо перегрузить объекты с сильно различной структурой или на стороне "источника" необходимо собирать объекты для выгрузки из разных объектов.
- Вам необходимо перегружать объекты с привязкой к выгрузке других объектов.
UPDATE от 11.11.2015
А что если оптимизировать выше написанное?
Пишу дополнение к статье, после оставленного пользователем TarasovAV комментария. Данный пользователь заметил, что можно оптимизировать выгрузку связанной информации, путем накопления списка тех объектов, информацию о которых надо будет отдельно выгружать, а потом через один запрос отобрать сразу всю информацию.
Описываю алгоритм предложенный вышеуказанным пользователем:
1. В правиле конвертации "После загрузки правил обмена", создается параметр типа ТаблицаЗначений, в который будет накапливаться список объектов, для которых в последующем будет выгружаться информация:
Параметры.Вставить("СписокФизическихЛиц", Новый ТаблицаЗначений());
Параметры.СписокФизическихЛиц.Колонки.Добавить("ФизическоеЛицо");
2. В в обработчике "После выгрузки" ПКО "Физические лица" (именно для них в примерах мы выгружаем контактные данные, образование и т.п.), мы пополняем нашу таблицу значений новым физическим лицом, проверяя перед этим, а не добавлено ли уже это физическое лицо в таблицу:
НайденнаяСтрока = Параметры.СписокФизическихЛиц.Найти(Источник);
Если НайденнаяСтрока = Неопределено Тогда
НоваяСтрока = Параметры.СписокФизическихЛиц.Добавить();
НоваяСтрока.ФизическоеЛицо = Источник;
КонецЕсли;
3. И финальным действием, будет непосредственная выгрузка информации, только уже с отбором по все физическим лицам сразу. Для этого все обработчики, что были приведены выше начиная, необходимо перенести в правило конвертации "После выгрузки данных", запросы же необходимо изменить, чтобы в них проверялось не равенство одному элементу, а вхождение значения реквизита в массив элементов:
Обратите внимание, как изменилась установка параметра запроса и проверка условия в запросе:
//...
"| И КонтактнаяИнформация.Объект В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
//...
Привожу полный код, исправленных ранее приведенных примеров:
//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| КонтактнаяИнформация.Представление,
| КонтактнаяИнформация.Вид,
| КонтактнаяИнформация.Тип,
| КонтактнаяИнформация.Объект
|ИЗ
| РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
|ГДЕ
| КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
| И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
| И КонтактнаяИнформация.Объект В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
Выборка = Запрос.Выполнить ().Выбрать ();
Пока Выборка.Следующий () Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "Объект";
СтрокаОтбора.Значение = Выборка.Объект;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Представление");
Строки.Колонки.Добавить("Вид");
Строки.Колонки.Добавить("Тип");
Строки.Колонки.Добавить("Объект");
Строка = Строки.Добавить();
Строка.Представление = Выборка.Представление;
Строка.Вид = Выборка.Вид;
Строка.Тип = Выборка.Тип;
Строка.Объект = Выборка.Объект;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");
КонецЦикла;
///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ФизическиеЛицаОбразование.Ссылка КАК Студент,
| ФизическиеЛицаОбразование.ВидОбразования,
| ФизическиеЛицаОбразование.УчебноеЗаведение,
| ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
| ФизическиеЛицаОбразование.Диплом,
| ФизическиеЛицаОбразование.ГодОкончания,
| ФизическиеЛицаОбразование.Квалификация
|ИЗ
| Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
|ГДЕ
| ФизическиеЛицаОбразование.Ссылка В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
ВходящиеДанные = Новый Структура;
ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
СерияДиплома = "";
НомерДиплома = "";
Выполнить(Алгоритмы.ПолучитьСериюИНомер);
ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
Иначе
ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
КонецЕсли;
ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;
///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ФизическиеЛицаУченыеСтепени.Ссылка,
| ФизическиеЛицаУченыеСтепени.УченаяСтепень,
| ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
| ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
| ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
|ИЗ
| Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
|ГДЕ
| ФизическиеЛицаУченыеСтепени.Ссылка В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "ФизическоеЛицо";
СтрокаОтбора.Значение = Выборка.Ссылка;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Ссылка");
Строки.Колонки.Добавить("ФизическоеЛицо");
Строки.Колонки.Добавить("УченаяСтепень");
Строки.Колонки.Добавить("Специальность");
Строки.Колонки.Добавить("НомерДиплома");
Строки.Колонки.Добавить("Период");
Строка = Строки.Добавить();
Строка.ФизическоеЛицо = Выборка.Ссылка;
Строка.УченаяСтепень = Выборка.УченаяСтепень;
Строка.Специальность = Выборка.ОтрасльНауки;
Строка.НомерДиплома = Выборка.ДипломСерияНомер;
Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");
КонецЦикла; 
