Отправка файлов через SOAP. SOAP with attachments, MTOM

Публикация № 1045578

Разработка - Системная интеграция - Интеграция с WEB

SOAP with Attachments MTOM веб сервисы

В продолжение «своеобразной» поддержки 1С протокола SOAP, описанной в https://infostart.ru/public/965259/, опишу еще одну особенность. 1С не поддерживает возможность отправки файлов-вложений. Для решения этой проблемы пришлось самостоятельно писать формирование пакетов SOAP и разбор ответов сервера.

Была задача сделать обмен 1С с  электронной торговой площадкой B2B-Center (https://www.b2b-center.ru/). У площадки есть SOAP интерфейс, но передача файлов поддерживается только по протоколу MTOM. Описание этого протокола есть здесь https://www.w3.org/TR/SOAP-attachments и здесь https://www.soapui.org/docs/soap-and-wsdl/attachments.html.

Если говорить кратко, то запрос SOAP представляет из себя HTTP POST запрос, в теле которого расположены данные в формате XML. Данные запрос представляют собой «конверт», содержащий заголовок запроса и тело запроса.  Если нужно отправить файл, то все сообщение оформляется multipart, одной частью является SOAP запрос, а файлы прикладываются как остальные части.


                                                         

 

Будем считать, что wsdl ссылка у нас успешно импортирована и мы может создавать XDTO объекты для обмена.

Местоположение = "https://demo.b2b-center.ru/market/remote_alternative.html";
URIПространстваИмен = "urn:ws";
ИмяСервиса = "ws";
ИмяТочкиПодключения = "wsPort";
АдресWSDL =  Местоположение + "?wsdl";
ИнтернетПрокси = ПолучениеФайловИзИнтернетаКлиентСервер.ПолучитьПрокси(АдресWSDL);
Таймаут = 120;
ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL;

WSПрокси = WSСсылки.WS_B2B_Center.СоздатьWSПрокси(URIПространстваИмен, ИмяСервиса, ИмяТочкиПодключения,
        ИнтернетПрокси, Таймаут, ЗащищенноеСоединение, Местоположение);

WSПрокси.Пользователь = "ИмяПользователя";
WSПрокси.Пароль       = "Пароль";


// отправка запроса без файлов
                ТипАвторизация      = WSПрокси.ФабрикаXDTO.Тип(URIПространстваИмен, "auth_info");
                ТипВнешнийИД        = WSПрокси.ФабрикаXDTO.Тип(URIПространстваИмен, "external_id");        
                Авторизация         = WSПрокси.ФабрикаXDTO.Создать(ТипАвторизация);
                
                Авторизация.token   = "Билет";
                ВнешнийИД           = WSПрокси.ФабрикаXDTO.Создать(ТипВнешнийИД);
                
                ВнешнийИД.id        = "Идентификатор";
                ВнешнийИД.type      = 0;
                
                Этап                = 0; //Номер этапа, 0 - основной, 1 - первая переторжка, 2 - вторая переторжка и т.д
                                
                ВходныеПараметры = Новый Структура;
                ВходныеПараметры.Вставить("auth",Авторизация);
                ВходныеПараметры.Вставить("auction_id",ИД_Аукциона);
                ВходныеПараметры.Вставить("external_id",ВнешнийИД);
                
                ВыходныеПараметры = Новый Структура;
                ВыходныеПараметры.Вставить("return","ret_auction_position");
                
                // получим данные по позициям от площадки для связки позиций в 1С и на площадке
                ОтветСервера = ОтправитьSOAPЗапрос(WSПрокси,URIПространстваИмен,"getPositions","RemoteAuction_getPositions",ВходныеПараметры,ВыходныеПараметры);
Успешно = (Число(ОтветСервера.status.error_code) = 0);                
Если НЕ Успешно Тогда
         ВызватьИсключение ОтветСервера.status.error_message;    
КонецЕсли;  


// отправка запроса с вложенными файлами
    СвязанныеФайлы  =   СвязанныеФайлыВызовСервера.СвязанныеФайлыПоВладельцу(Ссылка);

    Для каждого Файл Из СвязанныеФайлы Цикл
        Если ТипЗнч(Файл.Файл) <> Тип("СправочникСсылка.Файлы")  Тогда
            Продолжить;	
        КонецЕсли; 
        
        ДанныеФайла = РаботаСФайламиСлужебныйВызовСервера.ДанныеФайлаДляОткрытия(Файл.Файл, Неопределено, Неопределено, Неопределено, Неопределено);	
        
        // отправить файл
        // отправляем файлы по одному, чтобы можно было отправлять файлы максимального размера                    
        Хеш = Новый ХешированиеДанных(ХешФункция.MD5);
        Хеш.Добавить(ПолучитьИзВременногоХранилища(ДанныеФайла.СсылкаНаДвоичныеДанныеФайла));
        
        ИмяФайла     =   WSПрокси.ФабрикаXDTO.Создать(ТипИмяФайла);
        ИмяФайла.filename   = СтрШаблон("%1.%2",ДанныеФайла.Наименование,ДанныеФайла.Расширение);
        ИмяФайла.md5        = ПолучитьHexСтрокуИзДвоичныхДанных(Хеш.ХешСумма);    
        
        МассивФайлов = Новый Массив;
        МассивФайлов.Добавить(ДанныеФайла);
        
        Действие = "uploadDoc";
        Метод = "RemoteAuction_uploadDoc";
        
        ВходныеПараметры = Новый Структура;
        ВходныеПараметры.Вставить("auth",Авторизация);
        ВходныеПараметры.Вставить("auction_id",ИД_Аукциона);
        ВходныеПараметры.Вставить("external_id",ВнешнийИД);
        ВходныеПараметры.Вставить("type","docs");
        ВходныеПараметры.Вставить("append_mode",1);
        ВходныеПараметры.Вставить("attachment_name",ИмяФайла);      
        
        ВыходныеПараметры = Новый Структура;
        ВыходныеПараметры.Вставить("return","ret_status");
        
        ОтветСервера = ОтправитьSOAPЗапросСФайлами(WSПрокси,URIПространстваИмен,Действие,Метод,ВходныеПараметры,МассивФайлов,ВыходныеПараметры);                                    
        
        Успешно = (Число(ОтветСервера.status.error_code) = 0);
        Если НЕ Успешно Тогда
            ВызватьИсключение ОтветСервера.status.error_message;	
        КонецЕсли;         	
       
   КонецЦикла;








     /// ---------------------------------------------------------------------------------------------------------- 
// Работа с SOAP

Функция ОтправитьSOAPЗапрос(WSПрокси,URIПространстваИмен,Действие,Метод,ВходныеПараметры,ВыходныеПараметры)
    
    Результат = Неопределено;
    
    Заголовки = Новый Соответствие;
    Заголовки.Вставить("Content-Type",  "text/xml;charset=UTF-8");
    Заголовки.Вставить("SOAPAction",    СтрШаблон("%1#%2",URIПространстваИмен,Действие));

    ПространствоИменSOAP = "http://schemas.xmlsoap.org/soap/envelope/";
        
    // формируем конверт    
    ТелоЗапросаSOAP =  СформироватьКонвертSOAP(WSПрокси,URIПространстваИмен,Метод,ВходныеПараметры);    
 
    
    HTTPЗапрос = Новый HTTPЗапрос("/market/remote_alternative.html", Заголовки);
    HTTPЗапрос.УстановитьТелоИзСтроки(ТелоЗапросаSOAP, "UTF-8");
    
    ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL(, Новый СертификатыУдостоверяющихЦентровОС);   
    ПроксиСервер = Новый ИнтернетПрокси(Истина);     
    
    // https://demo.b2b-center.ru/market/remote_alternative.html
    HTTPСоединение = Новый HTTPСоединение("demo.b2b-center.ru",,,,ПроксиСервер,120,ЗащищенноеСоединение); 
    HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
    //
    ОтветСервера =  HTTPОтвет.ПолучитьТелоКакСтроку();
    
    // Обработка результата
    ЧтениеXML = Новый ЧтениеXML;
    ЧтениеXML.УстановитьСтроку(ОтветСервера);
    
    Результат = Новый Структура;
    
    Пока ЧтениеXML.Прочитать() Цикл        
        Если ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ИмяЭлемента = СтандартныеПодсистемыСервер.ПреобразоватьСтрокуВДопустимоеНаименованиеКолонки(ЧтениеXML.Имя);
            Если ВыходныеПараметры.Свойство(ИмяЭлемента) Тогда
                ТипОтвета = WSПрокси.ФабрикаXDTO.Тип(URIПространстваИмен,ВыходныеПараметры[ИмяЭлемента]);
                РезультатXDTO = WSПрокси.ФабрикаXDTO.ПрочитатьXML(ЧтениеXML,ТипОтвета);
                Если ТипЗнч(РезультатXDTO) = Тип("ОбъектXDTO") Тогда
                    //Результат = ОбъектXDTOВСтруктуру(РезультатXDTO);
                    Результат = РезультатXDTO;
                    Прервать;
                КонецЕсли;
            КонецЕсли; 
        КонецЕсли; 
    КонецЦикла; 
    
    ЧтениеXML.Закрыть();
        
    Возврат Результат;
    
КонецФункции
 
Функция ОтправитьSOAPЗапросСФайлами(WSПрокси,URIПространстваИмен,Действие,Метод,ВходныеПараметры,СписокФайлов,ВыходныеПараметры)
    
    Результат = Неопределено;
    
    Разделитель = СтрЗаменить(Строка(Новый УникальныйИдентификатор()), "-", ""); 
    
    Заголовки = Новый Соответствие;
    Заголовки.Вставить("Content-Type",  "text/xml;charset=UTF-8");
    Заголовки.Вставить("Content-Type",СтрШаблон("multipart/related; type=""text/xml""; boundary=""%1""",Разделитель));
    Заголовки.Вставить("SOAPAction",    СтрШаблон("%1#%2",URIПространстваИмен,Действие));
    
    // формируем конверт    
    ТелоЗапросаSOAP =  СформироватьКонвертSOAP(WSПрокси,URIПространстваИмен,Метод,ВходныеПараметры);    
    
    ПотокТелоЗапроса = Новый ПотокВПамяти();
    ЗаписьДанных = Новый ЗаписьДанных(ПотокТелоЗапроса);
    ЗаписьДанных.ЗаписатьСтроку(СтрШаблон("--%1",Разделитель));
    ЗаписьДанных.ЗаписатьСтроку("Content-Type: text/xml; charset=UTF-8");
    ЗаписьДанных.ЗаписатьСтроку("Content-Transfer-Encoding: 8bit");
    ЗаписьДанных.ЗаписатьСтроку("");

    ЗаписьДанных.ЗаписатьСтроку(ТелоЗапросаSOAP);

    // добавляем файлы
    Для каждого ДанныеФайла Из СписокФайлов Цикл
        
        ДопустимоеНаименованиеФайла = СтандартныеПодсистемыСервер.ПреобразоватьСтрокуВДопустимоеНаименованиеКолонки(ДанныеФайла.Наименование);
        ДопустимоеРасширениеФайла = СтандартныеПодсистемыСервер.ПреобразоватьСтрокуВДопустимоеНаименованиеКолонки(ДанныеФайла.Расширение);
        //ДопустимоеНаименованиеФайла = ДанныеФайла.Наименование;
        //ДопустимоеРасширениеФайла = ДанныеФайла.Расширение;        
        ИмяФайла   = СтрШаблон("%1.%2",ДопустимоеНаименованиеФайла,ДопустимоеРасширениеФайла);
        ЗаписьДанных.ЗаписатьСтроку(СтрШаблон("--%1",Разделитель));
        ЗаписьДанных.ЗаписатьСтроку(СтрШаблон("Content-Type: application/octet-stream; name=""%1""",ИмяФайла));
        ЗаписьДанных.ЗаписатьСтроку("Content-Transfer-Encoding: binary");
        ЗаписьДанных.ЗаписатьСтроку(СтрШаблон("Content-ID: <%1>",ИмяФайла));
        ЗаписьДанных.ЗаписатьСтроку(СтрШаблон("Content-Disposition: attachment; name=""%1""; filename=""%1""",ИмяФайла));
        ЗаписьДанных.ЗаписатьСтроку("");
        
        ЗаписьДанных.Записать(ПолучитьИзВременногоХранилища(ДанныеФайла.СсылкаНаДвоичныеДанныеФайла));        
        
    КонецЦикла; 
    
    
    ЗаписьДанных.Закрыть();
    
    
    HTTPЗапрос = Новый HTTPЗапрос("/market/remote_alternative.html", Заголовки);
    РазмерСообщения = ПотокТелоЗапроса.Размер();
    ДвоичныеДанныеТело = ПотокТелоЗапроса.ЗакрытьИПолучитьДвоичныеДанные();
    
    Заголовки.Вставить("Content-Length",XMLСтрока(РазмерСообщения));
    
    HTTPЗапрос.УстановитьТелоИзДвоичныхДанных(ДвоичныеДанныеТело);    
    
    ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL(, Новый СертификатыУдостоверяющихЦентровОС);   
    ПроксиСервер = Новый ИнтернетПрокси(Истина);     
    
    // https://demo.b2b-center.ru/market/remote_alternative.html
    HTTPСоединение = Новый HTTPСоединение("demo.b2b-center.ru",,,,ПроксиСервер,120,ЗащищенноеСоединение); 
    HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
    //
    ОтветСервера =  HTTPОтвет.ПолучитьТелоКакСтроку();
    
    // Обработка результата
    ЧтениеXML = Новый ЧтениеXML;
    ЧтениеXML.УстановитьСтроку(ОтветСервера);
    
    Результат = Новый Структура;
    
    Пока ЧтениеXML.Прочитать() Цикл        
        Если ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ИмяЭлемента = СтандартныеПодсистемыСервер.ПреобразоватьСтрокуВДопустимоеНаименованиеКолонки(ЧтениеXML.Имя);
            Если ВыходныеПараметры.Свойство(ИмяЭлемента) Тогда
                ТипОтвета = WSПрокси.ФабрикаXDTO.Тип(URIПространстваИмен,ВыходныеПараметры[ИмяЭлемента]);
                РезультатXDTO = WSПрокси.ФабрикаXDTO.ПрочитатьXML(ЧтениеXML,ТипОтвета);
                Если ТипЗнч(РезультатXDTO) = Тип("ОбъектXDTO") Тогда
                    //Результат = ОбъектXDTOВСтруктуру(РезультатXDTO);
                    Результат = РезультатXDTO;
                    Прервать;
                КонецЕсли;
            КонецЕсли; 
        КонецЕсли; 
    КонецЦикла; 
    
    ЧтениеXML.Закрыть();
        
    Возврат Результат;
    
КонецФункции

Функция СформироватьКонвертSOAP(WSПрокси,URIПространстваИмен,Метод,ВходныеПараметры)
    
    ПространствоИменSOAP = "http://schemas.xmlsoap.org/soap/envelope/";
    
    Пакет = WSПрокси.ФабрикаXDTO.Пакеты.Получить(URIПространстваИмен);
    СвойствоXDTOМетод = Пакет.КорневыеСвойства.Получить(Метод);
    
    // формируем конверт
    ЗаписьXML = Новый ЗаписьXML;
    ПараметрыЗаписиXML = Новый ПараметрыЗаписиXML("UTF-8");
    ЗаписьXML.УстановитьСтроку(ПараметрыЗаписиXML);
    ЗаписьXML.ЗаписатьОбъявлениеXML();
    ЗаписьXML.ЗаписатьНачалоЭлемента("Envelope", ПространствоИменSOAP);
    ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("soap", ПространствоИменSOAP);
    ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("xs", "http://www.w3.org/2001/XMLSchema");
    ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("xsi", "http://www.w3.org/2001/XMLSchema-instance");
    ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("urn", URIПространстваИмен);
    ЗаписьXML.ЗаписатьНачалоЭлемента("Header", ПространствоИменSOAP);
    ЗаписьXML.ЗаписатьКонецЭлемента();
    ЗаписьXML.ЗаписатьНачалоЭлемента("Body", ПространствоИменSOAP);
    ЗаписьXML.ЗаписатьНачалоЭлемента(СвойствоXDTOМетод.ЛокальноеИмя, URIПространстваИмен);
    Для каждого Элемент Из ВходныеПараметры Цикл
        Если ТипЗнч(Элемент.Значение) <> Тип("ОбъектXDTO") Тогда
            Значение = ЗначениеТипаВЗначениеXDTO(Элемент.Значение);
        Иначе
            Значение = Элемент.Значение;
        КонецЕсли;    
        WSПрокси.ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, Значение, Элемент.Ключ, URIПространстваИмен);   
    КонецЦикла; 
    ЗаписьXML.ЗаписатьКонецЭлемента();
    ЗаписьXML.ЗаписатьКонецЭлемента();
    ЗаписьXML.ЗаписатьКонецЭлемента();
    
    Возврат ЗаписьXML.Закрыть();    
    
КонецФункции

 

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. vano-ekt 847 19.04.19 08:16 Сейчас в теме
2. YPermitin 10354 20.04.19 20:46 Сейчас в теме
(0) Спасибо за полезный материал!
3. Kyrales 139 23.07.20 08:57 Сейчас в теме
Добрый день. Подскажите. У вас в статье приведен код. Но нет в нем информации по функции ЗначениеТипаВЗначениеXDTO(). Не могли бы вы код по этой функции скинуть?
4. mysm 45 23.07.20 23:34 Сейчас в теме
(3)
Функция ЗначениеТипаВЗначениеXDTO(знач ЗначениеТипа)
	Если ТипЗнч(ЗначениеТипа) = Тип("Строка") Тогда
		ТипXDTO = ФабрикаXDTO.Тип("http://www.w3.org/2001/XMLSchema", "string");
	ИначеЕсли ТипЗнч(ЗначениеТипа) = Тип("Булево") Тогда		  
		ТипXDTO = ФабрикаXDTO.Тип("http://www.w3.org/2001/XMLSchema", "boolean");
	ИначеЕсли ТипЗнч(ЗначениеТипа) = Тип("Дата") Тогда 
		ТипXDTO = ФабрикаXDTO.Тип("http://www.w3.org/2001/XMLSchema", "date");	
	ИначеЕсли ТипЗнч(ЗначениеТипа) = Тип("Число") Тогда 
		ТипXDTO = ФабрикаXDTO.Тип("http://www.w3.org/2001/XMLSchema", "integer");	
	КонецЕсли; 	
	Возврат ФабрикаXDTO.Создать(ТипXDTO, ЗначениеТипа);	
КонецФункции
Показать
5. voronin_a_2000 17 25.11.20 12:19 Сейчас в теме
Добрый день.
Спасибо за полезный материал!
Нет ли у вас модуля загрузки заявок из B2B-Center?
6. mysm 45 25.11.20 16:53 Сейчас в теме
(5) Универсального решения нет. Там есть вариации, в зависимости от типов торгов, скажем. Пишется под клиента.
Оставьте свое сообщение

См. также

.Net в 1С. На примере использования HTTPClient, AngleSharp. Удобный парсинг сайтов с помощью библиотеки AngleSharp, в том числе с авторизацией аля JQuery с использованием CSS селекторов. Динамическая компиляция Промо

Практика программирования WEB v7.7 v8 Бесплатно (free)

Часто приходится парсить сайты, в том числе с авторизацией, перескакивая со страницы на страницу по ссылкам. Тот, кто занимался вэб программированием, знает, как удобно использовать JQuery и CSS селекторы. На .Net написана очень удобная библиотека AngleSharp. Я покажу, как с её помощью можно значительно облегчить себе труд.

10.03.2016    56740    Serginio    33    

Как отправить сообщение Telegram в группу?

WEB v8 Россия Бесплатно (free)

Отправка сообщения в группу Telegram.

01.03.2021    441    kite2    0    

Альфа-Авто 5.0 и современные HTTP сервисы

WEB v8 1cv8.cf Автомобили, автосервисы УУ Бесплатно (free)

Решение, позволяющее программным продуктам, работающим на устаревших версиях платформы 1С (8.2), интегрироваться с современными HTTP сервисами. Решение, интегрированное с HTTP-сервисом программы по расчету компонентов для изготовления ЛКМ, описанное в настоящей статье, успешно работает в одном из автосервисов, работающем на устаревшей платформе и конфигурации Альфа-Авто 5.0.

01.03.2021    291    osivv    1    

Доступ из базы 1С к стандартному интерфейсу Odata базы 1С, в которой заведен пользователь

WEB v8 Россия Бесплатно (free)

Есть база, с пользователем/паролем, нужно подключиться к Odata из другой базы 1С, получить элементы справочника.

24.02.2021    496    user823999    6    

Online телефонный справочник из 1С: Зарплата и управление персоналом Промо

WEB Управление персоналом (HRM) Управление персоналом (HRM) v8 ЗУП3.x Россия Бесплатно (free)

В интернете представлено много реализаций online телефонных справочников организаций. Есть справочники, которые использует для хранения информации базу Active Directory (LDAP), есть справочники, которые реализованы с использованием СУБД (например, MySQL). Но я не нашел справочника, который использует информацию из базы 1С. Далее я рассмотрю данную разработку.

10.03.2017    26431    ruha    16    

Интеграция с API WB (Wildberries). Создание карточки товара (спецификации)

WEB v8 1cv8.cf ИТ-компания Россия Бесплатно (free)

Опыт интеграции с API WB (Wildberries), опыт создания карточки товара, получение токенов API WB.

18.01.2021    4467    jenyavp    36    

HTML редактор/editor (Wysiwyg) для WebKit 1С (CMS, B2B), альтернатива TinyMCE и стандартному ФорматированныйДокумент

WEB Интеграция v8 v8::УФ 1cv8.cf Бесплатно (free)

Suneditor - отличная замена HTML редактору TinyMCE (бесплатному), в публикации с открытым кодом подключим его в 1С с WebKit, скачать HTMLeditor обработку можно бесплатно.

28.12.2020    1801    SizovE    23    

Выгрузка HTML описаний с картинками (Base64) товаров на сайт/интернет-магазин/B2B, разберем регулярное выражение получения тега body, ПолучитьHTML, ФорматированныйДокумент

Практика программирования WEB Универсальные функции v8 v8::УФ 1cv8.cf Бесплатно (free)

Редактор HTML платформы 1С простой и очень удобный для небольших задач, однако ПолучитьHTML возвращает отдельно картинки и отдельно целиком HTML страницу со ссылкой на имена этих картинок, что неудобно для отправки в базу данных сайта/интернет-магазина/веб-приложения/B2B. Разберем на открытом коде, как решить эту проблему, напишем универсальную функцию получения значения любого тега HTML на регулярных выражениях. Бонусом - возможность редактировать теги HTML в текстовом режиме.

24.11.2020    696    SizovE    2    

Кэширование COM-соединения. Три способа Промо

Практика программирования Перенос данных из 1С7.7 в 1C8.X Внешние источники данных WEB v8 Россия Бесплатно (free)

Статья о трех способах кэширования COM-соединения в 1С:Предприятии 8.x.

11.04.2013    42069    YPermitin    41    

Как сделать интеграцию (обмен) с интернет-магазином? Пошаговый план действий (Часть 1)

WEB v8 1cv8.cf УУ Бесплатно (free)

C 2011 года я занимаюсь интеграцией с интернет-магазинами и за это время, наверное, повидал все. Делал интеграцию как «культурными», так и «экзотическими» способами. Количество магазинов исчисляется сотнями. В этой серии статей я буду делиться своим опытом, а также выкладывать какие-то полезные наработки.

19.11.2020    3401    markbraer    9    

Чтение вложенных свойств Структур Структуры, Соответствий, свойства через точку, разбор JSON

Практика программирования WEB Интеграция Универсальные функции v8 Бесплатно (free)

JSON: {user.device.type} - как получить значение {type}? А если вложенность значительно глубже? Как проверить, что оно заполнено или удалить его - всё это в публикации с открытым кодом и даже без рекурсии. Бонусом разбор дерева значений - ДанныеФормыЭлементДерева, СтрокаДереваЗначений.

17.11.2020    1641    SizovE    2    

Web Dashboard (мобильная и десктопная версия): оптимальная схема организации взаимодействия с зоопарком систем

WEB v8 Бесплатно (free)

Задача: из множества систем (1С:ERP, 1C:CRM, Кронос:WMS, 1С:Розница, 1С:УПП...) оперативно и онлайн осуществлять мониторинг на телефоне/десктопе/планшете/телевизоре бизнес-аналитику в дашборде для директора. Рассмотрим в статье, как правильно интегрировать между собой все базы, какие для этого инструменты использовать.

10.11.2020    5070    SizovE    2    

Заготовка для загрузки файлов по ftp Промо

WEB Перенос данных из 1C8 в 1C8 v8 1cv8.cf Бесплатно (free)

3 процедуры и 1 макет

03.06.2013    30779    anig99    6    

Отладка модуля ДиадокПро

WEB v8 1cv8.cf Бесплатно (free)

В обработке ДиадокПро все дополнительные модули встроены во внешние обработки, которые хранятся в макетах. Это усложняет процесс самостоятельной интеграции, так как теряется возможность попасть в них в режиме отладки. Но не всё так страшно, поэтому ниже инструкция)

30.10.2020    1867    Максим-777    13    

JSON примеры меню B2B web-приложения "Личный кабинет" на движке EDIbot для телефона/десктопа

WEB v8 Бесплатно (free)

Рассмотрим на примерах работу движка EDIbot при организации меню B2B "Личного кабинета" (мобильная версия, версия десктоп) грузовладельца WMS-системы.

29.10.2020    887    SizovE    0    

Обмен с сайтом посредством Post-запроса, json

WEB v8 1cv8.cf Бесплатно (free)

Задача - передавать на сайт объекты с наименованием и уникальным идентификатором (УИ), которые изменяются в 1С. Также нужно сохранять историю отправленных пакетов.

29.10.2020    4183    John_d    26    

Организация HTTP публикации каталога товаров используя PostgREST

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу порядок установки настройки и использования PostgREST на примере организации каталога товаров.

05.10.2020    936    malikov_pro    2    

Интеграционная прослойка(middleware) на Golang. Часть 5 - Обмен с 1С через HTTP-сервисы платформы

WEB v8 Бесплатно (free)

В этой статье научим прослойку отправлять данные в 1С, для этого используем HTTP-сервисы платформы. Обменяемся данными с новым справочником Клиенты. Но главное создадим HTTP-сервис для получения сообщений из очереди RabbitMQ.

28.09.2020    1552    dmitry-irk38    4    

Отладка http сервиса

WEB v8 Бесплатно (free)

При разработке http сервиса возникает ситуация, а как протестировать http сервис? Создали мы сервис, настроили шаблоны, передали, если нужно параметры, открываем браузер заполняем строку подключения и БАХ, ошибка. Что делать?

23.09.2020    2576    hpi    10    

Учимся создавать http сервисы (часть вторая). Передача параметра в http сервис

WEB v8 1cv8.cf Бесплатно (free)

Пошаговое руководство по созданию http-сервиса (часть вторая). Передача параметра в http сервис.

22.09.2020    5468    hpi    6    

Организация данных и вариант обработки для организации обмена с сайтом

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу вариант организации данных и обработки для обмена с сайтом.

22.09.2020    1415    malikov_pro    4    

Формирование списка документов и скачивание печатной формы документа через веб-сайт с использованием HTTP-сервиса, плюс особенности авторизации

Практика программирования Обмен данными 1С WEB v8 1cv8.cf Бесплатно (free)

В статье показан пример, как реализовать формирование списка документов клиента/пользователя по коду, а затем скачать его (документа) печатную форму по ссылке

18.09.2020    1045    R_o_n_n_y    3    

Формирование HTTP запроса формата multipart/form-data с двоичными данными, используя ПотокВПамяти

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу вариант формирования запроса

11.09.2020    3097    malikov_pro    11    

Ферма приложений на Kubernetes

WEB v8 Бесплатно (free)

При эксплуатации большого количества информационных систем 1С, предоставляющих интернет-сервисы, возникают проблемы, связанные с зависимостью от производительности и стабильности веб-сервера. Как объединить отдельно стоящие веб-сервера с помощью платформы Kubernetes для централизованного мониторинга всех опубликованных интернет-сервисов на конференции Infostart Event 2019 Inception рассказал программист компании BIA Technologies Владимир Кирбаба.

24.08.2020    1579    ComboBoy    0    

Использование шаблонного процессора для формирования HTML страниц

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу использование шаблонного процессора Handlebars запущенного на Node.js

24.08.2020    1643    malikov_pro    26    

Загрузка или обновление файла на яндекс диске через rest-api

Практика программирования Файловые протоколы обмена, FTP WEB v8 Бесплатно (free)

Коллеги, в данной публикации я хочу поделиться кодом, с помощью которого можно загрузить файл на яндекс диск или обновить существующий.

12.08.2020    2623    pavelpribytkin96    10    

Самый простой парсинг и обработка веб-страниц в 1С

WEB Универсальные функции v8 1cv8.cf Бесплатно (free)

Рассмотрим самый простой парсинг веб-страниц средствами платформы 1С и еще некоторые полезные приемы работы с веб-страницами.

07.08.2020    6827    YPermitin    19    

Загрузка или обновление файла на гугл диске

Практика программирования Файловые протоколы обмена, FTP WEB v8 1cv8.cf Бесплатно (free)

Коллеги, в данной публикации я хочу поделиться кодом, с помощью которого можно загрузить файл на гугл диск или обновить существующий.

06.08.2020    1727    pavelpribytkin96    6    

Использование Yandex Translate (Яндекс.Переводчик)

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу вариант подключения и использования Yandex Translate.

08.07.2020    4424    malikov_pro    8    

Когда хотим знать IP клиента...

WEB v8 Бесплатно (free)

В процессе разработки web приложения на 1С, и это не шутка))), а пожелание заказчика, возникла ситуации когда понадобилось знать, с какого IP подключался клиент.

03.07.2020    6052    IMihalev    10    

Ограничение доступа к HTTP публикациям 1С сервера используя NGINX

WEB v8 1cv8.cf Бесплатно (free)

В статье опишу вариант ограничения доступа к HTTP публикациям 1С сервера используя NGINX.

02.07.2020    7337    malikov_pro    7    

Структура обработки загрузки цен и остатков поставщика с примерами и комментариями

Внешние источники данных WEB v8 1cv8.cf Россия Бесплатно (free)

В статье опишу структуру обработки по загрузке цен и остатков от поставщика с примерами.

27.06.2020    1891    malikov_pro    0    

Вариант использования документа "Операция по Яндекс.Кассе" для других сервисов по оплате через интернет

WEB v8 1cv8.cf Россия Бесплатно (free)

В статье рассмотрю организацию эквайринга в УТ 11.4 и доработки для создания заказов на оплату к стороннему сервису, как пример Сбербанк.

24.06.2020    1507    malikov_pro    3    

Работа с AliExpress через API

WEB v8 Бесплатно (free)

В публикации опишу подход работы с API AliExpress и примеры кода.

23.06.2020    5893    malikov_pro    23    

История создания успешной системы чат-ботов на 1С

WEB v8 Бесплатно (free)

Использование чат-ботов в мессенджерах позволяет автоматизировать многие сложные бизнес-процессы путем диалога с системой через виртуального собеседника. О том, как создать универсальную систему ботов с бэкендом на 1С, работающую в Telegram, Viber и Facebook Messenger одновременно, на конференции Infostart Event 2019 Inception рассказал программист-фрилансер Константин Гейнрих.

21.05.2020    8335    CyberCerber    15    

Парсинг html страниц с выводом информации через JavaScript с использованием Selenium

WEB v8 1cv8.cf Бесплатно (free)

Есть девочки как девочки, есть мальчики как мальчики, есть сайтики как сайтики, но странички их обманщики. В целях сохранить информацию, от автоматизированного сбора, многие ресурсы пытаются защитить ее. Один из таких способов - вывод информации на странице через JavaScript. При получении такой страницы в 1С, JavaScript не успевает вывести необходимые данные, и в 1с получаем практически пустую страницу. В статье приведу пример разработки, для парсинга таких страниц, без регистрации и смс.

20.05.2020    5755    platonov.e    25    

Интеграция 1С и CMS WordPress посредством Rest API сайта. Шаг третий, WooCommerce, публикация категорий товаров

WEB v8 1cv8.cf Бесплатно (free)

Интеграция 1С и CMS WordPress посредством функционала Rest API. Используем только язык программирования 1С и штатный функционал Rest API предоставляемый CMS, без дополнительных библиотек и плагинов. Процедуры и функции публикации категорий товаров в магазин WooCommerce, с комментариями внутри.

13.05.2020    3661    osivv    3    

Интеграция 1С и CMS WordPress посредством Rest API сайта. Шаг второй, публикация картинок

WEB v8 Бесплатно (free)

Интеграция 1С и CMS WordPress посредством функционала Rest API. Используем только язык программирования 1С и штатный функционал Rest API предоставляемый CMS, без дополнительных библиотек и плагинов. Процедуры и функции передачи фото из 1С, с комментариями внутри.

13.05.2020    2469    osivv    0    

Интеграция Camunda BPM и 1С

WEB Интеграция v8 Бесплатно (free)

Быстрый старт. Только практические примеры. Установка, запуск и публикация бизнес-процесса на сервере Camunda BPM. Управление бизнес-процессами из 1С при помощи Camunda REST API.

12.05.2020    4526    zhichkin    30    

Интеграция 1С и CMS WordPress посредством Rest API сайта. Первый шаг

WEB v8 Россия Бесплатно (free)

Интеграция 1С и CMS WordPress посредством функционала Rest API. Используем только язык программирования 1С и штатный функционал Rest API предоставляемый CMS, без дополнительных библиотек и плагинов. Процедуры и функции 1С с комментариями внутри.

28.04.2020    5506    osivv    23    

Выразительный Web API

WEB v8 Бесплатно (free)

Теория разработки Web API с ожидаемым поведением, за который не будет стыдно за пределами мира 1С.

27.04.2020    7667    nbeliaev    22    

Хранение статистики публикаций автора сообщества Инфостарт ® (мобильное приложение И ++)

Мобильная разработка WEB v8 1cv8.cf Бесплатно (free)

Инфостарт ® достаточно удобный в плане работы со своим личным кабинетом сайт. Но программисты тем и отличаются от большинства людей, что им хочется знать больше. Поэтому появилась конфигурация 1С (она же мобильное приложение 1С) для более подробного учета статистики публикаций: рейтинг, количество просмотров, количество комментариев в динамике и в разрезах.

24.04.2020    2459    capitan    15    

Интеграция УАТ с топливными сервисами

WEB v8 1cv8.cf Автомобили, автосервисы Бесплатно (free)

Интеграция конфигурации Управление автотранспортом с топливными веб-сервисами.

21.04.2020    7704    RPGrigorev    2    

Интеграция 1С с веб-сервисами Лукойл ЛИКАРД

WEB v8 1cv8.cf Россия Бесплатно (free)

Описание интерфейса взаимодействия сервиса Лукойл- ЛИКАРД с информационной системой 1С.

20.04.2020    5720    RPGrigorev    0