Несколько групп для одной номенклатуры в УТ 11

26.10.20

Задачи пользователя - Адаптация типовых решений

+9 –

В статье опишу вариант доработки УТ 11 для использования нескольких групп для одной номенклатуры.

Вводные

Конфигурация Управление торговлей 11.4
Один элемент номенклатуры присутствует в нескольких группах (отношение "много ко многим")
- Деталь относится к типовой комплектации изделия и к конкретному изделию
- Товар на разных сайтах находится в разных группах
В форме списка и подбора спр. номенклатура нужна корректная фильтрация по группе
Реализовать в виде расширения

Реализация

Создал РС "аэ_ГруппыНоменклатуры", вывел на форму элемента спр. номенклатура

МодульФормы


&НаСервере
Процедура аэ_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	
	Если НЕ ЗначениеЗаполнено(Объект.Ссылка) ИЛИ Объект.ЭтоГруппа  Тогда
		Возврат;
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	аэ_ГруппыНоменклатуры.ГруппаНоменклатуры КАК ГруппаНоменклатуры
	|ИЗ
	|	РегистрСведений.аэ_ГруппыНоменклатуры КАК аэ_ГруппыНоменклатуры
	|ГДЕ
	|	аэ_ГруппыНоменклатуры.Номенклатура = &Номенклатура";
	Запрос.УстановитьПараметр("Номенклатура", Объект.Ссылка);
	РезультатЗапроса = Запрос.Выполнить();
	
	ГруппыНоменклатуры.Загрузить(РезультатЗапроса.Выгрузить());
	
КонецПроцедуры

&НаСервере
Процедура аэ_ПриЗаписиНаСервереПосле(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	
	Если Объект.ЭтоГруппа Тогда
		Возврат;
	КонецЕсли;
	
	НЗ = РегистрыСведений.аэ_ГруппыНоменклатуры.СоздатьНаборЗаписей();
	НЗ.Отбор.Номенклатура.Установить(ТекущийОбъект.Ссылка);
	
	Для каждого СтрГр Из ГруппыНоменклатуры Цикл
		СтрНЗ = НЗ.Добавить();
		СтрНЗ.Номенклатура = ТекущийОбъект.Ссылка;
		СтрНЗ.ГруппаНоменклатуры = СтрГр.ГруппаНоменклатуры;
	КонецЦикла;
	
	НЗ.Записать(Истина);
	
КонецПроцедуры

&НаКлиенте
Процедура аэ_ГруппыНоменклатурыПриИзмененииПосле(Элемент)
	ЭтаФорма.Модифицированность = Истина;
КонецПроцедуры

Скриншот

Фильтрация в УТ реализована в модуле "ПодборТоваровКлиентСервер" в который внес изменения. Сбрасываю отборы по "Родитель" и "Ссылка", после устанавливаю отбор по "Ссылка, ВидСравненияКомпоновкиДанных.ВСписке".

ПодборТоваровКлиентСервер

&Вместо("УстановитьОтборПоИерархииНоменклатуры")
Процедура аэ_УстановитьОтборПоИерархииНоменклатуры(Форма) Экспорт
	
	Если Не Форма.ИспользоватьФильтры Тогда
		Возврат;
	КонецЕсли;
	
	Если Не Форма.ВариантНавигации = ПредопределенноеЗначение("Перечисление.ВариантыНавигацииВФормахНоменклатуры.ПоИерархии") Тогда
		Возврат;
	КонецЕсли;
	
	ОтборПоИерархииНоменклатуры = Форма.ТекущаяИерархияНоменклатуры;
	
	ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(
		Форма.СписокНоменклатура,
		"Родитель",
		Неопределено,
		Неопределено,
		"Родитель",
		Ложь);
		
	ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(
		Форма.СписокНоменклатура,
		"Ссылка",
		Неопределено,
		Неопределено,
		"Ссылка",
		Ложь);
		
	//--
																			
	Если аэ_ВызовСервера.ЭтоДополнительнаяГруппа(ОтборПоИерархииНоменклатуры) Тогда
		
		ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(
			Форма.СписокНоменклатура,
			"Ссылка",
			аэ_ВызовСервера.ПолучитьСписокНоменклатурыПоДополнительнымГруппам(ОтборПоИерархииНоменклатуры),
			ВидСравненияКомпоновкиДанных.ВСписке,
			"Ссылка",
			Истина);
		
	Иначе
		
		ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(
			Форма.СписокНоменклатура,
			"Родитель",
			ОтборПоИерархииНоменклатуры,
			ВидСравненияКомпоновкиДанных.Равно,
			"Родитель",
			Истина);
		
	КонецЕсли;																			
	
		
КонецПроцедуры

Для определения что это доп группа добавил реквизит "аэ_ДополнительнаяГруппа". В запросе сначала выбираю группы в иерархии к текущей, после получаю данные из табличной части. Для отбора по конкретной группе и уменьшению нагрузки можно "И Номенклатура.Ссылка В ИЕРАРХИИ(&ГруппаНоменклатуры)" заменить на "И Номенклатура.Ссылка = &ГруппаНоменклатуры"

Вспомогательные функции

Функция ПолучитьСписокНоменклатурыПоДополнительнымГруппам(ГруппаНоменклатуры) Экспорт
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	               |	Номенклатура.Ссылка КАК Ссылка
	               |ПОМЕСТИТЬ втГруппыНоменклатуры
	               |ИЗ
	               |	Справочник.Номенклатура КАК Номенклатура
	               |ГДЕ
	               |	Номенклатура.ЭтоГруппа
	               |	И Номенклатура.Ссылка В ИЕРАРХИИ(&ГруппаНоменклатуры)
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ РАЗЛИЧНЫЕ
	               |	аэ_ГруппыНоменклатуры.Номенклатура КАК Номенклатура
	               |ИЗ
	               |	РегистрСведений.аэ_ГруппыНоменклатуры КАК аэ_ГруппыНоменклатуры
	               |ГДЕ
	               |	аэ_ГруппыНоменклатуры.ГруппаНоменклатуры В
	               |			(ВЫБРАТЬ
	               |				втГруппыНоменклатуры.Ссылка КАК Ссылка
	               |			ИЗ
	               |				втГруппыНоменклатуры КАК втГруппыНоменклатуры)";
	Запрос.УстановитьПараметр("ГруппаНоменклатуры", ГруппаНоменклатуры);
	РезультатЗапроса = Запрос.Выполнить();
	
	ТЗ = РезультатЗапроса.Выгрузить();
	Возврат ТЗ.ВыгрузитьКолонку("Номенклатура");
	
КонецФункции


Функция ЭтоДополнительнаяГруппа(ГруппаНоменклатуры) Экспорт
	
	Если ЗначениеЗаполнено(ГруппаНоменклатуры) Тогда
		Возврат ГруппаНоменклатуры.аэ_ДополнительнаяГруппа; 	
		
	Иначе
		Возврат Ложь;
	КонецЕсли;
	
КонецФункции

Скриншот

Итог

В УТ 11 относительно просто организовать работу с несколькими ветвями иерархии номенклатуры.

Благодарю за внимание.

Вступайте в нашу телеграмм-группу Инфостарт

+9 –

Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».

0% комиссии — оплата напрямую исполнителю;
Исполнители любого масштаба — от отдельных специалистов до команд под проект;
Прямой обмен контактами между заказчиком и исполнителем;
Безопасная сделка — при необходимости;
Рейтинги, кейсы и прозрачная система откликов.

См. также

Маркировка 2026 для УТ 10.3 (Новые товарные группы)

Разработка Адаптация типовых решений Производство готовой продукции (работ, услуг) Розничная торговля 1С:Управление торговлей 10 Россия Платные (руб)

Доработка для 1С:Управление торговлей 10.3 (релиз 10.3.88.3) добавляет поддержку маркировки новых категорий товаров согласно постановлениям Правительства РФ 2025–2026 гг. Конфигурация УТ 10.3 снята с поддержки — новые маркируемые категории в типовую поставку больше не попадают. Доработка закрывает этот пробел: новые виды номенклатуры, обмен с ГИС МТ «Честный Знак». Поставляется в виде файла .cf

14640 руб.

23.04.2026 1631 12 13

Интеграция Госключ в 1С

Адаптация типовых решений БСП (Библиотека стандартных подсистем) Кадровый учет ЭДО и ОФД 1C:Бухгалтерия 1С:Зарплата и кадры 7.7 1C:ERP 1С:ЗУП 1С:УТ 1С:ДО Платные (руб)

Наше расширение 1С Госключ обеспечивает интеграцию любой конфигурации 1С на базе БСП с мобильным приложением «Госключ», позволяя сотрудникам подписывать кадровые документы (КЭДО) и документы материальной ответственности (МОЛ, ПБ) усиленной электронной подписью прямо со смартфона. Решение автоматизирует формирование и отправку документов на подпись, отслеживает статусы подписания и хранит подписанные файлы непосредственно в базе 1С

25000 руб.

06.03.2026 1443 4 0

Вывод факсимиле в табличные документы (УПД, УКД, Счёт-фактура, ТОРГ-12, Акт сверки, М-15, заказ клиента и др.) для 1С УТ 11.5, КА 2.5, ERP 2.5, УНФ 3, Розница 3

Печатные формы Адаптация типовых решений Бухгалтер Пользователь 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Платные (руб)

Расширение позволяет вывести в табличном документе факсимиле печати и подписей и/или вывести произвольную картинку из прикреплённых файлов организации для 1С УТ 11.5, КА 2.5, ERP 2.5, УНФ 3, Розница 3. Вывод факсимиле возможен в табличные документы УПД, УКД, Счёт-фактура, ТОРГ-12 и другие. Возможно настроить вывод для любых типовых макетов (Акт сверки, М-15, ТТН), для этого потребуется отредактировать макет и разместить на нём картинки с соответствующими именами, при выводе на печать в размещённые картинки будут выводиться факсимиле из прикреплённых рисунков. Редактирование осуществляется через типовой механизм в пользовательском интерфейсе.

6000 руб.

07.02.2023 13661 120 25

Вес и объем в документах «Заказ поставщику» и «Заказ покупателя»

Адаптация типовых решений Логистика, склад и ТМЦ Пользователь 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Управленческий учет Платные (руб)

Теперь вывод весо-объемных характеристик в документы «Заказ поставщику» и «Заказ покупателя» возможен – наше расширение поможет в этом Вам!

5084 руб.

03.08.2023 3581 7 2

Автоматическое разнесение банковской выписки

Банковские операции Адаптация типовых решений Бухгалтер Пользователь 1С:Предприятие 8 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Решение позволяет автоматически заполнять отдельные реквизиты загружаемых банковских документов, основываясь на известных значениях реквизитов и тексте назначения платежа. Простая настройка, широкие возможности анализа назначения платежа без написания кода и сложных шаблонов.

9760 руб.

17.06.2025 4069 10 0

Остатки, цены, изображение в форме списка и выбора номенклатуры.

Адаптация типовых решений 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Расширение для вывода информации об остатках и ценах номенклатуры в форме списка и выбора номенклатуры. (УТ 11, КА 2, ERP). Позволяет получать информацию о ценах, остатках и доступности в разрезе складов и характеристик номенклатуры, информацию по документам резерва.

7930 руб.

16.10.2025 1558 2 0

Остатки и доступность номенклатуры в форме списка и в форме выбора

Адаптация типовых решений 1С 8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Расширение, которое в форму списка и форму выбора справочника «Номенклатура» добавляет табличную часть в виде дерева, в которую выводится информация об остатках и доступности выбранной номенклатурной позиции.

6710 руб.

20.04.2026 494 1 0

Автоматическое снятие резервов в Заказах покупателей для 1С:УНФ

Логистика, склад и ТМЦ Адаптация типовых решений Пользователь 1С:Предприятие 8 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Чтобы не допустить путаницы с обещаниями клиентам и для четкого контроля исполнения заказов мы используем резервирование товаров. Расширение для УНФ, чтобы автоматически отменять старые резервы и не мешалть эффективно продавать.

9150 руб.

02.08.2023 8453 26 5

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. work.sable 26 23.09.20 13:46 Сейчас в теме

Никогда не задумывался о такой возможности. Это прикольно, но не вижу практического применения. Зачем такое было реализовано, какое практическое применение?

2. malikov_pro 1356 23.09.20 14:08 Сейчас в теме

(1)
выгрузка на сайт, там это обычное дело.
на скриншотах выгрузка на Ali, у них ограничение в 2 уровня иерархии и поэтому под них делается отдельная ветка.

3. user1302055 02.03.21 18:45 Сейчас в теме

Тоже возьму на заметку эту статью. А ведь без шуток, функционал хоть и специфичный, но нужный. Неужели его нет в УТ из коробки?

4. malikov_pro 1356 02.03.21 19:23 Сейчас в теме

(3) Нет, потому что это отношение много-ко-многим которое проблематично использовать в отчетах, посмотрите какие предзапросы по сегментам присутствуют в отчетах по продажам.

5. user1302055 26.03.21 07:16 Сейчас в теме

Здравствуйте! Не могли бы вы поделиться конфигурацией. Я начинающий программист, понимаю логику, но не могу реализовать этот функционал, а очень надо.

6. malikov_pro 1356 26.03.21 07:31 Сейчас в теме

(7) "Хочешь накормить человека один раз — дай ему рыбу. Хочешь накормить его на всю жизнь — научи его рыбачить." - Конфуций.
Добавить таблицу (РС или ТЧ справочника), добавить на форму таблицу.
Если сделано через РС, то при создании на сервере заполнить, после записи на сервере записать изменения.
При необходимости добавить проверку на пересечения с основной группой.

Задавайте конкретные вопросы, по возможности помогу.

7. user1302055 26.03.21 08:59 Сейчас в теме

(6) Хорошо, спасибо. Ещё раз с нуля попробую сделать по инструкции. Если появятся вопросы - напишу. :)

8. user1302055 26.04.21 14:32 Сейчас в теме

(6)
У меня появился вопрос. Как бы сделать групповую обработку элементов. То есть группе элементов из списка Номенклатуры присваивать в РС значение виртуальной Группы?

19. TSAllea 05.08.22 08:19 Сейчас в теме

(6) может, подскажете, почему-то не отбирает
скрин

у группы установил признак дополнительной группы, в РС прописана связь
вызов ПолучитьСписокНоменклатурыПоДополнительнымГруппам отрабатывает и возвращает список номенклатуры
но не отображается на форме подбора

апд. вопрос решен. не то событие в расширении изменил

9. malikov_pro 1356 26.04.21 17:21 Сейчас в теме

(8) В форме списка номенклатуры сделать кнопку по которой брать выделенные строки, после открывать форму выбора группы, при выбранной группе добавлять/обновлять данные в ТЧ или РС.

10. user1302055 27.04.21 11:03 Сейчас в теме

(9) Благодарю за ответ!

11. user1622867 04.07.21 22:43 Сейчас в теме

Здравствуйте
Я совсем мало разбираюсь в 1С, но требуется вроде как именно тот функционал, который Вы описали в этой статье.
Можете подсказать, я правильно понял, что пользуясь этой статьей я смогу добавить один товар сразу в несколько разных "Групп списка" и при передаче данных на сайт этот товар будет сразу в нескольких разных категориях?

12. user1568297 22.11.21 10:59 Сейчас в теме

Здравствуйте, столкнулся с проблемой (аэ_ВызовСервера.ЭтоДополнительнаяГруппа - переменная не определенна) в модуле поставил галочку "Вызов сервера", и в каком модуле дописывается эта функция "Функция ПолучитьСписокНоменклатурыПоДополнительнымГруппам"?

13. malikov_pro 1356 22.11.21 14:55 Сейчас в теме

(12) аэ_ВызовСервера - общий модуль, проверьте что он есть в ваше конфигурации или расширении, в нем должна быть экспортная функция ЭтоДополнительнаяГруппа()

"ПолучитьСписокНоменклатурыПоДополнительнымГруппам()" - можете в том же аэ_ВызовСервера

14. malikov_pro 1356 22.11.21 14:56 Сейчас в теме

(11) с помощью разработки можете указать несколько групп для одной номенклатуры, чтобы это появилось на сайте нужно дописывать выгрузку.

15. user1670217 01.02.22 10:02 Сейчас в теме

Здравствуйте, а можно узнать, как именно нужно дописывать выгрузку на сайт? Опыта с таким функционалом нету вообще, хотелось бы понять, где вообще нужно найти алгоритм выгрузки и примерно понять как и что нужно дописать

16. malikov_pro 1356 01.02.22 14:57 Сейчас в теме

(15) Смотря на какой сайт и по какому протоколу, как пример можете разобрать битриксовый модуль. https://1c.1c-bitrix.ru/ecommerce/download.php?section=144110

17. TSAllea 02.08.22 08:23 Сейчас в теме

(16)
1. на последнем скрине группа aliexpress у Вас раскрывается (плюсик на скрине). поддерживается иерархия? то есть в алиэкспресс есть подгруппы?
2. один элемент может входить в несколько групп?
апд. второй вопрос снят - невнимательно прочел описание

18. malikov_pro 1356 02.08.22 22:05 Сейчас в теме

(17) 1. Это типовые группы в УТ.

Для отправки сообщения требуется регистрация/авторизация

Автор:

Александр Маликов (malikov_pro)

Рейтинг: 1356

Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.

Публикация:

№ 1297646

Создание 23.09.20 11:20

Обновление 26.10.20 02:37

Статистика:

Просмотры 6192

Загрузки 0

Рейтинг 9

Комментарии 19

Характеристики:

Код открыт Да

Рубрики Адаптация типовых решений

Кому Программист

Тип файла Нет файла

Платформа 1С:Предприятие 8

Конфигурация 1С:Управление торговлей 11

Операционная система Не имеет значения

Страна Россия

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Управленческий учет

Доступ к файлу Бесплатно (free)

Несколько групп для одной номенклатуры в УТ 11

Вводные

Реализация

Итог

См. также

Журнал

База знаний

Лаборатория

Анализ & Управление

Сопровождение 1С

Корпоративные решения

Обучение

Маркетплейс

Проектный офис

Мероприятия

Видеозаписи

Биржа заказов

Форум

Мерч

О компании