Организация данных и вариант обработки для организации обмена с сайтом

Процедура ОбработатьСостояниеОтправки(СтрИ, НастройкаОбмена, ДатаОкончания, ТипДанныхДляОбмена) Экспорт
	
	Если СтрИ.СостояниеОтправки.УспешноОтправлено Тогда
		
		//--Добавление
		Если СтрИ.Идентификатор = 0 И НЕ СтрИ.ПометкаУдаления Тогда
			
			Если СтрИ.СостояниеОтправки.Идентификатор > 0 Тогда
				
				СтрИ.Идентификатор = СтрИ.СостояниеОтправки.Идентификатор;
				
				ЗаписатьИдентификаторОбъекта(НастройкаОбмена, ТипДанныхДляОбмена, СтрИ.Ссылка, СтрИ.Идентификатор);  
				ЗаписатьОтправленныеДанные(НастройкаОбмена, СтрИ.Ссылка, СтрИ.СтрокаДанные);
				
			КонецЕсли;
			
			//--Обновление
		ИначеЕсли СтрИ.Идентификатор > 0 И НЕ СтрИ.ПометкаУдаления Тогда			
			
			ЗаписатьОтправленныеДанные(НастройкаОбмена, СтрИ.Ссылка, СтрИ.СтрокаДанные);	
			
			//-- Удаление	
		ИначеЕсли СтрИ.ПометкаУдаления Тогда 
			УдалитьИдентификаторОбъекта(НастройкаОбмена, ТипДанныхДляОбмена, СтрИ.Ссылка, СтрИ.Идентификатор);
			УдалитьОтправленныеДанные(НастройкаОбмена, СтрИ.Ссылка);	
		КонецЕсли;
		
		УдалитьИзмененияОбъекта(НастройкаОбмена, СтрИ.Ссылка, ДатаОкончания);
		
		//-- Если обновляем и элемента нет на сайте, то локально удаляем его идентификатор, добавление будет при следующем цикле обмена.
	ИначеЕсли СтрИ.Идентификатор > 0
		И НЕ СтрИ.СостояниеОтправки.Ошибка
		И НЕ СтрИ.СостояниеОтправки.Найдено Тогда			
		
		УдалитьИдентификаторОбъекта(НастройкаОбмена, ТипДанныхДляОбмена, СтрИ.Ссылка, СтрИ.Идентификатор);
		СтрИ.Идентификатор = 0;
		
	КонецЕсли;
	
	
КонецПроцедуры

 Функция ЗаписатьОтправленныеДанные(НастройкаОбмена, Объект, СтрокаДанные) Экспорт
    
    МЗ = РегистрыСведений.ос_ОтправленныеДанные.СоздатьМенеджерЗаписи();
    МЗ.Дата = ТекущаяДата();
    МЗ.НастройкаОбмена = НастройкаОбмена;
    МЗ.Объект = Объект;
    МЗ.СтрокаДанныеХэш = ПолучитьХэшMD5(СтрокаДанные);
    МЗ.Записать(Истина);
    
КонецФункции

Функция ПолучитьМассивИзмененныхОбъектов(НастройкаОбмена, Тип, ДатаОкончания) Экспорт
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	ос_ИсторияИзменений.Объект КАК Объект
	|ИЗ
	|	РегистрСведений.ос_ИсторияИзменений КАК ос_ИсторияИзменений
	|ГДЕ
	|	ос_ИсторияИзменений.Дата <= &ДатаОкончания
	|	И ос_ИсторияИзменений.Настройка = &НастройкаОбмена
	|	И ос_ИсторияИзменений.Тип = &Тип
	|
	|СГРУППИРОВАТЬ ПО
	|	ос_ИсторияИзменений.Объект";
	Запрос.УстановитьПараметр("НастройкаОбмена", НастройкаОбмена);
	Запрос.УстановитьПараметр("Тип", Тип);
	Запрос.УстановитьПараметр("ДатаОкончания", ДатаОкончания);
	РезультатЗапроса = Запрос.Выполнить();
	
	Возврат РезультатЗапроса.Выгрузить().ВыгрузитьКолонку("Объект");
	
КонецФункции

Функция ПолучитьТЗГруппыНоменклатуры(МассивОбъектов, ГруппыНоменклатуры = Неопределено) Экспорт
	
	ИмяСправочника = "Номенклатура";
	МаксимальнаяДлинаПути = 8; //МаксимальнаяДлинаПути(ИмяСправочника);
	
	Если ГруппыНоменклатуры = Неопределено ИЛИ ГруппыНоменклатуры.Количество() = 0 Тогда
		
		
		Пролог = "ВЫБРАТЬ Родитель НачалоДуги, Ссылка КонецДуги ПОМЕСТИТЬ ЗамыканияДлины1 ИЗ Справочник.Номенклатура 
		| ГДЕ Родитель <> Значение(Справочник.Номенклатура.ПустаяСсылка) И ЭтоГруппа
		| ОБЪЕДИНИТЬ ВЫБРАТЬ Ссылка, Ссылка ИЗ Справочник.Номенклатура ГДЕ ЭтоГруппа;";
		
	Иначе
		
		
		Пролог = "ВЫБРАТЬ Родитель НачалоДуги, Ссылка КонецДуги ПОМЕСТИТЬ ЗамыканияДлины1 ИЗ Справочник.Номенклатура 
		| ГДЕ Родитель <> Значение(Справочник.Номенклатура.ПустаяСсылка) И ЭтоГруппа И Ссылка В ИЕРАРХИИ (&ГруппыНоменклатуры)
		| ОБЪЕДИНИТЬ ВЫБРАТЬ Ссылка, Ссылка ИЗ Справочник.Номенклатура ГДЕ ЭтоГруппа И Ссылка В ИЕРАРХИИ (&ГруппыНоменклатуры);";
		
	КонецЕсли;
	

	Рефрен = "ВЫБРАТЬ РАЗЛИЧНЫЕ ПерваяДуга.НачалоДуги, ВтораяДуга.КонецДуги ПОМЕСТИТЬ ЗамыканияДлины#2 ИЗ ЗамыканияДлины#1 КАК ПерваяДуга 
			| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ЗамыканияДлины#1 КАК ВтораяДуга ПО ПерваяДуга.КонецДуги = ВтораяДуга.НачалоДуги; 
			| УНИЧТОЖИТЬ ЗамыканияДлины#1;";

	//Эпилог = "ВЫБРАТЬ КОЛИЧЕСТВО(НачалоДуги) - 1 Предок, КонецДуги Потомок ИЗ ЗамыканияДлины#2 СГРУППИРОВАТЬ ПО КонецДуги";
	
	Эпилог = "
	|ВЫБРАТЬ
	|	ВложенныйЗапрос.НачалоДуги КАК Потомок,
	|	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ЗамыканияДлины#2.НачалоДуги) - 1 КАК Предок
	|ИЗ
	|	(ВЫБРАТЬ
	|		ЗамыканияДлины#2.НачалоДуги КАК НачалоДуги,
	|		ЗамыканияДлины#2.КонецДуги КАК КонецДуги
	|	ИЗ
	|		ЗамыканияДлины#2 КАК ЗамыканияДлины#2
	|	ГДЕ
	|		ЗамыканияДлины#2.КонецДуги В(&МассивОбъектов)) КАК ВложенныйЗапрос
	|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ЗамыканияДлины#2 КАК ЗамыканияДлины8
	|		ПО ВложенныйЗапрос.НачалоДуги = ЗамыканияДлины#2.КонецДуги
	|
	|СГРУППИРОВАТЬ ПО
	|	ВложенныйЗапрос.НачалоДуги";
	
	//--
	
	Если МассивОбъектов = Неопределено ИЛИ МассивОбъектов.Количество() = 0 Тогда
		Эпилог = СтрЗаменить(Эпилог, "ЗамыканияДлины#2.КонецДуги В(&МассивОбъектов)", "ИСТИНА");
	КонецЕсли;
	
	Запрос = Новый Запрос(СтрЗаменить(Пролог, "Номенклатура", ИмяСправочника));
	
	МаксимальнаяДлинаЗамыканий = 1;

	Пока МаксимальнаяДлинаЗамыканий < МаксимальнаяДлинаПути Цикл

		Запрос.Текст = Запрос.Текст + СтрЗаменить(СтрЗаменить(Рефрен, "#1", Формат(МаксимальнаяДлинаЗамыканий, "ЧГ=0")), "#2", Формат(2 * МаксимальнаяДлинаЗамыканий, "ЧГ=0"));

		МаксимальнаяДлинаЗамыканий = 2 * МаксимальнаяДлинаЗамыканий

	КонецЦикла;

	Запрос.Текст = Запрос.Текст + СтрЗаменить(Эпилог, "#2", Формат(МаксимальнаяДлинаЗамыканий, "ЧГ=0")); 
	
	Запрос.УстановитьПараметр("МассивОбъектов", МассивОбъектов);
	Запрос.УстановитьПараметр("ГруппыНоменклатуры", ГруппыНоменклатуры);
	
	ТЗ_Уровни = Запрос.Выполнить().Выгрузить();
	
	//--
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	ТЗ_Уровни.Предок КАК Предок,
	|	ТЗ_Уровни.Потомок КАК Потомок
	|ПОМЕСТИТЬ втУровни
	|ИЗ
	|	&ТЗ_Уровни КАК ТЗ_Уровни
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	втУровни.Потомок КАК Ссылка,
	|	втУровни.Потомок.Родитель КАК Родитель,
	|	втУровни.Потомок.ПометкаУдаления КАК ПометкаУдаления,
	|	втУровни.Потомок.Код КАК Код,
	|	втУровни.Потомок.Наименование КАК Наименование,
	|	втУровни.Предок КАК Предок
	|ИЗ
	|	втУровни КАК втУровни
	|
	|УПОРЯДОЧИТЬ ПО
	|	Предок";
	Запрос.УстановитьПараметр("ТЗ_Уровни", ТЗ_Уровни);
	РезультатЗапроса = Запрос.Выполнить();
	
	ТЗГруппыНоменклатуры = РезультатЗапроса.Выгрузить();
	
	ДобавитьСлужебныеКолонки(ТЗГруппыНоменклатуры);
	
	Возврат ТЗГруппыНоменклатуры;
	
КонецФункции