Печать журнала регистрации по объекту

Перем СоответствиеСобытий;





Функция Печать() Экспорт
	ТабДокумент = Новый ТабличныйДокумент;
	ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ЖурналИзменений";

	ТаблицаДляПечати = ПолучитьТаблицуИзменений();

	Если ТаблицаДляПечати.Количество() = 0 Тогда
		Возврат ТабДокумент;
	КонецЕсли;

	Макет = ПолучитьМакет("Макет");

	ОбластьЗаголовок = Макет.ПолучитьОбласть("Шапка");
	ОбластьЗаголовок.Параметры.СсылкаНаОбъект = СсылкаНаОбъект;

	ТабДокумент.Вывести(ОбластьЗаголовок);

	ОбластьСтроки = Макет.ПолучитьОбласть("Строка");

	Для каждого СтрокаТаблицы Из ТаблицаДляПечати Цикл

		ОбластьСтроки.Параметры.Дата = СтрокаТаблицы.ДатаСобытия;
		ОбластьСтроки.Параметры.Событие = СтрокаТаблицы.Событие;
		ОбластьСтроки.Параметры.Пользователь = СтрокаТаблицы.Пользователь;

		ТабДокумент.Вывести(ОбластьСтроки);

	КонецЦикла;

	Возврат ТабДокумент;

КонецФункции


Функция ПолучитьТаблицуИзменений()
	ТаблицаИзменений = Новый ТаблицаЗначений;
	ТаблицаИзменений.Колонки.Добавить("ДатаСобытия");
	ТаблицаИзменений.Колонки.Добавить("Событие");
	ТаблицаИзменений.Колонки.Добавить("Пользователь");

	Если Не ЗначениеЗаполнено(СсылкаНаОбъект) Тогда
		Возврат ТаблицаИзменений;
	КонецЕсли;



	ВременныйФайл = ПолучитьИмяВременногоФайла("elf");

	СтруктураОтбора = Новый Структура;
	Если ЗначениеЗаполнено(ДатаНачала) Тогда
		СтруктураОтбора.Вставить("ДатаНачала", ДатаНачала);
	КонецЕсли;

	Если ЗначениеЗаполнено(ДатаОкончания) Тогда
		СтруктураОтбора.Вставить("ДатаОкончания", ДатаОкончания);
	КонецЕсли;

	СтруктураОтбора.Вставить("Данные", СсылкаНаОбъект);

	Состояние("Получение данных журнала регистрации");
	ВыгрузитьЖурналРегистрации(ВременныйФайл, СтруктураОтбора, "Дата, Пользователь, ИмяПользователя,  Событие");

	Состояние("Анализ данных журнала регистрации");

	ПараметрыЧтенияXML = Новый ПараметрыЧтенияXML(Неопределено, Неопределено, Неопределено, Неопределено, Истина, Истина, Истина, Истина, Истина);

	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.ОткрытьФайл(ВременныйФайл, ПараметрыЧтенияXML);
	ЧтениеXML.Прочитать();
	Если ЧтениеXML.Имя = "v8e:EventLog" Тогда
		Пока ЧтениеXML.Прочитать() Цикл
			Если ЧтениеXML.Имя = "v8e:Event" И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда

				ДатаСобытия = ПреобразоватьДату(ПрочитатьЗначениеТега(ЧтениеXML, "v8e:Date"));
				Событие = ПреобразоватьСобытие(ПрочитатьЗначениеТега(ЧтениеXML, "v8e:EventName"));
				ПользовательGUID = ПрочитатьЗначениеТега(ЧтениеXML, "v8e:UserID");
				ИмяПользователя = ПрочитатьЗначениеТега(ЧтениеXML, "v8e:UserName");

				Если ЗначениеЗаполнено(Событие) Тогда

					СтрокаТаблицы = ТаблицаИзменений.Добавить();
					СтрокаТаблицы.ДатаСобытия = ДатаСобытия;

					Если ПравоДоступа("Администрирование", Метаданные) Тогда
						ПользовательИБ = ПользователиИнформационнойБазы.НайтиПоУникальномуИдентификатору(Новый УникальныйИдентификатор(ПользовательGUID));
						Если ПользовательИБ <> Неопределено Тогда
							СтрокаТаблицы.Пользователь = ПользовательИБ;
						Иначе
							СтрокаТаблицы.Пользователь = ИмяПользователя + " <Удален>";
						КонецЕсли;
					Иначе
						СтрокаТаблицы.Пользователь = ИмяПользователя;
					КонецЕсли;
					СтрокаТаблицы.Событие = Событие;

				КонецЕсли;

			КонецЕсли;
		КонецЦикла;
	КонецЕсли;

	ЧтениеXML.Закрыть();
	УдалитьФайлы(ВременныйФайл);

	Возврат ТаблицаИзменений;

КонецФункции


Функция ПреобразоватьДату(ДатаXML)
	Дата1С = Дата('00010101000000');

	Если ДатаXML <> "" Тогда
		ТекстДаты = СтрЗаменить(ДатаXML, "-", "");
		ТекстДаты = СтрЗаменить(ТекстДаты, ":", "");
		ТекстДаты = СтрЗаменить(ТекстДаты, "T", "");
		Дата1С = Дата(ТекстДаты);
	КонецЕсли;

	Возврат Дата1С;

КонецФункции

Функция ПрочитатьЗначениеТега(ЧтениеXML, Имя)
	Результат = Неопределено;
	ЧтениеXML.Прочитать();

	Если ЧтениеXML.Имя = Имя И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
		ЧтениеXML.Прочитать();
		Результат = ЧтениеXML.Значение;
	КонецЕсли;
	ЧтениеXML.Прочитать();

	Возврат Результат;
КонецФункции


Функция ПреобразоватьСобытие(КлючЗначения)
	Возврат СоответствиеСобытий.Получить(КлючЗначения);

КонецФункции

СоответствиеСобытий = Новый Соответствие;
СоответствиеСобытий.Вставить("_$Session$_.Start", "Сеанс. Начало");
СоответствиеСобытий.Вставить("_$Session$_.Finish", "Сеанс. Завершение");
СоответствиеСобытий.Вставить("_$InfoBase$_.ConfigUpdate", "Информационная база. Изменение конфигурации");
СоответствиеСобытий.Вставить("_$InfoBase$_.DBConfigUpdate", "Информационная база. Изменение конфигурации базы данных");
СоответствиеСобытий.Вставить("_$InfoBase$_.EventLogSettingsUpdate", "Информационная база. Изменение параметров журнала регистрации");
СоответствиеСобытий.Вставить("_$InfoBase$_.InfoBaseAdmParamsUpdate", "Информационная база. Изменение параметров информационной базы");
СоответствиеСобытий.Вставить("_$InfoBase$_.MasterNodeUpdate", "Информационная база. Изменение главного узла");
СоответствиеСобытий.Вставить("_$InfoBase$_.RegionalSettingsUpdate", "Информационная база. Изменение региональных установок");
СоответствиеСобытий.Вставить("_$InfoBase$_.TARInfo", "Тестирование и исправление. Сообщение");
СоответствиеСобытий.Вставить("_$InfoBase$_.TARMess", "Тестирование и исправление. Предупреждение");
СоответствиеСобытий.Вставить("_$InfoBase$_.TARImportant", "Тестирование и исправление. Ошибка");
СоответствиеСобытий.Вставить("_$Data$_.New", "Данные. Добавление");
СоответствиеСобытий.Вставить("_$Data$_.Update", "Данные. Изменение");
СоответствиеСобытий.Вставить("_$Data$_.Delete", "Данные. Удаление");
СоответствиеСобытий.Вставить("_$Data$_.TotalsPeriodUpdate", "Данные. Изменение периода рассчитанных итогов");
СоответствиеСобытий.Вставить("_$Data$_.Post", "Данные. Проведение");
СоответствиеСобытий.Вставить("_$Data$_.Unpost", "Данные. Отмена проведения");
СоответствиеСобытий.Вставить("_$User$_.New", "Пользователи. Добавление");
СоответствиеСобытий.Вставить("_$User$_.Update", "Пользователи. Изменение");
СоответствиеСобытий.Вставить("_$User$_.Delete", "Пользователи. Удаление");
СоответствиеСобытий.Вставить("_$Job$_.Start", "Фоновое задание. Запуск");
СоответствиеСобытий.Вставить("_$Job$_.Succeed", "Фоновое задание. Успешное завершение");
СоответствиеСобытий.Вставить("_$Job$_.Fail", "Фоновое задание. Ошибка выполнения");
СоответствиеСобытий.Вставить("_$Job$_.Cancel", "Фоновое задание. Отмена");
СоответствиеСобытий.Вставить("_$PerformError$_", "Ошибка выполнения");
СоответствиеСобытий.Вставить("_$Transaction$_.Begin", "Транзакция. Начало");
СоответствиеСобытий.Вставить("_$Transaction$_.Commit", "Транзакция. Фиксация");
СоответствиеСобытий.Вставить("_$Transaction$_.Rollback", "Транзакция. Отмена.");