Структурирование доработок обработчиков событий объектов и форм

15.03.22

Разработка - Универсальные функции

В статье описан подход структурирования доработок обработчиков объектов и форм.

Для типовых решений большинство использует практику доработки поведения объектов с помощью подписок на события и доработки поведения форм с помощью переопределяемых модулей БСП. На этом не буду заострять внимание, положим, что вы так и реализуете доработки. Про переопределение в конфигурациях на БСП можно почитать, например, здесь.

Суть подхода в том, чтобы для каждого объекта или формы вынести все доработанные  обработчики в отдельные общие модули, для каждого объекта/формы свой модуль.
Имя модуля конструируется по определенному шаблону, так чтобы по имени объекта или формы можно было программно получить модуль. Это позволит не привязываться к конкретным именам и типам в коде и все обработчики вызывать единообразно.

Для форм предлагается шаблон - ПрефиксКонфигурации_ТипМетаданных_ИмяМетаданных_Форма_ИмяФормы,

Например, для формы "Справочник.Номенклатура.Форма.ФормаЭлемента", имя модуля получится "мк_Справочник_Номенклатура_Форма_ФормаЭлемента".

Для объектов шаблон имени модуля - ПрефиксКонфигурации_ТипМетаданных_ИмяМетаданных

И тогда для справочника "Номенклатура", имя модуля будет "мк_Справочник_Номенклатура".

Вызов самих обработчиков событий объектов будет выполнятся через соответствующий обработчик подписки на событие, напимер для справочников это общий модуль мк_СобытияСправочников. Вызов обработчиков событий форм будет вызываться через соответствующие методы общего модуля  мк_СобытияФорм, в этот модуль вызовы будут приходить из модуля МодификацияКонфигурацииПереопределяемый.

Схематично вызов для формы будет выглядеть так:

Ниже примеры кода для события справочника ПередЗаписью.

Общий обработчик объекта в модуле мк_СобытияСправочников

Процедура ПередЗаписью(Источник, Отказ) Экспорт

    Если Источник.ОбменДанными.Загрузка Тогда
        Возврат;
    КонецЕсли;

    // Определение общего модуля объекта.
    Модуль = ОбщийМодульОбъекта(Источник);

    // Параметры обработчиков.
    ПараметрыОбработчиков = ПараметрыОбработчиковОбъекта(Модуль);

    Если ПараметрыОбработчиков.ПередЗаписью Тогда
        Модуль.ПередЗаписью(Источник, Отказ);   
    КонецЕсли;  

КонецПроцедуры

Метод определение общего модуля:

Функция ОбщийМодульОбъекта(Источник)
	
	ТипИсточника = ТипЗнч(Источник);
	
	ИмяОбъекта = Метаданные.НайтиПоТипу(ТипИсточника).ПолноеИмя();
	Префикс = мк_ОбщегоНазначения.ПрефиксИмен();
	ИмяОбъекта = СтрЗаменить(ИмяОбъекта, ".", "_");
	ИмяМодуля = СтрШаблон("%1%2", Префикс, ИмяОбъекта);
	
	Модуль = ОбщийМодуль(ИмяМодуля);
	
	Возврат Модуль;

КонецФункции 

Метод определение параметров обработчиков объекта, который определит конкретные обработчики в модуле объекта:

Функция ПараметрыОбработчиковОбъекта(Модуль)

	ПараметрыОбработчиков = ПараметрыОбработчиковПоУмолчанию();
	
	Если Модуль = Неопределено Тогда
		Возврат ПараметрыОбработчиков;
	КонецЕсли;	
		
	Модуль.ОпределитьПараметрыОбработчиков(ПараметрыОбработчиков);
	
	Возврат ПараметрыОбработчиков; 

КонецФункции

// Инициализирует набор параметров, задающих флаги выполнения обработчиков.
//
// Возвращаемое значение:
//   Структура   - Обработчики, переопределенные для объекта.
//
Функция ПараметрыОбработчиковПоУмолчанию()
	
	ПараметрыОбработчиков = Новый Структура;
	
	ПараметрыОбработчиков.Вставить("ПередЗаписью", Ложь);
	ПараметрыОбработчиков.Вставить("ПриЗаписи", Ложь);
	
	ПараметрыОбработчиков.Вставить("ПередУдалением", Ложь);
	
	ПараметрыОбработчиков.Вставить("ОбработкаЗаполнения", Ложь);
	ПараметрыОбработчиков.Вставить("ОбработкаПроверкиЗаполнения", Ложь);
	
	ПараметрыОбработчиков.Вставить("ОбработкаПолученияПредставления", Ложь);
	ПараметрыОбработчиков.Вставить("ОбработкаПолученияФормы", Ложь);

	Возврат ПараметрыОбработчиков;

КонецФункции

 

Пример модуля модуля для справочника Номенклатура -  мк_Справочник_Номенклатура

// Инициализирует набор параметров, задающих флаги выполнения обработчиков.
//
// Параметры:
//  ПараметрыОбработчиков	 - Структура - Параметры обработчиков.
//
Процедура ОпределитьПараметрыОбработчиков(ПараметрыОбработчиков) Экспорт

	ПараметрыОбработчиков.Вставить("ПередЗаписью", Истина);

КонецПроцедуры

// Процедура - обработчик подписки на событие "ПередЗаписью".
//	См. "СправочникОбъект.ПередЗаписью" в синтакс-помощнике.
//
// Параметры:
//  Источник  - СправочникОбъект - Источник события.
//  Отказ  - Булево - Флаг отмены.
//
Процедура ПередЗаписью(Источник, Отказ) Экспорт
	
	ЗаполнитьИдентификатовAD(Источник);

КонецПроцедуры

 

Какие преимущества дает такой подход:

- Простота подключения новых объектов и новых обработчиков.

- Код получается более лучше структурирован. Все доработки объекта/формы собраны в одном модуле, проще ориентироваться в коде.

- Уменьшение конфликтов при совместной разработке.

 

Требования

  • Платформа 8.3.10 и выше.
  • Библиотека стандартных подсистем 2.4 и выше

Установка

Установите расширение или скопируйте объекты себе в конфигурацию.

 

Представленный подход реализован в виде расширения, исходники https://github.com/Bazil1c/events-handlers-1c

Обработчики адаптация подписки переопределяемый

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2670    0    John_d    8    

54

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4608    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3961    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8822    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16144    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7243    quazare    8    

109
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Cmapnep 18 16.03.22 09:46 Сейчас в теме
В методе ОбщийМодульОбъекта() используется поиск по метаданным
Для каждой открываемой формы это лишняя нагрузка
Метод лучше вынести в отдельный модуль с повторным использованием
2. Bazil 556 17.03.22 14:21 Сейчас в теме
(1) Да, пожалуй, так лучше.
Оставьте свое сообщение