Динамическая расшифровка СКД (на примере отчета)

08.12.20

Разработка - СКД

Предлагаю Вашему неподкупному вниманию вариант более-менее унифицированной реализации динамически формирующейся расшифровки СКД на примере простейшего отчета для конфигурации УТ 11.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование SM По подписке [?] Купить один файл
Отчет по продажам (пример динамической расшифровки СКД)
.erf 24,29Kb
31
31
1 SM
Скачать Купить за 1 850 руб.

Особенность данной реализации состоит в том, чтобы при формировании отчета по структуре получаемых настроек компоновщика динамически добавлялись соответствующие параметры расшифровки в определенные области макета полей СКД по которым и нужна расшифровка. И уже потом, в обработчике расшифровки табличного документа без особых усилий из расшифровываемого поля вытаскиваются все необходимые данные для формирования отбора отчета расшифровки, который откроется в новом окне. Такой приёмчик особенно сгодится для расшифровки показателей детальных записей.

А теперь, немножко поподробнее. Отчет для примера был написан на платформе 8.3.16.1063 в конфигурации Управление торговлей (11.4.11.106). В схеме компоновки данных примера добавлены два набора данных: "Продажи" и "Поступления" (тексты запросов из примера, если кому вдруг станет интересно, находятся в самом конце).

На вкладке Макеты, добавлены макеты соответствующих полей, в данном случае это Количество, Сумма и КоличествоПоступления. Заполненные области для них показаны на скрине:

Далее, в процедуре ПриКомпоновкеРезультата() перед компоновкой макета эти расшифровки областей макетов полей соответствущим образом дозаполняются, и вот тут-то и происходит основное волшебство! Заполнять их можно чем Душе угодно! Но в данном случае из структуры настроек с помощью процедуры ДобавитьПолеВРасшифровку() поля группировок и выбранных полей кроме исключаемых превращаются, абра-кадабра, в параметры расшифровок областей макетов полей, и, чтобы фокус до конца удался, сим-салабим, в вычисляемые поля, благо недоступные из пользовательского режима. Таким образом, после выполнения отчета, значения выражений вычисляемых полей появляются в значениях параметров полей данных расшифровки, которые и используются в событии обработки расшифровки табличного документа для создания настроек отчета расшифровки различной сложности.

Вот и я вновь не поскупился, и для увлекательности примера добавил в отчет ещё одну СКД "Расшифровка по документам" и разместил её во вложенных схемах. На самом деле, в данном случае, это не важно где находится СКД, можно было и нативно поместить, в макеты отчета рядом с основным СКД.

Итак, дабы не прослыть жадинкой и не желая быть голословным, ниже оставлю код из модуля объекта отчета:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	Настройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	// ДОБАВЛЕНИЕ ПОЛЕЙ ДЛЯ РАСШИФРОВКИ ПО ДОКУМЕНТАМ - Количество
	ИмяПоляМакета = "Количество";
	ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ПараметрыДанных.ПоДокументамПродаж", "Истина", "Истина");
	ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ЭтоГруппировка", , "Ложь", "Истина");
	ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, Настройки, "КоличествоПоступления");
	
	// ДОБАВЛЕНИЕ ПОЛЕЙ ДЛЯ РАСШИФРОВКИ ПО ДОКУМЕНТАМ - Сумма
	ИмяПоляМакета = "Сумма";
	ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ПараметрыДанных.ПоДокументамПродаж", "Истина", "Истина");
	ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ЭтоГруппировка", , "Ложь", "Истина");
	ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, Настройки, "КоличествоПоступления");
		
	// ДОБАВЛЕНИЕ ПОЛЕЙ ДЛЯ РАСШИФРОВКИ ПО ДОКУМЕНТАМ - КоличествоПоступления (есть только в варианте "Кросс-отчет")
	Если Настройки.ДополнительныеСвойства.Свойство("КлючТекущегоВарианта")
	И Настройки.ДополнительныеСвойства.КлючТекущегоВарианта = "КроссОтчет" Тогда
		ИмяПоляМакета = "КоличествоПоступления";
		ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ПараметрыДанных.ПоДокументамПоступлений", "Истина", "Истина");
		ДобавитьПолеВРасшифровку(ИмяПоляМакета, "ЭтоГруппировка", , "Ложь", "Истина");
		ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, Настройки, "Склад, Контрагент, КоличествоПоступления");
	КонецЕсли;
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
	
	// Есть в СКД такая неявная загагулинка,
	// если вдруг будет наложен отбор в приемнике связи,
	// то система делает связь "Внутренняя" (ВНУТРЕННЕЕ СОЕДИНЕНИЕ)
	//Для Каждого Связь Из МакетКомпоновки.СвязиНаборовДанных Цикл
	//	Связь.ТипСвязи = ТипСвязиНаборовДанныхКомпоновкиДанных.Внешняя;
	//КонецЦикла;
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки, Истина);
	
	ДокументРезультат.Очистить();
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	// ++ вывод построчно
	//ПроцессорВывода.НачатьВывод();
	//ЭлементРезультата = ПроцессорКомпоновки.Следующий();
	//Пока ЭлементРезультата <> Неопределено Цикл
	//	ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	//	ЭлементРезультата = ПроцессорКомпоновки.Следующий();
	//КонецЦикла;
	//ПроцессорВывода.ЗакончитьВывод();	
	// -- вывод построчно
	
	// Объединяет шапку с одинаковыми заголовками рядом
	ОбработатьЗаголовки(ДокументРезультат);
	
	// Чтобы можно было в дальнейшем из формы обращаться к именно той СКД по которой был сформирован отчет
	КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить("АдресСКД",
		ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных, Новый УникальныйИдентификатор));
	
КонецПроцедуры

Процедура ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, Структура, Знач ИсключаемыПоля = "")
	
	Если ТипЗнч(ИсключаемыПоля) = Тип("Строка") Тогда
		ИсключаемыПоля = Новый Структура(ИсключаемыПоля);
	КонецЕсли;
	
	Если ТипЗнч(Структура) = Тип("НастройкиКомпоновкиДанных")
	Или ТипЗнч(Структура) = Тип("ГруппировкаКомпоновкиДанных")
	Или ТипЗнч(Структура) = Тип("ГруппировкаТаблицыКомпоновкиДанных") Тогда
		Для Каждого ВыбранноеПоле Из Структура.Выбор.Элементы Цикл
			Если ВыбранноеПоле.Использование
			И ТипЗнч(ВыбранноеПоле) <> Тип("АвтоВыбранноеПолеКомпоновкиДанных")
			И ТипЗнч(ВыбранноеПоле) <> Тип("ГруппаВыбранныхПолейКомпоновкиДанных")
			// ++ Если вдруг нужно будет ресурс добавить в отбор для расшифровки, то тут комментируем
			И СхемаКомпоновкиДанных.ПоляИтога.Найти(Строка(ВыбранноеПоле.Поле)) = Неопределено
			// -- и в ИсключаемыеПоля добавляем вручную по каждому случаю
			И Не ИсключаемыПоля.Свойство(Строка(ВыбранноеПоле.Поле)) Тогда
				ДобавитьПолеВРасшифровку(ИмяПоляМакета, Строка(ВыбранноеПоле.Поле));
			КонецЕсли;
		КонецЦикла;
		ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, Структура.Структура, ИсключаемыПоля);
	Иначе
		Для Каждого ЭлСтруктуры Из Структура Цикл
			Если ТипЗнч(ЭлСтруктуры) = Тип("ТаблицаКомпоновкиДанных") Тогда
				ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, ЭлСтруктуры.Строки, ИсключаемыПоля);
				ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, ЭлСтруктуры.Колонки, ИсключаемыПоля);
			Иначе
				Для Каждого ПолеГруппировки Из ЭлСтруктуры.ПоляГруппировки.Элементы Цикл
					Если ПолеГруппировки.Использование
					// ++ Если вдруг нужно будет ресурс добавить в отбор для расшифровки, то тут комментируем
					И СхемаКомпоновкиДанных.ПоляИтога.Найти(Строка(ПолеГруппировки.Поле)) = Неопределено
					// -- и в ИсключаемыеПоля добавляем вручную по каждому случаю
					И Не ИсключаемыПоля.Свойство(Строка(ПолеГруппировки.Поле)) Тогда
						ДобавитьПолеВРасшифровку(ИмяПоляМакета, Строка(ПолеГруппировки.Поле));
					КонецЕсли;
				КонецЦикла;
				ДобавитьИзСтруктурыНастроекПоляДляРасшифровки(ИмяПоляМакета, ЭлСтруктуры, ИсключаемыПоля);
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;

КонецПроцедуры

Процедура ДобавитьПолеВРасшифровку(ИмяПоляМакета, ИмяПоля, ВыражениеПоляРасшифровки = "", ВыражениеПоля = "", ВыражениеИтога = "", ТипЗначенияПоля = "")
	
	МакетПоля = СхемаКомпоновкиДанных.МакетыПолей.Найти(ИмяПоляМакета);
	Если МакетПоля <> Неопределено Тогда
		Макет = СхемаКомпоновкиДанных.Макеты.Найти(МакетПоля.Макет);
		ПараметрыРасшифровки = Макет.Параметры.Найти("Расшифровка");
		Если ПараметрыРасшифровки <> Неопределено Тогда
			ИмяПоляРасшифровки = "р"+ИмяПоля;
			Если СхемаКомпоновкиДанных.ВычисляемыеПоля.Найти(ИмяПоляРасшифровки) = Неопределено Тогда
				НовоеПоле = СхемаКомпоновкиДанных.ВычисляемыеПоля.Добавить();
				НовоеПоле.ПутьКДанным = ИмяПоляРасшифровки;
				НовоеПоле.Выражение = ?(ПустаяСтрока(ВыражениеПоля), ИмяПоля, ВыражениеПоля);
				НовоеПоле.ТипЗначения = Новый ОписаниеТипов(ТипЗначенияПоля);
				НовоеПоле.ОграничениеИспользования.Группировка = Ложь;
				НовоеПоле.ОграничениеИспользования.Поле = Ложь;
				НовоеПоле.ОграничениеИспользования.Порядок = Ложь;
				НовоеПоле.ОграничениеИспользования.Условие = Ложь;
				НовоеПоле = СхемаКомпоновкиДанных.ПоляИтога.Добавить();
				НовоеПоле.ПутьКДанным = ИмяПоляРасшифровки;
				НовоеПоле.Выражение = ?(ПустаяСтрока(ВыражениеИтога), "Неопределено", ВыражениеИтога);
			КонецЕсли;
			Если ПараметрыРасшифровки.ВыраженияПолей.Найти(ИмяПоляРасшифровки) = Неопределено Тогда
				Параметр = ПараметрыРасшифровки.ВыраженияПолей.Добавить();
				Параметр.Поле = ИмяПоляРасшифровки;
				Параметр.Выражение = ?(ПустаяСтрока(ВыражениеПоляРасшифровки), ИмяПоляРасшифровки, ВыражениеПоляРасшифровки);
				// Если указано ВыражениеПоляРасшифровки, то в обработке расшифровки как в случае с Детальными записями
				// так и с Группировкой всегда будет доступно одинаковое значение этого выражения
			КонецЕсли;			
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

Ладушки, так уж и быть, уболтали ;) ловите заодно и код из модуля формы отчета:

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриЗагрузкеВариантаНаСервере(Настройки)
	
	Отчет.КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить("КлючТекущегоВарианта", КлючТекущегоВарианта);
	
	// Настройки по-умолчанию
	Если КлючТекущегоВарианта = "Основной" Тогда
				
	ИначеЕсли КлючТекущегоВарианта = "КроссОтчет" Тогда
				
	КонецЕсли;	
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовФормы

&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
	
	Перем ВыбранноеДействие;
	Перем ПараметрыВыбранногоДействия;
	
	СтандартнаяОбработка = Ложь;
	
	ОбработкаРасшифровки =  Новый ОбработкаРасшифровкиКомпоновкиДанных(АдресДанныхРасшифровки, Новый ИсточникДоступныхНастроекКомпоновкиДанных(Отчет));
	
	ДоступныеДействия = Новый Массив;
	ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
	ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.Расшифровать);
	ДополнительныеПунктыМеню = Новый СписокЗначений;
	ДополнительныеПунктыМеню.Добавить("РасшифроватьПоДокументам", "Расшифровать по документам");
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ОбработкаВыбораДействияРасшифровки", ЭтотОбъект, Расшифровка);
	ОбработкаРасшифровки.ПоказатьВыборДействия(ОписаниеОповещения, Расшифровка, ДоступныеДействия, ДополнительныеПунктыМеню, Истина);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаВыбораДействияРасшифровки(ВыбранноеДействие, ПараметрыВыбранногоДействия, Расшифровка) Экспорт
	
	Если ВыбранноеДействие <> ДействиеОбработкиРасшифровкиКомпоновкиДанных.Нет Тогда
		
		Если ВыбранноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
			ПоказатьЗначение(, ПараметрыВыбранногоДействия);
		ИначеЕсли ВыбранноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.Расшифровать Или ВыбранноеДействие = "РасшифроватьПоДокументам" Тогда
			Если ВыбранноеДействие = "РасшифроватьПоДокументам" Тогда
				ПараметрыФормы = ОбработатьРасшифровкуПоДокументамИПолучитьПараметрыДляОткрытияФормыРасшифровки(Расшифровка);
			Иначе // аналог платформенной обработки расшифровки, как если бы СтандартнаяОбработка = Истина;
				ПараметрыФормы = ОбработатьРасшифровкуИПолучитьПараметрыДляОткрытияФормыРасшифровки(Расшифровка, ПараметрыВыбранногоДействия);
			КонецЕсли;			
			ОткрытьФорму("ВнешнийОтчет.Продажи_ПримерДинамическойРасшифровкиСКД.Форма.ФормаРасшифровки", ПараметрыФормы, ВладелецФормы, Новый УникальныйИдентификатор);
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

&НаСервере
Функция ОбработатьРасшифровкуИПолучитьПараметрыДляОткрытияФормыРасшифровки(Расшифровка, НастройкиРасшифровки)
			
	ДанныеРасшифровки = ПолучитьИзВременногоХранилища(АдресДанныхРасшифровки);
	
	Если Отчет.КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Свойство("АдресСКД") Тогда
		// СКД из ПриКомпоновкеРезультата()
		АдресСКДРасшифровки = Отчет.КомпоновщикНастроек.Настройки.ДополнительныеСвойства.АдресСКД;
	КонецЕсли;
	
	Если Не ЗначениеЗаполнено(АдресСКДРасшифровки) Тогда
		ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
		СхемаКомпоновкиДанных = ОтчетОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
		АдресСКДРасшифровки = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных, УникальныйИдентификатор);
	Иначе
		СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСКДРасшифровки);	
	КонецЕсли;
	
	НастройкиОтчета = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
		
	// Вывод поля группировки
	ЭлементГруппировки = НастройкиРасшифровки.Структура[0];
	ВыбранноеПоле = ЭлементГруппировки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
	ВыбранноеПоле.Поле = ЭлементГруппировки.ПоляГруппировки.Элементы[0].Поле;
	
	// Вывод поля показателя
	ЭлементРасшифровки = ДанныеРасшифровки.Элементы.Получить(Расшифровка);
	ВыбранноеПоле = ЭлементГруппировки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
	ВыбранноеПоле.Поле = Новый ПолеКомпоновкиДанных(ЭлементРасшифровки.ПолучитьПоля()[0].Поле);
	
	// Параметры
	ЗаполнитьЭлементыНастроек(НастройкиРасшифровки.ПараметрыДанных, НастройкиОтчета.ПараметрыДанных);
	
	// Отбор общий
	СкопироватьЭлементыНастроек(НастройкиРасшифровки.Отбор, НастройкиОтчета.Отбор, Истина);
	
	// Отбор по группировке
	ПоляДляОтбораПоГруппировке = ПолучитьПоляДляОтбораПоГруппировке(ЭлементРасшифровки);
	Для Каждого ПолеДляОтбораПоГруппировке Из ПоляДляОтбораПоГруппировке Цикл
		ЗаполнитьЭлементОтбора(НастройкиРасшифровки.Отбор, ПолеДляОтбораПоГруппировке.Поле, ПолеДляОтбораПоГруппировке.Значение);
	КонецЦикла;
		
	ПараметрыФормы = СформироватьРезультатИПолучитьПараметрыДляОткрытияФормыРасшифровки(СхемаКомпоновкиДанных, НастройкиРасшифровки, УникальныйИдентификатор);
	ПараметрыФормы.Вставить("АдресСКД", АдресСКДРасшифровки);
	ПараметрыФормы.Вставить("Заголовок", "Расшифровка");
	
	Возврат ПараметрыФормы;
	
КонецФункции

&НаСервере
Функция ОбработатьРасшифровкуПоДокументамИПолучитьПараметрыДляОткрытияФормыРасшифровки(Расшифровка)	
	
	ДанныеРасшифровки = ПолучитьИзВременногоХранилища(АдресДанныхРасшифровки);
	
	Если Не ЗначениеЗаполнено(АдресСКДРасшифровкиПоДокументам) Тогда
		ОтчетОбъект = РеквизитФормыВЗначение("Отчет"); // СКД для расшифровки по документам находится во вложенных схемах
		СхемаКомпоновкиДанных = ОтчетОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных").ВложенныеСхемыКомпоновкиДанных["РасшифровкаПоДокументам"].Схема;
		АдресСКДРасшифровкиПоДокументам = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных, УникальныйИдентификатор);
	Иначе
		СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСКДРасшифровкиПоДокументам);
	КонецЕсли;
	
	НастройкиОтчета = Отчет.КомпоновщикНастроек.ПолучитьНастройки();
	
	КомпоновщикНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
	ИсточникДоступныхНастроек = Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных);
	КомпоновщикНастроек.Инициализировать(ИсточникДоступныхНастроек);
	КомпоновщикНастроек.ЗагрузитьНастройки(СхемаКомпоновкиДанных.НастройкиПоУмолчанию);
	НастройкиРасшифровки = КомпоновщикНастроек.ПолучитьНастройки();
	
	// Параметры
	ЗаполнитьЭлементыНастроек(НастройкиРасшифровки.ПараметрыДанных, НастройкиОтчета.ПараметрыДанных);
	
	// Отбор общий
	СкопироватьЭлементыНастроек(НастройкиРасшифровки.Отбор, НастройкиОтчета.Отбор, Истина);
	
	// Отбор по группировке с доп. расшифровкой
	ЭлементРасшифровки = ДанныеРасшифровки.Элементы.Получить(Расшифровка);
	ПоляДляОтбора = ЭлементРасшифровки.ПолучитьПоля();
	Для Каждого ПолеДляОтбора Из ПоляДляОтбора Цикл
		
		// Первым полем всегда должно идти поле по которому идет расшифровка (поле показателя)
		Если ПоляДляОтбора.Индекс(ПолеДляОтбора) = 0 Тогда
			Продолжить;
		КонецЕсли;
		
		Если СтрРазделить(ПолеДляОтбора.Поле,".")[0] = "рПараметрыДанных" Тогда
			ПраметрДанных = НастройкиРасшифровки.ПараметрыДанных.Элементы.Найти(СтрРазделить(ПолеДляОтбора.Поле,".")[1]);
			ПраметрДанных.Использование = Истина;
			ПраметрДанных.Значение = ПолеДляОтбора.Значение;
			Продолжить;
		КонецЕсли;
		
		Если ПолеДляОтбора.Поле = "рЭтоГруппировка" И Не ПолеДляОтбора.Значение Тогда
			Продолжить;
		ИначеЕсли ПолеДляОтбора.Поле = "рЭтоГруппировка" И ПолеДляОтбора.Значение Тогда
			ПоляДляОтбораПоГруппировке = ПолучитьПоляДляОтбораПоГруппировке(ЭлементРасшифровки);
			Для Каждого ПолеДляОтбораПоГруппировке Из ПоляДляОтбораПоГруппировке Цикл
				ЗаполнитьЭлементОтбора(НастройкиРасшифровки.Отбор, ПолеДляОтбораПоГруппировке.Поле, ПолеДляОтбораПоГруппировке.Значение);
			КонецЦикла;
			Прервать;
		КонецЕсли;
		
		ЗаполнитьЭлементОтбора(НастройкиРасшифровки.Отбор, Сред(ПолеДляОтбора.Поле, 2), ПолеДляОтбора.Значение);
		
	КонецЦикла;
	
	ПараметрыФормы = СформироватьРезультатИПолучитьПараметрыДляОткрытияФормыРасшифровки(СхемаКомпоновкиДанных, НастройкиРасшифровки, УникальныйИдентификатор);
	ПараметрыФормы.Вставить("АдресСКД", АдресСКДРасшифровкиПоДокументам);
	ПараметрыФормы.Вставить("Заголовок", "Расшифровка по документам");
	
	Возврат ПараметрыФормы;
	
КонецФункции

&НаСервереБезКонтекста
Функция СформироватьРезультатИПолучитьПараметрыДляОткрытияФормыРасшифровки(СхемаКомпоновкиДанных, НастройкиРасшифровки, УникальныйИдентификатор)
	
	ДанныеРасшифровки = Неопределено;
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиРасшифровки, ДанныеРасшифровки);
		
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки, Истина);
	
	Результат = Новый ТабличныйДокумент;
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(Результат);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
	// ++ для отладки
	//РезультатТЗ = Новый ТаблицаЗначений;
	//ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	//ПроцессорВывода.УстановитьОбъект(РезультатТЗ);
	//ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	// -- для отладки
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("Результат", Результат);
	ПараметрыФормы.Вставить("АдресДанныхРасшифровки", ПоместитьВоВременноеХранилище(ДанныеРасшифровки, УникальныйИдентификатор));
	
	Возврат ПараметрыФормы;
	
КонецФункции

&НаСервереБезКонтекста
Функция ПолучитьПоляДляОтбораПоГруппировке(ЭлементРасшифровки, Результат = Неопределено)
	
	Если Результат = Неопределено Тогда
		Результат = Новый ("ЗначенияПолейРасшифровкиКомпоновкиДанных");
	КонецЕсли;
	
	РодителиЭлементаРасшифровки = ЭлементРасшифровки.ПолучитьРодителей();
	Если Не РодителиЭлементаРасшифровки.Количество() Тогда
		Возврат Результат;
	КонецЕсли;
	
	РодительЭлементаРасшифровки = РодителиЭлементаРасшифровки[0];
	Если ТипЗнч(РодительЭлементаРасшифровки) <> Тип("ЭлементРасшифровкиКомпоновкиДанныхГруппировка") Тогда
		Для Каждого ПолеДляОтбора Из РодительЭлементаРасшифровки.ПолучитьПоля() Цикл
			ЗаполнитьЗначенияСвойств(Результат.Добавить(), ПолеДляОтбора);
		КонецЦикла;
	КонецЕсли;
	
	Возврат ПолучитьПоляДляОтбораПоГруппировке(РодительЭлементаРасшифровки, Результат); 
	
КонецФункции

&НаСервереБезКонтекста
Процедура ЗаполнитьЭлементОтбора(Отбор, ИмяПоля, ЗначениеПоля, ДобавлятьЕслиНеНайден = Истина)
	
	ЕстьЭлементОтбора = Ложь;
	Для Каждого ЭлементОтбора Из Отбор.Элементы Цикл
		Если Строка(ЭлементОтбора.ЛевоеЗначение) = ИмяПоля Тогда
			ЭлементОтбора.Использование = ЗначениеПоля <> Неопределено; //ЗначениеЗаполнено(ЗначениеПоля);
			ЭлементОтбора.ПравоеЗначение = ЗначениеПоля;
			ЕстьЭлементОтбора = Истина;
			Прервать;
		КонецЕсли;
	КонецЦикла;
	Если Не ЕстьЭлементОтбора И ДобавлятьЕслиНеНайден Тогда
		ЭлементОтбора = Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
		ЭлементОтбора.Использование = ЗначениеПоля <> Неопределено;
		ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ИмяПоля);
		ЭлементОтбора.ПравоеЗначение = ЗначениеПоля;
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура СкопироватьЭлементыНастроек(ПриемникЗначения, ИсточникЗначения, ОчищатьПриемник = Ложь)
    
    Если ТипЗнч(ИсточникЗначения) = Тип("УсловноеОформлениеКомпоновкиДанных")
        ИЛИ ТипЗнч(ИсточникЗначения) = Тип("ВариантыПользовательскогоПоляВыборКомпоновкиДанных")
        ИЛИ ТипЗнч(ИсточникЗначения) = Тип("ОформляемыеПоляКомпоновкиДанных")
        ИЛИ ТипЗнч(ИсточникЗначения) = Тип("ЗначенияПараметровДанныхКомпоновкиДанных") Тогда
        СоздаватьПоТипу = Ложь;
    Иначе
        СоздаватьПоТипу = Истина;
    КонецЕсли;
    
    ПриемникЭлементов = ПриемникЗначения.Элементы;
    Если ОчищатьПриемник Тогда
        ПриемникЭлементов.Очистить();
    КонецЕсли;
    ИсточникЭлементов = ИсточникЗначения.Элементы;
    
    Для каждого ЭлементИсточник Из ИсточникЭлементов Цикл
        
        Если ТипЗнч(ЭлементИсточник) = Тип("ЭлементПорядкаКомпоновкиДанных") Тогда
            Индекс = ИсточникЭлементов.Индекс(ЭлементИсточник); // Элементы порядка добавляем в начало
            ЭлементПриемник = ПриемникЭлементов.Вставить(Индекс, ТипЗнч(ЭлементИсточник));
        Иначе
			Если СоздаватьПоТипу Тогда
                ЭлементПриемник = ПриемникЭлементов.Добавить(ТипЗнч(ЭлементИсточник));
            Иначе
                ЭлементПриемник = ПриемникЭлементов.Добавить();
			КонецЕсли;
			
        КонецЕсли;
        
        ЗаполнитьЗначенияСвойств(ЭлементПриемник, ЭлементИсточник);
        
        // В некоторых коллекциях необходимо заполнить другие коллекции

        Если ТипЗнч(ИсточникЭлементов) = Тип("КоллекцияЭлементовУсловногоОформленияКомпоновкиДанных") Тогда
            ЗаполнитьЭлементыНастроек(ЭлементПриемник.Поля, ЭлементИсточник.Поля);
            ЗаполнитьЭлементыНастроек(ЭлементПриемник.Отбор, ЭлементИсточник.Отбор);
            ЗаполнитьЭлементыНастроек(ЭлементПриемник.Оформление, ЭлементИсточник.Оформление); 
        ИначеЕсли ТипЗнч(ИсточникЭлементов) = Тип("КоллекцияВариантовПользовательскогоПоляВыборКомпоновкиДанных") Тогда
            ЗаполнитьЭлементыНастроек(ЭлементПриемник.Отбор, ЭлементИсточник.Отбор);
        КонецЕсли;
        
        // В некоторых элементах коллекции необходимо заполнить другие коллекции

        Если ТипЗнч(ЭлементИсточник) = Тип("ГруппаЭлементовОтбораКомпоновкиДанных") Тогда
            ЗаполнитьЭлементыНастроек(ЭлементПриемник, ЭлементИсточник);
        ИначеЕсли ТипЗнч(ЭлементИсточник) = Тип("ГруппаВыбранныхПолейКомпоновкиДанных") Тогда
            ЗаполнитьЭлементыНастроек(ЭлементПриемник, ЭлементИсточник);
        ИначеЕсли ТипЗнч(ЭлементИсточник) = Тип("ПользовательскоеПолеВыборКомпоновкиДанных") Тогда
            ЗаполнитьЭлементыНастроек(ЭлементПриемник.Варианты, ЭлементИсточник.Варианты);
        ИначеЕсли ТипЗнч(ЭлементИсточник) = Тип("ПользовательскоеПолеВыражениеКомпоновкиДанных") Тогда
            ЭлементПриемник.УстановитьВыражениеДетальныхЗаписей (ЭлементИсточник.ПолучитьВыражениеДетальныхЗаписей());
            ЭлементПриемник.УстановитьВыражениеИтоговыхЗаписей(ЭлементИсточник.ПолучитьВыражениеИтоговыхЗаписей());
            ЭлементПриемник.УстановитьПредставлениеВыраженияДетальныхЗаписей(ЭлементИсточник.ПолучитьПредставлениеВыраженияДетальныхЗаписей());
            ЭлементПриемник.УстановитьПредставлениеВыраженияИтоговыхЗаписей(ЭлементИсточник.ПолучитьПредставлениеВыраженияИтоговыхЗаписей());
        КонецЕсли;
        
    КонецЦикла;
    
КонецПроцедуры

&НаСервереБезКонтекста
Процедура ЗаполнитьЭлементыНастроек(ПриемникЗначения, ИсточникЗначения, ПервыйУровень = Неопределено) Экспорт
    
    Если ТипЗнч(ПриемникЗначения) = Тип("КоллекцияЗначенийПараметровКомпоновкиДанных") Тогда
        КоллекцияЗначений = ИсточникЗначения;
    Иначе
        КоллекцияЗначений = ИсточникЗначения.Элементы;
    КонецЕсли;
    
    Для каждого ЭлементИсточник Из КоллекцияЗначений Цикл
        Если ПервыйУровень = Неопределено Тогда
            ЭлементПриемник = ПриемникЗначения.НайтиЗначениеПараметра(ЭлементИсточник.Параметр);
        Иначе
            ЭлементПриемник = ПервыйУровень.НайтиЗначениеПараметра(ЭлементИсточник.Параметр);
        КонецЕсли;
        Если ЭлементПриемник = Неопределено Тогда
            Продолжить;
        КонецЕсли;
        ЗаполнитьЗначенияСвойств(ЭлементПриемник, ЭлементИсточник);
        Если ТипЗнч(ЭлементИсточник) = Тип("ЗначениеПараметраКомпоновкиДанных") Тогда
            Если ЭлементИсточник.ЗначенияВложенныхПараметров.Количество() <> 0 Тогда
                ЗаполнитьЭлементыНастроек(ЭлементПриемник.ЗначенияВложенныхПараметров, ЭлементИсточник.ЗначенияВложенныхПараметров, ПриемникЗначения);
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
    
КонецПроцедуры

#КонецОбласти

Даже модуль формы расшифровки для вас обнажу, я сегодня добрый:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("Заголовок") Тогда
		Заголовок = Параметры.Заголовок;
	КонецЕсли;
	
	Если Параметры.Свойство("Результат") Тогда
		Результат = Параметры.Результат;
	КонецЕсли;
	
	Если Параметры.Свойство("АдресСКД") Тогда
		АдресСКД = Параметры.АдресСКД;
	КонецЕсли;
	
	Если Параметры.Свойство("АдресДанныхРасшифровки") Тогда
		АдресДанныхРасшифровки = Параметры.АдресДанныхРасшифровки;
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
	
	Перем ВыбранноеДействие;
	Перем ПараметрыВыбранногоДействия;
	
	СтандартнаяОбработка = Ложь;
	
	ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(АдресДанныхРасшифровки, Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСКД));
	
	ДоступныеДействия = Новый Массив;
	ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
		
	ОбработкаРасшифровки.ВыбратьДействие(Расшифровка, ВыбранноеДействие, ПараметрыВыбранногоДействия, ДоступныеДействия, , Истина);
	
	Если ВыбранноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
		ОткрытьЗначение(ПараметрыВыбранногоДействия);
	КонецЕсли;
	
КонецПроцедуры

А в целом, внутренности формы отчета и формы расшифровки выглядят так:

Текст запроса набора данных "Продажи":

ВЫБРАТЬ
	Итоговая.Дата КАК Дата,
	Итоговая.Организация КАК Организация,
	Итоговая.Склад КАК Склад,
	Итоговая.Контрагент КАК Контрагент,
	Итоговая.Номенклатура КАК Номенклатура,
	Итоговая.Характеристика КАК Характеристика,
	СУММА(Итоговая.Количество) КАК Количество,
	СУММА(Итоговая.Сумма) КАК Сумма
ИЗ
	(ВЫБРАТЬ
		НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ) КАК Дата,
		Документы.Организация КАК Организация,
		Документы.Склад КАК Склад,
		Документы.Контрагент КАК Контрагент,
		ДокументыТовары.Номенклатура КАК Номенклатура,
		ДокументыТовары.Характеристика КАК Характеристика,
		СУММА(ДокументыТовары.Количество) КАК Количество,
		СУММА(ДокументыТовары.Сумма) КАК Сумма
	ИЗ
		Документ.РеализацияТоваровУслуг КАК Документы
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг.Товары КАК ДокументыТовары
			ПО Документы.Ссылка = ДокументыТовары.Ссылка
	ГДЕ
		Документы.Проведен
	{ГДЕ
		(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}
	
	СГРУППИРОВАТЬ ПО
		НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
		Документы.Организация,
		Документы.Контрагент,
		ДокументыТовары.Номенклатура,
		ДокументыТовары.Характеристика,
		Документы.Склад
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
		Документы.Организация,
		Документы.Склад,
		"Розничный покупатель",
		ДокументыТовары.Номенклатура,
		ДокументыТовары.Характеристика,
		СУММА(ДокументыТовары.Количество),
		СУММА(ДокументыТовары.Сумма)
	ИЗ
		Документ.ОтчетОРозничныхПродажах КАК Документы
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ОтчетОРозничныхПродажах.Товары КАК ДокументыТовары
			ПО Документы.Ссылка = ДокументыТовары.Ссылка
	ГДЕ
		Документы.Проведен
	{ГДЕ
		(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}
	
	СГРУППИРОВАТЬ ПО
		НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
		Документы.Организация,
		ДокументыТовары.Номенклатура,
		ДокументыТовары.Характеристика,
		Документы.Склад) КАК Итоговая

СГРУППИРОВАТЬ ПО
	Итоговая.Характеристика,
	Итоговая.Склад,
	Итоговая.Дата,
	Итоговая.Организация,
	Итоговая.Контрагент,
	Итоговая.Номенклатура

Текст запроса набора данных "Поступления":

ВЫБРАТЬ
	НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ) КАК Дата,
	Документы.Организация КАК Организация,
	ДокументыТовары.Номенклатура КАК Номенклатура,
	ДокументыТовары.Характеристика КАК Характеристика,
	СУММА(ДокументыТовары.Количество) КАК КоличествоПоступления
ИЗ
	Документ.ПриобретениеТоваровУслуг КАК Документы
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриобретениеТоваровУслуг.Товары КАК ДокументыТовары
		ПО Документы.Ссылка = ДокументыТовары.Ссылка
ГДЕ
	Документы.Проведен
{ГДЕ
	(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}

СГРУППИРОВАТЬ ПО
	НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
	Документы.Организация,
	ДокументыТовары.Номенклатура,
	ДокументыТовары.Характеристика

Текст запроса набора данных в СКД "Расшифровка по документам":

ВЫБРАТЬ
	// ++ для отбора
	НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ) КАК Дата,
	Документы.Организация КАК Организация,
	Документы.Склад КАК Склад,
	Документы.Контрагент КАК Контрагент,
	ДокументыТовары.Номенклатура КАК Номенклатура,
	ДокументыТовары.Характеристика КАК Характеристика,
	// -- для отбора
	ДокументыТовары.Ссылка КАК Документ,
	ДокументыТовары.НомерСтроки КАК НомерСтроки,
	ДокументыТовары.Количество КАК Количество,
	ДокументыТовары.Сумма КАК Сумма
ИЗ
	Документ.РеализацияТоваровУслуг КАК Документы
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг.Товары КАК ДокументыТовары
		ПО Документы.Ссылка = ДокументыТовары.Ссылка
ГДЕ
	&ПоДокументамПродаж
	И Документы.Проведен
{ГДЕ
	(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	// ++ для отбора
	НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
	Документы.Организация,
	Документы.Склад,
	"Розничный покупатель",
	ДокументыТовары.Номенклатура,
	ДокументыТовары.Характеристика,
	// -- для отбора
	ДокументыТовары.Ссылка,
	ДокументыТовары.НомерСтроки,
	ДокументыТовары.Количество,
	ДокументыТовары.Сумма
ИЗ
	Документ.ОтчетОРозничныхПродажах КАК Документы
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ОтчетОРозничныхПродажах.Товары КАК ДокументыТовары
		ПО Документы.Ссылка = ДокументыТовары.Ссылка
ГДЕ
	&ПоДокументамПродаж
	И Документы.Проведен
{ГДЕ
	(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	// ++ для отбора
	НАЧАЛОПЕРИОДА(Документы.Дата, ДЕНЬ),
	Документы.Организация,
	null, // так отбор по складу будет игнорироваться
	null, // так отбор по контрагенту будет игнорироваться
	ДокументыТовары.Номенклатура,
	ДокументыТовары.Характеристика,
	// -- для отбора
	ДокументыТовары.Ссылка,
	ДокументыТовары.НомерСтроки,
	ДокументыТовары.Количество,
	ДокументыТовары.Сумма
ИЗ
	Документ.ПриобретениеТоваровУслуг КАК Документы
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриобретениеТоваровУслуг.Товары КАК ДокументыТовары
		ПО Документы.Ссылка = ДокументыТовары.Ссылка
ГДЕ
	&ПоДокументамПоступлений
	И Документы.Проведен
{ГДЕ
	(Документы.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания)}

На этом пока всё! За лаконичность описания сильно не обижаемся. Надеюсь что-нибудь из представленного кому-нибудь пригодится.

Счастья, добра, любви, удачи и 1С! :)

 

Универсальная расшифровка отчета динамическое заполнение параметров макета СКД унифицированная обработка расшифровки

См. также

Инструментарий разработчика Роли и права Запросы СКД Программист Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 руб.

02.09.2020    140910    772    391    

803

Запросы СКД Программист Стажер Система компоновки данных Россия Бесплатно (free)

Часто при разработке отчетов в СКД возникает ситуация, когда не совсем понятно, почему отчет выводит не те данные, которые нужны, либо не выводит вовсе. Возникает потребность увидеть конечный запрос, который формирует СКД. Как это сделать, рассмотрим в этой статье.

15.05.2024    5266    implecs_team    6    

44

Инструментарий разработчика СКД Программист Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    5605    43    obmailok    21    

78

Запросы СКД Программист Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2601    2    Yashazz    0    

33

СКД WEB-интеграция Программист Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    9491    21    John_d    25    

124

СКД Программист Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    6237    PROSTO-1C    13    

67
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. ovasiliev 6 12.12.20 10:38 Сейчас в теме
".. код из общего модуля отчета"
казнить нельзя помиловать?
Не, я не то что вредничаю, у меня просто препроцессор сломался в этом месте при компиляции.
2. mr_sav 93 13.12.20 14:03 Сейчас в теме
(1) Благодарю за наводку. Не знаю почему я так странно ошибся в орфографии, но имелось ввиду модуль объекта)). Поправил.
3. user1888420 08.02.23 19:15 Сейчас в теме
Здравствуйте!
Огромное спасибо за эту статью!

Небольшое замечание:
в процедуре ДобавитьПолеВРасшифровку я не понял, откуда Вы берёте ТипЗначенияПоля
я взял отсюда: НастройкиКомпоновки.ДоступныеПоляВыбора.Элементы -> Поле.Тип

И у меня без указания выражения в итогах не работает:
НовоеПоле.Выражение = ?(ПустаяСтрока(ВыражениеИтога), "Неопределено", ВыражениеИтога);
вместо "Неопределено" я подставил ИмяПоля
Оставьте свое сообщение